| 1 |
/* |
| 2 |
synth_stereo_x86_64: SSE optimized synth for x86-64 (stereo specific version) |
| 3 |
|
| 4 |
copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1 |
| 5 |
see COPYING and AUTHORS files in distribution or http://mpg123.org |
| 6 |
initially written by Taihei Monma |
| 7 |
*/ |
| 8 |
|
| 9 |
#include "x86_64_defs.h" |
| 10 |
#include "mangle.h" |
| 11 |
|
| 12 |
#ifdef IS_MSABI |
| 13 |
/* short *window; */ |
| 14 |
#define WINDOW %r10 |
| 15 |
/* short *b0l; */ |
| 16 |
#define B0L %rdx |
| 17 |
/* short *b0r; */ |
| 18 |
#define B0R %r8 |
| 19 |
/* short *samples; */ |
| 20 |
#define SAMPLES %r9 |
| 21 |
#else |
| 22 |
/* short *window; */ |
| 23 |
#define WINDOW %rdi |
| 24 |
/* short *b0l; */ |
| 25 |
#define B0L %rsi |
| 26 |
/* short *b0r; */ |
| 27 |
#define B0R %rdx |
| 28 |
/* short *samples; */ |
| 29 |
#define SAMPLES %r9 |
| 30 |
#endif |
| 31 |
|
| 32 |
#define XMMREG_CLIP %xmm15 |
| 33 |
#define XMMREG_MAX %xmm14 /* {32767, 32767, 32767, 32767} */ |
| 34 |
#define XMMREG_MIN %xmm13 /* {-32769, -32769, -32769, -32769} : not -32768 because SSE doesn't have "less than" comparison... */ |
| 35 |
#define XMMREG_FULL %xmm12 /* {0xFFFFFFFF, 0xFFFFFFFF, 0xFFFFFFFF, 0xFFFFFFFF} */ |
| 36 |
|
| 37 |
/* |
| 38 |
int synth_1to1_s_x86_64_asm(short *window, short *b0l, short *b0r, short *samples, int bo1); |
| 39 |
return value: number of clipped samples |
| 40 |
*/ |
| 41 |
|
| 42 |
RODATA |
| 43 |
ALIGN32 |
| 44 |
ASM_NAME(INT123_maxmin_x86_64): |
| 45 |
.long 32767 |
| 46 |
.long 32767 |
| 47 |
.long 32767 |
| 48 |
.long 32767 |
| 49 |
.long -32769 |
| 50 |
.long -32769 |
| 51 |
.long -32769 |
| 52 |
.long -32769 |
| 53 |
.text |
| 54 |
ALIGN16 |
| 55 |
.globl ASM_NAME(INT123_synth_1to1_s_x86_64_asm) |
| 56 |
ASM_NAME(INT123_synth_1to1_s_x86_64_asm): |
| 57 |
#ifdef IS_MSABI /* should save xmm6-15 */ |
| 58 |
movl 40(%rsp), %eax /* 5th argument; placed after 32-byte shadow space */ |
| 59 |
subq $168, %rsp /* stack alignment + 10 xmm registers */ |
| 60 |
movaps %xmm6, (%rsp) |
| 61 |
movaps %xmm7, 16(%rsp) |
| 62 |
movaps %xmm8, 32(%rsp) |
| 63 |
movaps %xmm9, 48(%rsp) |
| 64 |
movaps %xmm10, 64(%rsp) |
| 65 |
movaps %xmm11, 80(%rsp) |
| 66 |
movaps %xmm12, 96(%rsp) |
| 67 |
movaps %xmm13, 112(%rsp) |
| 68 |
movaps %xmm14, 128(%rsp) |
| 69 |
movaps %xmm15, 144(%rsp) |
| 70 |
#endif |
| 71 |
|
| 72 |
#ifdef IS_MSABI |
| 73 |
shlq $32, %rax |
| 74 |
shrq $31, %rax |
| 75 |
movq %rcx, %r10 |
| 76 |
#else |
| 77 |
movq %r8, %rax |
| 78 |
shlq $32, %rax |
| 79 |
shrq $31, %rax |
| 80 |
movq %rcx, %r9 |
| 81 |
#endif |
| 82 |
leaq 32(WINDOW), WINDOW |
| 83 |
subq %rax, WINDOW |
| 84 |
|
| 85 |
leaq ASM_NAME(INT123_maxmin_x86_64)(%rip), %rax |
| 86 |
movaps (%rax), XMMREG_MAX |
| 87 |
movaps 16(%rax), XMMREG_MIN |
| 88 |
pxor XMMREG_CLIP, XMMREG_CLIP |
| 89 |
pcmpeqd XMMREG_FULL, XMMREG_FULL |
| 90 |
|
| 91 |
movl $4, %ecx |
| 92 |
|
| 93 |
ALIGN16 |
| 94 |
1: |
| 95 |
movups (WINDOW), %xmm0 |
| 96 |
movups 16(WINDOW), %xmm1 |
| 97 |
movups 64(WINDOW), %xmm2 |
| 98 |
movups 80(WINDOW), %xmm3 |
| 99 |
movups 128(WINDOW), %xmm4 |
| 100 |
movups 144(WINDOW), %xmm5 |
| 101 |
movups 192(WINDOW), %xmm6 |
| 102 |
movups 208(WINDOW), %xmm7 |
| 103 |
movaps %xmm0, %xmm8 |
| 104 |
movaps %xmm1, %xmm9 |
| 105 |
movaps %xmm2, %xmm10 |
| 106 |
movaps %xmm3, %xmm11 |
| 107 |
pmaddwd (B0L), %xmm0 |
| 108 |
pmaddwd 16(B0L), %xmm1 |
| 109 |
pmaddwd 32(B0L), %xmm2 |
| 110 |
pmaddwd 48(B0L), %xmm3 |
| 111 |
pmaddwd (B0R), %xmm8 |
| 112 |
pmaddwd 16(B0R), %xmm9 |
| 113 |
pmaddwd 32(B0R), %xmm10 |
| 114 |
pmaddwd 48(B0R), %xmm11 |
| 115 |
paddd %xmm1, %xmm0 |
| 116 |
paddd %xmm3, %xmm2 |
| 117 |
paddd %xmm9, %xmm8 |
| 118 |
paddd %xmm11, %xmm10 |
| 119 |
movaps %xmm4, %xmm1 |
| 120 |
movaps %xmm5, %xmm9 |
| 121 |
movaps %xmm6, %xmm3 |
| 122 |
movaps %xmm7, %xmm11 |
| 123 |
pmaddwd 64(B0L), %xmm4 |
| 124 |
pmaddwd 80(B0L), %xmm5 |
| 125 |
pmaddwd 96(B0L), %xmm6 |
| 126 |
pmaddwd 112(B0L), %xmm7 |
| 127 |
pmaddwd 64(B0R), %xmm1 |
| 128 |
pmaddwd 80(B0R), %xmm9 |
| 129 |
pmaddwd 96(B0R), %xmm3 |
| 130 |
pmaddwd 112(B0R), %xmm11 |
| 131 |
paddd %xmm5, %xmm4 |
| 132 |
paddd %xmm7, %xmm6 |
| 133 |
paddd %xmm1, %xmm9 |
| 134 |
paddd %xmm3, %xmm11 |
| 135 |
|
| 136 |
movaps %xmm0, %xmm1 |
| 137 |
movaps %xmm4, %xmm3 |
| 138 |
movaps %xmm8, %xmm5 |
| 139 |
movaps %xmm9, %xmm7 |
| 140 |
punpckldq %xmm2, %xmm0 |
| 141 |
punpckldq %xmm6, %xmm4 |
| 142 |
punpckhdq %xmm2, %xmm1 |
| 143 |
punpckhdq %xmm6, %xmm3 |
| 144 |
punpckldq %xmm10, %xmm8 |
| 145 |
punpckldq %xmm11, %xmm9 |
| 146 |
punpckhdq %xmm10, %xmm5 |
| 147 |
punpckhdq %xmm11, %xmm7 |
| 148 |
movaps %xmm0, %xmm2 |
| 149 |
movaps %xmm1, %xmm6 |
| 150 |
movaps %xmm8, %xmm10 |
| 151 |
movaps %xmm5, %xmm11 |
| 152 |
movlhps %xmm4, %xmm0 |
| 153 |
movhlps %xmm2, %xmm4 |
| 154 |
movlhps %xmm3, %xmm1 |
| 155 |
movhlps %xmm6, %xmm3 |
| 156 |
movlhps %xmm9, %xmm8 |
| 157 |
movhlps %xmm10, %xmm9 |
| 158 |
movlhps %xmm7, %xmm5 |
| 159 |
movhlps %xmm11, %xmm7 |
| 160 |
paddd %xmm4, %xmm0 |
| 161 |
paddd %xmm3, %xmm1 |
| 162 |
paddd %xmm9, %xmm8 |
| 163 |
paddd %xmm7, %xmm5 |
| 164 |
paddd %xmm1, %xmm0 |
| 165 |
paddd %xmm5, %xmm8 |
| 166 |
psrad $13, %xmm0 |
| 167 |
psrad $13, %xmm8 |
| 168 |
|
| 169 |
movaps %xmm0, %xmm1 |
| 170 |
movaps %xmm0, %xmm2 |
| 171 |
movaps %xmm0, %xmm3 |
| 172 |
movaps %xmm8, %xmm4 |
| 173 |
punpckldq %xmm8, %xmm0 |
| 174 |
punpckhdq %xmm8, %xmm1 |
| 175 |
packssdw %xmm1, %xmm0 |
| 176 |
movups %xmm0, (SAMPLES) |
| 177 |
|
| 178 |
pcmpgtd XMMREG_MAX, %xmm2 |
| 179 |
pcmpgtd XMMREG_MIN, %xmm3 |
| 180 |
pcmpgtd XMMREG_MAX, %xmm4 |
| 181 |
pcmpgtd XMMREG_MIN, %xmm8 |
| 182 |
packssdw %xmm4, %xmm2 |
| 183 |
packssdw %xmm8, %xmm3 |
| 184 |
pxor XMMREG_FULL, %xmm3 |
| 185 |
psrlw $15, %xmm2 |
| 186 |
psrlw $15, %xmm3 |
| 187 |
paddw %xmm3, %xmm2 |
| 188 |
paddw %xmm2, XMMREG_CLIP |
| 189 |
|
| 190 |
leaq 256(WINDOW), WINDOW |
| 191 |
leaq 128(B0L), B0L |
| 192 |
leaq 128(B0R), B0R |
| 193 |
leaq 16(SAMPLES), SAMPLES |
| 194 |
|
| 195 |
decl %ecx |
| 196 |
jnz 1b |
| 197 |
|
| 198 |
movl $4, %ecx |
| 199 |
|
| 200 |
ALIGN16 |
| 201 |
1: |
| 202 |
movups (WINDOW), %xmm0 |
| 203 |
movups 16(WINDOW), %xmm1 |
| 204 |
movups 64(WINDOW), %xmm2 |
| 205 |
movups 80(WINDOW), %xmm3 |
| 206 |
movups 128(WINDOW), %xmm4 |
| 207 |
movups 144(WINDOW), %xmm5 |
| 208 |
movups 192(WINDOW), %xmm6 |
| 209 |
movups 208(WINDOW), %xmm7 |
| 210 |
movaps %xmm0, %xmm8 |
| 211 |
movaps %xmm1, %xmm9 |
| 212 |
movaps %xmm2, %xmm10 |
| 213 |
movaps %xmm3, %xmm11 |
| 214 |
pmaddwd (B0L), %xmm0 |
| 215 |
pmaddwd 16(B0L), %xmm1 |
| 216 |
pmaddwd -32(B0L), %xmm2 |
| 217 |
pmaddwd -16(B0L), %xmm3 |
| 218 |
pmaddwd (B0R), %xmm8 |
| 219 |
pmaddwd 16(B0R), %xmm9 |
| 220 |
pmaddwd -32(B0R), %xmm10 |
| 221 |
pmaddwd -16(B0R), %xmm11 |
| 222 |
paddd %xmm1, %xmm0 |
| 223 |
paddd %xmm3, %xmm2 |
| 224 |
paddd %xmm9, %xmm8 |
| 225 |
paddd %xmm11, %xmm10 |
| 226 |
movaps %xmm4, %xmm1 |
| 227 |
movaps %xmm5, %xmm9 |
| 228 |
movaps %xmm6, %xmm3 |
| 229 |
movaps %xmm7, %xmm11 |
| 230 |
pmaddwd -64(B0L), %xmm4 |
| 231 |
pmaddwd -48(B0L), %xmm5 |
| 232 |
pmaddwd -96(B0L), %xmm6 |
| 233 |
pmaddwd -80(B0L), %xmm7 |
| 234 |
pmaddwd -64(B0R), %xmm1 |
| 235 |
pmaddwd -48(B0R), %xmm9 |
| 236 |
pmaddwd -96(B0R), %xmm3 |
| 237 |
pmaddwd -80(B0R), %xmm11 |
| 238 |
paddd %xmm5, %xmm4 |
| 239 |
paddd %xmm7, %xmm6 |
| 240 |
paddd %xmm1, %xmm9 |
| 241 |
paddd %xmm3, %xmm11 |
| 242 |
|
| 243 |
movaps %xmm0, %xmm1 |
| 244 |
movaps %xmm4, %xmm3 |
| 245 |
movaps %xmm8, %xmm5 |
| 246 |
movaps %xmm9, %xmm7 |
| 247 |
punpckldq %xmm2, %xmm0 |
| 248 |
punpckldq %xmm6, %xmm4 |
| 249 |
punpckhdq %xmm2, %xmm1 |
| 250 |
punpckhdq %xmm6, %xmm3 |
| 251 |
punpckldq %xmm10, %xmm8 |
| 252 |
punpckldq %xmm11, %xmm9 |
| 253 |
punpckhdq %xmm10, %xmm5 |
| 254 |
punpckhdq %xmm11, %xmm7 |
| 255 |
movaps %xmm0, %xmm2 |
| 256 |
movaps %xmm1, %xmm6 |
| 257 |
movaps %xmm8, %xmm10 |
| 258 |
movaps %xmm5, %xmm11 |
| 259 |
movlhps %xmm4, %xmm0 |
| 260 |
movhlps %xmm2, %xmm4 |
| 261 |
movlhps %xmm3, %xmm1 |
| 262 |
movhlps %xmm6, %xmm3 |
| 263 |
movlhps %xmm9, %xmm8 |
| 264 |
movhlps %xmm10, %xmm9 |
| 265 |
movlhps %xmm7, %xmm5 |
| 266 |
movhlps %xmm11, %xmm7 |
| 267 |
paddd %xmm4, %xmm0 |
| 268 |
paddd %xmm3, %xmm1 |
| 269 |
paddd %xmm9, %xmm8 |
| 270 |
paddd %xmm7, %xmm5 |
| 271 |
paddd %xmm1, %xmm0 |
| 272 |
paddd %xmm5, %xmm8 |
| 273 |
psrad $13, %xmm0 |
| 274 |
psrad $13, %xmm8 |
| 275 |
|
| 276 |
movaps %xmm0, %xmm1 |
| 277 |
movaps %xmm0, %xmm2 |
| 278 |
movaps %xmm0, %xmm3 |
| 279 |
movaps %xmm8, %xmm4 |
| 280 |
punpckldq %xmm8, %xmm0 |
| 281 |
punpckhdq %xmm8, %xmm1 |
| 282 |
packssdw %xmm1, %xmm0 |
| 283 |
movups %xmm0, (SAMPLES) |
| 284 |
|
| 285 |
pcmpgtd XMMREG_MAX, %xmm2 |
| 286 |
pcmpgtd XMMREG_MIN, %xmm3 |
| 287 |
pcmpgtd XMMREG_MAX, %xmm4 |
| 288 |
pcmpgtd XMMREG_MIN, %xmm8 |
| 289 |
packssdw %xmm4, %xmm2 |
| 290 |
packssdw %xmm8, %xmm3 |
| 291 |
pxor XMMREG_FULL, %xmm3 |
| 292 |
psrlw $15, %xmm2 |
| 293 |
psrlw $15, %xmm3 |
| 294 |
paddw %xmm3, %xmm2 |
| 295 |
paddw %xmm2, XMMREG_CLIP |
| 296 |
|
| 297 |
leaq 256(WINDOW), WINDOW |
| 298 |
leaq -128(B0L), B0L |
| 299 |
leaq -128(B0R), B0R |
| 300 |
leaq 16(SAMPLES), SAMPLES |
| 301 |
|
| 302 |
decl %ecx |
| 303 |
jnz 1b |
| 304 |
|
| 305 |
movhlps XMMREG_CLIP, %xmm0 |
| 306 |
paddw XMMREG_CLIP, %xmm0 |
| 307 |
pshuflw $0x55, %xmm0, %xmm1 |
| 308 |
pshuflw $0xaa, %xmm0, %xmm2 |
| 309 |
pshuflw $0xff, %xmm0, %xmm3 |
| 310 |
paddw %xmm1, %xmm0 |
| 311 |
paddw %xmm2, %xmm0 |
| 312 |
paddw %xmm3, %xmm0 |
| 313 |
|
| 314 |
movd %xmm0, %eax |
| 315 |
andl $0xffff, %eax |
| 316 |
|
| 317 |
#ifdef IS_MSABI |
| 318 |
movaps (%rsp), %xmm6 |
| 319 |
movaps 16(%rsp), %xmm7 |
| 320 |
movaps 32(%rsp), %xmm8 |
| 321 |
movaps 48(%rsp), %xmm9 |
| 322 |
movaps 64(%rsp), %xmm10 |
| 323 |
movaps 80(%rsp), %xmm11 |
| 324 |
movaps 96(%rsp), %xmm12 |
| 325 |
movaps 112(%rsp), %xmm13 |
| 326 |
movaps 128(%rsp), %xmm14 |
| 327 |
movaps 144(%rsp), %xmm15 |
| 328 |
addq $168, %rsp |
| 329 |
#endif |
| 330 |
ret |
| 331 |
|
| 332 |
NONEXEC_STACK |