Debian Codegraph @

src/libmpg123/synth_x86_64.S

raw
1 /*
2 synth_x86_64: SSE optimized synth for x86-64
3
4 copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1
5 see COPYING and AUTHORS files in distribution or http://mpg123.org
6 initially written by Taihei Monma
7 */
8
9 #include "x86_64_defs.h"
10 #include "mangle.h"
11
12 #ifdef IS_MSABI
13 /* short *window; */
14 #define ARG0 %r10
15 /* short *b0; */
16 #define ARG1 %rdx
17 /* short *samples; */
18 #define ARG2 %r8
19 /* int bo1; */
20 #define ARG3 %r9
21 #else
22 /* short *window; */
23 #define ARG0 %rdi
24 /* short *b0; */
25 #define ARG1 %rsi
26 /* short *samples; */
27 #define ARG2 %rdx
28 /* int bo1; */
29 #define ARG3 %rcx
30 #endif
31
32 #define XMMREG_CLIP %xmm15
33 #define XMMREG_MAX %xmm14 /* {32767, 32767, 32767, 32767} */
34 #define XMMREG_MIN %xmm13 /* {-32769, -32769, -32769, -32769} : not -32768 because SSE doesn't have "less than" comparison... */
35 #define XMMREG_FULL %xmm12 /* {0xFFFFFFFF, 0xFFFFFFFF, 0xFFFFFFFF, 0xFFFFFFFF} */
36
37 /*
38 int synth_1to1_x86_64_asm(short *window, short *b0, short *samples, int bo1);
39 return value: number of clipped samples
40 */
41
42 RODATA
43 ALIGN32
44 ASM_NAME(INT123_maxmin_x86_64):
45 .long 32767
46 .long 32767
47 .long 32767
48 .long 32767
49 .long -32769
50 .long -32769
51 .long -32769
52 .long -32769
53 .text
54 ALIGN16
55 .globl ASM_NAME(INT123_synth_1to1_x86_64_asm)
56 ASM_NAME(INT123_synth_1to1_x86_64_asm):
57 #ifdef IS_MSABI /* should save xmm6-15 */
58 movq %rcx, ARG0
59 subq $104, %rsp /* stack alignment + 6 xmm registers */
60 movaps %xmm6, (%rsp)
61 movaps %xmm7, 16(%rsp)
62 movaps %xmm12, 32(%rsp)
63 movaps %xmm13, 48(%rsp)
64 movaps %xmm14, 64(%rsp)
65 movaps %xmm15, 80(%rsp)
66 #endif
67
68 leaq ASM_NAME(INT123_maxmin_x86_64)(%rip), %rax
69 movaps (%rax), XMMREG_MAX
70 movaps 16(%rax), XMMREG_MIN
71 pxor XMMREG_CLIP, XMMREG_CLIP
72 pcmpeqd XMMREG_FULL, XMMREG_FULL
73
74 andq $0xf, ARG3
75 shlq $1, ARG3
76 leaq 32(ARG0), ARG0
77 subq ARG3, ARG0
78
79 movl $4, %ecx
80
81 ALIGN16
82 1:
83 movups (ARG0), %xmm0
84 movups 16(ARG0), %xmm1
85 movups 64(ARG0), %xmm2
86 movups 80(ARG0), %xmm3
87 movups 128(ARG0), %xmm4
88 movups 144(ARG0), %xmm5
89 movups 192(ARG0), %xmm6
90 movups 208(ARG0), %xmm7
91 pmaddwd (ARG1), %xmm0
92 pmaddwd 16(ARG1), %xmm1
93 pmaddwd 32(ARG1), %xmm2
94 pmaddwd 48(ARG1), %xmm3
95 pmaddwd 64(ARG1), %xmm4
96 pmaddwd 80(ARG1), %xmm5
97 pmaddwd 96(ARG1), %xmm6
98 pmaddwd 112(ARG1), %xmm7
99
100 paddd %xmm1, %xmm0
101 paddd %xmm3, %xmm2
102 paddd %xmm5, %xmm4
103 paddd %xmm7, %xmm6
104
105 movaps %xmm0, %xmm1
106 movaps %xmm4, %xmm3
107 punpckldq %xmm2, %xmm0
108 punpckldq %xmm6, %xmm4
109 punpckhdq %xmm2, %xmm1
110 punpckhdq %xmm6, %xmm3
111 movaps %xmm0, %xmm5
112 movaps %xmm1, %xmm7
113 movlhps %xmm4, %xmm0
114 movhlps %xmm5, %xmm4
115 movlhps %xmm3, %xmm1
116 movhlps %xmm7, %xmm3
117 paddd %xmm4, %xmm0
118 paddd %xmm3, %xmm1
119 paddd %xmm1, %xmm0
120 psrad $13, %xmm0
121
122 movups (ARG2), %xmm3
123 movaps %xmm0, %xmm1
124 movaps %xmm0, %xmm2
125 packssdw %xmm0, %xmm0
126 pcmpgtd XMMREG_MAX, %xmm1
127 pcmpgtd XMMREG_MIN, %xmm2
128 movhlps %xmm3, %xmm4
129 pshuflw $0xdd, %xmm3, %xmm3
130 pshuflw $0xdd, %xmm4, %xmm4
131 psrlq $32, %xmm3
132 psllq $32, %xmm4
133 por %xmm4, %xmm3
134 punpcklwd %xmm3, %xmm0
135 movups %xmm0, (ARG2)
136
137 pxor XMMREG_FULL, %xmm2
138 psrld $31, %xmm1
139 psrld $31, %xmm2
140 paddd %xmm2, %xmm1
141 paddd %xmm1, XMMREG_CLIP
142
143 leaq 256(ARG0), ARG0
144 leaq 128(ARG1), ARG1
145 leaq 16(ARG2), ARG2
146
147 decl %ecx
148 jnz 1b
149
150 movl $4, %ecx
151
152 ALIGN16
153 1:
154 movups (ARG0), %xmm0
155 movups 16(ARG0), %xmm1
156 movups 64(ARG0), %xmm2
157 movups 80(ARG0), %xmm3
158 movups 128(ARG0), %xmm4
159 movups 144(ARG0), %xmm5
160 movups 192(ARG0), %xmm6
161 movups 208(ARG0), %xmm7
162 pmaddwd (ARG1), %xmm0
163 pmaddwd 16(ARG1), %xmm1
164 pmaddwd -32(ARG1), %xmm2
165 pmaddwd -16(ARG1), %xmm3
166 pmaddwd -64(ARG1), %xmm4
167 pmaddwd -48(ARG1), %xmm5
168 pmaddwd -96(ARG1), %xmm6
169 pmaddwd -80(ARG1), %xmm7
170
171 paddd %xmm1, %xmm0
172 paddd %xmm3, %xmm2
173 paddd %xmm5, %xmm4
174 paddd %xmm7, %xmm6
175
176 movaps %xmm0, %xmm1
177 movaps %xmm4, %xmm3
178 punpckldq %xmm2, %xmm0
179 punpckldq %xmm6, %xmm4
180 punpckhdq %xmm2, %xmm1
181 punpckhdq %xmm6, %xmm3
182 movaps %xmm0, %xmm5
183 movaps %xmm1, %xmm7
184 movlhps %xmm4, %xmm0
185 movhlps %xmm5, %xmm4
186 movlhps %xmm3, %xmm1
187 movhlps %xmm7, %xmm3
188 paddd %xmm4, %xmm0
189 paddd %xmm3, %xmm1
190 paddd %xmm1, %xmm0
191 psrad $13, %xmm0
192
193 movups (ARG2), %xmm3
194 movaps %xmm0, %xmm1
195 movaps %xmm0, %xmm2
196 packssdw %xmm0, %xmm0
197 pcmpgtd XMMREG_MAX, %xmm1
198 pcmpgtd XMMREG_MIN, %xmm2
199 movhlps %xmm3, %xmm4
200 pshuflw $0xdd, %xmm3, %xmm3
201 pshuflw $0xdd, %xmm4, %xmm4
202 psrlq $32, %xmm3
203 psllq $32, %xmm4
204 por %xmm4, %xmm3
205 punpcklwd %xmm3, %xmm0
206 movups %xmm0, (ARG2)
207
208 pxor XMMREG_FULL, %xmm2
209 psrld $31, %xmm1
210 psrld $31, %xmm2
211 paddd %xmm2, %xmm1
212 paddd %xmm1, XMMREG_CLIP
213
214 leaq 256(ARG0), ARG0
215 leaq -128(ARG1), ARG1
216 leaq 16(ARG2), ARG2
217
218 decl %ecx
219 jnz 1b
220
221 pshuflw $0xee, XMMREG_CLIP, %xmm0
222 movhlps XMMREG_CLIP, %xmm1
223 pshuflw $0xee, %xmm1, %xmm2
224 paddd %xmm0, XMMREG_CLIP
225 paddd %xmm1, XMMREG_CLIP
226 paddd %xmm2, XMMREG_CLIP
227
228 movd XMMREG_CLIP, %eax
229
230 #ifdef IS_MSABI
231 movaps (%rsp), %xmm6
232 movaps 16(%rsp), %xmm7
233 movaps 32(%rsp), %xmm12
234 movaps 48(%rsp), %xmm13
235 movaps 64(%rsp), %xmm14
236 movaps 80(%rsp), %xmm15
237 addq $104, %rsp
238 #endif
239 ret
240
241 NONEXEC_STACK