| 1 |
% Based on the Computer Modern source file calu.mf by D E Knuth. |
| 2 |
|
| 3 |
% Edited by Ariel Barton to produce correct symbols with sans serif parameters |
| 4 |
|
| 5 |
% Date: 2013/03/22 |
| 6 |
|
| 7 |
% Calligraphic capitals with `fixed' pens, by N. N. Billawala (1985). |
| 8 |
|
| 9 |
% These letters are intended for math, hence |math_fitting| is assumed. |
| 10 |
|
| 11 |
% Character codes \0101 through \0132 are generated. |
| 12 |
|
| 13 |
cmchar "Calligraphic A"; |
| 14 |
beginchar("A",14.4u#,cap_height#,0); |
| 15 |
italcorr .5u#; |
| 16 |
adjust_fit(-.05w#,0); pickup cal.nib; |
| 17 |
lft x5=.54w; x7=.9w; |
| 18 |
top y5=h+.4cal_cap_curve; bot y7=bot_flourish_line; |
| 19 |
z6=.3[z7,z5]-bend; |
| 20 |
pickup tilted.nib; |
| 21 |
lft x1=.05w; x2=.2w; if hefty: x4=x5; else: rt x4=x5; fi |
| 22 |
y1=y2+.1h; bot y2=bot_flourish_line; top y4=h+.4cal_cap_curve; |
| 23 |
y3=y6; z3=whatever[z2,z4]+2bend; |
| 24 |
draw\\(z1..tension 1.2..{right}z2) softjoin flex(z2,z3,z4); % left diagonal |
| 25 |
pickup cal.nib; |
| 26 |
erase fill\\(0,bot y5)--(w,bot y5)--(w,top y5)--(0,top y5)--cycle; |
| 27 |
draw flex(z5,z6,z7) softjoin (z7--z7+cal.extension); % right diagonal |
| 28 |
draw rt z3--z6; % bar |
| 29 |
math_fit(.5u#-.1cap_height#*slant,ic#); labels(1,2,3,4,5,6,7); endchar; |
| 30 |
|
| 31 |
cmchar "Calligraphic B"; |
| 32 |
beginchar("B",9.9u#,cap_height#,0); |
| 33 |
italcorr max(.8h#*slant-.1w#,.3h#*slant)+.5u#; |
| 34 |
adjust_fit(0,0); pickup cal.nib; |
| 35 |
lft x1=lft x3=0; x4=.6[x2,x5]; rt x5=.9w; x6=.4w; rt x7=w; |
| 36 |
x8=.4[x9,x7]; lft x9=rt x3; |
| 37 |
top y1=h+o; bot y3=-o; z2=.3[z3,z1]+bend; |
| 38 |
y4=y1; y5=.6[y6,y4]; y6=.55h; y7=.45[y8,y6]; bot y8=-o; y9=.1h; |
| 39 |
draw z1-cal.extension--flex(z1,z2,z3); % stem |
| 40 |
draw z2{up}...z4...z5{down}...{dir 200}z6{dir 10} |
| 41 |
...z7{down}...z8{left}...z9; % lobes |
| 42 |
math_fit(.5u#,.3h#*slant+.5u#); labels(1,2,3,4,5,6,7,8,9); endchar; |
| 43 |
|
| 44 |
cmchar "Calligraphic C"; |
| 45 |
beginchar("C",9.4u#,cap_height#,0); |
| 46 |
italcorr max(h#*slant-.15w#,.2h#*slant)+.5u#; |
| 47 |
adjust_fit(0,0); pickup cal.nib; |
| 48 |
x0=.7[x2,x1]; rt x1=.85w; x2=.6w; lft x3=0; x4=.5w; rt x5=w; |
| 49 |
y0=.7h; y1=.8[y0,y2]; top y2=h+o; y3=.5h; bot y4=-o; y5=.2h; |
| 50 |
draw\\(z0{2(x1-x0),y1-y0}...z1) |
| 51 |
softjoin (z1...z2{left}....z3{down}...z4...z5); % stroke |
| 52 |
math_fit(.5u#-.5h#*slant,.2h#*slant+.5u#); labels(0,1,2,3,4,5); endchar; |
| 53 |
|
| 54 |
cmchar "Calligraphic D"; |
| 55 |
beginchar("D",10u#,cap_height#,0); |
| 56 |
italcorr .6h#*slant+.5u#; |
| 57 |
adjust_fit(4u#,0); pickup cal.nib; |
| 58 |
lft x1=lft x3=0; x4=.2[x1,x5]; rt x5=w; x6=.2w; x7=0; |
| 59 |
top y1=top y4=h; bot y3=0; z2=.5[z3,z1]+bend; |
| 60 |
y5=.51[y6,y4]; bot y6=bot y7=0; |
| 61 |
draw flex(z1,z2,z3); % stem |
| 62 |
draw z1---z4....z5{down}...z6---z7; % lobe |
| 63 |
draw z1{left}...{down}z1-flourish_change; % swash |
| 64 |
math_fit(.5u#-.8h#*slant,ic#-.5u#); labels(1,2,3,4,5,6,7); endchar; |
| 65 |
|
| 66 |
cmchar "Calligraphic E"; |
| 67 |
beginchar("E",8.5u#,cap_height#,0); |
| 68 |
italcorr max(h#*slant-.1w#,.2h#*slant)+.5u#; |
| 69 |
adjust_fit(0,0); pickup cal.nib; |
| 70 |
x1=.9[x3,x2]; rt x2=.9w; x3=.6[x4,x2]; lft x4=.05w; |
| 71 |
x5=.7[x6,x2]; lft x6=0; x7=.5[x6,x8]; rt x8=w; |
| 72 |
y1=y2-.1h; y2=.9h+o; top y3=h+o; y4=.5[y5,y3]; |
| 73 |
y5=.55h; y6=.6[y5,y7]; bot y7=-o; y8=.2h; |
| 74 |
draw\\(z1{2(x2-x1),y2-y1}...z2) |
| 75 |
softjoin (z2...z3{left}...z4{down}...{right}z5); % upper arc |
| 76 |
draw z5{left}...z6{down}...z7{right}...z8; % lower arc |
| 77 |
math_fit(.5u#-.2h#*slant,.2h#*slant+.5u#); |
| 78 |
labels(1,2,3,4,5,6,7,8); endchar; |
| 79 |
|
| 80 |
cmchar "Calligraphic F"; |
| 81 |
beginchar("F",13.5u#,cap_height#,0); |
| 82 |
italcorr h#*slant+.5u#; |
| 83 |
adjust_fit(-.1w#,-u#); pickup cal.nib; |
| 84 |
x1=.5w; x3=.4w; lft x4=.1w; x5=x2+.35w; x6=.7[x1,x7]; rt x7=w; |
| 85 |
top y1=top y6=h; z2=.5[z3,z1]+bend; |
| 86 |
bot y3=-o; y4=.1h; y5=y2; y7=.9h; |
| 87 |
draw flex(z1,z2,z3) softjoin (z3...{x4-x3,5(y4-y3)}z4); % stem |
| 88 |
draw z1-flourish_change+(0,.15asc_height){up}...{right}(z1-(2u,0)) |
| 89 |
---z6...{down}z7; % upper bar |
| 90 |
draw z2--z5--z5-(0,.1cal_cap_curve); % middle bar |
| 91 |
math_fit(0,.5ic#); labels(1,2,3,4,5,6,7); endchar; |
| 92 |
|
| 93 |
cmchar "Calligraphic G"; |
| 94 |
beginchar("G",9.4u#,cap_height#,.5desc_depth#); |
| 95 |
italcorr max(h#*slant-.05w#,.5h#*slant)+.5u#; |
| 96 |
adjust_fit(0,0); pickup cal.nib; |
| 97 |
x0=.7[x2,x1]; rt x1=.95w; x2=.6w; lft x3=0; x4=.5w; |
| 98 |
rt x5=w; x6=.5[x7,x5]; lft x7=.2w; |
| 99 |
y0=.7h+o; y1=.8[y0,y2]; top y2=h+o; y3=.5[y4,y2]; bot y4=.1h; |
| 100 |
y5=.5h; bot y6=-d-o; y7=-.5d; |
| 101 |
draw\\(z0{2(x1-x0),y1-y0}...z1) |
| 102 |
softjoin (z1...z2{left}....z3{down}...z4...{up}z5); % arc |
| 103 |
draw z5{down}...z6{left}...z7; % tail |
| 104 |
math_fit(.5u#-.4h#*slant,.5h#*slant+.5u#); |
| 105 |
labels(0,1,2,3,4,5,6,7); endchar; |
| 106 |
|
| 107 |
cmchar "Calligraphic H"; |
| 108 |
beginchar("H",12.2u#,cap_height#,0); |
| 109 |
italcorr max(h#*slant-.2w#,.15h#*slant)+.5u#; |
| 110 |
adjust_fit(4u#,0); pickup cal.nib; |
| 111 |
lft x1=lft x3=.5u; rt x4=rt x6=.8w-.6u; rt x9=w; |
| 112 |
top y1=top y4=h; bot y3=-.06h; bot y6=bot_flourish_line; y9=y6+.1h; |
| 113 |
z2=.6[z3,z1]+bend; z5=.4[z6,z4]-bend; |
| 114 |
path p[]; p1=flex(z1,z2,z3); p2=flex(z4,z5,z6); |
| 115 |
p3=(-w,.45h)--(2w,.45h); |
| 116 |
rt z7+2bend=p3 intersectionpoint p1; rt z8=p3 intersectionpoint p2; |
| 117 |
draw (z1-flourish_change-bend{curl2}....z1-(u,0)---z1) softjoin p1; % left stem |
| 118 |
draw p2 softjoin (z6{right}...{up}z9); % right stem |
| 119 |
draw z7--z8; % bar |
| 120 |
math_fit(.5u#-.8h#*slant,.15h#*slant+.5u#); |
| 121 |
labels(1,2,3,4,5,6,7,8,9); endchar; |
| 122 |
|
| 123 |
cmchar "Calligraphic I"; |
| 124 |
beginchar("I",10.8u#,cap_height#,0); |
| 125 |
italcorr max(h#*slant+.5cal_cap_curve#-.2w#,.15h#*slant)+.5u#; |
| 126 |
adjust_fit(0,0); pickup cal.nib; |
| 127 |
lft x0=0; x1=.9w; x2=x4=.5w; x5=.2w; x6=.8w; rt x7=1.05w; |
| 128 |
y0=.8h; top y1=top y2=h; z3=.5[z4,z2]+bend; |
| 129 |
bot y4=bot y5=bot y6=0; y7=.15h; |
| 130 |
draw z0{up}...z2---z1; % upper bar |
| 131 |
z8=.5[z2,z1]; |
| 132 |
draw z8{left}...z3{down}...{left}.5[z4,z5]; % stem |
| 133 |
draw z5---z6...{up}z7; % lower bar |
| 134 |
math_fit(.5u#-.8h#*slant,.15h#*slant+.5u#); |
| 135 |
labels(0,1,2,3,4,5,6,7); endchar; |
| 136 |
|
| 137 |
cmchar "Calligraphic J"; |
| 138 |
beginchar("J",11.7u#,cap_height#,.5desc_depth#); |
| 139 |
italcorr h#*slant+.25u#; |
| 140 |
adjust_fit(0,0); pickup cal.nib; |
| 141 |
x0=.6w; rt x1=w; rt x2=.75w; x3=.5[x4,x2]; lft x4=0; |
| 142 |
top y0=top y1=h; y2=.2h; bot y3=-d-o; y4=d; |
| 143 |
draw z1---z0...{down}z0-(4u,2/7h); % upper bar |
| 144 |
draw z1{left}...z2{down}...z3{left}...{up}z4; % stem and tail |
| 145 |
math_fit(.5u#,0); labels(0,1,2,3,4); endchar; |
| 146 |
|
| 147 |
cmchar "Calligraphic K"; |
| 148 |
beginchar("K",11u#,cap_height#,0); |
| 149 |
italcorr max(h#*slant-.2w#,.2h#*slant)+.5u#; |
| 150 |
adjust_fit(0,.1w#); pickup cal.nib; |
| 151 |
lft x1=lft x3=0; top y1=h+o; bot y3=-o; z2=.6[z3,z1]+bend; |
| 152 |
draw z1-cal.extension--flex(z1,z2,z3); % stem |
| 153 |
pickup light_cal.nib; |
| 154 |
rt x4=.9w; x5=x4-.1w; x7=.8w; rt x8=1.1w; |
| 155 |
y4=.9h; top y5=h+o; bot y7=-o; y8=.2h-o; |
| 156 |
(lft z6)t_=z2.t_+penoffset up of pen_[cal.nib]; |
| 157 |
draw z4{up}...{left}z5..tension atleast 2..{down}z6 |
| 158 |
..tension atleast 3 and atleast 2..z7{right}...{up}z8; % diagonals |
| 159 |
math_fit(.5u#,.2h#*slant+.5u#); labels(1,2,3,4,5,6,7,8); endchar; |
| 160 |
|
| 161 |
cmchar "Calligraphic L"; |
| 162 |
beginchar("L",10.8u#,cap_height#,0); |
| 163 |
italcorr .2h#*slant+.5u#; |
| 164 |
adjust_fit(0,0); pickup heavy_cal.nib; |
| 165 |
x1=.2w; x2=x1+.3w; rt x3=x2+.25w; lft x4=0; |
| 166 |
x5=.8[x4,x6]; rt x6=w; x7=.2[x4,x5]; |
| 167 |
y1=.4h-o; top y2=h+o; y3=.8h; bot y4=bot y5=-o; |
| 168 |
y6=.2h-o; y7=9/70h-o; |
| 169 |
path p; p=z4...z7{right}..{right}z5...{up}z6; draw p; % arm |
| 170 |
draw z4{dir .75angle(direction 0 of p)} |
| 171 |
...z1{up}...z2{right}...{down}z3; % stem and flourish |
| 172 |
math_fit(.5u#,ic#); labels(1,2,3,4,5,6,7); endchar; |
| 173 |
|
| 174 |
cmchar "Calligraphic M"; |
| 175 |
beginchar("M",19.8u#,cap_height#,0); |
| 176 |
italcorr max(h#*slant-u#,.75cal_cap_curve#)+.5cal_cap_curve#+.5u#; |
| 177 |
adjust_fit(-.1w#,0); pickup med_cal.nib; |
| 178 |
(z20)t_=(z5)t_+penoffset down of currentpen |
| 179 |
=(z4)t_+penoffset down of pen_[tilted.nib]; |
| 180 |
z6=.3[z7,z5]-bend; z9=.3[z8,z10]+.5bend; z12=.3[z13,z11]-bend; |
| 181 |
x7=.5[x2,x13]; bot y7=.05h; top y5=h+o; |
| 182 |
(z0)t_=(z7)t_+penoffset right of currentpen |
| 183 |
=(z8)t_+penoffset right of pen_[tilted.nib]; |
| 184 |
pickup cal.nib; |
| 185 |
(z30)t_=(z11)t_+penoffset up of currentpen |
| 186 |
=(z10)t_+penoffset up of pen_[tilted.nib]; |
| 187 |
x13=w; bot y13=bot_flourish_line; |
| 188 |
pickup tilted.nib; |
| 189 |
lft x1=.1w; x2=.2w; x4=.2[x2,x7]; x10=.8[x7,x13]; |
| 190 |
y1=.05h+y2; bot y2=bot_flourish_line; top y10=h+o; |
| 191 |
z3=whatever[z2,z4]+2bend; y3=y6; |
| 192 |
draw\\(z1..tension1.2..{right}z2) softjoin flex(z2,z3,z4); % left stem |
| 193 |
erase fill z20--(.5w,y20)--(.5w,top y4)--(x20-4u,top y4)--cycle; |
| 194 |
pickup med_cal.nib; |
| 195 |
draw flex(z5,z6,z7); % left diagonal |
| 196 |
pickup cal.nib; |
| 197 |
draw flex(z11,z12,z13) softjoin (z13--z13+cal.extension); % right stem |
| 198 |
pickup tilted.nib; |
| 199 |
path p; p=flex(z8,z9,z10); |
| 200 |
erase fill z0--(x0,y0-.5h)--(x9,y0-.5h)--subpath(1,0) of p--cycle; |
| 201 |
erase fill z30--(x30,y30+.5h)--(x9,y30+.5h)--subpath(1,2) of p--cycle; |
| 202 |
draw p; % right diagonal |
| 203 |
math_fit(.5u#-.05h#*slant,ic#); |
| 204 |
labels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,20,30); endchar; |
| 205 |
|
| 206 |
cmchar "Calligraphic N"; |
| 207 |
beginchar("N",9u#,cap_height#,0); |
| 208 |
italcorr h#*slant+.5u#; |
| 209 |
adjust_fit(2u#,2.5u#); pickup med_cal.nib; |
| 210 |
(z0)t_=(z5)t_+penoffset down of currentpen |
| 211 |
=(z4)t_+penoffset down of pen_[tilted.nib]; |
| 212 |
(z20)t_=(z7)t_+penoffset up of currentpen |
| 213 |
=(z8)t_+penoffset up of pen_[tilted.nib]; |
| 214 |
z6=.3[z7,z5]-bend; rt z7=(w,0); top y5=h+o; |
| 215 |
pickup tilted.nib; |
| 216 |
lft x1=x2-2u; x2=-u; x4=0; x10=w; rt x11=w+3u; |
| 217 |
y1=y2+.05h; bot y2=bot_flourish_line; |
| 218 |
y3=y6; z3=whatever[z2,z4]+2bend; |
| 219 |
y10=h; z9=.7[z8,z10]-.5bend; bot y11=h; |
| 220 |
draw\\(z1..tension1.2..{right}z2) softjoin flex(z2,z3,z4); % left stem |
| 221 |
draw flex(z8,z9,z10)...{right}z11; % right stem |
| 222 |
pickup med_cal.nib; |
| 223 |
erase fill z0--(.5w,y0)--(.5w,1.5h)--(x0-4u,1.5h)--cycle; |
| 224 |
erase fill z20--(.5w,y20)--(.5w,-.5h)--(x20+4u,-.5h)--cycle; |
| 225 |
draw flex(z5,z6,z7); % diagonal |
| 226 |
math_fit(.5u#-.05h#*slant,.3h#*slant); |
| 227 |
labels(0,1,2,3,4,5,6,7,8,9,10,11,20); endchar; |
| 228 |
|
| 229 |
cmchar "Calligraphic O"; |
| 230 |
beginchar("O",12.6u#,cap_height#,0); |
| 231 |
italcorr .7h#*slant+.5u#; |
| 232 |
adjust_fit(0,0); pickup cal.nib; |
| 233 |
x1=.3w; lft x2=0; x3=.5w; rt x4=w; x5=.6w; lft x6=.27w; |
| 234 |
top y1=top y5=h+o; y2=.55h; bot y3=-o; y4=.5h; y6=y2; |
| 235 |
path p; p=z1...z2{down}...z3{right}...z4{up}...z5{left}...{down}z6; |
| 236 |
draw subpath(0,4.8) of p; % bowl |
| 237 |
math_fit(.5u#-.3h#*slant,ic#-.5u#); |
| 238 |
labels(1,2,3,4,5,6); endchar; |
| 239 |
|
| 240 |
cmchar "Calligraphic P"; |
| 241 |
beginchar("P",9u#,cap_height#,0); |
| 242 |
italcorr .8h#*slant+.5u#; |
| 243 |
adjust_fit(4u#,0); pickup cal.nib; |
| 244 |
lft x1=lft x3=0; x4=x6=.3[x1,x5]; rt x5=w; |
| 245 |
top y1=top y4=h; y3=-o; y5=.55[y6,y4]; bot y6=.3h; |
| 246 |
z2=.5[z3,z1]+bend; |
| 247 |
draw flex(z1,z2,z3); % stem |
| 248 |
draw z1{left}...{down}z1-flourish_change; % swash |
| 249 |
draw z1---z4...z5{down}...{left}z6; % lobe |
| 250 |
math_fit(.5u#-.8h#*slant,.5ic#); labels(1,2,3,4,5,6); endchar; |
| 251 |
|
| 252 |
cmchar "Calligraphic Q"; |
| 253 |
beginchar("Q",11.7u#,cap_height#,.5desc_depth#); |
| 254 |
italcorr max(0,.6h#*slant-2u#)+.5u#; |
| 255 |
adjust_fit(0,2u#); pickup cal.nib; |
| 256 |
x0=.6w; x1=.4w; lft x2=0; x3=.5w; rt x4=w; x5=.6w; lft x6=0; |
| 257 |
x7=.23w; rt x8=w; x9=x8+2u; |
| 258 |
y0=.25h; bot y1=.15h; y2=.45[y1,y3]; top y3=h+o; y4=.5h; bot y5=0; |
| 259 |
y6=y7=y9=0; y8=-d; |
| 260 |
draw z0...z1{left}...z2{up}...z3{right} |
| 261 |
...z4{down}...z5...{left}z7; % bowl |
| 262 |
draw z7{right}...z8{right}...{up}z9; % tail |
| 263 |
math_fit(.5u#,ic#); labels(0,1,2,3,4,5,6,7,8,9); endchar; |
| 264 |
|
| 265 |
cmchar "Calligraphic R"; |
| 266 |
beginchar("R",12.6u#,cap_height#,0); |
| 267 |
italcorr .2h#*slant; |
| 268 |
adjust_fit(4u#,0); pickup cal.nib; |
| 269 |
lft x1=lft x3=0; x4=1/4[x1,x5]; rt x5=.7w; |
| 270 |
x6=.4[x1,x5]; rt x7=.8w; rt x8=w; |
| 271 |
top y1=top y4=h; bot y3=bot y7=-o; y5=.55[y6,y4]; bot y6=.4h; y8=.15h; |
| 272 |
z2=.5[z3,z1]+bend; |
| 273 |
draw flex(z1,z2,z3); % stem |
| 274 |
draw z1{left}...{down}z1-flourish_change; % swash |
| 275 |
draw z1---z4....z5{down}...{left}z6; % lobe |
| 276 |
draw z6{right}..tension atleast 1.5..z7{right}..z8; % tail |
| 277 |
math_fit(.5u#-.8h#*slant,ic#); labels(1,2,3,4,5,6,7,8); endchar; |
| 278 |
|
| 279 |
cmchar "Calligraphic S"; |
| 280 |
beginchar("S",9.9u#,cap_height#,0); |
| 281 |
italcorr max(.9h#*slant-.05w#,.3h#*slant)+.5u#; |
| 282 |
adjust_fit(0,0); pickup cal.nib; |
| 283 |
rt x0=rt x1=.95w; x2=.5[x3,x1]; lft x3=.15w; x4=.5[x6,x2]; |
| 284 |
rt x5=w; x6=.5w; lft x7=0; lft x8=.075w; |
| 285 |
y0=.8h; y1=.9h; top y2=h+o; y3=.55[y4,y2]; y4=.55[y6,y2]; |
| 286 |
y5=.45[y6,y4]; bot y6=-o; y7=.2h; y8=.35h; |
| 287 |
draw\\(z0--z1) softjoin (z1...z2{left}...z3{down}...z4...z5{down} |
| 288 |
...z6{left}...z7) softjoin (z7{up}...{right}z8); % stroke |
| 289 |
math_fit(.5u#-.3h#*slant,.3h#*slant+.5u#); |
| 290 |
labels(0,1,2,3,4,5,6,7,8); endchar; |
| 291 |
|
| 292 |
cmchar "Calligraphic T"; |
| 293 |
beginchar("T",13u#,cap_height#,0); |
| 294 |
italcorr h#*slant+.5u#; |
| 295 |
adjust_fit(0,-.5u#); pickup heavy_cal.nib; |
| 296 |
x1=.47w; x3=.5w; lft x4=0; x5=.25w; x6=.85w; rt x7=1.05w; |
| 297 |
top y1=h; bot y3=-.1h; y4=3/4h; top y5=top y6=h; top y7=1.05h; |
| 298 |
z2=.3[z3,z1]+bend; |
| 299 |
top y0=y1; x0=x2; |
| 300 |
z8=(2u,.2h); |
| 301 |
draw z0---z2...z3; % stem |
| 302 |
draw z4{curl 2}...z5{right}...z6{right}...{up}z7; % arms |
| 303 |
math_fit(.5u#-5/7h#*slant,-u#); labels(1,2,3,4,5,6,7); endchar; |
| 304 |
|
| 305 |
cmchar "Calligraphic U"; |
| 306 |
beginchar("U",11u#,cap_height#,0); |
| 307 |
italcorr h#*slant+.5u#; |
| 308 |
adjust_fit(0,0); pickup cal.nib; |
| 309 |
x1=x2-.15w; lft x2=.05w; x3=x2; x4=.25[x3,x6]; rt x6=rt x8=w; |
| 310 |
y1=y2-.05h; top y2=h; y3=.3w; bot y4=-o; |
| 311 |
top y6=h; bot y8=bot_flourish_line; |
| 312 |
z7=.3[z8,z6]-bend; |
| 313 |
draw z1...z2{right}..tension 2 and 1..z3{down} |
| 314 |
...{right}z4..tension atleast 1.5..{up}z6; % left stem and arc |
| 315 |
draw flex(z6,z7,z8) softjoin (z8--z8+cal.extension); % right stem |
| 316 |
math_fit(.5u#-min(.3h#*slant+.1w#,.95h#*slant),.5ic#); |
| 317 |
labels(1,2,3,4,6,7,8); endchar; |
| 318 |
|
| 319 |
cmchar "Calligraphic V"; |
| 320 |
beginchar("V",11.25u#,cap_height#,0); |
| 321 |
italcorr .8h#*slant+.5u#; |
| 322 |
adjust_fit(0,0); pickup med_cal.nib; |
| 323 |
x1=0; top y1=h; z3=(.48w,0); |
| 324 |
z0.t_=z2.t_+penoffset down of currentpen |
| 325 |
=z3.t_+penoffset down of pen_[tilted.nib]; |
| 326 |
draw z1{right}..tension atleast 1 and infinity..z2; % left diagonal |
| 327 |
pickup tilted.nib; rt x4=w; x5=x4-.2w; top y4=.8h; top y5=h; |
| 328 |
path p; p=z3..tension atleast 3 and 1..{up}z4; |
| 329 |
erase fill z0--(x0,y0-.5h)--(x4,y0-.5h)--(x4+eps,y4)--reverse p--cycle; |
| 330 |
draw p...{left}z5; % right diagonal |
| 331 |
math_fit(.5u#+.5cal_cap_curve#-h#*slant,.5ic#); labels(0,1,2,3,4,5); endchar; |
| 332 |
|
| 333 |
cmchar "Calligraphic W"; |
| 334 |
beginchar("W",18u#,cap_height#,0); |
| 335 |
italcorr .8h#*slant+.5u#; |
| 336 |
adjust_fit(0,0); pickup med_cal.nib; |
| 337 |
x1=0; x3=.5[x1,x6]; x6=.52w; x9=.58[x6,x10]; y3=y9=0; top y1=top y6=h; |
| 338 |
z7=.5[z8,z6]+bend; z4=.5[z3,z5]+bend; |
| 339 |
(z0)t_=(z2)t_+penoffset down of currentpen |
| 340 |
=(z3)t_+penoffset down of pen_[tilted.nib]; |
| 341 |
(z20)t_=(z8)t_+penoffset down of currentpen |
| 342 |
=(z9)t_+penoffset down of pen_[tilted.nib]; |
| 343 |
draw z1{right}..tension atleast 1 and infinity..z2; % first diagonal |
| 344 |
pickup tilted.nib; |
| 345 |
x5=x6; rt x10=w; x11=x10-.1w; top y5=h; top y10=.8h; top y11=h; |
| 346 |
erase fill z0--(x0,y0-.5h)--(x5,y0-.5h)--z5..z4..z3--cycle; |
| 347 |
draw z3..z4..z5; % second diagonal |
| 348 |
pickup med_cal.nib; |
| 349 |
erase fill\\(.3w,bot y6)--(w,bot y6)--(w,top y6)--(.3w,top y6)--cycle; |
| 350 |
draw z6..z7..z8; % third diagonal |
| 351 |
pickup tilted.nib; path p; p=z9..tension atleast 3 and 1..{up}z10; |
| 352 |
erase fill z20--(x20,y20-.5h)--(x10,y20-.5h)--(x10+eps,y10) |
| 353 |
--reverse p--cycle; |
| 354 |
draw p..{left}z11; % fourth diagonal |
| 355 |
math_fit(.5u#+.5cal_cap_curve#-h#*slant,.5ic#); |
| 356 |
labels(0,1,2,3,4,5,6,7,8,9,10,11,20); endchar; |
| 357 |
|
| 358 |
cmchar "Calligraphic X"; |
| 359 |
beginchar("X",11.4u#,cap_height#,0); |
| 360 |
italcorr h#*slant+.5u#; |
| 361 |
adjust_fit(0,0); pickup cal.nib; |
| 362 |
lft x1=.08w; lft x2=.2w; x4-x3=x2-x1; rt x4=w; |
| 363 |
h-y1=y4=1/9h; top y2=h; bot y3=0; |
| 364 |
draw z1{up}....z2{right} |
| 365 |
... .2[z2+(.1w,0),z3-(.1w,0)]---.8[z2+(.1w,0),z3-(.1w,0)] |
| 366 |
...{right}z3....{up}z4; % left diagonal |
| 367 |
x5=x6-u; rt x6=w; lft x7=0; x8=x7+u; |
| 368 |
top y5=h; y6=.85h; y7=h-y6; bot y8=0; |
| 369 |
draw z5{right}...z6{down} |
| 370 |
..tension atleast 3..{down}z7...{right}z8; % right diagonal |
| 371 |
math_fit(.5u#,1/7h#*slant+.5u#); labels(1,2,3,4,5,6,7,8); endchar; |
| 372 |
|
| 373 |
cmchar "Calligraphic Y"; |
| 374 |
beginchar("Y",11.75u#,cap_height#,.5desc_depth#); |
| 375 |
italcorr .8h#*slant+.5u#; |
| 376 |
adjust_fit(0,0); pickup med_tilted.nib; |
| 377 |
rt x5=w; x6=x5-2.2u; top y5=.8h; top y6=h; |
| 378 |
x4=.4w; lft x3=.15w; y3=good.y 0; y4=good.y -d; |
| 379 |
path p; p=z3..z4{right}..tension atleast 3 and 1..z5{up}...{left}z6; |
| 380 |
pickup med_cal.nib; x1=x2-u; y1=y2-.05h; lft x2=.6u; top y2=h; |
| 381 |
draw z1...z2{right}..tension atleast 1 and infinity |
| 382 |
..rt point 4/3 of p; % left diagonal |
| 383 |
erase fill subpath(2,1) of p--(x5,y4)--(x5+eps,y5)--cycle; |
| 384 |
pickup med_tilted.nib; draw p; % right diagonal |
| 385 |
math_fit(max(-1.2u#,.9u#-.95h#*slant),.5ic#); labels(1,2,3,4,5,6); endchar; |
| 386 |
|
| 387 |
cmchar "Calligraphic Z"; |
| 388 |
beginchar("Z",10.4u#,cap_height#,0); |
| 389 |
italcorr h#*slant+.5u#; |
| 390 |
adjust_fit(0,0); pickup heavy_cal.nib; |
| 391 |
lft x1=.05w; x2=.4w; rt x3=w; lft x7=0; x8=.8[x7,x9]; rt x9=1.1w; |
| 392 |
top y1=58/70h; top y2=top y3=h; bot y7=bot y8=0; bot y9=15/70h; |
| 393 |
z5=.55[z7,z3]+bend; |
| 394 |
x10=x5-2.5u; x11=x5+2u; x12=.2[x3,x2]; x13=.2[x7,x8]; |
| 395 |
y10=y5; bot y11=y10-6/70h; y12=64/70h; y13=6/70h; |
| 396 |
draw z1{up}...z2{right}...{right}z12...z3; % upper arm |
| 397 |
draw flex(z3,z5,z7); % diagonal |
| 398 |
draw z7...z13{right}...{right}z8...{up}z9; % lower arm |
| 399 |
pickup light_cal.nib; |
| 400 |
draw z10...z5{right}...{down}z11; % bar |
| 401 |
math_fit(.5u#,.6ic#); labels(1,2,3,5,7,8,9,10,11,12,13); endchar; |