Debian Codegraph @

texmf-dist/fonts/source/public/sansmathfonts/sans-symbol.mf

raw
1 % Based on the Computer Modern source file symbol.mf by D E Knuth.
2
3 % Edited by Ariel Barton to produce better sans serif symbols
4
5 % Date: 2013/03/22
6
7 % This file defines the symbols of a \TeX\ math symbol font.
8 % Character codes \0000--\0100 and \0133--\0177 are generated.
9
10 % (Improvements to Knuth's original characters were worked out in 1982
11 % by Ronald F. Whitney and other members of
12 % the American Mathematical Society.)
13
14 % Italic corrections have not been computed for most of these characters,
15 % since they are generally not slanted.
16
17 minus=oct"000"; cdot=oct"001"; diamond=oct"005";
18 plus_minus=oct"006"; o_plus=oct"010"; o_times=oct"012";
19 eqv=oct"021"; leq=oct"024"; geq=oct"025";
20 subset=oct"032"; superset=oct"033";
21 left_arrow=oct"040"; right_arrow=oct"041";
22 up_arrow=oct"042"; down_arrow=oct"043"; double_arrow=oct"044";
23 infty=oct"061"; elt=oct"062";
24 for_all=oct"070"; there_exists=oct"071"; false_that=oct"072";
25 cup=oct"133"; cap=oct"134"; meet=oct"136"; join=oct"137";
26 left_brace=oct"146"; right_brace=oct"147"; vertical=oct"152";
27 backslash=oct"156"; integral=oct"163";
28
29 input sans-sym; % symbols common to other fonts
30
31 cmchar "Times operator";
32 beginarithchar(oct"002"); pickup rule.nib;
33 x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
34 x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
35 draw z1--z2; draw z3--z4; % diagonals
36 labels(1,2,3,4); endchar;
37
38 cmchar "Asterisk at the axis";
39 beginchar(oct"003",9u#,v_center(x_height#));
40 adjust_fit(0,0);
41 numeric ast_flare; ast_flare=hround .7[thin_join,stem];
42 x0=.5w; y0=h-.5x_height;
43 for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
44 numeric theta; theta=angle(z[d]-z0);
45 fill z0+.5(0,-thin_join)rotated theta
46 ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
47 ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
48 ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
49 labels(0,[-150],[-90],[-30],30,90,150); endchar;
50
51 cmchar "Elementary division operator";
52 beginarithchar(oct"004"); pickup fine.nib; pickup rule.nib;
53 numeric del; del=dot_size-currentbreadth; % currentbreadth=fine
54 x3-.5del=good.x(.5w-.5del); center_on(x3);
55 y3+.5del=good.y(math_axis+math_spread[.5x_height,.6x_height]+.5del);
56 lft x1=hround u-eps; x2=w-x1; y1=y2=math_axis;
57 draw z1--z2; % bar
58 pos3(dot_size,0); pos4(dot_size,90); z3=z4;
59 pos5(dot_size,0); pos6(dot_size,90); z5=z6; x5=x3; .5[y3,y5]=math_axis;
60 dot(3,4); dot(5,6); % dots
61 penlabels(1,2,3,4,5,6); endchar;
62
63 cmchar "Minus-or-plus sign";
64 beginarithchar(oct"007"); pickup rule.nib;
65 numeric shiftup; shiftup=-vround 1.5u;
66 x1=x2=.5w; lft x3=lft x5=hround u-eps; x4=x6=w-x3;
67 .5[y1,y2]=y3=y4=math_axis+shiftup; top y1=h+shiftup; y5=y6=y1;
68 draw z1--z2; % stem
69 draw z3--z4; % plus bar
70 draw z5--z6; % minus bar
71 labels(1,2,3,4,5,6); endchar;
72
73 cmchar "Circle-minus operator";
74 beginarithchar(oct"011"); pickup light_rule.nib; autorounded;
75 lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
76 circle_points; draw_circle; % circle
77 draw z2--z6; % bar
78 labels(1,2,3,4,5,6,7,8); endchar;
79
80 cmchar "Circle-divide operator";
81 beginarithchar(oct"013"); pickup light_rule.nib; autorounded;
82 lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
83 circle_points; draw_circle; % circle
84 draw z1--z5; % diagonal
85 labels(1,2,3,4,5,6,7,8); endchar;
86
87 cmchar "Circle-dot operator";
88 beginarithchar(oct"014"); pickup light_rule.nib; autorounded;
89 lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
90 circle_points; draw_circle; % circle
91 fill fullcircle scaled(if square_dots: 1.6 else: 1.3 fi dot_size+eps) shifted(.5[z4,z8]); % dot
92 labels(1,2,3,4,5,6,7,8); endchar;
93
94 cmchar "Circle for copyright, etc.";
95 beginchar(oct"015",18u#,asc_height#,desc_depth#); autorounded;
96 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
97 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
98 circle_points; draw_circle; % circle
99 labels(1,2,3,4,5,6,7,8); endchar;
100
101 cmchar "Circle operator";
102 beginchar(oct"016",9u#,v_center(7u#));
103 adjust_fit(0,0); pickup rule.nib; autorounded;
104 lft x6=hround u; x2=w-x6; top y8=h; y8-y4=x2-x6;
105 circle_points; draw_circle; % circle
106 labels(1,2,3,4,5,6,7,8); endchar;
107
108 cmchar "Bullet";
109 beginchar(oct"017",9u#,v_center(7u#));
110 adjust_fit(0,0); pickup rule.nib; autorounded;
111 lft x6=hround u; x2=w-x6; top y8=h; y8-y4=x2-x6; circle_points;
112 filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
113 ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle; % circle and interior
114 labels(1,2,3,4,5,6,7,8); endchar;
115
116 cmchar "Hardy's asymptotic equivalence sign";
117 compute_spread(.45x_height#,.55x_height#);
118 beginchar(oct"020",14u#,v_center(2spread#+rule_thickness#));
119 adjust_fit(0,0); pickup rule.nib; autorounded;
120 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; x5=x6=.5w;
121 y1=y2=good.y h; y3=y4; .5[y1,y3]=.5[y5,y6]=math_axis;
122 y5=good.y .3[y1,y3];
123 draw z1{x5-x1,2(y5-y1)}...z5{right}...z2{x2-x5,2(y2-y5)}; % upper bar
124 draw z3{x6-x3,2(y6-y3)}...z6{right}...z4{x4-x6,2(y4-y6)}; % lower bar
125 labels(1,2,3,4,5,6); endchar;
126
127 cmchar "Subset or equal to sign";
128 compute_spread(.45x_height#,.55x_height#);
129 spread#':=spread#; spread':=spread; % the spread of `$=$'
130 compute_spread(5/4x_height#,3/2x_height#);
131 beginchar(oct"022",14u#,v_center(spread#'+spread#+rule_thickness#));
132 adjust_fit(0,0); pickup rule.nib; autorounded;
133 lft x2=hround 1.5u-eps; x1=x3=w-x2;
134 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
135 x4=x5=.5w; y4=y1; y5=y3;
136 draw z1---z4...z2{down}...z5---z3; % arc and bars
137 x8=x1; lft x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
138 labels(1,2,3,4,5,8,9); endchar;
139
140 cmchar "Superset or equal to sign";
141 compute_spread(.45x_height#,.55x_height#);
142 spread#':=spread#; spread':=spread; % the spread of `$=$'
143 compute_spread(5/4x_height#,3/2x_height#);
144 beginchar(oct"023",14u#,v_center(spread#'+spread#+rule_thickness#));
145 adjust_fit(0,0); pickup rule.nib; autorounded;
146 lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
147 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
148 x4=x5=.5w; y4=y1; y5=y3;
149 draw z1---z4...z2{down}...z5---z3; % arc and bars
150 x8=x1; rt x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
151 labels(1,2,3,4,5,8,9); endchar;
152
153 cmchar "Precedes or equals sign";
154 compute_spread(.45x_height#,.55x_height#);
155 spread#':=spread#; spread':=spread; % the spread of `$=$'
156 compute_spread(5/4x_height#,3/2x_height#);
157 beginchar(oct"026",14u#,v_center(spread#'+spread#+rule_thickness#));
158 adjust_fit(0,0); pickup rule.nib; autorounded;
159 lft x2=hround 1.5u-eps; x1=x3=w-x2;
160 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
161 draw z1{-u,-spread}...{left}z2; % upper diagonal
162 draw z3{-u,spread}...{left}z2; % lower diagonal
163 x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % bar
164 labels(1,2,3,8,9); endchar;
165
166 cmchar "Follows or equals sign";
167 compute_spread(.45x_height#,.55x_height#);
168 spread#':=spread#; spread':=spread; % the spread of `$=$'
169 compute_spread(5/4x_height#,3/2x_height#);
170 beginchar(oct"027",14u#,v_center(spread#'+spread#+rule_thickness#));
171 adjust_fit(0,0); pickup rule.nib; autorounded;
172 lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
173 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
174 draw z1{u,-spread}...{right}z2; % upper diagonal
175 draw z3{u,spread}...{right}z2; % lower diagonal
176 x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9; % bar
177 labels(1,2,3,8,9); endchar;
178
179 cmchar "Similarity sign";
180 compute_spread(.45x_height#,.55x_height#);
181 beginchar(oct"030",14u#,v_center(spread#+rule_thickness#));
182 adjust_fit(0,0);
183 pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
184 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
185 lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
186 bot y1=bot y3=-d; top y2=top y4=h;
187 draw z1{up}...z2{right}..{right}z3...{up}z4; % stroke
188 labels(1,2,3,4); endchar;
189
190 cmchar "Approximate equality sign";
191 compute_spread(.45x_height#,.55x_height#);
192 spread#':=spread#; spread':=spread; % the spread of `$=$'
193 compute_spread(.54x_height#,.66x_height#);
194 beginchar(oct"031",14u#,v_center(spread#'+spread#+rule_thickness#));
195 adjust_fit(0,0);
196 pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
197 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
198 lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
199 y1=y3; top y2=top y4=h; top y2-bot y1=spread';
200 draw z1{up}...z2{right}..{right}z3...{up}z4; % upper stroke
201 z1-z5=z2-z6=z3-z7=z4-z8=(0,spread);
202 draw z5{up}...z6{right}..{right}z7...{up}z8; % lower stroke
203 labels(1,2,3,4,5,6,7,8); endchar;
204
205 cmchar "Much less sign";
206 compute_spread(5/4x_height#,3/2x_height#);
207 beginchar(oct"034",18u#,v_center(spread#+rule_thickness#));
208 adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
209 lft x2=hround u-epsilon; x1=x3=hround 12.5u-x2;
210 y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
211 draw z1--z2--z3; % left diagonals
212 z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
213 draw z4--z5--z6; % right diagonals
214 labels(1,2,3,4,5,6); endchar;
215
216 cmchar "Much greater sign";
217 compute_spread(5/4x_height#,3/2x_height#);
218 beginchar(oct"035",18u#,v_center(spread#+rule_thickness#));
219 adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
220 lft x1=hround u-epsilon; x2=hround 12.5u-x1; x3=x1;
221 y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
222 draw z1--z2--z3; % left diagonals
223 z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
224 draw z4--z5--z6; % right diagonals
225 labels(1,2,3,4,5,6); endchar;
226
227 cmchar "Precedes sign";
228 compute_spread(5/4x_height#,3/2x_height#);
229 beginchar(oct"036",14u#,v_center(spread#+rule_thickness#));
230 adjust_fit(0,0); pickup rule.nib; autorounded;
231 lft x2=hround 1.5u-epsilon; x1=x3=w-x2;
232 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
233 draw z1{-u,-spread}...{left}z2; % upper diagonal
234 draw z3{-u,spread}...{left}z2; % lower diagonal
235 labels(1,2,3); endchar;
236
237 cmchar "Follows sign";
238 compute_spread(5/4x_height#,3/2x_height#);
239 beginchar(oct"037",14u#,v_center(spread#+rule_thickness#));
240 adjust_fit(0,0); pickup rule.nib; autorounded;
241 lft x1=hround 1.5u-epsilon; x2=w-x1; x3=x1;
242 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
243 draw z1{u,-spread}...{right}z2; % upper diagonal
244 draw z3{u,spread}...{right}z2; % lower diagonal
245 labels(1,2,3); endchar;
246
247 cmchar "Northeast arrow";
248 beginchar(oct"045",18u#,asc_height#,asc_depth#);
249 adjust_fit(0,0); pickup crisp.nib;
250 x1-.5rule_thickness=hround u; rt x0=hround(w-u);
251 y1-.5rule_thickness=-d; top y0=h;
252 numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
253 if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
254 pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
255 pos3(rule_thickness,theta); pos4(rule_thickness,theta);
256 z3-z0=(-4u,.36asc_height) rotated theta;
257 z4-z0=(-4u,-.36asc_height) rotated theta;
258 pos5(rule_thickness,-90); z5l=z0; pos6(rule_thickness,-180); z6l=z0;
259 z9=.2[.5[z3,z4],z0];
260 numeric t; path p; p=z4l{z9-z4}..z6r;
261 t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
262 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
263 ---z1l..z1r---subpath (t,0) of\\(z3l{z9-z3}..z5r)
264 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
265 penlabels(0,1,2,3,4,5,6,9); endchar;
266
267 cmchar "Southeast arrow";
268 beginchar(oct"046",18u#,asc_height#,asc_depth#);
269 adjust_fit(0,0); pickup crisp.nib;
270 x1-.5rule_thickness=hround u; rt x0=hround(w-u);
271 y1+.5rule_thickness=h; bot y0=-d;
272 numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
273 if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
274 pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
275 pos3(rule_thickness,theta); pos4(rule_thickness,theta);
276 z3-z0=(-4u,.36asc_height) rotated theta;
277 z4-z0=(-4u,-.36asc_height) rotated theta;
278 pos5(rule_thickness,180); z5l=z0; pos6(rule_thickness,90); z6l=z0;
279 z9=.2[.5[z3,z4],z0];
280 numeric t; path p; p=z4l{z9-z4}..z6r;
281 t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
282 filldraw z0..{z4-z9}z4r
283 --subpath (0,t) of\\(z4l{z9-z4}..z6r)
284 ---z1l..z1r---subpath (t,0) of\\(z3l{z9-z3}..z5r)
285 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
286 penlabels(0,1,2,3,4,5,6,9); endchar;
287
288 cmchar "Similar or equal sign";
289 compute_spread(.45x_height#,.55x_height#);
290 beginchar(oct"047",14u#,v_center(2spread#+rule_thickness#));
291 adjust_fit(0,0);
292 pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
293 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
294 lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
295 bot y1=bot y3=floor math_axis; top y2=top y4=h;
296 draw z1{up}...z2{right}..{right}z3...{up}z4; % stroke
297 pickup rule.nib; lft x5=hround u-eps; x6=w-x5; y5=y6=math_axis-spread;
298 draw z5--z6; % bar
299 labels(1,2,3,4,5,6); endchar;
300
301 cmchar "Double leftward arrow";
302 compute_spread(.45x_height#,.55x_height#);
303 beginchar(oct"050",18u#,v_center(spread#+rule_thickness#));
304 adjust_fit(0,0); pickup rule.nib;
305 lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
306 y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
307 draw z1--z7; draw z2--z8; % bars
308 pickup crisp.nib; lft x0=hround u-eps; y0=good.y math_axis;
309 pos3(rule_thickness,0); pos4(rule_thickness,0);
310 y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+6u+eps;
311 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
312 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
313 z9=.381966[.5[z3,z4],z0];
314 erase filldraw z0..{z3-z9}z3--(0,y3)
315 --(0,y4)--z4{z9-z4}..z0 & cycle; % erase excess
316 numeric t; path p; p=z4r{z9-z4}..z6r;
317 t=xpart(p intersectiontimes((0,y0)--(w,y0)));
318 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
319 --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle; % arrowhead
320 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
321
322 cmchar "Double rightward arrow";
323 compute_spread(.45x_height#,.55x_height#);
324 beginchar(oct"051",18u#,v_center(spread#+rule_thickness#));
325 adjust_fit(0,0); pickup rule.nib;
326 lft x1=hround u-eps; x2=x1; x7=x8=w-x1;
327 y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
328 draw z1--z7; draw z2--z8; % bars
329 pickup crisp.nib; rt x0=hround(w-u)+eps; y0=good.y math_axis;
330 pos3(rule_thickness,0); pos4(rule_thickness,0);
331 y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0-6u-eps;
332 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
333 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
334 z9=.381966[.5[z3,z4],z0];
335 erase filldraw z0..{z3-z9}z3--(w,y3)
336 --(w,y4)--z4{z9-z4}..z0 & cycle; % erase excess
337 numeric t; path p; p=z4l{z9-z4}..z6r;
338 t=xpart(p intersectiontimes((0,y0)--(w,y0)));
339 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
340 --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle; % arrowhead
341 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
342
343 cmchar "Double upward arrow";
344 beginchar(oct"052",11u#,asc_height#,asc_depth#);
345 adjust_fit(0,0); pickup rule.nib;
346 compute_spread(.45x_height#,.55x_height#);
347 bot y1=bot y2=-d-eps; top y7=h; y8=y7;
348 x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
349 draw z1--z7; draw z2--z8; % bars
350 pickup crisp.nib; top y0=h+eps; x0=good.x .5w;
351 pos3(rule_thickness,90); pos4(rule_thickness,90);
352 x2-x3=x4-x1=3u+eps; y3=y4=y0-.48asc_height-eps;
353 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
354 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
355 z9=.381966[.5[z3,z4],z0];
356 erase filldraw z0..{z3-z9}z3--(x3,h)
357 --(x4,h)--z4{z9-z4}..z0 & cycle; % erase excess
358 numeric t; path p; p=z4l{z9-z4}..z6r;
359 t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
360 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
361 --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle; % arrowhead
362 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
363
364 cmchar "Double downward arrow";
365 beginchar(oct"053",11u#,asc_height#,asc_depth#);
366 adjust_fit(0,0); pickup rule.nib;
367 compute_spread(.45x_height#,.55x_height#);
368 top y1=top y2=h+eps; bot y7=-d; y8=y7;
369 x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
370 draw z1--z7; draw z2--z8; % bars
371 pickup crisp.nib; bot y0=-d-eps; x0=good.x .5w;
372 pos3(rule_thickness,90); pos4(rule_thickness,90);
373 x2-x3=x4-x1=3u+eps; y3=y4=y0+.48asc_height-eps;
374 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
375 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
376 z9=.381966[.5[z3,z4],z0];
377 erase filldraw z0..{z3-z9}z3--(x3,-d)
378 --(x4,-d)--z4{z9-z4}..z0 & cycle; % erase excess
379 numeric t; path p; p=z4r{z9-z4}..z6r;
380 t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
381 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
382 --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle; % arrowhead
383 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
384
385 cmchar "Double left-and-right arrow";
386 compute_spread(.45x_height#,.55x_height#);
387 beginchar(oct"054",18u#,v_center(spread#+rule_thickness#));
388 adjust_fit(if monospace: -u#,-u# else: 0,0 fi); pickup rule.nib;
389 lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
390 y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
391 draw z1--z7; draw z2--z8; % bars
392 pickup crisp.nib; lft x0=hround u-o; y0=good.y math_axis;
393 pos3(rule_thickness,0); pos4(rule_thickness,0);
394 y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+5u+eps;
395 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
396 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
397 z9=.381966[.5[z3,z4],z0];
398 erase filldraw z0..{z3-z9}z3--(0,y3)
399 --(0,y4)--z4{z9-z4}..z0 & cycle; % erase excess at left
400 numeric t; path p; p=z4r{z9-z4}..z6r;
401 t=xpart(p intersectiontimes((0,y0)--(w,y0)));
402 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
403 --subpath (t,0) of\\(z3r{z9-z3}..z5r)
404 --z3l{z9-z3}..z0 & cycle; % left arrowhead
405 rt x10=hround(w-u)+o; y10=good.y math_axis;
406 pos13(rule_thickness,0); pos14(rule_thickness,0);
407 y13=y3; y14=y4; x13=x14=x10-5u-eps;
408 pos15(rule_thickness,angle(z14-z10)); z15l=z10;
409 pos16(rule_thickness,angle(z13-z10)); z16l=z10;
410 z19=.381966[.5[z13,z14],z10];
411 erase filldraw z10..{z13-z19}z13--(w,y13)
412 --(w,y14)--z14{z19-z14}..z10 & cycle; % erase excess at right
413 numeric t; path p; p=z14l{z19-z14}..z16r;
414 t=xpart(p intersectiontimes((0,y10)--(w,y10)));
415 filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
416 --subpath (t,0) of\\(z13l{z19-z13}..z15r)
417 --z13r{z19-z13}..z10 & cycle; % right arrowhead
418 penlabels(0,1,2,3,4,5,6,7,8,9,10,13,14,15,16,19); endchar;
419
420 cmchar "Northwest arrow";
421 beginchar(oct"055",18u#,asc_height#,asc_depth#);
422 adjust_fit(0,0); pickup crisp.nib;
423 x1+.5rule_thickness=hround(w-u); lft x0=hround u;
424 y1-.5rule_thickness=-d; top y0=h;
425 numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
426 if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
427 pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
428 pos3(rule_thickness,-180+theta); pos4(rule_thickness,-180+theta);
429 z4-z0=(4u,.36asc_height) rotated theta;
430 z3-z0=(4u,-.36asc_height) rotated theta;
431 pos5(rule_thickness,0); z5l=z0; pos6(rule_thickness,-90); z6l=z0;
432 z9=.2[.5[z3,z4],z0];
433 numeric t; path p; p=z4l{z9-z4}..z6r;
434 t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
435 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
436 ---z1l..z1r---subpath (t,0) of\\(z3l{z9-z3}..z5r)
437 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
438 penlabels(0,1,2,3,4,5,6,9); endchar;
439
440 cmchar "Southwest arrow";
441 beginchar(oct"056",18u#,asc_height#,asc_depth#);
442 adjust_fit(0,0); pickup crisp.nib;
443 x1+.5rule_thickness=hround(w-u); lft x0=hround u;
444 y1+.5rule_thickness=h; bot y0=-d;
445 numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
446 if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
447 pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
448 pos3(rule_thickness,-180+theta); pos4(rule_thickness,-180+theta);
449 z4-z0=(4u,.36asc_height) rotated theta;
450 z3-z0=(4u,-.36asc_height) rotated theta;
451 pos5(rule_thickness,90); z5l=z0; pos6(rule_thickness,0); z6l=z0;
452 z9=.2[.5[z3,z4],z0];
453 numeric t; path p; p=z4l{z9-z4}..z6r;
454 t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
455 filldraw z0..{z4-z9}z4r
456 --subpath (0,t) of\\(z4l{z9-z4}..z6r)
457 ---z1l..z1r---subpath (t,0) of\\(z3l{z9-z3}..z5r)
458 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
459 penlabels(0,1,2,3,4,5,6,9); endchar;
460
461 cmchar "Proportionality sign";
462 beginchar(oct"057",16.5u#,x_height#,0);
463 italcorr x_height#*slant-.5u#;
464 adjust_fit(0,-2.5u#); pickup fine.nib;
465 numeric theta,phi; phi=angle(3u,h); theta=angle(5u,-h);
466 pos1(vair,180); pos2(.5[vair,stem],90+.5theta); pos3(stem,90+theta);
467 pos4(stem,90+theta); pos5(.5[vair,stem],90+.5theta);
468 pos6(vair,180); pos7(.2[vair,stem],270+.5phi);
469 pos8(.3[vair,stem],270+phi); pos9(.2[vair,stem],270+.5phi);
470 lft x1r=w-rt x6l=hround u; x2=x9=.4[x1,x8]; x5=x7=.6[x8,x6];
471 if monospace: x2l:=x2r; x5r:=x5l; x7r:=x7l; x9l:=x9r; fi
472 y1=y6=.5h; top y2r=top y7l=h+oo; bot y5l=bot y9r=-oo;
473 x8=.5[x3,x4]=.5w; y8=.5[y3,y4]=.5h;
474 y3-y4=h/3; z3-z4=whatever*dir theta;
475 filldraw stroke z1e{up}...z2e{right}...z3e---z4e...z5e{right}...z6e{up}
476 ...z7e{left}...{-dir phi}z8e...{left}z9e...z1e{up}; % `infinity' bowls
477 erase fill (w-3.5u,h+o)--(w,h+o)
478 --(w,-o)--(w-3.5u,-o)--cycle; % erase excess
479 penlabels(1,2,3,4,5,6,7,8,9); endchar;
480
481 cmchar "Prime symbol (intended as superscript only)";
482 beginchar(oct"060",3u#+max(1.75u#,curve#+2(curve#-stem#)),
483 .8asc_height#,0);
484 adjust_fit(0,0); pickup fine.nib;
485 numeric light_stem,heavy_stem;
486 light_stem=if hefty: vair else: hround .5[vair,stem] fi;
487 heavy_stem=hround(bold+2bigdw);
488 x1+.5heavy_stem=hround(w-.25u); y1+.5heavy_stem=h;
489 x2-.5light_stem=hround .5u; y2=1/12asc_height;
490 numeric theta; theta=angle(z1-z2)-90;
491 pos1(heavy_stem,theta); pos2(light_stem,theta);
492 filldraw circ_stroke z1e--z2e; % diagonal
493 penlabels(1,2); endchar;
494
495 cmchar "Ownership sign";
496 compute_spread(5/4x_height#,3/2x_height#);
497 beginchar(oct"063",12u#,v_center(spread#+rule_thickness#));
498 adjust_fit(0,0); pickup rule.nib; autorounded;
499 lft x1=hround 1.5u-eps; x1=x3=x6=w-x2;
500 y1-y3=spread; y2=y6=.5[y1,y3]=math_axis;
501 x4=x5=.5w-u; y4=y1; y5=y3;
502 draw z1---z4...z2{down}...z5---z3; % arc and bars
503 draw z2--z6; % middle bar
504 labels(1,2,3,4,5,6); endchar;
505
506 cmchar "Large triangle";
507 beginchar(oct"064",16u#,asc_height#,desc_depth#);
508 adjust_fit(0,0); pickup rule.nib;
509 bot y1=0; y2=y1; top y3=h+o;
510 .5[x1,x2]=x3=good.x .5w; center_on(x3); lft x1=hround(.5w-u*sqrt48);
511 draw z1--z2--z3--cycle; % stroke
512 labels(1,2,3); endchar;
513
514 cmchar "Large inverted triangle";
515 beginchar(oct"065",16u#,asc_height#,desc_depth#);
516 adjust_fit(0,0); pickup rule.nib;
517 top y1=h-d; y2=y1; bot y3=-d-o;
518 .5[x1,x2]=x3=good.x .5w; center_on(x3); lft x1=hround(.5w-u*sqrt48);
519 draw z1--z2--z3--cycle; % stroke
520 labels(1,2,3); endchar;
521
522 cmchar "Zero-width slash to negate a relation";
523 beginchar(oct"066",14u#,asc_height#,asc_depth#);
524 adjust_fit(0,0); pickup rule.nib;
525 rt x5=hround(w-2.5u)-eps; lft x6=hround 2.5u+eps;
526 top y5=h+o; .5[y5,y6]=math_axis;
527 draw z5--z6; % diagonal
528 labels(5,6); zero_width; endchar;
529
530 cmchar "Maps-to relation";
531 compute_spread(.45x_height#,.55x_height#);
532 beginchar(oct"067",14u#,v_center(spread#+rule_thickness#));
533 % this character should be followed immediately by minus or rightarrow
534 adjust_fit(0,0); pickup rule.nib;
535 lft x1=hround u; x2=x1+.5u; x3=x4=x1;
536 y1=y2=math_axis; y1-y3=y4-y1=.24asc_height+eps;
537 draw z3--z4; % stem
538 draw z1--z2; % bar stub
539 labels(1,2,3,4); zero_width; endchar;
540
541 cmchar "Empty set symbol";
542 beginchar(oct"073",9u#,body_height#,body_height#-asc_height#);
543 adjust_fit(0,0);
544 penpos1(vair,90); penpos3(vair,-90); penpos2(stem,180); penpos4(stem,0);
545 if not monospace: interim superness:=sqrt(more_super*hein_super); fi
546 x2r=hround max(.7u,1.45u-.5stem);
547 x4r=w-x2r; x1=x3=.5w; y1r=asc_height+o; y3r=-o;
548 y2=y4=.5asc_height-vair_corr; y2l:=y4l:=.52asc_height;
549 penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
550 & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
551 pickup rule.nib; lft x6=hround 2u-eps; x5=w-x6; top y5=h+o; bot y6=-d-o;
552 draw z5--z6; % diagonal
553 penlabels(1,2,3,4,5,6); endchar;
554
555 cmchar "Uppercase Fraktur R";
556 beginchar(oct"074",13u#,asc_height#,0);
557 adjust_fit(0,0); pickup fine.nib;
558 if hefty:
559 pos1(vair,15); pos2(vair,90); pos3(vair,190);
560 pos4(vair,210); pos5(vair,190);
561 pos10(vair,-165); pos11(vair,-165);
562 else:
563 pos1(hair,0); pos2(vair,90); pos3(1/6[hair,stem],190);
564 pos4(1/4[hair,stem],210); pos5(1/8[hair,stem],190);
565 pos10(hair,-135); pos11(hair,-135);
566 fi
567 pos6(vair,90); pos7(cap_stem,0); pos8(cap_stem,0);
568 pos9(vair,-90);
569 pos12(vair,135); pos13(vair,135);
570 lft x1l=lft x5r=hround u; x2=.4[x1,x3];
571 if hefty: x3=0.5[x1r,x7l]; else: rt x3l=hround 3.5u; fi
572 x4=.6[x3,x5];
573 x6=3u; lft x7=hround(6u-.5cap_stem); x8=x7;
574 if hefty: x9=3.3u; else: x9=3.5u; fi
575 x10=5/3u; x11=4/3u; x12=u; x13=2u;
576 y1=.47h; bot y2l=vround.35h; y3=1/3[y2,y6]; y5=3/4[y2,y6]; y4=.6[y3,y5];
577 top y6r=h+oo; y7=.64h; y8=.57y7; bot y9r=-o;
578 y10=1/6y7; y12=1/5y7; y13=1/4y7;
579 z11-z10=whatever*(z13-z12) rotated 90;
580 filldraw stroke z1e{down}...z2e{right}...z3e{up}..z4e..z5e{up}
581 ...pulled_arc.e(6,7)..pulled_arc.e(8,9)
582 ...z10e---z11e; % flourish and left stem
583 if hefty: else: filldraw stroke z12e--z13e; fi % cross
584 pos20(cap_bar,180); pos21(cap_bar,90);
585 x20=x7; y20=.75h; rt x21=hround(w-3.5u+.5cap_stem); top y21r=h+o;
586 filldraw stroke z20e{up}...{right}z21e; % top of bowl
587 rt x22r=hround(w-.1u); y22r=good.y .64h;
588 numeric theta; theta=angle(z21r-z22r);
589 pos22(cap_stem,theta-90); pos23(cap_bar,theta); z22l=z23l;
590 path p; p=z20{up}...(z21--(w,y21));
591 z=p intersectionpoint(z22l--z22l+(h,0) rotated theta);
592 filldraw z--z21r--z22r--z22l--cycle; % diagonal of bowl
593 pos24(cap_bar,90); pos25(cap_bar,90); x24=w-4u; x25=x7;
594 y24=y25; top y24r=vround(.52h+.5cap_bar);
595 filldraw stroke z23e{dir(theta+90)}...z24e---z25e; % bottom of bowl
596 if hefty:
597 pos26(cap_stem,0); pos27(cap_stem,0);
598 pos28(vair,90); pos30(vair,150);
599 x26=x24; x27=x26+.25u; x28l=w-2.5u; y26=y24r; y27=1/3y26; bot y28l=-o;
600 x30l=good.x(w-.5u); y30l=good.y .09h;
601 filldraw stroke z26e---z27e..{right}z28e..z30e;
602 else:
603 pos26(cap_stem,0); pos27(cap_stem,0); pos28(cap_stem,0);
604 x26=x24; x27=x26+.25u; x28l=w-2.5u; y26=y24r; y27=1/3y26; bot y28=-o;
605 filldraw stroke z26e--z27e...{right}z28e; % lower diagonal
606 pos29(cap_bar,0); pos30(cap_bar,-30); z29l=z28l;
607 x30r=good.x(w-.5u); y30r=good.y .09h;
608 erase filldraw z29r--z28r--z30r--cycle; % erase excess
609 filldraw stroke z29e--z30e; % serif of lower diagonal
610 fi
611 %% \begingroup\thinmuskip=3mu
612 penlabels(1,2,3,4,5,6,7,8,9,10,11,if hefty: else: 12,13, fi 20,21,22,23,24,25,26,27,28,29,30);
613 %% \endgroup
614 endchar;
615
616 cmchar "Uppercase Fraktur I";
617 beginchar(oct"075",13u#,asc_height#,0);
618 adjust_fit(0,0); pickup fine.nib;
619 if hefty:
620 pos1(vair,270); pos2(vair,180); pos3(vair,90);
621 pos4(cap_stem,45); pos5(vair,90); pos6(vair,180);
622 x1=5u; lft x2r=hround u; x3=x1; x4=0.5[x3,x5];
623 x5=w-2.5u; rt x6l=hround(w-.5u);
624 top y1l=vround.5h; y2=.5[y1,y3]; top y3r=h+oo;
625 y4=.5[y5,y3]; y6=.6[y5,y3]; bot y5l=ceiling(1/6[x_height,h]);
626 filldraw stroke z1e{left}...z2e{up}...z3e{right}
627 ..z4e..z5e{right}...{up}z6e; % upper stroke
628 pos7(vair,-90); pos9(vair,-90);
629 lft x7=hround 1.3u; y7=0.25h; x9=.5w+u; bot y9r=-oo;
630 z8 = 0.5[z7,z9]; pos8(cap_stem,-135);
631 pos10(cap_stem,0); pos11(cap_stem,0); pos12(vair,-90); pos13(vair,-180);
632 x10=w-2.5u; x11r=x12-u; x12=x5; x13=x6;
633 y10=1/3y12; y11=3/4y12; top y12l=x_height; y13=4/5y12;
634 filldraw stroke z13e{up}..z12e{left} ..z11e{down} ..z10e{down} ..z9e{left}..z8e{dir 135}..z7e{left};
635 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13);
636 else:
637 pos1(vair,270); pos2(cap_hair,180); pos3(vair,90);
638 pos4(cap_stem,0); pos5(vair,90); pos6(cap_hair,180);
639 x1=5u; lft x2r=hround u; x3=.5[x2,x4l]; x4r=x5-.75u;
640 x5=.5[x4l,x6l]; rt x6l=hround(w-.5u);
641 top y1l=vround.5h; y2=.5[y1,y3]; top y3r=h+oo;
642 y4=.2[y5,y3]; y6=.3[y5,y3]; bot y5l=ceiling(1/6[x_height,h]);
643 filldraw stroke z1e{left}...z2e{up}...z3e{right}
644 ..z4e..z5e{right}...{up}z6e; % upper stroke
645 pos7(vair,90); pos8(cap_stem,0); pos9(cap_stem,0);
646 lft x7=hround u; z7r=z8l; x9=.5w+u; y8=good.y .25h; bot y9=-oo;
647 filldraw z8l---z8r..{right}z9r+(0,eps)
648 --z9r---z9l..{left}z7l--cycle; % lower left stroke
649 pos10(cap_stem,0); pos11(cap_stem,0); pos12(vair,-90); pos13(cap_hair,-180);
650 x10=w-2.5u; x11r=x12-u; x12=x5; x13=x6;
651 y10=1/3y12; y11=3/4y12; top y12l=x_height; y13=4/5y12;
652 filldraw z9l+(0,eps){right}...{up}z10l
653 --z10r{down}...z9r---z9l--cycle; % lower link
654 filldraw stroke z10e{up}...z11e{up}
655 ...z12e{right}...{down}z13e; % lower right stroke
656 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13);
657 fi
658 endchar;
659
660 cmchar "Lattice top";
661 beginchar(oct"076",14u#,asc_height#,0);
662 adjust_fit(0,0); pickup rule.nib;
663 x1=x2=good.x .5w; center_on(x1); lft x3=hround u; x4=w-x3;
664 bot y1=0; y2-y1=x4-x3;
665 if top y2>h: y2:=bot h; fi
666 y3=y4=y2;
667 draw z1--z2; % stem
668 draw z3--z4; % bar
669 labels(1,2,3,4); endchar;
670
671 cmchar "Perpendicular sign or lattice bottom";
672 beginchar(oct"077",14u#,asc_height#,0);
673 adjust_fit(0,0); pickup rule.nib;
674 x1=x2=good.x .5w; center_on(x1); lft x3=hround u; x4=w-x3;
675 bot y1=0; y2-y1=x4-x3;
676 if top y2>h: y2:=bot h; fi
677 y3=y4=y1;
678 draw z1--z2; % stem
679 draw z3--z4; % bar
680 labels(1,2,3,4); endchar;
681
682 cmchar "Hebrew letter aleph";
683 beginchar(oct"100",11u#,asc_height#,0);
684 adjust_fit(0,0); pickup fine.nib;
685 numeric aleph_stroke, aleph_short_stroke;
686 if hefty: aleph_stroke = min(cap_stem,1.5*vair)/sind 45;
687 aleph_short_stroke = aleph_stroke * 0.85;
688 else: aleph_stroke = aleph_short_stroke = cap_stem; fi
689 pos1(aleph_stroke,75); pos2(aleph_stroke,90);
690 pos3(aleph_stroke,90); pos4(aleph_stroke,75);
691 lft x1l=hround u-eps; x2=2.5u=w-x3; rt x4r=hround(w-u)+eps;
692 top y1r=h; bot y4l=0; z2=whatever[z1l,z4r]; z3=whatever[z1l,z4r];
693 filldraw z1r{4(x1l-x1r),y1l-y1r}...{down}z1l...z2l
694 ---z3l...{down}z4l{4(x4r-x4l),y4r-y4l}...{up}z4r...z3r
695 ---z2r...{up}cycle; % long diagonal
696 pos5(aleph_short_stroke,75); pos6(aleph_short_stroke,90);
697 pos7(aleph_short_stroke,75);
698 lft x5l=hround(w-4u if hefty: -cap_stem/2 fi)-eps;
699 x6=.5[x5,x7]; x7=x4;
700 y5r=y1r; bot y7l=x_height-o if hefty: -cap_stem/3 fi;
701 z6=whatever[z5l,z7r];
702 filldraw z5r{4(x5l-x5r),y5l-y5r}...{down}z5l
703 ...z6l{z7r-z5l}...{down}z7l{4(x7r-x7l),y7r-y7l}...{up}z7r
704 ...z6r{z5l-z7l}...{up}cycle; % short diagonal
705 if hefty: pos8(vair,0); pos9(vair,0);
706 else: pos8(cap_hair,0); pos9(cap_hair,0); fi
707 z8=z6; x9=x8-.75u; z9=whatever[z2,z3];
708 filldraw stroke z8e{down}..{down}z9e; % right stem
709 pos10(cap_hair,-30);
710 lft x11l=hround 1.5u; x10=.4[x11,.5w]; z10=whatever[z2,z3];
711 if hefty:
712 pos11(0.3[vair,stem],0);
713 pos12(0.3[vair,cap_curve],0);
714 y11 = 0.6 y10;
715 x12 = x10;
716 y12 = 1.5u;
717 pos13(vair,-90); pos14(vair/2,75);
718 x14=x1l; y14=y13l;
719 bot y13r=-o; x13 = 0.5[x1l,x12l];
720 filldraw z12r{down}..z13r{left}..z14{up} & z14---z13l{right}..z12l{up}--cycle;
721 else:
722 pos11(stem,0); pos12(cap_curve,0);
723 y11=.5y10;
724 x10=x12;
725 pos13(cap_curve,0); pos14(vair,90);
726 lft x13l=hround u; z13l=z14l; y12=.2[y14r,y11]; bot y13=0;
727 filldraw z12r{down}...z13r---z13l--z14r{right}...{up}z12l--cycle; % flourish
728 fi
729
730 filldraw stroke z10e{2(x11-x10),y11-y10}
731 ...z11e{down}..{down}z12e; % left stem
732 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
733
734 cmchar "Multiset union sign";
735 beginchar(oct"135",12u#,.8asc_height#,0); autorounded;
736 adjust_fit(if monospace:-.5u#,-.5u# else: 0,0 fi); pickup rule.nib;
737 lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
738 y1=good.y h+o; bot y3=-o; y2=y4=2/3[y1,y3]; y5=y1;
739 draw z1---z2...z3...z4---z5; % stems and cup
740 y8=y9=.47[y1,y3]; x8=w-x9=x1+2rule_thickness+eps;
741 if (x9-x8) < (x5-x1)/2: x8:=x1+1.5rule_thickness+eps; x9:=w-x8; fi
742 x6=x7=x3; .5[y6,y7]=y8; y7-y6=x9-x8;
743 draw z8--z9; draw z6--z7; % enclosed plus sign
744 labels(1,2,3,4,5,6,7,8,9); endchar;
745
746 cmchar "Left turnstile";
747 beginchar(oct"140",11u#,asc_height#,0);
748 adjust_fit(0,0); pickup rule.nib;
749 .5[y1,y2]=y3=y4; x1=x2=x3;
750 lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
751 draw z1--z2; % stem
752 draw z3--z4; % bar
753 labels(1,2,3,4); endchar;
754
755 cmchar "Right turnstile";
756 beginchar(oct"141",11u#,asc_height#,0);
757 adjust_fit(0,0); pickup rule.nib;
758 .5[y1,y2]=y3=y4; x1=x2=x4;
759 lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
760 draw z1--z2; % stem
761 draw z3--z4; % bar
762 labels(1,2,3,4); endchar;
763
764 cmchar "Left floor bracket";
765 beginchar(oct"142",8u#,body_height#,paren_depth#);
766 adjust_fit(0,0); pickup rule.nib;
767 x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
768 top y1=h; .5[y1,y2]=math_axis; y3=y2;
769 draw z1--z2--z3; % stem and bar
770 labels(1,2,3); endchar;
771
772 cmchar "Right floor bracket";
773 beginchar(oct"143",8u#,body_height#,paren_depth#);
774 adjust_fit(0,0); pickup rule.nib;
775 x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
776 top y1=h; .5[y1,y2]=math_axis; y3=y2;
777 draw z1--z2--z3; % stem and bar
778 labels(1,2,3); endchar;
779
780 cmchar "Left ceiling bracket";
781 beginchar(oct"144",8u#,body_height#,paren_depth#);
782 adjust_fit(0,0); pickup rule.nib;
783 x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
784 top y1=h; .5[y1,y2]=math_axis; y3=y1;
785 draw z3--z1--z2; % stem and bar
786 labels(1,2,3); endchar;
787
788 cmchar "Right ceiling bracket";
789 beginchar(oct"145",8u#,body_height#,paren_depth#);
790 adjust_fit(0,0); pickup rule.nib;
791 x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
792 top y1=h; .5[y1,y2]=math_axis; y3=y1;
793 draw z3--z1--z2; % stem and bar
794 labels(1,2,3); endchar;
795
796 cmchar "Left angle bracket";
797 beginchar(oct"150",7u#,body_height#,paren_depth#);
798 adjust_fit(0,0); pickup rule.nib;
799 rt x1=hround(w-u)+eps; x1=x3; lft x2=hround 2u-1-eps;
800 top y1=h+eps; .5[y1,y3]=y2=math_axis;
801 draw z1--z2--z3; % diagonals
802 labels(1,2,3); endchar;
803
804 cmchar "Right angle bracket";
805 beginchar(oct"151",7u#,body_height#,paren_depth#);
806 adjust_fit(0,0); pickup rule.nib;
807 rt(w-x1)=hround(w-u)+eps; x1=x3; lft(w-x2)=hround 2u-1-eps;
808 top y1=h+eps; .5[y1,y3]=y2=math_axis;
809 draw z1--z2--z3; % diagonals
810 labels(1,2,3); endchar;
811
812 cmchar "Double vertical line (norm or cardinality)";
813 beginchar(oct"153",9u#,body_height#,paren_depth#);
814 adjust_fit(0,0); pickup rule.nib;
815 x1=x2; top y1=h; .5[y1,y2]=math_axis;
816 x3=x4=w-x1; y3=y1; y4=y2;
817 compute_spread(.45x_height#,.55x_height#); x3-x1=spread;
818 draw z1--z2; draw z3--z4; % stems
819 labels(1,2,3,4); endchar;
820
821 cmchar "Up-and-down arrow";
822 beginchar(oct"154",9u#,body_height#,paren_depth#);
823 adjust_fit(0,0); pickup crisp.nib;
824 pos1(rule_thickness,0); pos2(rule_thickness,0);
825 pos3(rule_thickness,90); pos4(rule_thickness,90);
826 lft x1l=hround(.5w-.5rule_thickness); y1=.5[-d,h];
827 x0=x1=x2; bot y0=-d-o; x0-x3=x4-x0=4u+eps;
828 y3=y4=y0+.36asc_height+eps;
829 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
830 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
831 z9=.2[.5[z3,z4],z0];
832 numeric t; path p; p=z4r{z9-z4}..z6r;
833 t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
834 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
835 ---z1r..z1l---subpath (t,0) of\\(z3r{z9-z3}..z5r)
836 --z3l{z9-z3}..z0 & cycle; % lower arrowhead and stem
837 pos11(rule_thickness,0); pos12(rule_thickness,0); z11=z1;
838 pos13(rule_thickness,90); pos14(rule_thickness,90);
839 x10=x11=x12; top y10=h+o; x10-x13=x14-x10=4u+eps;
840 y13=y14=y10-.36asc_height-eps;
841 pos15(rule_thickness,angle(z14-z10)); z15l=z10;
842 pos16(rule_thickness,angle(z13-z10)); z16l=z10;
843 z19=.2[.5[z13,z14],z10];
844 numeric t; path p; p=z14l{z19-z14}..z16r;
845 t=xpart(p intersectiontimes((x12r,-d)--(x12r,h))); y12=ypart point t of p;
846 filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
847 ---z11r..z11l---subpath (t,0) of\\(z13l{z19-z13}..z15r)
848 --z13r{z19-z13}..z10 & cycle; % upper arrowhead and stem
849 penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14,15,16,19); endchar;
850
851 cmchar "Double up-and-down arrow";
852 beginchar(oct"155",11u#,body_height#,paren_depth#);
853 adjust_fit(0,0); pickup rule.nib;
854 compute_spread(.45x_height#,.55x_height#);
855 bot y1=bot y2=-d-eps; top y7=h; y8=y7;
856 x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
857 draw z1--z7; draw z2--z8; % bars
858 pickup crisp.nib; top y0=h+o; x0=good.x .5w;
859 pos3(rule_thickness,90); pos4(rule_thickness,90);
860 x2-x3=x4-x1=3u+eps; y3=y4=y0-.4asc_height-eps;
861 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
862 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
863 z9=.381966[.5[z3,z4],z0];
864 erase filldraw z0..{z3-z9}z3--(x3,h)
865 --(x4,h)--z4{z9-z4}..z0 & cycle; % erase excess at top
866 numeric t; path p; p=z4l{z9-z4}..z6r;
867 t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
868 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
869 --subpath (t,0) of\\(z3l{z9-z3}..z5r)
870 --z3r{z9-z3}..z0 & cycle; % top arrowhead
871 bot y10=-d-o; x10=good.x .5w;
872 pos13(rule_thickness,90); pos14(rule_thickness,90);
873 x13=x3; x14=x4; y13=y14=y10+.4asc_height-eps;
874 pos15(rule_thickness,angle(z14-z10)); z15l=z10;
875 pos16(rule_thickness,angle(z13-z10)); z16l=z10;
876 z19=.381966[.5[z13,z14],z10];
877 erase filldraw z10..{z13-z19}z13--(x13,-d)
878 --(x14,-d)--z14{z19-z14}..z10 & cycle; % erase excess at bottom
879 numeric t; path p; p=z14r{z19-z14}..z16r;
880 t=xpart(p intersectiontimes((x10,-d)--(x10,h)));
881 filldraw z10..{z14-z19}z14l--subpath (0,t) of\\(z14r{z19-z14}..z16r)
882 --subpath (t,0) of\\(z13r{z19-z13}..z15r)
883 --z13l{z19-z13}..z10 & cycle; % bottom arrowhead
884 penlabels(0,1,2,3,4,5,6,7,8,9,13,14,15,16,19); endchar;
885
886 cmchar "Wreath product";
887 beginchar(oct"157",5u#,asc_height#,asc_depth#);
888 adjust_fit(if monospace: u#,u# else: 0,0 fi);
889 pickup pencircle yscaled .7rule_thickness xscaled 1.4rule_thickness;
890 % If rule_thickness is too big, this doesn't wiggle enough
891 % so we shrink the pen
892 if (w-2u) < 2*(rt 0 - lft 0): pickup pencircle xscaled ((w-2u)/2) yscaled ((w-2u)/4); fi
893 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
894 lft x1=lft x3=hround u; x2=x4=w-x1;
895 top y1=vround .75[math_axis,h];
896 .5[y1,y4]=.5[y2,y3]=math_axis; y1-y2=1/4(y1-y4);
897 draw z1{right}...z2{down}..{down}z3...{right}z4; % stroke
898 labels(1,2,3,4); endchar;
899
900 cmchar "Radical sign";
901 beginchar(oct"160",15u#,rule_thickness#,
902 body_height#+paren_depth#-rule_thickness#);
903 big_sqrt; endchar;
904
905 cmchar "Amalgamation symbol or coproduct symbol";
906 beginchar(oct"161",13u#+width_adj#,cap_height#,0);
907 italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
908 adjust_fit(cap_serif_fit#,cap_serif_fit#);
909 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
910 pos3(cap_stem,0); pos4(cap_stem,0);
911 lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
912 top y1=top y3=h; bot y2=bot y4=0;
913 filldraw stroke z1e--z2e; % left stem
914 filldraw stroke z3e--z4e; % right stem
915 penpos5(cap_bar,90); penpos6(cap_bar,90);
916 x5=x1; x6=x3; y5=y6; y5l=0;
917 fill stroke z5e--z6e; % bar
918 if serifs: numeric inner_jut;
919 if rt x1r+cap_jut+u+2<=lft x3l-cap_jut: inner_jut=cap_jut;
920 else: rt x1r+inner_jut+u+2=lft x3l-inner_jut; fi
921 dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut); % upper left serif
922 nodish_serif(2,1,c,1/3,cap_jut,d,1/3,eps); % lower left serif
923 dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut); % upper right serif
924 nodish_serif(4,3,g,1/3,eps,h,1/3,cap_jut); % lower right serif
925 else:
926 nodish_serif(2,1,c,1/3,I_cap_jut,d,1/3,eps); % lower left serif
927 nodish_serif(4,3,g,1/3,eps,h,1/3,I_cap_jut); % lower right serif
928 fi
929 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
930
931 cmchar "Nabla or backwards-difference operator";
932 beginchar(oct"162",15u#,cap_height#,0);
933 adjust_fit(0,0);
934 numeric right_stem,alpha;
935 right_stem=cap_hair if hefty: -3stem_corr fi;
936 x1l=w-x4r=.75u; y1=y4=h;
937 x2-x1=x4-x3; x3l=x2l+apex_corr; y2=y3=-apex_o-apex_oo;
938 alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
939 penpos1(alpha*cap_stem,0); penpos2(alpha*cap_stem,0);
940 penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
941 fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle; % triangle
942 z0=whatever[z1r,z2r]=whatever[z3l,z4l];
943 y5=y6=h-cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
944 if y0>cap_notch_cut: y0:=cap_notch_cut;
945 unfill z0+.5right{up}...{z4-z3}z6--z5{z2-z1}
946 ...{down}z0+.5left--cycle; % counter
947 else: unfill z0--z5--z6--cycle; fi % counter
948 penlabels(0,1,2,3,4,5,6); endchar;
949
950 cmchar "Square set union sign (Scott lub)";
951 beginchar(oct"164",12u#,.8asc_height#,0);
952 adjust_fit(0,0); pickup rule.nib;
953 lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
954 y1=good.y h+o; bot y2=0; y4=y2; y5=y1;
955 draw z1---z2---z4---z5; % stems and bar
956 labels(1,2,4,5); endchar;
957
958 cmchar "Square set intersection sign (Scott glb)";
959 beginchar(oct"165",12u#,.8asc_height#,0);
960 adjust_fit(0,0); pickup rule.nib;
961 lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
962 y2=good.y h+o; bot y1=0; y4=y2; y5=y1;
963 draw z1---z2---z4---z5; % stems and bar
964 labels(1,2,4,5); endchar;
965
966 cmchar "Square subset or equal to sign";
967 compute_spread(.45x_height#,.55x_height#);
968 spread#':=spread#; spread':=spread; % the spread of `$=$'
969 compute_spread(5/4x_height#,3/2x_height#);
970 beginchar(oct"166",14u#,v_center(spread#'+spread#+rule_thickness#));
971 adjust_fit(0,0); pickup rule.nib;
972 lft x2=hround(1.5u+oo); x1=x4=hround(w-1.5u)+eps; x3=x2;
973 y1-y4=spread; y2=y1; y3=y4; top y1=h;
974 draw z1--z2--z3--z4; % bars and stem
975 x8=x1; x9=x2-oo-eps; y8=y9; y4-y9=spread';
976 draw z8--z9; % lower bar
977 labels(1,2,3,4,8,9); endchar;
978
979 cmchar "Square superset or equal to sign";
980 compute_spread(.45x_height#,.55x_height#);
981 spread#':=spread#; spread':=spread; % the spread of `$=$'
982 compute_spread(5/4x_height#,3/2x_height#);
983 beginchar(oct"167",14u#,v_center(spread#'+spread#+rule_thickness#));
984 adjust_fit(0,0); pickup rule.nib;
985 x1=x4=hround 1.5u-eps; rt x2=hround(w-1.5u-oo); x3=x2;
986 y1-y4=spread; y2=y1; y3=y4; top y1=h;
987 draw z1--z2--z3--z4; % bars and stem
988 x8=x1; x9=x2+oo+eps; y8=y9; y4-y9=spread';
989 draw z8--z9; % lower bar
990 labels(1,2,3,4,8,9); endchar;
991
992 cmchar "Section sign";
993 beginchar(oct"170",6.5u#+max(1.5u#,stem#),asc_height#,desc_depth#);
994 adjust_fit(0,0); pickup fine.nib;
995 numeric sstem; sstem=hround .75[hair,stem];
996 if serifs:
997 pos0(stem,0); pos1(hair,0); pos2(vair,90);
998 pos8(vair,-90); pos9(hair,-180); pos10(stem,-180);
999 else:
1000 pos0(vair,0); pos1(vair,0); pos2(vair,90);
1001 pos8(vair,-90); pos9(vair,-180); pos10(vair,-180); fi
1002 pos3(sstem,180); pos4(vair,270);
1003 pos5'(sstem,0); pos5(sstem,180);
1004 pos6(vair,90); pos7(sstem,0);
1005 top y2r=h+oo; bot y8r=-d-oo; y2-y1=y9-y8=(y2-y8)/8;
1006 y3=.52[y4,y2]; y5=.52[y4,y6]; y7=.52[y6,y8]; y5'=.52[y6,y4];
1007 y2-y4=y4-y6=y6-y8;
1008 rt x1r=hround(w-1.5u); lft x3r=hround 1.25u;
1009 x4=x6=.5w; x5=x7=w-x3; x5'=x3; x9=w-x1;
1010 if serifs: x2=x8=.5w; else: x2=w-x8=.5[x3l,x1l]; fi
1011 sansbulb(2,1,0); sansbulb(8,9,10);
1012 filldraw stroke z2e{left}...z3e{down}...z4e{3(x5-x3),y5-y3}
1013 ...z5e{down}...{left}z6e; % upper stroke
1014 filldraw stroke z4e{left}...z5'e{down}...z6e{3(x7-x5'),y7-y5'}
1015 ...z7e{down}...{left}z8e; % upper stroke
1016 penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
1017
1018 cmchar "Dagger mark";
1019 beginchar(oct"171",8u#,asc_height#,desc_depth#);
1020 adjust_fit(0,0); pickup fine.nib;
1021 pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
1022 pos4(if hefty: thin_join else: hair fi,0);
1023 pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
1024 x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); center_on(x1);
1025 x5-.5stem=hround u; x6=w-x5;
1026 y1+.5stem=h+oo; y2=y5=y6; y3=.57y2;
1027 bot y4=-d-o if hefty: + (x4r-x4l)/2 fi;
1028 y5+.5stem=floor(x_height+.5stem);
1029 if fine<2:
1030 filldraw circ_stroke z1e{down}..z2e{down}; % stem
1031 filldraw circ_stroke z4e{up}..z3e{up}..z2e{up}; % stem
1032 else:
1033 filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e; % stem
1034 fi
1035 filldraw circ_stroke z5e{right}..{right}z2'e; % left bulb
1036 filldraw circ_stroke z6e{left}..{left}z2'e; % right bulb
1037 penlabels(1,2,3,4,5,6); endchar;
1038
1039 cmchar "Double dagger mark";
1040 beginchar(oct"172",8u#,asc_height#,desc_depth#);
1041 adjust_fit(0,0); pickup fine.nib;
1042 pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
1043 pos4(stem,90); pos2'(thin_join,90); pos5(stem,90); z2'=z2;
1044 x1=x2=x3; x1-.5stem=hround(.5w-.5stem); center_on(x1);
1045 x4-.5stem=hround u; x5=w-x4;
1046 y1+.5stem=h+oo; y2=y4=y5=.5[y1,y3]; y3-.5stem=ceiling(.5[-d,h]);
1047 filldraw circ_stroke z1e{down}..{down}z2e; % top stem
1048 filldraw circ_stroke z3e{up}..{up}z2e; % upper middle stem
1049 filldraw circ_stroke z4e{right}..{right}z2'e; % top left bulb
1050 filldraw circ_stroke z5e{left}..{left}z2'e; % top right bulb
1051 pos6(stem,0); pos7(thin_join,0); pos8(stem,0);
1052 pos9(stem,90); pos7'(thin_join,90); pos0(stem,90); z7'=z7;
1053 x6=x7=x8=x1; x9=x4; x0=x5;
1054 y6=y3-stem-1; y7=y9=y0=.5[y6,y8]; y8-.5stem=-d-oo;
1055 filldraw circ_stroke z6e{down}..{down}z7e; % lower middle stem
1056 filldraw circ_stroke z8e{up}..{up}z7e; % bottom stem
1057 filldraw circ_stroke z9e{right}..{right}z7'e; % bottom left bulb
1058 filldraw circ_stroke z0e{left}..{left}z7'e; % bottom right bulb
1059 penlabels(1,2,3,4,5,6,7,8,9,0); endchar;
1060
1061 cmchar "Paragraph mark";
1062 beginchar(oct"173",11u#,asc_height#,desc_depth#);
1063 adjust_fit(0,0); pickup rule.nib; autorounded;
1064 top y1=h; bot y6=-d-eps; y4=y7=y9=y1;
1065 y8=y6; y3=y5=good.y .5[y1,y6];
1066 x7-x4=ceiling(rule_thickness+1.25u);
1067 lft x2=hround u; y2=.5[y1,y3]; x4=x5=x6; rt x9=hround(w-.5u);
1068 x7=x8=good.x(x9-1.5u); x1=x3=min(.5w,x4);
1069 filldraw z4..z1{left}...z2{down}...{right}z5--cycle; % filled bowl
1070 draw z9--z4--z6; % left stem and upper serif
1071 draw z7--z8; % right stem
1072 labels(1,2,3,4,5,6,7,8,9); endchar;
1073
1074 cmchar "Club suit";
1075 beginchar(oct"174",14u#,asc_height#,2/3desc_depth#);
1076 adjust_fit(0,0); pickup rule.nib; autorounded;
1077 x1=x4=x30=x33=good.x .5w; center_on(x1);
1078 x2=good.x(x1-.5u)-eps; lft x1-rt x10=hround .5pt; lft x12=hround .5u;
1079 x11=.6[x12,x10]; x13=.5[x12,x10]=x5; x32-x31=x1-.5u-x12;
1080 x2+x3=x5+x6=x10+x20=x11+x21=x12+x22=x13+x23=x31+x32=2x1;
1081 top y30=h+o+oo; bot y11=bot y21=-o; top y13=top y23=vround .53h;
1082 y30-y33=y13-y11; y31=y32=y4=.5[y30,y33]; y12=y22=.5[y11,y13];
1083 y1=y10=y20=good.y .1h; bot y5=bot y6=y1+.75; bot y2=bot y3=-d;
1084 filldraw z30{left}...z31{down}...z33{right}...z32{up}...cycle; % top bowl
1085 filldraw z13{left}...z12{down}...z11{right}...z10{up}...cycle; % left bowl
1086 filldraw z23{left}...z20{down}...z21{right}...z22{up}...cycle; % right bowl
1087 filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
1088 ...{up}cycle; % stem
1089 filldraw z4--z5--z6--cycle; % filling
1090 labels(1,2,3,4,5,6,10,11,12,13,20,21,22,23,30,31,32,33); endchar;
1091
1092 cmchar "Diamond suit";
1093 beginchar(oct"175",14u#,asc_height#,2/3desc_depth#);
1094 adjust_fit(0,0); pickup rule.nib; autorounded;
1095 x1=x4=good.x .5w; center_on(x1);
1096 lft x2=hround u; x3=w-x2;
1097 top y1=h+o+oo; bot y4=-d-o-oo; y2=y3=.5[y1,y4];
1098 draw z1{x3-x1,1.5(y3-y1)}...z3{1.5(x3-x1),y3-y1}; % upper right diagonal
1099 draw z1{x2-x1,1.5(y2-y1)}...z2{1.5(x2-x1),y2-y1}; % upper left diagonal
1100 draw z4{x2-x4,1.5(y2-y4)}...z2{1.5(x2-x4),y2-y4}; % lower left diagonal
1101 draw z4{x3-x4,1.5(y3-y4)}...z3{1.5(x3-x4),y3-y4}; % lower right diagonal
1102 labels(1,2,3,4); endchar;
1103
1104 cmchar "Heart suit";
1105 beginchar(oct"176",14u#,asc_height#,2/3desc_depth#);
1106 adjust_fit(0,0); pickup rule.nib; autorounded;
1107 x1=x5=good.x .5w; center_on(x1);
1108 lft x7=hround u; x8=4u; x2+x8=x3+x7=x4+x6=w;
1109 y1=good.y .77h; top y2=h+o; y3=.7h; y4=.2h; bot y5=-o-oo;
1110 y2=y8; y3=y7; y4=y6; z4=whatever[z3,z5];
1111 x0=x9=w; y0=1.5h; y9=.6h;
1112 draw z1{x2-x1,8(y2-y1)}...z2{right}....z3{down}...{z4-z9}z4
1113 ...{z5-z0}z5; % right half bowl
1114 draw z1{x8-x1,8(y8-y1)}...z8{left}....z7{down}...{(z4-z9)xscaled-1}z6
1115 ...{(z5-z0)xscaled-1}z5; % left half bowl
1116 labels(0,1,2,3,4,5,6,7,8,9); endchar;
1117
1118 cmchar "Spade suit";
1119 beginchar(oct"177",14u#,asc_height#,2/3desc_depth#);
1120 adjust_fit(0,0); pickup rule.nib; autorounded;
1121 x1=x10=good.x .5w; center_on(x1);
1122 x2=good.x(x1-.5u)-eps; lft x1-rt x6=hround .5pt; x5=x6;
1123 x7=.5[x8,x6]; lft x8=hround u;
1124 x2+x3=x5+x15=x6+x14=x7+x13=x8+x12=x9+x11=2x10;
1125 top y10=h+o+oo; y9=y11=.7h; y8=y12=.3h;
1126 y1=y6=y14=good.y .1h; bot y5=bot y15=y1+.75;
1127 bot y7=bot y13=-o; bot y2=bot y3=-d; z9=whatever[z8,z10];
1128 filldraw z10{-w,-3h}...z9{-w,-h}...z8{down}...z7{right}...z6---z5
1129 --z15---z14...{right}z13...{up}z12...{-w,h}z11
1130 ...{-w,3h}cycle; % filled bowl
1131 filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
1132 ...{up}cycle; % stem
1133 labels(1,2,3,5,6,7,8,9,10,11,12,13,14,15); endchar;