Debian Codegraph @

src/libmpg123/synth_stereo_avx_accurate.S

raw
1 /*
2 synth_stereo_avx_accurate: AVX optimized synth for x86-64 (stereo specific, MPEG-compliant 16bit output version)
3
4 copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1
5 see COPYING and AUTHORS files in distribution or http://mpg123.org
6 initially written by Taihei Monma
7 */
8
9 #include "x86_64_defs.h"
10 #include "mangle.h"
11
12 #ifdef IS_MSABI
13 /* real *window; */
14 #define WINDOW %r10
15 /* real *b0l; */
16 #define B0L %rdx
17 /* real *b0r; */
18 #define B0R %r8
19 /* real *samples; */
20 #define SAMPLES %r9
21 #else
22 /* real *window; */
23 #define WINDOW %rdi
24 /* real *b0l; */
25 #define B0L %rsi
26 /* real *b0r; */
27 #define B0R %rdx
28 /* real *samples; */
29 #define SAMPLES %r9
30 #endif
31
32 /*
33 int synth_1to1_s_avx_accurate_asm(real *window, real *b0l, real *b0r, real *samples, int bo1);
34 return value: number of clipped samples
35 */
36
37 RODATA
38 ALIGN32
39 maxmin_avx:
40 .long 1191182335
41 .long 1191182335
42 .long 1191182335
43 .long 1191182335
44 .long 1191182335
45 .long 1191182335
46 .long 1191182335
47 .long 1191182335
48 .long -956301312
49 .long -956301312
50 .long -956301312
51 .long -956301312
52 .long -956301312
53 .long -956301312
54 .long -956301312
55 .long -956301312
56 .text
57 ALIGN16
58 .globl ASM_NAME(INT123_synth_1to1_s_avx_accurate_asm)
59 ASM_NAME(INT123_synth_1to1_s_avx_accurate_asm):
60 #ifdef IS_MSABI /* should save xmm6-15 */
61 push %rbp
62 mov %rsp, %rbp
63 sub $144, %rsp
64 movaps %xmm6, (%rsp)
65 movaps %xmm7, 16(%rsp)
66 movaps %xmm8, 32(%rsp)
67 movaps %xmm9, 48(%rsp)
68 movaps %xmm10, 64(%rsp)
69 movaps %xmm11, 80(%rsp)
70 movaps %xmm12, 96(%rsp)
71 movaps %xmm13, 112(%rsp)
72 movaps %xmm14, 128(%rsp)
73 movl 48(%rbp), %eax /* 5th argument; placed after 32-byte shadow space */
74 #endif
75
76 #ifdef IS_MSABI
77 shl $2, %eax
78 mov %rcx, WINDOW
79 #else
80 mov %r8d, %eax
81 shl $2, %eax
82 mov %rcx, SAMPLES
83 #endif
84 add $64, WINDOW
85 sub %rax, WINDOW
86
87 mov $128, %rax
88 mov $4, %ecx
89 vpxor %xmm14, %xmm14, %xmm14
90
91 ALIGN16
92 1:
93 vmovups (WINDOW), %ymm8
94 vmovups 32(WINDOW), %ymm9
95 vmovups (WINDOW,%rax), %ymm10
96 vmovups 32(WINDOW,%rax), %ymm11
97 vmulps (B0L), %ymm8, %ymm0
98 vmulps 32(B0L), %ymm9, %ymm1
99 vmulps (B0R), %ymm8, %ymm2
100 vmulps 32(B0R), %ymm9, %ymm3
101 vmulps 64(B0L), %ymm10, %ymm4
102 vmulps 96(B0L), %ymm11, %ymm5
103 vmulps 64(B0R), %ymm10, %ymm6
104 vmulps 96(B0R), %ymm11, %ymm7
105 vaddps %ymm1, %ymm0, %ymm8
106 vaddps %ymm3, %ymm2, %ymm0
107 vaddps %ymm5, %ymm4, %ymm9
108 vaddps %ymm7, %ymm6, %ymm1
109 lea (WINDOW,%rax,2), WINDOW
110 add %rax, B0L
111 add %rax, B0R
112
113 vmovups (WINDOW), %ymm10
114 vmovups 32(WINDOW), %ymm11
115 vmovups (WINDOW,%rax), %ymm12
116 vmovups 32(WINDOW,%rax), %ymm13
117 vmulps (B0L), %ymm10, %ymm2
118 vmulps 32(B0L), %ymm11, %ymm3
119 vmulps (B0R), %ymm10, %ymm4
120 vmulps 32(B0R), %ymm11, %ymm5
121 vmulps 64(B0L), %ymm12, %ymm6
122 vmulps 96(B0L), %ymm13, %ymm10
123 vmulps 64(B0R), %ymm12, %ymm7
124 vmulps 96(B0R), %ymm13, %ymm11
125 vaddps %ymm3, %ymm2, %ymm2
126 vaddps %ymm5, %ymm4, %ymm3
127 vaddps %ymm6, %ymm10, %ymm4
128 vaddps %ymm7, %ymm11, %ymm5
129 lea (WINDOW,%rax,2), WINDOW
130 add %rax, B0L
131 add %rax, B0R
132
133 vunpcklps %ymm0, %ymm8, %ymm6
134 vunpckhps %ymm0, %ymm8, %ymm0
135 vunpcklps %ymm1, %ymm9, %ymm7
136 vunpckhps %ymm1, %ymm9, %ymm1
137 vaddps %ymm6, %ymm0, %ymm0
138 vaddps %ymm7, %ymm1, %ymm1
139 vunpcklps %ymm3, %ymm2, %ymm6
140 vunpckhps %ymm3, %ymm2, %ymm2
141 vunpcklps %ymm5, %ymm4, %ymm7
142 vunpckhps %ymm5, %ymm4, %ymm3
143 vaddps %ymm6, %ymm2, %ymm2
144 vaddps %ymm7, %ymm3, %ymm3
145
146 vunpcklpd %ymm1, %ymm0, %ymm4
147 vunpckhpd %ymm1, %ymm0, %ymm0
148 vunpcklpd %ymm3, %ymm2, %ymm5
149 vunpckhpd %ymm3, %ymm2, %ymm1
150 vsubps %ymm0, %ymm4, %ymm0
151 vsubps %ymm1, %ymm5, %ymm1
152 vperm2f128 $0x20, %ymm1, %ymm0, %ymm2
153 vperm2f128 $0x31, %ymm1, %ymm0, %ymm3
154 vaddps %ymm3, %ymm2, %ymm0
155 vcmpnleps maxmin_avx(%rip), %ymm0, %ymm1
156 vcmpltps 32+maxmin_avx(%rip), %ymm0, %ymm2
157 vextractf128 $0x1, %ymm1, %xmm3
158 vextractf128 $0x1, %ymm2, %xmm4
159 vpackssdw %xmm2, %xmm1, %xmm1
160 vpackssdw %xmm4, %xmm3, %xmm3
161 vpaddw %xmm3, %xmm1, %xmm1
162 vpaddw %xmm1, %xmm14, %xmm14
163 vcvtps2dq %ymm0, %ymm0
164 vextractf128 $0x1, %ymm0, %xmm1
165 vpackssdw %xmm1, %xmm0, %xmm0
166
167 vmovups %xmm0, (SAMPLES)
168 add $16, SAMPLES
169 dec %ecx
170 jnz 1b
171
172 mov $4, %ecx
173
174 ALIGN16
175 1:
176 vmovups (WINDOW), %ymm8
177 vmovups 32(WINDOW), %ymm9
178 vmovups (WINDOW,%rax), %ymm10
179 vmovups 32(WINDOW,%rax), %ymm11
180 vmulps (B0L), %ymm8, %ymm0
181 vmulps 32(B0L), %ymm9, %ymm1
182 vmulps (B0R), %ymm8, %ymm2
183 vmulps 32(B0R), %ymm9, %ymm3
184 vmulps -64(B0L), %ymm10, %ymm4
185 vmulps -32(B0L), %ymm11, %ymm5
186 vmulps -64(B0R), %ymm10, %ymm6
187 vmulps -32(B0R), %ymm11, %ymm7
188 vaddps %ymm1, %ymm0, %ymm8
189 vaddps %ymm3, %ymm2, %ymm0
190 vaddps %ymm5, %ymm4, %ymm9
191 vaddps %ymm7, %ymm6, %ymm1
192 lea (WINDOW,%rax,2), WINDOW
193 sub %rax, B0L
194 sub %rax, B0R
195
196 vmovups (WINDOW), %ymm10
197 vmovups 32(WINDOW), %ymm11
198 vmovups (WINDOW,%rax), %ymm12
199 vmovups 32(WINDOW,%rax), %ymm13
200 vmulps (B0L), %ymm10, %ymm2
201 vmulps 32(B0L), %ymm11, %ymm3
202 vmulps (B0R), %ymm10, %ymm4
203 vmulps 32(B0R), %ymm11, %ymm5
204 vmulps -64(B0L), %ymm12, %ymm6
205 vmulps -32(B0L), %ymm13, %ymm10
206 vmulps -64(B0R), %ymm12, %ymm7
207 vmulps -32(B0R), %ymm13, %ymm11
208 vaddps %ymm3, %ymm2, %ymm2
209 vaddps %ymm5, %ymm4, %ymm3
210 vaddps %ymm6, %ymm10, %ymm4
211 vaddps %ymm7, %ymm11, %ymm5
212 lea (WINDOW,%rax,2), WINDOW
213 sub %rax, B0L
214 sub %rax, B0R
215
216 vunpcklps %ymm0, %ymm8, %ymm6
217 vunpckhps %ymm0, %ymm8, %ymm0
218 vunpcklps %ymm1, %ymm9, %ymm7
219 vunpckhps %ymm1, %ymm9, %ymm1
220 vaddps %ymm6, %ymm0, %ymm0
221 vaddps %ymm7, %ymm1, %ymm1
222 vunpcklps %ymm3, %ymm2, %ymm6
223 vunpckhps %ymm3, %ymm2, %ymm2
224 vunpcklps %ymm5, %ymm4, %ymm7
225 vunpckhps %ymm5, %ymm4, %ymm3
226 vaddps %ymm6, %ymm2, %ymm2
227 vaddps %ymm7, %ymm3, %ymm3
228
229 vunpcklpd %ymm1, %ymm0, %ymm4
230 vunpckhpd %ymm1, %ymm0, %ymm0
231 vunpcklpd %ymm3, %ymm2, %ymm5
232 vunpckhpd %ymm3, %ymm2, %ymm1
233 vaddps %ymm0, %ymm4, %ymm0
234 vaddps %ymm1, %ymm5, %ymm1
235 vperm2f128 $0x20, %ymm1, %ymm0, %ymm2
236 vperm2f128 $0x31, %ymm1, %ymm0, %ymm3
237 vaddps %ymm3, %ymm2, %ymm0
238 vcmpnleps maxmin_avx(%rip), %ymm0, %ymm1
239 vcmpltps 32+maxmin_avx(%rip), %ymm0, %ymm2
240 vextractf128 $0x1, %ymm1, %xmm3
241 vextractf128 $0x1, %ymm2, %xmm4
242 vpackssdw %xmm2, %xmm1, %xmm1
243 vpackssdw %xmm4, %xmm3, %xmm3
244 vpaddw %xmm3, %xmm1, %xmm1
245 vpaddw %xmm1, %xmm14, %xmm14
246 vcvtps2dq %ymm0, %ymm0
247 vextractf128 $0x1, %ymm0, %xmm1
248 vpackssdw %xmm1, %xmm0, %xmm0
249
250 vmovups %xmm0, (SAMPLES)
251 add $16, SAMPLES
252 dec %ecx
253 jnz 1b
254
255 vzeroupper
256
257 pxor %xmm1, %xmm1
258 psubw %xmm14, %xmm1
259 pshufd $0x4e, %xmm1, %xmm0
260 paddw %xmm1, %xmm0
261 pshuflw $0x4e, %xmm0, %xmm1
262 paddw %xmm1, %xmm0
263 pshuflw $0x11, %xmm0, %xmm1
264 paddw %xmm1, %xmm0
265 movd %xmm0, %eax
266 and $0x7f, %eax
267
268 #ifdef IS_MSABI
269 movaps (%rsp), %xmm6
270 movaps 16(%rsp), %xmm7
271 movaps 32(%rsp), %xmm8
272 movaps 48(%rsp), %xmm9
273 movaps 64(%rsp), %xmm10
274 movaps 80(%rsp), %xmm11
275 movaps 96(%rsp), %xmm12
276 movaps 112(%rsp), %xmm13
277 movaps 128(%rsp), %xmm14
278 mov %rbp, %rsp
279 pop %rbp
280 #endif
281 ret
282
283 NONEXEC_STACK