Debian Codegraph @

src/libmpg123/synth_x86_64_accurate.S

raw
1 /*
2 synth_x86_64_accurate: SSE optimized synth for x86-64 (MPEG-compliant 16bit output version)
3
4 copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1
5 see COPYING and AUTHORS files in distribution or http://mpg123.org
6 initially written by Taihei Monma
7 */
8
9 #include "x86_64_defs.h"
10 #include "mangle.h"
11
12 #ifdef IS_MSABI
13 /* short *window; */
14 #define ARG0 %r10
15 /* short *b0; */
16 #define ARG1 %rdx
17 /* short *samples; */
18 #define ARG2 %r8
19 /* int bo1; */
20 #define ARG3 %r9
21 #else
22 /* real *window; */
23 #define ARG0 %rdi
24 /* real *b0; */
25 #define ARG1 %rsi
26 /* real *samples; */
27 #define ARG2 %rdx
28 /* int bo1; */
29 #define ARG3 %rcx
30 #endif
31
32 #define XMMREG_MAX %xmm15 /* {32767.0, 32767.0, 32767.0, 32767.0} */
33 #define XMMREG_MIN %xmm14 /* {-32768.0, -32768.0, -32768.0, -32768.0} */
34 #define XMMREG_CLIP %xmm13
35
36 /*
37 int synth_1to1_x86_64_accurate_asm(real *window, real *b0, short *samples, int bo1);
38 return value: number of clipped samples
39 */
40
41 RODATA
42 ALIGN32
43 ASM_NAME(INT123_maxmin_s16):
44 .long 1191181824
45 .long 1191181824
46 .long 1191181824
47 .long 1191181824
48 .long -956301312
49 .long -956301312
50 .long -956301312
51 .long -956301312
52 .text
53 ALIGN16
54 .globl ASM_NAME(INT123_synth_1to1_x86_64_accurate_asm)
55 ASM_NAME(INT123_synth_1to1_x86_64_accurate_asm):
56 #ifdef IS_MSABI /* should save xmm6-15 */
57 movq %rcx, ARG0
58 subq $152, %rsp /* stack alignment + 9 xmm registers */
59 movaps %xmm6, (%rsp)
60 movaps %xmm7, 16(%rsp)
61 movaps %xmm8, 32(%rsp)
62 movaps %xmm9, 48(%rsp)
63 movaps %xmm10, 64(%rsp)
64 movaps %xmm11, 80(%rsp)
65 movaps %xmm13, 96(%rsp)
66 movaps %xmm14, 112(%rsp)
67 movaps %xmm15, 128(%rsp)
68 #endif
69
70 leaq ASM_NAME(INT123_maxmin_s16)(%rip), %rax
71 movaps (%rax), XMMREG_MAX
72 movaps 16(%rax), XMMREG_MIN
73
74 xorps XMMREG_CLIP, XMMREG_CLIP
75
76 andq $0xf, ARG3
77 shlq $2, ARG3
78 leaq 64(ARG0), ARG0
79 subq ARG3, ARG0
80
81 movl $4, %ecx
82
83 ALIGN16
84 1:
85 movups (ARG0), %xmm8
86 movups 16(ARG0), %xmm1
87 movups 32(ARG0), %xmm2
88 movups 48(ARG0), %xmm3
89 movups 128(ARG0), %xmm9
90 movups 144(ARG0), %xmm5
91 movups 160(ARG0), %xmm6
92 movups 176(ARG0), %xmm7
93 mulps (ARG1), %xmm8
94 mulps 16(ARG1), %xmm1
95 mulps 32(ARG1), %xmm2
96 mulps 48(ARG1), %xmm3
97 mulps 64(ARG1), %xmm9
98 mulps 80(ARG1), %xmm5
99 mulps 96(ARG1), %xmm6
100 mulps 112(ARG1), %xmm7
101
102 addps %xmm1, %xmm8
103 addps %xmm2, %xmm3
104 addps %xmm5, %xmm9
105 addps %xmm7, %xmm6
106 addps %xmm3, %xmm8
107 addps %xmm6, %xmm9
108 leaq 256(ARG0), ARG0
109 leaq 128(ARG1), ARG1
110
111 movups (ARG0), %xmm10
112 movups 16(ARG0), %xmm1
113 movups 32(ARG0), %xmm2
114 movups 48(ARG0), %xmm3
115 movups 128(ARG0), %xmm11
116 movups 144(ARG0), %xmm5
117 movups 160(ARG0), %xmm6
118 movups 176(ARG0), %xmm7
119 mulps (ARG1), %xmm10
120 mulps 16(ARG1), %xmm1
121 mulps 32(ARG1), %xmm2
122 mulps 48(ARG1), %xmm3
123 mulps 64(ARG1), %xmm11
124 mulps 80(ARG1), %xmm5
125 mulps 96(ARG1), %xmm6
126 mulps 112(ARG1), %xmm7
127
128 addps %xmm1, %xmm10
129 addps %xmm2, %xmm3
130 addps %xmm5, %xmm11
131 addps %xmm7, %xmm6
132 addps %xmm3, %xmm10
133 addps %xmm6, %xmm11
134 leaq 256(ARG0), ARG0
135 leaq 128(ARG1), ARG1
136
137 movaps %xmm8, %xmm0
138 movaps %xmm10, %xmm1
139 unpcklps %xmm9, %xmm8
140 unpcklps %xmm11, %xmm10
141 unpckhps %xmm9, %xmm0
142 unpckhps %xmm11, %xmm1
143 movaps %xmm8, %xmm2
144 movaps %xmm0, %xmm3
145 movlhps %xmm10, %xmm8
146 movhlps %xmm2, %xmm10
147 movlhps %xmm1, %xmm0
148 movhlps %xmm3, %xmm1
149 subps %xmm10, %xmm8
150 subps %xmm1, %xmm0
151 addps %xmm8, %xmm0
152
153 movups (ARG2), %xmm3
154 movaps %xmm0, %xmm1
155 movaps %xmm0, %xmm2
156 cmpnleps XMMREG_MAX, %xmm1
157 cmpltps XMMREG_MIN, %xmm2
158 cvtps2dq %xmm0, %xmm0
159 packssdw %xmm0, %xmm0
160 movhlps %xmm3, %xmm4
161 pshuflw $0xdd, %xmm3, %xmm3
162 pshuflw $0xdd, %xmm4, %xmm4
163 psrlq $32, %xmm3
164 psllq $32, %xmm4
165 por %xmm4, %xmm3
166 punpcklwd %xmm3, %xmm0
167 movups %xmm0, (ARG2)
168
169 psrld $31, %xmm1
170 psrld $31, %xmm2
171 paddd %xmm2, %xmm1
172 paddd %xmm1, XMMREG_CLIP
173
174 leaq 16(ARG2), ARG2
175 decl %ecx
176 jnz 1b
177
178 movl $4, %ecx
179
180 ALIGN16
181 1:
182 movups (ARG0), %xmm8
183 movups 16(ARG0), %xmm1
184 movups 32(ARG0), %xmm2
185 movups 48(ARG0), %xmm3
186 movups 128(ARG0), %xmm9
187 movups 144(ARG0), %xmm5
188 movups 160(ARG0), %xmm6
189 movups 176(ARG0), %xmm7
190 mulps (ARG1), %xmm8
191 mulps 16(ARG1), %xmm1
192 mulps 32(ARG1), %xmm2
193 mulps 48(ARG1), %xmm3
194 mulps -64(ARG1), %xmm9
195 mulps -48(ARG1), %xmm5
196 mulps -32(ARG1), %xmm6
197 mulps -16(ARG1), %xmm7
198
199 addps %xmm1, %xmm8
200 addps %xmm2, %xmm3
201 addps %xmm5, %xmm9
202 addps %xmm7, %xmm6
203 addps %xmm3, %xmm8
204 addps %xmm6, %xmm9
205 leaq 256(ARG0), ARG0
206 leaq -128(ARG1), ARG1
207
208 movups (ARG0), %xmm10
209 movups 16(ARG0), %xmm1
210 movups 32(ARG0), %xmm2
211 movups 48(ARG0), %xmm3
212 movups 128(ARG0), %xmm11
213 movups 144(ARG0), %xmm5
214 movups 160(ARG0), %xmm6
215 movups 176(ARG0), %xmm7
216 mulps (ARG1), %xmm10
217 mulps 16(ARG1), %xmm1
218 mulps 32(ARG1), %xmm2
219 mulps 48(ARG1), %xmm3
220 mulps -64(ARG1), %xmm11
221 mulps -48(ARG1), %xmm5
222 mulps -32(ARG1), %xmm6
223 mulps -16(ARG1), %xmm7
224
225 addps %xmm1, %xmm10
226 addps %xmm2, %xmm3
227 addps %xmm5, %xmm11
228 addps %xmm7, %xmm6
229 addps %xmm3, %xmm10
230 addps %xmm6, %xmm11
231 leaq 256(ARG0), ARG0
232 leaq -128(ARG1), ARG1
233
234 movaps %xmm8, %xmm0
235 movaps %xmm10, %xmm1
236 unpcklps %xmm9, %xmm8
237 unpcklps %xmm11, %xmm10
238 unpckhps %xmm9, %xmm0
239 unpckhps %xmm11, %xmm1
240 movaps %xmm8, %xmm2
241 movaps %xmm0, %xmm3
242 movlhps %xmm10, %xmm8
243 movhlps %xmm2, %xmm10
244 movlhps %xmm1, %xmm0
245 movhlps %xmm3, %xmm1
246 addps %xmm10, %xmm8
247 addps %xmm1, %xmm0
248 addps %xmm8, %xmm0
249
250 movups (ARG2), %xmm3
251 movaps %xmm0, %xmm1
252 movaps %xmm0, %xmm2
253 cmpnleps XMMREG_MAX, %xmm1
254 cmpltps XMMREG_MIN, %xmm2
255 cvtps2dq %xmm0, %xmm0
256 packssdw %xmm0, %xmm0
257 movhlps %xmm3, %xmm4
258 pshuflw $0xdd, %xmm3, %xmm3
259 pshuflw $0xdd, %xmm4, %xmm4
260 psrlq $32, %xmm3
261 psllq $32, %xmm4
262 por %xmm4, %xmm3
263 punpcklwd %xmm3, %xmm0
264 movups %xmm0, (ARG2)
265
266 psrld $31, %xmm1
267 psrld $31, %xmm2
268 paddd %xmm2, %xmm1
269 paddd %xmm1, XMMREG_CLIP
270
271 leaq 16(ARG2), ARG2
272 decl %ecx
273 jnz 1b
274
275 pshuflw $0xee, XMMREG_CLIP, %xmm0
276 movhlps XMMREG_CLIP, %xmm1
277 pshuflw $0xee, %xmm1, %xmm2
278 paddd %xmm0, XMMREG_CLIP
279 paddd %xmm1, XMMREG_CLIP
280 paddd %xmm2, XMMREG_CLIP
281
282 movd XMMREG_CLIP, %eax
283
284 #ifdef IS_MSABI
285 movaps (%rsp), %xmm6
286 movaps 16(%rsp), %xmm7
287 movaps 32(%rsp), %xmm8
288 movaps 48(%rsp), %xmm9
289 movaps 64(%rsp), %xmm10
290 movaps 80(%rsp), %xmm11
291 movaps 96(%rsp), %xmm13
292 movaps 112(%rsp), %xmm14
293 movaps 128(%rsp), %xmm15
294 addq $152, %rsp
295 #endif
296 ret
297
298 NONEXEC_STACK