Debian Codegraph @

texmf-dist/fonts/source/public/sansmathfonts/sans-asymbols.mf

raw
1 % Based on the American Mathematical Society's asymbols.mf
2
3 % Edited by Ariel Barton to produce better sans serif symbols
4
5 % Date: 2013/03/22
6
7 % Italic corrections have not been computed for most of these characters,
8 % since they are generally not slanted.
9
10 % Changed some assignments for
11 %
12 % cmchar "Circle-R brand"
13 % cmchar "Circle-S brand"
14 %
15 % to avoid rounding problems and the differences in TFM files for
16 % different magnifications
17 %
18 % Changed by Stefan Lindner 15.03.1991
19 %
20 % original: radius=.5(6u++cap_height)+3u; radius=radius#*hppp;
21 % changed: radius#=.5(6u#++cap_height#)+3u#; radius:=radius#*hppp;
22 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
23
24
25
26
27 def makesquare (suffix i,j,k,l) =
28 %% z.j, z.k are the lower left and right corners
29 %% assumed on baseline; ie, y.k=y.j=0
30 %% z.i, z.l are upper left and right corners
31 %% that is, start labeling with upper left corner, and
32 %% proceed to the successive corners counter-clockwise.
33 y.i-y.j=x.k-x.j; y.i:=good.y y.i+o; y.l=y.i
34 %% user must draw the square him/herself.
35 enddef;
36
37
38 cmchar "Square with dot";
39 beginchar(oct"000",14u#,12u#,0);
40 adjust_fit(0,0); pickup rule.nib;
41 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
42 bot y2=0; y4=y2;
43 makesquare (1,2,4,5);
44 y3=good.y .5[y1,y2]; x3=good.x .5[x1,x5];
45 draw z1---z2---z4---z5---cycle; % square
46 if square_dots:
47 filldraw (unitsquare shifted (-.5,-.5)) scaled (dot_size-.5rule_thickness) shifted z3; % dot
48 else:
49 fill fullcircle scaled dot_size shifted z3; % dot
50 fi
51 penlabels(1,2,3,4,5); endchar;
52
53 cmchar "Square plus";
54 beginchar(oct"001",14u#,12u#,0);
55 adjust_fit(0,0); pickup rule.nib;
56 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
57 bot y2=0; y4=y2; makesquare(1,2,4,5);
58 draw z1---z2---z4---z5---cycle; % square
59 x6=x1; x7=x4; y6=.5[y1,y2]; y7=y6; % cross strut
60 y8=y1; y9=y2; x8=.5[x1, x5]; x9=x8; % vertical strut
61 draw z6---z7; draw z8---z9; % plus
62 penlabels(1,2,4,5,6,7,8,9); endchar;
63
64 cmchar "Square times";
65 beginchar(oct"002",14u#,12u#,0);
66 adjust_fit(0,0); pickup rule.nib;
67 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
68 bot y2=0; y4=y2; makesquare(1,2,4,5);
69 draw z1---z2---z4---z5---cycle; % square
70 draw z1---z4; draw z2---z5; % diagonals
71 penlabels(1,2,4,5); endchar;
72
73 cmchar "Square";
74 beginchar(oct"003",14u#,12u#,0);
75 adjust_fit(0,0); pickup rule.nib;
76 lft x1=hround 1.0u; x2=x1;
77 x4=x5=w-x1;
78 bot y2=0; y4=y2; makesquare(1,2,4,5);
79 draw z1---z2---z4---z5---cycle; % square
80 penlabels(1,2,4,5); endchar;
81
82 cmchar "Filled square";
83 beginchar(oct"004",14u#,12u#,0);
84 adjust_fit(0,0); pickup rule.nib;
85 lft x1=hround 1.0u; x2=x1; x4=x5=w-x1;
86 bot y2=0; y4=y2; makesquare(1,2,4,5);
87 filldraw z1---z2---z4---z5---cycle; % square
88 penlabels(1,2,4,5); endchar;
89
90 cmchar "Small filled square";
91 beginchar(oct"005",5u#,.8asc_height#,0);
92 adjust_fit(0,0); pickup rule.nib;
93 lft x1=hround 1.0u; x2=x1; x3=x4=w-x1;
94 bot y2=0; y3=y2; makesquare(1,2,3,4);
95 filldraw z1---z2---z3---z4---cycle; % draw and fill square
96 penlabels(1,2,3,4); endchar;
97
98
99 cmchar "Diamond";
100 beginchar(oct"006",12u#,asc_height#,2u#);
101 adjust_fit(0,0); pickup rule.nib;
102 %% z1, z2 are left & right vertices
103 %% z3, z4 are top and bottom points
104 lft x1=hround u; x2=w-x1; y1=y2;
105 x3=x4=.5[x1, x2]; bot y4=-d-o; top y3= good.y h+o;
106 y1=.5[y4,y3];
107 draw z1---z3---z2---z4---cycle; % draw diamond
108 penlabels(1,2,3,4); endchar;
109
110 cmchar "Filled Diamond";
111 beginchar(oct"007",12u#,asc_height#,2u#);
112 adjust_fit(0,0); pickup rule.nib;
113 %% z1, z2 are left & right vertices
114 %% z3, z4 are top and bottom points
115 lft x1=hround u; x2=w-x1; y1=y2;
116 x3=x4=.5[x1, x2]; bot y4=-d-o; top y3= good.y h+o;
117 y1=.5[y4,y3];
118 filldraw z1---z3---z2---z4---cycle; % draw diamond
119 penlabels(1,2,3,4); endchar;
120
121 % do char "011 before char "010.
122 cmchar "Counter-clockwise-circle indicator";
123 beginarithchar(oct"011"); pickup light_rule.nib;
124 autorounded; lft x6=hround u; x2=w-x6;
125 y2=math_axis; top y8=h;
126 circle_points; % define points on circumference
127 %% see page 487 of vol E
128 path p; numeric t;
129 p=z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
130 ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle;
131 t=xpart(p intersectiontimes ((4.5u,0)--(4.5u,y8)));
132 draw subpath (if hefty: 0.1 else: 0 fi,t) of p; % circle with gap
133 z0=.5[z5,z1]; % the origin of the circle
134 %% Now prepare for left arrowhead--see pg E465
135 pickup crisp.nib;
136 pos12(rule_thickness,90); pos13(min(bar,rule_thickness),0); pos14(min(bar,rule_thickness),0);
137 y10=y12=y8; lft x10=hround x8 if hefty: -rule_thickness fi;
138 y13-y10=y10-y14=.19asc_height+eps; x13=x14=x10+3u+eps;
139 pos15(min(bar,rule_thickness),angle(z14-z10)); z15l=z10;
140 pos16(min(bar,rule_thickness),angle(z13-z10)); z16l=z10;
141 z19=.38[.5[z13,z14],z10];
142 numeric t; path p; % re-use t, p
143 p=z14r{z19-z14}..z16r;
144 t=xpart(p intersectiontimes((0,y12l)--(w,y12l)));
145 x12=xpart point t of p;
146 path p;
147 p=z10..{z14-z19}z14l--subpath(0,t) of
148 (z14r{z19-z14}..z16r)--z12l--z12r
149 --subpath(t,0) of (z13r{z19-z13}..z15r)
150 --z13l{z19-z13}..z10&cycle; % arrowhead
151 p:=p shifted -z8; % move back to origin
152 p:=p rotated if hefty: -14 else: -16 fi; % rotate down a bit
153 p:=p shifted z8; % move back to tip of circle
154 filldraw p;
155 penlabels(0,1,2,3,5,6,7,8,9,10,11,12,13,14,15,16,19);
156 picture v; v:=currentpicture; endchar;
157
158 cmchar "Clockwise-circle indicator";
159 beginarithchar(oct"010");
160 currentpicture:=v reflectedabout ((w/2,0),(w/2,h));
161 penlabels(0,1,2,3,5,6,7,8,9,10); endchar;
162
163 cmchar "Left-Right Harpoons";
164 compute_spread(.45x_height#,.55x_height#);
165 beginchar(oct"013",18u#,v_center(spread#+.48asc_height#));
166 path topleft; % for top left half arrow (harpoon)
167 adjust_fit(0,0);
168 pickup crisp.nib;
169 pos1(rule_thickness,90); pos2(rule_thickness,90);
170 pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0); y0=y1=y2=math_axis;
171 x1+.5rule_thickness=hround(w-u); lft x0=hround u;
172 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
173 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0));
174 z6l=z0; numeric t; path p; p=z4r..{2(x0-x4),y0-y4}z6r;
175 t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
176 x2=xpart point t of p;
177 topleft=z0--(x0,y2l)---z1l..z1r---z2r
178 ..subpath (t,0) of\\(z3r..{2(x0-x3),y0-y3}z5r)
179 --z3l..{2(x0-x3),y0-y3}cycle; % arrowhead and stem
180 topleft:=
181 topleft shifted (0,.5spread); % shift above math_axis
182 path botright; % for bottom right half arrow
183 botright:=topleft reflectedabout ((w/2,0),(w/2,h));
184 botright:=botright reflectedabout
185 ((0,math_axis+eps),(w,math_axis+eps));
186 filldraw topleft; filldraw botright;
187 penlabels(0,1,2,3,4,5,6); endchar;
188
189 cmchar "Right-Left Harpoons";
190 compute_spread(.45x_height#,.55x_height#);
191 beginchar(oct"012",18u#,v_center(spread#+.48asc_height#));
192 path topright, botleft;
193 adjust_fit(0,0);
194 pickup crisp.nib;
195 topright:=topleft reflectedabout((w/2,0),(w/2,h));
196 botleft:=botright reflectedabout((w/2,0),(w/2,h));
197 filldraw topright; filldraw botleft; endchar;
198
199 cmchar "Square minus";
200 beginchar(oct"014",14u#,12u#,0); adjust_fit(0,0);
201 pickup rule.nib; lft x1=hround 1.0u; x2=x1; x4=x5=w-x1; bot
202 y2=0; y4=y2; makesquare(1,2,4,5);
203 draw z1---z2---z4---z5---cycle; % square
204 x6=x1; x7=x4; y6=.5[y1,y2]; y7=y6; % cross strut
205 draw z6---z7; % minus
206 penlabels(1,2,4,5,6,7); endchar;
207
208 cmchar "Forces";
209 beginchar(oct"015",13u#,asc_height#,0);
210 adjust_fit(0,0);; pickup rule.nib;
211 top y1=h; bot y2=0; y3=y4=good.y .5h; y5=y1; y6=y2;
212 lft x5=hround u; x4=w-x5;
213 compute_spread(.45x_height#,.55x_height#);
214 x1=x5+spread; x1=x2=x3; x6=x5;
215 draw z6--z5; draw z2--z1; draw z3--z4;
216 penlabels(1,2,3,4,5,6); endchar;
217
218 cmchar "Forces with extra bar";
219 beginchar(oct"016",16u#, asc_height#,0);
220 adjust_fit(0,0); pickup rule.nib;
221 compute_spread(.42x_height#,.52x_height#);
222 top y1=h; bot y2=0; y3=y4=good.y .5h;
223 y5=y7=y1; y6=y8=y2; lft x7=hround u; x4=w-x7;
224 x5=good.x x7+spread; x1=good.x x5+spread;
225 x1=x2=x3; x6=x5; x7=x8;
226 draw z7--z8; draw z5--z6; draw z1--z2; % verticals
227 draw z3--z4; % horizontal piece
228 penlabels(1,2,3,4,5,6,7,8); endchar;
229
230 cmchar "Satisfies";
231 beginchar(oct"017",11u#,asc_height#,0);
232 adjust_fit(0,0); pickup rule.nib;
233 compute_spread(.45x_height#,.55x_height#);
234 top y1=h; bot y2=0; y0=good.y .5[y1,y2];
235 y3=vround y0+.5spread;
236 y5=vround y0- .5spread; y4=y3; y6=y5;
237 lft x1=hround u; x4=w-x1;
238 x1=x2=x3=x5; x4=x6; x0=x1;
239 draw z1--z2; % vertical line
240 draw z3--z4; % draw top horizontal piece
241 draw z5--z6; % draw bottom horizontal piece
242 penlabels(0,1,2,3,4,5,6); endchar;
243
244 cmchar "Rightward double arrowhead";
245 compute_spread(.45x_height#,.55x_height#);
246 beginchar(oct"020",18u#,v_center(spread#+.48asc_height#)); adjust_fit(0,0);
247 pickup crisp.nib; pos1(rule_thickness,90); pos2(rule_thickness,90);
248 pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0); y0=y1=y2=math_axis; x1-.5rule_thickness=hround u;
249 rt x0=hround(w-u); y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps;
250 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0;
251 z9=.381966[.5[z3,z4],z0]; numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
252 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p; path p;
253 p=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
254 --z2l--z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
255 --z3r{z9-z3}..z0 & cycle;
256 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
257 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
258 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
259 filldraw p shifted (x3l-x0,0);
260 penlabels(0,1,2,3,4,5,6,9); endchar;
261
262 cmchar "Leftward double arrowhead";
263 compute_spread(.45x_height#,.55x_height#);
264 beginchar(oct"021",18u#,v_center(spread#+.48asc_height#));
265 adjust_fit(0,0); pickup crisp.nib;
266 pos1(rule_thickness,90); pos2(rule_thickness,90);
267 pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0); y0=y1=y2=math_axis;
268 x1+.5rule_thickness=hround(w-u); lft x0=hround u;
269 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
270 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0));
271 z6l=z0; z9=.381966[.5[z3,z4],z0];
272 numeric t; path p;
273 p=z4r{z9-z4}..z6r;
274 t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
275 x2=xpart point t of p;
276 path p; p=z0..{z4-z9}z4l--subpath (0,t)
277 of\\(z4r{z9-z4}..z6r)
278 --z2l--z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
279 --z3l{z9-z3}..z0 & cycle; % second arrowhead
280 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
281 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
282 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
283 filldraw p shifted (x3r-x0,0);
284 penlabels(0,1,2,3,4,5,6,9); endchar;
285
286 cmchar "Leftward double arrow";
287 compute_spread(.45x_height#,.55x_height#);
288 beginchar(oct"022",18u#,v_center(spread#+.96asc_height#));
289 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
290 pos2(rule_thickness,90); pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0);
291 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft
292 x0=hround u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
293 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0));
294 z6l=z0; z9=.381966[.5[z3,z4],z0]; numeric t; path p;
295 p=z4r{z9-z4}..z6r; t=xpart(p
296 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
297 path p; % re-use p
298 p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
299 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
300 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
301 p:=p shifted (0,y2-y4+eps); filldraw p; % top arrow
302 p:= p shifted (0,y4-y3-eps); filldraw p; % bottom arrow
303 penlabels(0,1,2,3,4,5,6,9); endchar;
304
305 cmchar "Rightward double arrow";
306 compute_spread(.45x_height#,.55x_height#);
307 beginchar(oct"023",18u#,v_center(spread#+.96asc_height#));
308 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
309 pos2(rule_thickness,90); pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0);
310 y0=y1=y2=math_axis; x1-.5rule_thickness=hround u; rt
311 x0=hround(w-u); y3-y0=y0-y4=.24asc_height+eps;
312 x3=x4=x0-3u-eps; pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0;
313 pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
314 numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
315 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
316 path p; p=z0..{z4-z9}z4r--subpath (0,t)
317 of\\(z4l{z9-z4}..z6r)
318 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
319 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
320 p:=p shifted (0,y2-y4+eps); filldraw p; % top
321 p:=p shifted (0,y4-y3-eps); filldraw p; %bottom
322 penlabels(0,1,2,3,4,5,6,9); endchar;
323
324 cmchar "Double upward arrow";
325 beginchar(oct"024",15u#,asc_height#,asc_depth#); italcorr
326 .76asc_height#*slant+.5crisp#-u#; adjust_fit(0,0); pickup
327 crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
328 pos3(min(bar,rule_thickness),90); pos4(min(bar,rule_thickness),90); lft
329 x1l=hround(.5w-.5rule_thickness); y1-.5rule_thickness=-d;
330 x0=x1=x2; top y0=h; x0-x3=x4-x0=3u+eps;
331 y3=y4=y0-.24asc_height-eps; pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0;
332 pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
333 numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
334 intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of
335 p;
336 path p; p=z0..{z4-z9}z4r--subpath (0,t)
337 of\\(z4l{z9-z4}..z6r)
338 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3l{z9-z3}..z5r)
339 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
340 p:=p shifted (x0-x4-eps,0); filldraw p; % left arrow
341 p:=p shifted (x4-x3+eps,0); filldraw p;
342 penlabels(0,1,2,3,4,5,6,9); endchar;
343
344 cmchar "Double downward arrow";
345 beginchar(oct"025",15u#,asc_height#,asc_depth#);
346 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,0);
347 pos2(rule_thickness,0); pos3(min(bar,rule_thickness),90); pos4(min(bar,rule_thickness),90); lft
348 x1l=hround(.5w-.5rule_thickness); y1+.5rule_thickness=h;
349 x0=x1=x2; bot y0=-d; x0-x3=x4-x0=3u+eps;
350 y3=y4=y0+.24asc_height+eps; pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0;
351 pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
352 numeric t; path p; p=z4r{z9-z4}..z6r; t=xpart(p
353 intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of
354 p;
355 path p; p=z0..{z4-z9}z4l--subpath (0,t)
356 of\\(z4r{z9-z4}..z6r)
357 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
358 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
359 p:=p shifted (x0-x4-eps,0); filldraw p; % left arrow
360 p:=p shifted (x4-x3+eps,0); filldraw p;
361 penlabels(0,1,2,3,4,5,6,9); endchar;
362
363 %%
364 cmchar "Upward rightward harpoon";
365 beginchar(oct"026",7.5u#,asc_height#, asc_depth#);
366 %% see page E431
367 adjust_fit(0,0); pickup crisp.nib;
368 x0=x1=x2; lft x1l=hround(.5w-.5rule_thickness);
369 y1-.5rule_thickness=-d; pos1(rule_thickness,0);
370 pos2(rule_thickness,0); pos3(min(bar,rule_thickness),-90); pos4(min(bar,rule_thickness),-90);
371 top y0=vround h;
372 x3-x0=x0-x4=.24asc_height+eps; y3=y4=y0-3u-eps;
373 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0;
374 pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0;
375 z9=.381966[.5[z3,z4],z0];
376 numeric t; path p;
377 p=z4r..{y0-y4,2(x0-x4)}z6r;
378 t=xpart (p intersectiontimes ((x2l,0)--(x2l,h)));
379 y2=ypart point t of p;
380 filldraw z0--(x2l,y0)---z1l..z1r---z2r
381 ..subpath(t,0) of (z3r..{x0-x3,2(y0-y3)}z5r)
382 --z3l..{x0-x3,2(y0-y3)}cycle;
383 picture v; v:=currentpicture;
384 penlabels(0,1,2,3,4,5,6,9); endchar;
385
386 cmchar "Downward rightward harpoon";
387 beginchar(oct"027",7.5u#,asc_height#,asc_depth#);
388 adjust_fit(0,0);
389 currentpicture:=v
390 reflectedabout((0,.5(h-d)*aspect_ratio+eps),(w,.5(h-d)*aspect_ratio+eps));
391 penlabels(0,1,2,3,4,5,6); endchar;
392
393 cmchar "Upward leftward harpoon";
394 beginchar(oct"030",7.5u#,asc_height#, asc_depth#);
395 adjust_fit(0,0);
396 currentpicture:=
397 v reflectedabout((w/2+eps,-d),(w/2+eps,h));
398 picture v; v:=currentpicture;
399 penlabels(0,1,2,3,4,5,6); endchar;
400
401 cmchar "Downward leftward harpoon";
402 beginchar(oct"031",7.5u#,asc_height#,asc_depth#);
403 adjust_fit(0,0);
404 currentpicture:=v
405 reflectedabout((0,.5(h-d)*aspect_ratio+eps),(w,.5(h-d)*aspect_ratio+eps));
406 penlabels(0,1,2,3,4,5,6); endchar;
407
408 cmchar "Rightward arrow with tail";
409 compute_spread(.45x_height#,.55x_height#);
410 beginchar(oct"032",20u#,v_center(spread#+.48asc_height#));
411 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
412 pos2(rule_thickness,90); pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0);
413 y0=y1=y2=math_axis; x1-.5rule_thickness=hround 1.5u; rt
414 x0=hround(w-3u); y3-y0=y0-y4=.24asc_height+eps;
415 x3=x4=x0-3u-eps; pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0;
416 pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
417 numeric t; path p; p=z4l{z9-z4}..z6r; t=xpart(p
418 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
419 path p;
420 p=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
421 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
422 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
423 path arrow;
424 arrow=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
425 --z2l---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
426 --z3r{z9-z3}..z0 & cycle;
427 p:=p shifted (2u,0); filldraw p;
428 arrow:=arrow shifted (-13u+min(bar,rule_thickness),0); filldraw arrow;
429 penlabels(0,1,2,3,4,5,6,9); endchar;
430
431 cmchar "Leftward arrow with tail";
432 beginchar(oct"033",20u#,v_center(spread#+.48asc_height#));
433 adjust_fit(0,0); pickup crisp.nib;
434 p:= p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
435 arrow:= arrow reflectedabout ((w/2+eps,-d),(w/2+eps,h));
436 filldraw p; filldraw arrow;
437 penlabels(0,1,2,3,4,5,6,9); endchar;
438
439 cmchar "Leftward-rightward parallel arrows";
440 compute_spread(.45x_height#,.55x_height#);
441 beginchar(oct"034",18u#,v_center(spread#+.96asc_height#));
442 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
443 pos2(rule_thickness,90); pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0);
444 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft
445 x0=hround u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
446 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0));
447 z6l=z0; z9=.381966[.5[z3,z4],z0]; numeric t; path p;
448 p=z4r{z9-z4}..z6r; t=xpart(p
449 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
450 path p, q; % re-use p
451 p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
452 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
453 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
454 p:=p shifted (0,.5[y3,y4]+eps); filldraw p; % top arrow
455 p:= p shifted (0,y4-y3);
456 q:= p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
457 p:=p shifted (0,y3-y4+eps); % restore p's position
458 filldraw q; % bottom arrow
459 penlabels(0,1,2,3,4,5,6,9); endchar;
460
461 cmchar "Rightward-leftward parallel arrow";
462 compute_spread(.45x_height#,.55x_height#);
463 beginchar(oct"035",18u#,v_center(spread#+.96asc_height#));
464 adjust_fit(0,0); pickup crisp.nib;
465 p:=p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
466 q:=q reflectedabout ((w/2+eps,-d),(w/2+eps,h));
467 filldraw p; filldraw q;
468 penlabels(0,1,2,3,4,5,6,9); endchar;
469
470 cmchar "Leftward shift";
471 beginchar(oct"036",9u#,asc_height#, 0);
472 adjust_fit(0,0); pickup crisp.nib; pos1(rule_thickness,90);
473 pos2(rule_thickness,90); pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0);
474 y0=y1=y2=.8h; x1+.5rule_thickness=hround(w-u); lft x0=hround
475 u; y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
476 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0));
477 z6l=z0; z9=.381966[.5[z3,z4],z0];
478 z10=z1; x11=x10; y11-.5rule_thickness =vround -d;
479 pos10(rule_thickness,0); pos11(rule_thickness,0);
480 numeric t; path p; p=z4r{z9-z4}..z6r;
481 t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
482 x2=xpart point t of p;
483 path p;
484 p=z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
485 --z2l---(x10l,y1l)--z11l..z11r---{up}z10r..{left}z1r---z2r--subpath
486 (t,0) of\\(z3r{z9-z3}..z5r)
487 --z3l{z9-z3}..z0 & cycle; % arrowhead and bent stem
488 filldraw p;
489 penlabels(0,1,2,3,4,5,6,9,10); endchar;
490
491 cmchar "Rightward shift";
492 beginchar(oct"037",9u#,asc_height#, 0);
493 adjust_fit(0,0); pickup crisp.nib;
494 p:=p reflectedabout((w/2+eps,-d),(w/2+eps,h));
495 filldraw p;
496 penlabels(0,1,2,3,4,5,6,9); endchar;
497
498 compute_spread(.45x_height#,.55x_height#);
499 cmchar "Rightward squiggly arrow";
500 beginchar(oct"040",18u#,v_center(spread# +
501 rule_thickness#));
502 adjust_fit(0,0); pickup crisp.nib;
503 pos1(rule_thickness,90); pos2(rule_thickness,90);
504 pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0); y0=y1=y2=math_axis;
505 x1-.5rule_thickness=hround 11u; rt x0=hround(w-u);
506 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps;
507 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0));
508 z6l=z0; z9=.381966[.5[z3,z4],z0];
509 numeric t; path p;
510 p=z4l{z9-z4}..z6r; t=xpart(p
511 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
512 path p;
513 p=z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
514 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
515 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
516 filldraw p;
517 %% now for squiggle
518 x12-x11=x13-x12=x14-x13=x15-x14=x16-x15=x1-x16;
519 x1-x11=hround (w-2u-x0+x1-.5rule_thickness);
520 y11=y13=y15=y0; y12=y16=.5[y0,y3];
521 y14=.5[y4,y0];
522 pickup pencircle scaled rule_thickness;
523 draw z11---z12---z14---z16---z1;
524 penlabels(0,1,2,3,4,5,6,9,11,12,13,14,15,16); endchar;
525
526 compute_spread(.45x_height#,.55x_height#);
527 cmchar "Leftward rightward squiggly arrow";
528 beginchar(oct"041",25u#,v_center(spread# +
529 rule_thickness#));
530 adjust_fit(0,0); pickup crisp.nib;
531 arrow_length=4.5u+eps;
532 pos1(rule_thickness,90); pos2(rule_thickness,90);
533 pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0); y0=y1=y2=math_axis;
534 x1+.5rule_thickness=hround(u+arrow_length);
535 lft x0=hround u; y3-y0=y0-y4=.24asc_height+eps;
536 x3=x4=x0+3u+eps; pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0;
537 pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
538 numeric t; path p; p=z4r{z9-z4}..z6r; t=xpart(p
539 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
540 path p; p=z0..{z4-z9}z4l--subpath (0,t)
541 of\\(z4r{z9-z4}..z6r)
542 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
543 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
544 filldraw p; % left arrow
545 p:=p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
546 filldraw p; % right arrow
547 z10=z1 reflectedabout ((w/2+eps,-d),(w/2+eps,h));
548 y11=y15=y19=.5[y0,y3]; y13=y17=.5[y4,y0];
549 y12=y14=y16=y18=y10;
550 x11-x1=x12-x11=x13-x12=x14-x13=x15-x14=x16-x15=x17-x16=x18-x17=
551 x19-x18=x10-x19;
552 pickup pencircle scaled rule_thickness;
553 draw z1---z11---z13---z15---z17---z19---z10;
554 penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14,15,16,17,18,19);
555 endchar;
556
557 cmchar "Leftward curly arrow";
558 beginchar(oct"042",18u#,.8asc_height#,0#);
559 adjust_fit(0,0); pickup crisp.nib;
560 numeric arrow_length; arrow_length=.66*(w-2u+eps);
561 pos1(rule_thickness,90); pos2(rule_thickness,90);
562 pos3(min(bar,rule_thickness),0); pos4(min(bar,rule_thickness),0); y0=y1=y2=math_axis;
563 x1+.5rule_thickness=hround(u+arrow_length);
564 lft x0=hround u; y3-y0=y0-y4=.24asc_height+eps;
565 x3=x4=x0+3u+eps; pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0;
566 pos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0];
567 numeric t; path p; p=z4r{z9-z4}..z6r; t=xpart(p
568 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
569 path p; p=z0..{z4-z9}z4l--subpath (0,t)
570 of\\(z4r{z9-z4}..z6r)
571 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
572 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
573 filldraw p; % left arrow
574 z10=z1; x13=x14=hround(u+arrow_length+eps); y13=y1; y14=-o;
575 x12=.5[x11,x13]; y12=h; rt x11=hround(w-u); y11=.5[y10,y12];
576 pickup pencircle scaled rule_thickness;
577 path q;
578 q=z10{right}..tension0.8..{up}z11..tension0.8..{left}z12
579 ..tension0.8..{down}z13--z14;
580 draw q;
581 penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14); endchar;
582
583 cmchar "Rightward curly arrow";
584 beginchar(oct"043",18u#,.8asc_height#,0#);
585 adjust_fit(0,0); pickup crisp.nib;
586 p:=p reflectedabout ((w/2+eps,-d),(w/2+eps,h));
587 filldraw p;
588 pickup pencircle scaled rule_thickness;
589 q:=q reflectedabout ((w/2+eps,-d),(w/2+eps,h));
590 draw q; endchar;
591
592 numeric circ_diam; % diameter of little circle
593 circ_diam=2.5u;
594 cmchar "Equals circle sign";
595 compute_spread(.45x_height#,.55x_height#);
596 beginchar(oct"044",14u#,v_center(4spread#+rule_thickness#+2.5u#));
597 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
598 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
599 y1-y3=spread; .5[y1,y3]=math_axis; draw z1--z2; % upper bar
600 draw z3--z4; % lower bar %
601 penpos11(rule_thickness,90); penpos13(rule_thickness,-90);
602 penpos12(rule_thickness,180); penpos14(rule_thickness,0);
603 x12r=hround(.5w-.5circ_diam-rule_thickness); %
604 x14r=w-x12r; x11=x13=.5w; y11l=y13l+circ_diam;
605 y12=y14=.5[y11,y13]; y13r=vround(y1+.8spread); %
606 penstroke pulled_arc.e(11,12) & pulled_arc.e(12,13)
607 & pulled_arc.e(13,14) & pulled_arc.e(14,11) & cycle; %
608 penlabels(1,2,3,4,11,12,13,14); endchar;
609
610
611
612 cmchar "Follows or equals sign";
613 compute_spread(.45x_height#,.55x_height#);
614 spread#':=spread#; spread':=spread; % spread of similarity sign
615 compute_spread(.54 x_height#,.66 x_height#);
616 spread#'':=spread#; spread'':=spread; % spread between symbols
617 compute_spread(5/4 x_height#,3/2 x_height#); % spread of follows sign
618 beginchar(oct"045",14u#,v_center(spread#'+spread#+spread#''));
619 adjust_fit(0,0); pickup rule.nib; autorounded;
620 lft x1=hround 1.5u-eps; x1=x3; x2=w-x1;
621 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
622 draw z1{u,-spread}...{right}z2; %upper `diagonal'
623 draw z3{u,spread}...{right}z2; % lower diagonal
624 pickup pencircle xscaled .7rule_thickness yscaled
625 1.4rule_thickness;
626 if vair#>.8curve#: pickup rule.nib; autorounded; fi
627 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
628 bot y11=bot y13; top y12=top y14;
629 top y12-bot y11=spread'';
630 y3-y14=spread';
631 draw z11{up}...z12{right}..{right}z13...{up}z14;
632 penlabels(1,2,3,11,12,13,14); endchar;
633
634 cmchar "Greater than or similar to sign";
635 compute_spread(.45x_height#,.55x_height#);
636 spread#':=spread#; spread':=spread;
637 compute_spread(.54x_height#,.66x_height#);
638 spread#'':=spread#; spread'':=spread;
639 compute_spread(5/4 x_height#,3/2 x_height#);
640 beginchar(oct"046",14u#,v_center(spread#'+spread#+spread#''));
641 adjust_fit(0,0); pickup rule.nib; autorounded;
642 lft x1=hround 1.5u-eps; x1=x3; x2=w-x1;
643 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
644 draw z1--z2--z3;
645 pickup pencircle xscaled .7rule_thickness yscaled
646 1.4rule_thickness;
647 if vair#>.8curve#: pickup rule.nib; autorounded; fi
648 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
649 bot y11=bot y13; top y12=top y14;
650 top y12-bot y11=spread'';
651 y3-y14=spread';
652 draw z11{up}...z12{right}..{right}z13...{up}z14;
653 penlabels(1,2,3,4,11,12,13,14); endchar;
654
655 cmchar "Greater than or approximately equal to sign";
656 compute_spread(.45x_height#,.55x_height#);
657 spread#':=spread#; spread':=spread;
658 compute_spread(.54x_height#,.66x_height#);
659 spread#'':=spread#; spread'':=spread; % spread between similarities
660 compute_spread(1.111 x_height#,1.333 x_height#);
661 beginchar(oct"047",14u#,v_center(spread#+2spread#''+2rule_thickness#));
662 adjust_fit(0,0); pickup rule.nib; autorounded;
663 lft x1=hround 1.5u-eps; x1=x3; x2=w-x1;
664 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
665 draw z1--z2--z3;
666 pickup pencircle xscaled .7rule_thickness yscaled
667 1.4rule_thickness;
668 if vair#>.8curve#: pickup rule.nib; autorounded; fi
669 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
670 bot y11=bot y13; top y12=top y14;
671 top y12-bot y11=spread';
672 bot y3- top y13 = spread'';
673 path p; p=z11{up}...z12{right}..{right}z13...{up}z14;
674 draw p; draw p shifted (0,-spread'');
675 penlabels(1,2,3,4,11,12,13,14); endchar;
676
677 cmchar "Multimap symbol";
678 beginchar(oct"050",20u#,.8asc_height#,0#);
679 adjust_fit(0,0); pickup rule.nib; autorounded;
680 numeric circ_diam; circ_diam=5u;
681 y2=math_axis; y8=y2+.5circ_diam; rt x2=w-u;
682 x6=x2-circ_diam;
683 circle_points; draw_circle;
684 x9=u+.5rule_thickness; y9=y10=y2; x10=x6-.5rule_thickness;
685 draw z9---z10;
686 penlabels(1,2,3,4,5,6,7,8,9,10); endchar;
687
688 cmchar "Therefore";
689 beginchar(oct"051",12u#,asc_height#,0);
690 adjust_fit(0,0);
691 lft x1=hround 1.5u; x2=w-x1; bot y1=-o; y2=y1;
692 z3-z1=(z2-z1)rotated60;
693 if square_dots:
694 pickup rule.nib;
695 filldraw unitsquare shifted (-.5,-.5) scaled (dot_size-.5rule_thickness) shifted z1;
696 filldraw unitsquare shifted (-.5,-.5) scaled (dot_size-.5rule_thickness) shifted z2;
697 filldraw unitsquare shifted (-.5,-.5) scaled (dot_size-.5rule_thickness) shifted z3;
698 else:
699 fill fullcircle scaled dot_size shifted z1;
700 % left bottom dot
701 fill fullcircle scaled dot_size shifted z2;
702 % rigth bottom
703 fill fullcircle scaled dot_size shifted z3; % top dot
704 fi
705 penlabels(1,2,3); endchar;
706
707
708 cmchar "Because";
709 beginchar(oct"052",12u#,asc_height#,0);
710 adjust_fit(0,0);
711 lft x1=hround 1.5u; x2=w-x1; y2=y1;
712 x3=w/2; y3=-o;
713 z3-z1=(z2-z1)rotated-60;
714 if square_dots:
715 pickup rule.nib;
716 filldraw unitsquare shifted (-.5,-.5) scaled (dot_size-.5rule_thickness) shifted z1;
717 filldraw unitsquare shifted (-.5,-.5) scaled (dot_size-.5rule_thickness) shifted z2;
718 filldraw unitsquare shifted (-.5,-.5) scaled (dot_size-.5rule_thickness) shifted z3;
719 else:
720 fill fullcircle scaled dot_size shifted z1; % top left dot
721 fill fullcircle scaled dot_size shifted z2;
722 % top right dot
723 fill fullcircle scaled dot_size shifted z3; % bottom dot
724 fi
725 penlabels(1,2,3); endchar;
726
727 cmchar "Equals-and-dots sign";
728 beginarithchar(oct"053");
729 compute_spread(.45x_height#,.55x_height#);
730 pickup rule.nib;
731 lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
732 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
733 draw z1--z2; draw z3--z4; % draw bars
734 pickup light_rule.nib;
735 x5=x6=x7=x8=hround w/2+eps; z5=z6; z7=z8;
736 penpos5(.8dot_size,0); penpos6(.8dot_size,90);
737 penpos7(.8dot_size,0); penpos8(.8dot_size,90);
738 y5-y1=y3-y7=spread;
739 dot(5,6); dot(7,8); % draw dots
740 penlabels(1,2,3,4,5,6,7,8); endchar;
741
742 cmchar "Equals sign with triangle";
743 beginchar(oct"054", 14u#,12u#+math_axis# ,6u#-math_axis#);
744 compute_spread(.45x_height#,.55x_height#);
745 pickup rule.nib;
746 lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
747 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
748 draw z1--z2; draw z3--z4; % draw bars
749 numeric tri_side; % length of equilateral triangle
750 tri_side=7u;
751 x6-x5=tri_side; .5[x5,x6]=w/2; y5=y6; y5-y1=.8spread;
752 %top y7=body_height;x7=w/2;
753 z7-z5=(z6-z5) rotated 60;
754 draw z5--z6--z7--cycle;
755 penlabels(1,2,3,4,5,6,7); endchar;
756
757
758 cmchar "Precedes or equals sign";
759 compute_spread(.45x_height#,.55x_height#);
760 spread#':=spread#; spread':=spread;
761 compute_spread(.54x_height#,.55x_height#);
762 spread#'':=spread#; spread'':=spread;
763 compute_spread(5/4 x_height#,3/2 x_height#);
764 beginchar(oct"055",14u#,v_center(spread#'+spread#+spread#''));
765 adjust_fit(0,0); pickup rule.nib; autorounded;
766 lft x2=hround 1.5u-eps; x1=x3=w-x2;
767 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
768 draw z1{-u,-spread}...{left}z2; %upper `diagonal'
769 draw z3{-u,spread}...{left}z2; % lower diagonal
770 pickup pencircle xscaled .7rule_thickness yscaled
771 1.4rule_thickness;
772 if vair#>.8curve#: pickup rule.nib; autorounded; fi
773 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
774 bot y11=bot y13; top y12=top y14;
775 top y12-bot y11=spread'';
776 y3-y14=spread';
777 draw z11{up}...z12{right}..{right}z13...{up}z14;
778 penlabels(1,2,3,11,12,13,14); endchar;
779
780 cmchar "Less than or similar to sign";
781 compute_spread(.45x_height#,.55x_height#);
782 spread#':=spread#; spread':=spread;
783 compute_spread(.54x_height#,.55x_height#);
784 spread#'':=spread#; spread'':=spread;
785 compute_spread(5/4 x_height#,3/2 x_height#);
786 beginchar(oct"056",14u#,v_center(spread#'+spread#+spread#''));
787 adjust_fit(0,0); pickup rule.nib; autorounded;
788 lft x2=hround 1.5u-eps; x1=x3=w-x2;
789 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
790 draw z1--z2--z3;
791 pickup pencircle xscaled .7rule_thickness yscaled
792 1.4rule_thickness;
793 if vair#>.8curve#: pickup rule.nib; autorounded; fi
794 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
795 bot y11=bot y13; top y12=top y14;
796 top y12-bot y11=spread'';
797 y3-y14=spread';
798 draw z11{up}...z12{right}..{right}z13...{up}z14;
799 penlabels(1,2,3,4,11,12,13,14); endchar;
800
801 cmchar "Less than or approximately equal to sign";
802 compute_spread(.45x_height#,.55x_height#);
803 spread#':=spread#; spread':=spread;
804 compute_spread(.54x_height#,.66x_height#);
805 spread#'':=spread#; spread'':=spread; % spread between similarities
806 compute_spread(1.111 x_height#,1.333 x_height#);
807 beginchar(oct"057",14u#,v_center(spread#+2spread#''+2rule_thickness#));
808 adjust_fit(0,0); pickup rule.nib; autorounded;
809 lft x2=hround 1.5u-eps; x1=x3=w-x2;
810 y1-y3=spread; y2=.5[y1,y3]; top y1=h;
811 draw z1--z2--z3;
812 pickup pencircle xscaled .7rule_thickness yscaled
813 1.4rule_thickness;
814 if vair#>.8curve#: pickup rule.nib; autorounded; fi
815 lft x11=hround u; x12=4u; x13=w-x12; x14=w-x11;
816 bot y11=bot y13; top y12=top y14;
817 top y12-bot y11=spread';
818 bot y3- top y13 = spread'';
819 path p; p=z11{up}...z12{right}..{right}z13...{up}z14;
820 draw p; draw p shifted (0,-spread'');
821 penlabels(1,2,3,4,11,12,13,14); endchar;
822
823 cmchar "Equal or less than sign";
824 compute_spread(.45x_height#,.55x_height#);
825 spread#':=spread#; spread':=spread;
826 compute_spread(5/4x_height#,3/2x_height#);
827 beginchar(oct"060",14u#,v_center(spread#'+spread#+rule_thickness#));
828 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
829 lft x2=hround 1.5u-eps; x1=x3=w-x2; y1-y3=spread;
830 y2=.5[y1,y3]; y8-y1=y9-y2=spread'; top y8=h;
831 x2=x9; x1=x8;
832 draw z1--z2--z3; % diagonals
833 draw z8--z9; % equal sign
834 penlabels(1,2,3,8,9); endchar;
835
836 cmchar "Equal or greater than sign";
837 compute_spread(.45x_height#,.55x_height#);
838 spread#':=spread#; spread':=spread;
839 compute_spread(5/4x_height#,3/2x_height#);
840 beginchar(oct"061",14u#,v_center(spread#'+spread#+rule_thickness#));
841 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
842 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
843 x2=x9; x1=x8;
844 y2=.5[y1,y3]; y8-y1=y9-y2=spread'; top y8=h;
845 draw z1--z2--z3; % diagonals
846 draw z8--z9;
847 penlabels(1,2,3,8,9); endchar;
848
849 cmchar "Less than or (slanted) equal sign";
850 compute_spread(.45x_height#,.55x_height#);
851 spread#':=spread#; spread':=spread;
852 compute_spread(5/4x_height#,3/2x_height#);
853 beginchar(oct"066",14u#,v_center(spread#'+spread#+rule_thickness#));
854 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
855 lft x2=hround 1.5u-eps; x1=x3=w-x2; y1-y3=spread;
856 y2=.5[y1,y3]; y3-y8=y2-y9=spread'; top y1=h;
857 x2=x9; x1=x8;
858 draw z1--z2--z3; % diagonals
859 draw z8--z9; % equal sign
860 penlabels(1,2,3,8,9); endchar;
861
862 cmchar "Greater than or (slanted) equal sign";
863 compute_spread(.45x_height#,.55x_height#);
864 spread#':=spread#; spread':=spread;
865 compute_spread(5/4x_height#,3/2x_height#);
866 beginchar(oct"076",14u#,v_center(spread#'+spread#+rule_thickness#));
867 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
868 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
869 x2=x9; x1=x8;
870 y2=.5[y1,y3]; y3-y8=y2-y9=spread'; top y1=h;
871 draw z1--z2--z3; % diagonals
872 draw z8--z9;
873 penlabels(1,2,3,8,9); endchar;
874 cmchar "Less than or greater than sign";
875 compute_spread(.4x_height#,.5x_height#);
876 spread#':=spread#; spread':=spread;
877 compute_spread(1.111 x_height#,1.333 x_height#);
878 beginchar(oct"067",14u#,v_center(2spread#'+spread#+rule_thickness#));
879 adjust_fit(0,0); pickup rule.nib; autorounded;
880 lft x1=hround w-1.5u+eps; x1=x3=x5; x2=x4=x6=w-x1;
881 y1-y3=spread; top y1=h; y2-y4=spread'; y4-y6=spread;
882 y2=.5[y1,y3]; y5=.5[y4,y6];
883 draw z1--z2--z3; draw z4--z5--z6;
884 penlabels(1,2,3,4,5,6); endchar;
885
886 cmchar "Greater than or less than sign";
887 compute_spread(.4x_height#,.5x_height#);
888 spread#':=spread#; spread':=spread;
889 compute_spread(1.111 x_height#,1.333x_height#);
890 beginchar(oct"077",14u#,v_center(2spread#'+spread#+rule_thickness#));
891 adjust_fit(0,0); pickup rule.nib; autorounded;
892 lft x1=hround 1.5u-eps; x1=x3=x5; x2=x4=x6=w-x1;
893 y1-y3=spread; top y1=h; y2-y4=spread'; y4-y6=spread;
894 y2=.5[y1,y3]; y5=.5[y4,y6];
895 draw z1--z2--z3; draw z4--z5--z6;
896 penlabels(1,2,3,4,5,6); endchar;
897
898 cmchar "Equals or precedes sign";
899 compute_spread(.45x_height#,.55x_height#);
900 spread#':=spread#; spread':=spread;
901 compute_spread(5/4x_height#,3/2x_height#);
902 beginchar(oct"062",14u#,v_center(spread#'+spread#+rule_thickness#));
903 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
904 lft x2=hround(1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
905 y2=.5[y1,y3]; top y8-bot y1=top y9-bot y2=spread'; bot y3=0;
906 x2=x9;x8=x1-2u;
907 draw z1{-u,-spread}...{left}z2;
908 draw z3{-u, spread}...{left}z2;
909 draw z8{-u,-spread}...{left}z9;
910 penlabels(1,2,3,8,9); endchar;
911
912 cmchar "Equals or follows sign";
913 compute_spread(.45x_height#,.55x_height#);
914 spread#':=spread#; spread':=spread;
915 compute_spread(5/4x_height#,3/2x_height#);
916 beginchar(oct"063",14u#,v_center(spread#'+spread#+rule_thickness#));
917 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
918 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
919 y2=.5[y1,y3]; top y8-bot y1=top y9-bot y2=spread'; bot y3=0;% top y8=h;
920 x2=x9;x8=x1+2u;
921 draw z1{u,-spread}...{right}z2;
922 draw z3{u, spread}...{right}z2;
923 draw z8{u,-spread}...{right}z9;
924 penlabels(1,2,3,8,9); endchar;
925
926 cmchar "Precedes or curvy equals sign";
927 compute_spread(.45x_height#,.55x_height#);
928 spread#':=spread#; spread':=spread;
929 compute_spread(5/4x_height#,3/2x_height#);
930 beginchar(oct"064",14u#,v_center(spread#'+spread#+rule_thickness#));
931 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
932 lft x2=hround(1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
933 y2=.5[y1,y3]; top y3-bot y8=top y2-bot y9=spread'; bot y3=0;
934 x2=x9;x8=x1-2u;
935 %for i=1 upto 3: %lower entire character
936 %y[i]:=y[i]-spread'; endfor
937 %for i=8 upto 9:
938 %y[i]:=y[i]-spread'; endfor
939 draw z1{-u,-spread}...{left}z2;
940 draw z3{-u, spread}...{left}z2;
941 draw z8{-u, spread}...{left}z9;
942 penlabels(1,2,3,8,9); endchar;
943
944 cmchar "Follows or curvy equals sign";
945 compute_spread(.45x_height#,.55x_height#);
946 spread#':=spread#; spread':=spread;
947 compute_spread(5/4x_height#,3/2x_height#);
948 beginchar(oct"074",14u#,v_center(spread#'+spread#+rule_thickness#));
949 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
950 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
951 y2=.5[y1,y3]; top y3-bot y8=top y2-bot y9=spread'; bot y3=0;
952 x2=x9;x8=x1+2u;
953 %for i=1 upto 3: %lower entire character
954 %y[i]:=y[i]-spread'; endfor
955 %for i=8 upto 9:
956 %y[i]:=y[i]-spread'; endfor
957 draw z1{u,-spread}...{right}z2;
958 draw z3{u, spread}...{right}z2;
959 draw z8{u, spread}...{right}z9;
960 penlabels(1,2,3,8,9); endchar;
961
962 cmchar "Less than or (double) equals sign";
963 compute_spread(.45x_height#,.55x_height#);
964 spread#':=spread#; spread':=spread;
965 compute_spread(5/4x_height#,3/2x_height#);
966 beginchar(oct"065",14u#,v_center(2spread#'+spread#+2rule_thickness#));
967 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
968 lft x2=hround 1.5u-eps; x1=x3=w-x2; y1-y3=spread;
969 y2=.5[y1,y3]; top y1=h;
970 x2=x9=x7; x1=x8=x6; y7=y6; y8=y9;
971 y7-y9=spread'; top y3-bot y6=spread';
972 draw z1--z2--z3; % diagonals
973 draw z6--z7; draw z8--z9; % equal sign
974 penlabels(1,2,3,6,7,8,9); endchar;
975
976 cmchar "Greater than or (double) equals sign";
977 compute_spread(.45x_height#,.55x_height#);
978 spread#':=spread#; spread':=spread;
979 compute_spread(5/4x_height#,3/2x_height#);
980 beginchar(oct"075",14u#,v_center(2spread#'+spread#+2rule_thickness#));
981 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
982 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2; y1-y3=spread;
983 x2=x7=x9; x1=x6=x8; y6=y7; y8=y9;
984 y2=.5[y1,y3]; top y3-bot y6=spread'; top y1=h;
985 y7-y9=spread';
986 draw z1--z2--z3; % diagonals
987 draw z6--z7; draw z8--z9;
988 penlabels(1,2,3,6,7,8,9); endchar;
989
990 cmchar "Reverse prime symbol (superscript only)";
991 beginchar(oct"070",3u#+max(1.75u#,curve#+2(curve#-stem#)),
992 .8asc_height#,0); adjust_fit(0,0); pickup fine.nib; numeric
993 light_stem,heavy_stem;
994 light_stem=if hefty: vair else: hround .5[vair,stem] fi;
995 heavy_stem=hround(bold+2bigdw); x1-.5heavy_stem=hround(.25u);
996 y1+.5heavy_stem=h; x2+.5light_stem=hround (w-.5u);
997 y2=1/12asc_height;
998 numeric theta; theta=angle(z1-z2)-90;
999 pos1(heavy_stem,theta); pos2(light_stem,theta);
1000 filldraw circ_stroke z1e--z2e; % diagonal
1001 penlabels(1,2); endchar;
1002
1003 cmchar "short axis line";
1004 beginchar(oct"071",9u#,27/7u#+math_axis#,27/7u#-math_axis#); pickup rule.nib;
1005 lft x1=hround 1.5u-eps; x2=w-x1; y1=y2=math_axis;
1006 draw z1--z2;
1007 labels(1,2); endchar;
1008
1009 cmchar "Dotted (right-left) equals sign";
1010 compute_spread(.45x_height#,.55x_height#);
1011 beginchar(oct"072",14u#,v_center(3spread#+2rule_thickness#));
1012 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1013 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
1014 y1-y3=spread; .5[y1,y3]=math_axis; draw z1--z2; % upper bar
1015 draw z3--z4; % lower bar
1016 pickup tiny.nib;
1017 x6=x5=x2; y6=y5=y1+spread;
1018 pos5(dot_size,0); pos6(dot_size,90);
1019 x7=x8=x3; y7=y8=y4-spread;
1020 pos7(dot_size,0); pos8(dot_size,90);
1021 dot(5,6); dot(7,8);
1022 penlabels(1,2,3,4,5,6,7,8); endchar;
1023
1024 cmchar "Dotted (left-right) equals sign";
1025 compute_spread(.45x_height#,.55x_height#);
1026 beginchar(oct"073",14u#,v_center(3spread#+2rule_thickness#));
1027 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1028 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
1029 y1-y3=spread; .5[y1,y3]=math_axis;
1030 draw z1--z2; % upper bar
1031 draw z3--z4; % lower bar
1032 pickup tiny.nib;
1033 x6=x5=x1; y6=y5=y1+spread;
1034 pos5(dot_size,0); pos6(dot_size,90);
1035 x7=x8=x4; y7=y8=y4-spread;
1036 pos7(dot_size,0); pos8(dot_size,90);
1037 dot(5,6); dot(7,8);
1038 penlabels(1,2,3,4,5,6,7,8); endchar;
1039
1040 cmchar "Square subset sign"; % taken from vol E, p533
1041 compute_spread(5/4x_height#,3/2x_height#);
1042 beginchar(oct"100",14u#,v_center(spread#+rule_thickness#));
1043 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1044 x1=x4=hround(w-x2)+eps; x3=x2; y1-y4=spread; y2=y1; y3=y4;
1045 top y1=h; draw z1--z2--z3--z4; % bars and stem x8=x1;
1046 penlabels(1,2,3,4); endchar;
1047
1048 cmchar "Square superset sign";
1049 compute_spread(5/4x_height#,3/2x_height#);
1050 beginchar(oct"101",14u#,v_center(spread#+rule_thickness#));
1051 adjust_fit(0,0); pickup rule.nib;
1052 x2=hround(w-1.5u); x1=x4=hround w-x2-eps; x3=x2;
1053 y1-y4=spread; y2=y1; y3=y4; top y1=h; draw z1--z2--z3--z4;
1054 % bars and stem
1055 penlabels(1,2,3,4); endchar;
1056
1057 cmchar "Rightward pointing isosceles triangle";
1058 compute_spread(.45x_height#,.55x_height#);
1059 spread#':=spread#; spread':=spread; % the spread of `$=$'
1060 compute_spread(5/4x_height#,3/2x_height#);
1061 beginchar(oct"102",14u#,v_center(spread#+rule_thickness#));
1062 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1063 x3=x2; x1=hround(w-x2);
1064 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1065 draw z1--z2--z3--cycle;
1066 penlabels(1,2,3); endchar;
1067
1068 cmchar "Leftward pointing isosceles triangle";
1069 compute_spread(.45x_height#,.55x_height#);
1070 spread#':=spread#; spread':=spread; % the spread of `$=$'
1071 compute_spread(5/4x_height#,3/2x_height#);
1072 beginchar(oct"103",14u#,v_center(spread#+rule_thickness#));
1073 adjust_fit(0,0); pickup rule.nib; rt x2=hround(w-1.5u-eps);
1074 x3=x2; x1=hround(w-x2);
1075 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1076 draw z1--z2--z3--cycle;
1077 penlabels(1,2,3); endchar;
1078
1079 cmchar "Rightward isosceles triangle with lower bar";
1080 compute_spread(.45x_height#,.55x_height#);
1081 spread#':=spread#; spread':=spread; % the spread of `$=$'
1082 compute_spread(5/4x_height#,3/2x_height#);
1083 beginchar(oct"104",14u#,v_center(spread#'+spread#+rule_thickness#));
1084 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1085 x3=x2; x1=hround(w-x2);
1086 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1087 x4=x2; x5=x1; y3-y4=spread'; y5=y4;
1088 draw z1--z2--z3--cycle; draw z4--z5;
1089 penlabels(1,2,3,4,5); endchar;
1090
1091 cmchar "Leftward isosceles triangle with lower bar";
1092 compute_spread(.45x_height#,.55x_height#);
1093 spread#':=spread#; spread':=spread; % the spread of `$=$'
1094 compute_spread(5/4x_height#,3/2x_height#);
1095 beginchar(oct"105",14u#,v_center(spread#'+spread#+rule_thickness#));
1096 adjust_fit(0,0); pickup rule.nib; rt x2=hround(w-1.5u-eps);
1097 x3=x2; x1=hround(w-x2);
1098 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1099 x4=x2; x5=x1; y3-y4=spread'; y5=y4;
1100 draw z1--z2--z3--cycle; draw z4--z5;
1101 penlabels(1,2,3,4,5); endchar;
1102
1103 cmchar "Large, filled, 5-pointed star";
1104 beginchar(oct"106",asc_height#+desc_depth#,asc_height#,desc_depth#);
1105 adjust_fit(.5u#, .5u#); pickup tiny.nib;
1106 numeric theta; theta=360/5;
1107 x0=good.x .5w; y0=good.y .5[h, -d]; x1=x0; top y1=h;
1108 for n=2 upto 5: z[n]=z0+(z1-z0) rotated((n-1)*theta); endfor
1109 % z0 is the `origin'
1110 % z1 thru z5 are the points; z1 at the top going
1111 % counterclockwise
1112 z6=(z1--z3)intersectionpoint(z2--z5);
1113 for n=7 upto10: z[n]=z0+(z6-z0)rotated((n-1)*theta); endfor
1114 filldraw z1--z6--z2--z7--z3--z8--z4--z9--z5--z10--cycle;
1115 penlabels(0,1,2,3,4,5); endchar;
1116
1117 cmchar "Vertical overlapping slurs";
1118 beginchar(oct"107",9u#,body_height#,paren_depth#);
1119 adjust_fit(0,0); pickup fine.nib;
1120 numeric light_stem; light_stem=Vround .5[vair,stem];
1121 y2=.5[h,-d]; x2r=hround w-1.5u; pos2(light_stem,0);
1122 x1-.5hair=hround w-x2; x3=x1; y1+.5hair=h; y3-.5hair=-d;
1123 numeric theta; theta= angle((z2-z1)xscaled3);
1124 numeric theta'; theta'=angle((z3-z2)xscaled3);
1125 pos1(min(hair,rule_thickness), theta+90);
1126 pos3(min(hair,rule_thickness), theta'+90);
1127 path p;
1128 p=z1l{dir theta}...z2l...{dir theta'}z3l
1129 ..z3r{-dir theta'}...z2r...{-dir theta}z1r..cycle;
1130 filldraw p;
1131 p:=p reflectedabout((.5w,-d),(.5w,h)); filldraw p;
1132 penlabels(1,2,3); endchar;
1133
1134 cmchar "Filled rightward pointing isosceles triangle";
1135 compute_spread(.45x_height#,.55x_height#);
1136 spread#':=spread#; spread':=spread; % the spread of `$=$'
1137 compute_spread(5/4x_height#,3/2x_height#);
1138 beginchar(oct"111",14u#,v_center(spread#+rule_thickness#));
1139 adjust_fit(0,0); pickup rule.nib; lft x2=hround(1.5u);
1140 x3=x2; x1=hround(w-x2);
1141 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1142 filldraw z1--z2--z3--cycle;
1143 penlabels(1,2,3); endchar;
1144
1145 cmchar "Filled leftward pointing isosceles triangle";
1146 compute_spread(.45x_height#,.55x_height#);
1147 spread#':=spread#; spread':=spread; % the spread of `$=$'
1148 compute_spread(5/4x_height#,3/2x_height#);
1149 beginchar(oct"112",14u#,v_center(spread#+rule_thickness#));
1150 adjust_fit(0,0); pickup rule.nib; rt x2=hround(w-1.5u-eps);
1151 x3=x2; x1=hround(w-x2);
1152 top y2=h; y2-y3=spread; y1=.5[y2,y3];
1153 filldraw z1--z2--z3--cycle;
1154 penlabels(1,2,3); endchar;
1155
1156 cmchar "short axis right arrow";
1157 beginchar(oct"113",9u#,27/7u#+math_axis#,27/7u#-math_axis#);
1158 pickup rule.nib;
1159 penpos1(.25rule_thickness,90); penpos2(.25rule_thickness,90); penpos3(min(bar,rule_thickness),0);
1160 penpos4(min(bar,rule_thickness),0);
1161 y0=y1=y2=math_axis;
1162 x1=hround 1.5u-eps;
1163 rt x0=w-x1;
1164 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0-3u-eps;
1165 penpos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; penpos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0;
1166 z9=.381966[.5[z3,z4],z0];
1167 numeric t; path p; p=z4l{z9-z4}..z6r;
1168 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
1169 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
1170 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
1171 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
1172 penlabels(0,1,2,3,4,5,6,9); endchar;
1173
1174 cmchar "short axis left arrow";
1175 beginchar(oct"114",9u#,27/7u#+math_axis#,27/7u#-math_axis#);
1176 pickup rule.nib;
1177 penpos1(.25rule_thickness,90); penpos2(.25rule_thickness,90); penpos3(min(bar,rule_thickness),0);
1178 penpos4(min(bar,rule_thickness),0);
1179 y0=y1=y2=math_axis; x0=hround 1.5u-eps;
1180 rt x1=w-x0;
1181 y3-y0=y0-y4=.24asc_height+eps; x3=x4=x0+3u+eps;
1182 penpos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; penpos6(min(bar,rule_thickness),angle(z3-z0)); z6l=z0;
1183 z9=.381966[.5[z3,z4],z0];
1184 numeric t; path p; p=z4r{z9-z4}..z6r;
1185 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
1186 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
1187 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
1188 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
1189 penlabels(0,1,2,3,4,5,6,9); endchar;
1190
1191
1192 cmchar "Filled downward triangle";
1193 beginchar(oct"110",.8asc_height#+3u#,.8asc_height#,0pt#);
1194 adjust_fit(0,0); pickup rule.nib;
1195 y2=0; lft x1=1.5u;
1196 x3=hround w-x1;
1197 y1=y3=vround h-y2; x2=.5[x1,x3];
1198 filldraw z1--z2--z3--cycle;
1199 penlabels(1,2,3); endchar;
1200
1201 cmchar "Downward triangle";
1202 beginchar(oct"117",.8asc_height#+3u#,.8asc_height#,0pt#);
1203 adjust_fit(0,0); pickup rule.nib;
1204 y2=0; lft x1=1.5u;
1205 x3=hround w-x1;
1206 y1=y3=vround h-y2; x2=.5[x1,x3];
1207 draw z1--z2--z3--cycle;
1208 penlabels(1,2,3); endchar;
1209
1210 cmchar "Upward triangle";
1211 beginchar(oct"115",.8asc_height#+3u#,.8asc_height#,0pt#);
1212 adjust_fit(0,0); pickup rule.nib;
1213 y2=h; lft x1=1.5u;
1214 x3=hround w-x1;
1215 y1=y3=vround h-y2; x2=.5[x1,x3];
1216 draw z1--z2--z3--cycle;
1217 penlabels(1,2,3); endchar;
1218
1219 cmchar "Filled upward triangle";
1220 beginchar(oct"116",.8asc_height#+3u#,.8asc_height#,0pt#);
1221 adjust_fit(0,0); pickup rule.nib;
1222 y2=h; lft x1=1.5u;
1223 x3=hround w-x1;
1224 y1=y3=vround h-y2; x2=.5[x1,x3];
1225 filldraw z1--z2--z3--cycle;
1226 penlabels(1,2,3); endchar;
1227
1228 cmchar "Egg sandwich";
1229 compute_spread(.45x_height#,.55x_height#);
1230 beginchar(oct"120",14u#,asc_height#,0);
1231 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1232 lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
1233 y1=y2; y3=y4;
1234 y1-y3=spread;
1235 .5[y1,y3]=math_axis;
1236 draw z1--z2; % upper bar
1237 draw z3--z4; % lower bar
1238 if tiny = 0: pickup rule.nib; else: pickup tiny.nib; fi
1239 x5=x6=hround w/2; bot y5=bot y1; top y6=top y3;
1240 y7=y8=math_axis;x8-x7=y5-y6;
1241 x6=.5[x7,x8];
1242 draw z5{right}..z8..z6{left}..z7..cycle;
1243 penlabels(1,2,3,4,5,6,7,8); endchar;
1244
1245 cmchar "Stacked symbols: <, bar, >";
1246 compute_spread(.45x_height#,.55x_height#);
1247 spread#':=spread#; spread':=spread;
1248 compute_spread(.98 x_height#,1.176 x_height#);
1249 beginchar(oct"121",14u#,v_center(2spread#'+2spread#+rule_thickness#));
1250 adjust_fit(0,0); pickup rule.nib;
1251 y1=y2; lft x1=hround 1.5u-eps; rt x2=w-x1;
1252 x4=x6=x8=x1; x3=x5=x7=x2;
1253 y5-y1=y1-y6=spread';top y3=h; y3-y5=spread;
1254 y6-y8=spread;
1255 y7=.5[y6,y8]; y4=.5[y3,y5];
1256 draw z3--z4--z5; draw z6--z7--z8; draw z1--z2;
1257 penlabels(1,2,3,4,5,6,7,8); endchar;
1258
1259 cmchar "Stacked symbls: greater than, bar, less than";
1260 compute_spread(.45x_height#,.55x_height#);
1261 spread#':=spread#; spread':=spread;
1262 compute_spread(.98 x_height#,1.176 x_height#);
1263 beginchar(oct"122",14u#,v_center(2spread#'+2spread#+rule_thickness#));
1264 adjust_fit(0,0); pickup rule.nib;
1265 y1=y2; lft x2=hround 1.5u-eps; rt x1=w-x2;
1266 x4=x6=x8=x1; x3=x5=x7=x2;
1267 y5-y1=y1-y6=spread';top y3=h; y3-y5=spread;
1268 y6-y8=spread;
1269 y7=.5[y6,y8]; y4=.5[y3,y5];
1270 draw z3--z4--z5; draw z6--z7--z8; draw z1--z2;
1271 numeric bar_ht; bar_ht=y1; %save height of bar
1272 penlabels(1,2,3,4,5,6,7,8); endchar;
1273
1274 cmchar "Stacked symbls: less than, =, greater than";
1275 compute_spread(.45x_height#,.55x_height#);
1276 spread#':=spread#; spread':=spread;
1277 compute_spread(.98 x_height#,1.176 x_height#);
1278 beginchar(oct"123",14u#,v_center(3spread#'+2spread#+rule_thickness#));
1279 adjust_fit(0,0); pickup rule.nib; autorounded;
1280 lft x1=hround 1.5u-eps; x2=w-x1;
1281 x1'=x1; x2=x2'; x4=x6=x8=x1;
1282 x3=x5=x7=x2;
1283 y1=y2; y1'=y2'; y2-y2'=spread'; bot y2=math_axis+.5spread';
1284 draw z1--z2; draw z1'--z2';
1285 y3-y5=y6-y8=spread;
1286 y5-y2=y2'-y6=spread';
1287 y7=.5[y6,y8]; y4=.5[y3,y5];
1288 draw z3--z4--z5; draw z6--z7--z8;
1289 penlabels(1,1',2,2',3,4,5,6,7,8); endchar;
1290
1291 cmchar "Stacked symbols: greater than, =, less than";
1292 compute_spread(.45x_height#,.55x_height#);
1293 spread#':=spread#; spread':=spread;
1294 compute_spread(.98 x_height#,1.176 x_height#);
1295 beginchar(oct"124",14u#,v_center(3spread#'+2spread#+rule_thickness#));
1296 adjust_fit(0,0); pickup rule.nib;
1297 lft x2=hround 1.5u-eps; x1=w-x2;
1298 x1'=x1; x2=x2'; x4=x6=x8=x1;
1299 x3=x5=x7=x2;
1300 y1=y2; y1'=y2'; y2-y2'=spread'; bot y2=math_axis+.5spread';
1301 draw z1--z2; draw z1'--z2';
1302 y3-y5=y6-y8=spread;
1303 y5-y2=y2'-y6=spread';
1304 y7=.5[y6,y8]; y4=.5[y3,y5];
1305 draw z3--z4--z5; draw z6--z7--z8;
1306 penlabels(1,1',2,2',3,4,5,6,7,8); endchar;
1307
1308 cmchar "Yen symbol";
1309 compute_spread(.45x_height#, .55x_height#);
1310 beginchar(oct"125",13u#,cap_height#,0); %% adapted from "Y"
1311 italcorr cap_height#*slant+.45u#;
1312 adjust_fit(cap_serif_fit#,cap_serif_fit#); numeric
1313 left_stem,right_stem,outer_jut,dy,alpha;
1314 left_stem=cap_stem-stem_corr; right_stem=min(cap_hair if
1315 hefty:-2stem_corr fi,left_stem); outer_jut=.75cap_jut;
1316 x1l=w-x4r=l+letter_fit+outer_jut+.05u;
1317 x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h;
1318 y2=y3=y5=.4h; dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
1319 penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
1320 penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
1321 penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
1322 z0=whatever[z1r,z2r]=whatever[z3l,z4l]; if
1323 y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
1324 fill
1325 z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
1326 --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
1327 ...{down}z0+.5left--cycle; % diagonals and stem
1328 else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
1329 --diag_end(5r,6r,1,1,6l,5l)--z5l
1330 --diag_end(2l,1l,1,1,1r,0)--cycle; fi % diagonals & stem
1331 if serifs: numeric inner_jut; pickup tiny.nib;
1332 prime_points_inside(1,2); prime_points_inside(4,3);
1333 prime_points_inside(6,5);
1334 if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut:
1335 inner_jut=cap_jut;
1336 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
1337 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);
1338 %upper lft serif
1339 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);
1340 % upper right serif
1341 dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi
1342 % lower serif
1343 pickup pencircle scaled .5[fine, rule_thickness];
1344 x7=x9=x1l; x8=x10=x4r;
1345 y9=y10;
1346 top y7=bar_height; y7=y8; draw z7--z8;
1347 y9-y7=spread;
1348 draw z9--z10;
1349 penlabels(0,1,2,3,4,5,6,1',2',3',4',5',6',7,8,9,10); endchar;
1350
1351 cmchar "Triple rightward arrow";
1352 compute_spread(.45x_height#,.55x_height#);
1353 beginchar(oct"126",18u#,v_center(2spread#+.5asc_height#+rule_thickness#));
1354 adjust_fit(0,0); pickup rule.nib; penpos1(rule_thickness,90);
1355 penpos2(rule_thickness,90); penpos3(1.5min(bar,rule_thickness),0); penpos4(1.5min(bar,rule_thickness),0);
1356 y0=y1=y2=math_axis; x1-.5rule_thickness=u;
1357 rt x0=hround (w-u); x0'=x0''=x0; x1'=x1''=x1;
1358 y1'=y1+spread;y1''=y1-spread; y0'=y1'; y0''=y1'';
1359 draw z0'--z1'; draw z0''--z1''; % draw bars
1360 pickup crisp.nib;
1361 y3-y0'=y0''-y4=.24asc_height+eps; x3=x4=x0-6u-eps;
1362 penpos5(min(bar,rule_thickness),angle(z0-z4)); z5r=z0; penpos6(min(bar,rule_thickness),angle(z0-z3));
1363 z6r=z0; z9=.381966[.5[z3,z4],z0]; erase filldraw
1364 z0..{z3-z9}z3--(w,y3)--(w,y4)--z4{z9-z4}..z0& cycle;
1365 numeric t; path p;
1366 p=z4l{z9-z4}..z6l; t=xpart(p intersectiontimes((0,y2l)--(w,y2l)));
1367 x2=xpart point t of p;
1368 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6l)
1369 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5l)
1370 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
1371 penlabels(0,1,2,3,4,5,6,9,0',0'',1',1''); endchar;
1372
1373
1374 cmchar "Triple leftward arrow";
1375 compute_spread(.45x_height#,.55x_height#);
1376 beginchar(oct"127",18u#,v_center(2spread#+.5asc_height#+rule_thickness#));
1377 adjust_fit(0,0); pickup rule.nib; penpos1(rule_thickness,90);
1378 penpos2(rule_thickness,90); penpos3(1.5min(bar,rule_thickness),0); penpos4(1.5min(bar,rule_thickness),0);
1379 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft
1380 x0=hround u; x0'=x0''=x0; x1'=x1''=x1;
1381 y1'=y1+spread;y1''=y1-spread; y0'=y1'; y0''=y1''; draw
1382 z0'--z1'; draw z0''--z1''; % draw bars
1383 pickup crisp.nib;
1384 y3-y0'=y0''-y4=.24asc_height+eps; x3=x4=x0+6u+eps;
1385 pos5(min(bar,rule_thickness),angle(z4-z0)); z5l=z0; pos6(min(bar,rule_thickness),angle(z3-z0));
1386 z6l=z0; z9=.381966[.5[z3,z4],z0]; erase filldraw
1387 z0..{z3-z9}z3--(0,y3)
1388 --(0,y4)--z4{z9-z4}..z0& cycle; numeric t; path p;
1389 p=z4r{z9-z4}..z6r; t=xpart(p
1390 intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
1391 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
1392 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
1393 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
1394 penlabels(0,1,2,3,4,5,6,9,0',0'',1',1''); endchar;
1395
1396 cmchar "Check mark"; beginchar(oct"130",15u#,asc_height#,
1397 0); adjust_fit(0,0); pickup cal.nib;
1398 lft x1=hround(1.5u);y1=math_axis; y2=0; x2=hround(w/3);
1399 x3=w-x1; y3=asc_height-o;
1400 x4=w-1.5x2; y4=asc_height;
1401 draw z1--z2{z4-z2}..z3;
1402 penlabels(1,2,3,4);
1403 endchar;
1404
1405 cmchar "Vee on bar";
1406 compute_spread(.45x_height#,.55x_height#);
1407 beginchar(oct"131",11u#,asc_height#, desc_depth#);
1408 adjust_fit(0,0); pickup rule.nib;
1409 lft x1=lft x4=hround u; x3=x5=w-x1; x2=hround(w/2);
1410 bot y4=bot y5=0; y2=y4+spread; top y1=top y3=h+o;
1411 draw z1--z2--z3; draw z4--z5;
1412 penlabels(1,2,3,4,5);
1413 endchar;
1414
1415 cmchar "Bar on mountain";
1416 compute_spread(.45x_height#,.55x_height#);
1417 beginchar(oct"132",11u#,asc_height#, desc_depth#); adjust_fit(0,0);
1418 pickup rule.nib;
1419 lft x1=lft x4=hround u; x3=x5=w-x1; x2=hround(w/2);
1420 top y4=top y5=h+o; y2=y4-spread; bot y1=bot y3=0;
1421 draw z1--z2--z3; draw z4--z5;
1422 numeric t; % t is used in char"133, = on mountain
1423 t=y2-y3;
1424 penlabels(1,2,3,4,5);
1425 endchar;
1426
1427 cmchar "Equal sign on mountain";
1428 compute_spread(.45x_height#,.55x_height#);
1429 beginchar(oct"133",11u#,body_height#, desc_depth#); adjust_fit(0,0);
1430 pickup rule.nib;
1431 lft x1=lft x4=lft x6=hround u; x3=x5=x7=w-x1; x2=hround(w/2);
1432 y4=y5; y6=y7; y6-y4=y4-y2=spread; top y4=asc_height+o-.5spread;
1433 y2-y1=t; % t is defined in char "132
1434 y1=y3;
1435 draw z1--z2--z3; draw z4--z5; draw z6--z7;
1436 penlabels(1,2,3,4,5,6,7);
1437 endchar;
1438
1439 cmchar "Angle sign (simple)";
1440 beginchar(oct"134",13u#,asc_height#, 0);
1441 adjust_fit(0,0); pickup rule.nib;
1442 lft x2=hround u; x1=x3=w-x2;
1443 bot y2=bot y3=0; top y1=h;
1444 draw z1--z2--z3;
1445 penlabels(1,2,3);
1446 endchar;
1447
1448 cmchar "Angle sign (with small arc)";
1449 beginchar(oct"135",13u#,asc_height#, 0);
1450 adjust_fit(0,0); pickup rule.nib;
1451 lft x2=hround u; x1=x3=w-x2;
1452 bot y2=bot y3=0; y1=h;
1453 draw z1--z2--z3;
1454 path p; p=quartercircle scaled 15u;
1455 numeric t; t= xpart(p intersectiontimes (z1--z2));
1456 draw subpath (0,t) of p;
1457 penlabels(1,2,3);
1458 endchar;
1459
1460 cmchar "Eye-like angle sign (with small arc)";
1461 beginchar(oct"136",13u#,v_center(.75body_height#));
1462 adjust_fit(0,0); pickup rule.nib;
1463 lft x2=hround u; x1=x3=w-x2;
1464 y2=math_axis; y2=.5[y1,y3]; y1-y3=.75body_height;
1465 draw z1--z2--z3;
1466 path p; p=quartercircle scaled 17u;
1467 numeric t; t= xpart(p intersectiontimes ((z1--z2)shifted
1468 -z2));
1469 draw subpath (0,t) of p shifted z2;
1470 draw subpath (0,t) of p shifted z2
1471 reflectedabout(z2,(w,y2));
1472 penlabels(1,2,3);
1473 endchar;
1474
1475 cmchar "Proportional sign made of circles";
1476 beginchar(oct"137",14u#,asc_height#,0);
1477 adjust_fit(0,0); pickup pencircle scaled rule_thickness;
1478 numeric radius; radius:=w-2u; radius:=radius/3;
1479 radius:=radius-.5rule_thickness;
1480 x2=hround w-u; x1=w-x2+radius;
1481 y1=y2=math_axis;
1482 pair m; m=(rule_thickness,0);
1483 draw fullcircle scaled 2radius shifted (z1+.5m);
1484 draw (halfcircle scaled 2radius rotated 90) shifted
1485 (z2-.5m);
1486 penlabels(1,2);
1487 endchar;
1488
1489 cmchar "Simple slur below (smile)";
1490 beginchar(oct"140",14u#,asc_height#,desc_depth#);
1491 adjust_fit(0,0); pickup rule.nib;
1492 lft x1=hround u; y1=vround(math_axis+.25x_height);
1493 x3=w-x1; y3=y1; penpos2(rule_thickness,90); x2=.5w;
1494 y2l=good.y -(.25x_height-math_axis);
1495 numeric theta; theta=angle((z2-z1)yscaled 3);
1496 penpos1(rule_thickness,90+theta);
1497 penpos3(rule_thickness,90-theta);
1498 draw z1{dir theta}...z2...{dir-theta}z3;
1499 penlabels(1,2,3); endchar;
1500
1501 cmchar "Simple slur above (frown)";
1502 beginchar(oct"141",14u#,asc_height#,desc_depth#);
1503 adjust_fit(0,0); pickup rule.nib;
1504 lft x1=hround u; y1=vround(math_axis-.25x_height);
1505 x3=w-x1; y3=y1;
1506 penpos2(rule_thickness,90); x2=.5w; y2=good.y(.25x_height+math_axis);
1507 numeric theta; theta=angle((z2-z1)yscaled 3);
1508 penpos1(rule_thickness,90+theta);
1509 penpos3(rule_thickness,90-theta);
1510 draw z1{dir theta}...z2...{dir-theta}z3; penlabels(1,2,3);
1511 endchar;
1512
1513 cmchar "Very proper subset sign";
1514 compute_spread(.45x_height#,.55x_height#);
1515 spread#':=spread#; spread':=spread; % the spread of `$=$'
1516 spread':=spread'-rule_thickness;
1517 compute_spread(5/4x_height#,3/2x_height#);
1518 beginchar(oct"142",14u#,v_center(spread#+rule_thickness#));
1519 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1520 autorounded; lft x2=hround 1.5u-eps; x1=x3=w-x2;
1521 y1-y3=spread; y2=.5[y1,y3]=math_axis; x4=x5=.5w; y4=y1;
1522 y5=y3; draw z1---z4...z2{down}...z5---z3; % arc and bars
1523 x1'=x3'=x1; y1-y1'=y3'-y3=spread';
1524 x4'=x5'=x4; y4-y4'=y5'-y5=spread';
1525 y2'=y2; x2'-x2=spread';
1526 draw z1'--z4'..z2'{down}..z5'--z3';
1527 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1528
1529 cmchar "Very proper superset sign";
1530 compute_spread(.45x_height#,.55x_height#);
1531 spread#':=spread#; spread':=spread; % the spread of `$=$'
1532 spread':=spread'-rule_thickness;
1533 compute_spread(5/4x_height#,3/2x_height#);
1534 beginchar(oct"143",14u#,v_center(spread#+rule_thickness#));
1535 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1536 autorounded; lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
1537 y1-y3=spread; y2=.5[y1,y3]=math_axis; x4=x5=.5w; y4=y1;
1538 y5=y3; draw z1---z4...z2{down}...z5---z3; % arc and bars
1539 x1'=x3'=x1; y1-y1'=y3'-y3=spread';
1540 x4'=x5'=x4; y4-y4'=y5'-y5=spread';
1541 y2'=y2; x2-x2'=spread';
1542 draw z1'--z4'..z2'..z5'--z3';
1543 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1544
1545 cmchar "Parallel set union sign";
1546 compute_spread(.45x_height#,.55x_height#);
1547 spread#':=spread#; spread':=spread; % the spread of `$=$'
1548 spread':=spread'-rule_thickness;
1549 beginchar(oct"144",12u#,.8asc_height#,0);
1550 italcorr .8asc_height#*slant-.5u#;
1551 adjust_fit(0,0); pickup rule.nib; autorounded;
1552 lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
1553 y1=good.y h+o; bot y3=-o; y2=y4=2/3[y1,y3]; y5=y1;
1554 draw z1---z2...z3...z4---z5; % stems and cup
1555 y1'=y5'=y1; x1'-x1=x5-x5'=spread';
1556 y2'=y4'=y2+u; x2'-x2=x4-x4'=spread';
1557 x3'=x3; y3'-y3=spread';
1558 draw z1'..{down}z2'..z3'{right}..z4'{up}..z5';
1559 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1560
1561 cmchar "Parallel set intersection sign";
1562 compute_spread(.45x_height#,.55x_height#);
1563 spread#':=spread#; spread':=spread; % the spread of `$=$'
1564 spread':=spread'-rule_thickness;
1565 beginchar(oct"145",12u#,.8asc_height#,0);
1566 italcorr .8asc_height#*slant-.5u#; adjust_fit(0,0);
1567 pickup rule.nib; autorounded;
1568 lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
1569 y3=good.y h+o; bot y1=-o; y2=y4=2/3[y1,y3]; y5=y1;
1570 draw z1---z2...z3...z4---z5; % stems and cap
1571 y1'=y5'=y1; x1'-x1=x5-x5'=spread';
1572 y2'=y4'=y2-u; x2'-x2=x4-x4'=spread';
1573 x3'=x3; y3-y3'=spread';
1574 draw z1'..{up}z2'..z3'{right}..z4'{down}..z5';
1575 penlabels(1,2,3,4,5,1',2',3',4',5'); endchar;
1576
1577 cmchar "Subset or (double) equal to sign";
1578 compute_spread(.45x_height#,.55x_height#);
1579 spread#':=spread#; spread':=spread; % the spread of `$=$'
1580 compute_spread(5/4x_height#,3/2x_height#);
1581 beginchar(oct"152",14u#,v_center(2spread#'+spread#+2rule_thickness#));
1582 adjust_fit(0,0); pickup rule.nib; autorounded; lft x2=hround
1583 1.5u-eps; x1=x3=w-x2; y1-y3=spread; y2=.5[y1,y3]; top y1=h;
1584 x4=x5=.5w; y4=y1; y5=y3; draw z1---z4...z2{down}...z5---z3;
1585 % arc and bars
1586 x8=x1; x9=x2;
1587 y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
1588 x9'=x9; x8'=x8; y9'=y8'; y9-y9'=spread'; draw z8'--z9';
1589 penlabels(1,2,3,4,5,8,9,8',9'); endchar;
1590
1591 cmchar "Superset or (double) equal to sign";
1592 compute_spread(.45x_height#,.55x_height#);
1593 spread#':=spread#; spread':=spread; % the spread of `$=$'
1594 compute_spread(5/4x_height#,3/2x_height#);
1595 beginchar(oct"153",14u#,v_center(2spread#'+spread#+2rule_thickness#));
1596 adjust_fit(0,0); pickup rule.nib; autorounded; lft x1=hround
1597 1.5u-eps; x2=w-x1; x3=x1; y1-y3=spread; y2=.5[y1,y3]; top
1598 y1=h; x4=x5=.5w; y4=y1; y5=y3; draw
1599 z1---z4...z2{down}...z5---z3; % arc and bars
1600 x8=x1;
1601 x9=x2;
1602 y8=y9; y3-y9=spread'; draw z8--z9; % lower bar
1603 x9'=x9; x8'=x8; y9'=y8'; y9-y9'=spread'; draw z8'--z9';
1604 labels(1,2,3,4,5,8,9); endchar;
1605
1606 cmchar "Christmas tree symbol";
1607 compute_spread(5/4x_height#,3/2x_height#);
1608 beginchar(oct"146",spread#+4u#,.8asc_height#,0);
1609 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1610 autorounded;
1611 lft x1=1.5u; x3=w-x1; x2=.5[x1,x3];
1612 bot y1=-d-o; y3=y1; top y2=h+o;
1613 draw z1{spread,u}...{up}z2;
1614 draw z3{-spread,u}...{up}z2;
1615 penlabels(1,2,3); endchar;
1616
1617 cmchar "Inverted Christmas tree symbol";
1618 compute_spread(5/4x_height#,3/2x_height#);
1619 beginchar(oct"147",spread#+4u#,.8asc_height#,0);
1620 italcorr h#*slant-u#; adjust_fit(0,0); pickup rule.nib;
1621 autorounded;
1622 lft x1=1.5u; x3=w-x1; x2=.5[x1,x3];
1623 top y1=h+o; y3=y1; bot y2=-d-o;
1624 draw z1{spread,-u}...{down}z2;
1625 draw z3{-spread,-u}...{down}z2;
1626 penlabels(1,2,3); endchar;
1627
1628 cmchar "Stylized lambda symbol";
1629 beginchar(oct"150",14u#,asc_height#,0);
1630 adjust_fit(0,0); pickup rule.nib; autorounded;
1631 lft x1=u; top y1=h;
1632 rt x2=w-u; bot y2=-o;
1633 draw z1--z2;
1634 z3=.5[z1,z2];
1635 x4=x1; y4=y2; draw z3--z4;
1636 penlabels(1,2,3,4); endchar;
1637
1638 cmchar "Reflected stylized lambda symbol";
1639 beginchar(oct"151",14u#,asc_height#,0);
1640 adjust_fit(0,0); pickup rule.nib; autorounded;
1641 lft x1=u; bot y1=-o;
1642 rt x2=w-u; top y2=h;
1643 draw z1--z2;
1644 z3=.5[z1,z2];
1645 x4=x2; y4=y1; draw z3--z4;
1646 penlabels(1,2,3,4); endchar;
1647
1648 cmchar "Sunrise symbol";
1649 compute_spread(.45x_height#,.55x_height#);
1650 beginchar(oct "154",14u#,v_center(3spread#+rule_thickness#));
1651 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1652 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
1653 y1-y3=spread; .5[y1,y3]=math_axis;
1654 y5=y6=y1; x7=.5[x1,x2]; x5=.3[x1,x2];
1655 x2-x6=x5-x1;
1656 y7-y1=.5(x6-x5);
1657 draw z1--z5{up}...z7...{down}z6--z2; % upper bar
1658 draw z3--z4; % lower bar
1659 penlabels(1,2,3,4,5,6,7); endchar;
1660
1661 cmchar "Sunrise-over-water symbol";
1662 compute_spread(.45x_height#,.55x_height#);
1663 beginchar(oct "155",14u#,v_center(3spread#+rule_thickness#));
1664 italcorr h#*slant-.5u#; adjust_fit(0,0); pickup rule.nib;
1665 lft x1=hround u-eps; x3=x1; x2=x4=w-x1; y1=y2; y3=y4;
1666 y1-y3=spread; .5[y1,y3]=math_axis;
1667 y5=y6=y1; x7=.5[x1,x2]; x5=.3[x1,x2];
1668 x2-x6=x5-x1;
1669 y7-y1=.5(x6-x5);
1670 x5'=x5; x7'=x7; x6'=x6; y5'=y6'=y3; y3-y7'=y7-y1;
1671 draw z1--z5{up}...z7...{down}z6--z2; % upper bar
1672 draw z3--z5'{down}...z7'...{up}z6'--z4; % lower bar
1673 penlabels(1,2,3,4,5,6,7); endchar;
1674
1675 cmchar "Much, much less sign";
1676 compute_spread(5/4x_height#,3/2x_height#);
1677 beginchar(oct"156",24u#,v_center(spread#+rule_thickness#));
1678 adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup
1679 rule.nib; lft x2=hround u-epsilon; x1=x3=hround 12.5u-x2;
1680 y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
1681 draw z1--z2--z3; % left diagonals
1682 z4-z1=z5-z2=z6-z3=z7-z4=z8-z5=z9-z6;
1683 x7=w-x2; y4=y1;
1684 draw z4--z5--z6; % middle diagonals
1685 draw z7--z8--z9; % right diagonals
1686 penlabels(1,2,3,4,5,6,7,8,9); endchar;
1687
1688 cmchar "Much, much greater sign";
1689 compute_spread(5/4x_height#,3/2x_height#);
1690 beginchar(oct"157",24u#,v_center(spread#+rule_thickness#));
1691 adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup
1692 rule.nib;
1693 lft x1=hround u-epsilon; x2=hround 12.5u-u; x1=x3;
1694 y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
1695 draw z1--z2--z3; % left diagonals
1696 z4-z1=z5-z2=z6-z3=z7-z4=z8-z5=z9-z6;
1697 x8=w-x1; y4=y1;
1698 draw z4--z5--z6; % middle diagonals
1699 draw z7--z8--z9; % right diagonals
1700 penlabels(1,2,3,4,5,6,7,8,9); endchar;
1701
1702 cmchar "Northwest right angle symbol";
1703 beginchar(oct"160",9u#, asc_height#, 0);
1704 adjust_fit(0,0); pickup rule.nib;
1705 x1=x2; lft x1=u; x3=w-x1; y2=y3; top y2=h;
1706 y2-y1=x3-x2;
1707 draw z1--z2--z3;
1708 penlabels(1,2,3); endchar;
1709
1710 cmchar "Northeast right angle symbol";
1711 beginchar(oct"161",9u#,asc_height#,0);
1712 adjust_fit(0,0); pickup rule.nib;
1713 lft x3=u; x2=w-x3; top y3=h; y3=y2; x1=x2; x2-x3=y2-y1;
1714 draw z1--z2--z3;
1715 penlabels(1,2,3); endchar;
1716
1717 cmchar "Southwest right angle symbol";
1718 beginchar(oct"170", 9u#, 7u#,0);
1719 adjust_fit(0,0); pickup rule.nib;
1720 lft x2=u; x3=w-x2; x1=x2; bot y2=-o; y3=y2;
1721 y1-y2=x3-x2;
1722 draw z1--z2--z3;
1723 penlabels(1,2,3); endchar;
1724
1725 cmchar "Southeast right angle symbol";
1726 beginchar(oct"171", 9u#, 7u#,0);
1727 adjust_fit(0,0); pickup rule.nib;
1728 lft x3=u; x2=w-x3; x1=x2; bot y2=-o; y3=y2;
1729 y1-y2=x2-x3;
1730 draw z1--z2--z3;
1731 penlabels(1,2,3); endchar;
1732
1733 %% include these parameters to `shrink R and S so they
1734 %% fit inside a circle
1735 %
1736 begingroup
1737 save u, width_adj, cap_serif_fit, letter_fit,
1738 body_height, cap_height, x_height, bar_height, comma_depth,
1739 flare, cap_hair, stem, cap_stem, cap_curve, cap_ess,
1740 cap_jut, beak_jut, beak, slab, cap_bar, cap_band, cap_notch_cut,
1741 o, apex_o;
1742 numeric radius;
1743 old.u:=u; old.cap_curve:=cap_curve; old.cap_height:=cap_height;
1744 old.u#:=u#; old.cap_curve#:=cap_curve#; old.cap_height#:=cap_height#;
1745 forsuffixes $=u, width_adj, cap_serif_fit, letter_fit,
1746 body_height, cap_height, x_height, bar_height,
1747 comma_depth, flare, cap_hair,
1748 stem, cap_stem, cap_curve, cap_ess,
1749 cap_jut, beak_jut, beak,
1750 slab, cap_bar,
1751 cap_band, cap_notch_cut,
1752 o, apex_o: $.#:=lower.$.#; endfor
1753 fudge:=lower.fudge;
1754 font_setup;
1755 % Changed by Stefan Lindner 15.03.1991 -sl
1756 % original: radius=.5(6u++cap_height)+3u; radius=radius#*hppp;
1757 radius#=.5(6u#++cap_height#)+3u#; radius:=radius#*hppp;
1758 % end of change
1759 %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
1760
1761 cmchar "Circle-R brand";
1762 beginchar(oct"162",13u#, .52cap_height#+radius#,radius#-.52cap_height#);
1763 adjust_fit(4u#,4u#);
1764 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1765 lft x1l=lft x2l=hround max(2u,3u-.5cap_stem');
1766 top y1=cap_height; bot y2=0;
1767 filldraw stroke z1e--z2e; % stem
1768 penpos3(cap_band,90); penpos4(cap_band,90);
1769 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1770 penpos6(vair,-90); penpos7(vair,-90);
1771 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1772 x7=x2; y7l=vround(.5cap_height+.5vair); x4=x6;
1773 if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
1774 else: x4=.5w+.5u; x5r=hround(w-u); fi
1775 x4l:=x6l:=x4-.125cap_curve;
1776 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1777 if serifs: pos6'(vair,-90); pos0(cap_stem,180);
1778 pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
1779 z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
1780 y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
1781 bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
1782 filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up}; % tail
1783 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1784 dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower serif
1785 else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
1786 x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
1787 fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi % tail
1788 math_fit(0,.75ic#);
1789 pickup rule.nib;
1790 z100=(hround w/2,.52cap_height); z101=z100+(0,radius); z103=z100-(0,radius);
1791 z102=z100+(radius,0); z104=z100-(radius,0);
1792 draw z101...z102...z103...z104...cycle;
1793 penlabels(0,1,2,3,4,5,6,7,8,9,10,100,101,102,103,104);
1794 endchar;
1795
1796 cmchar "Circle-S brand";
1797 beginchar(oct"163",10u#,radius#+.52cap_height#,radius#-.52cap_height#);
1798 adjust_fit(5u#,5u#);
1799 numeric theta; theta=90-angle(50u,cap_height); slope:=-cap_height/50u; % angle at middle
1800 numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
1801 numeric ess'; ess'=max(fine.breadth,cap_ess);
1802 pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-90);
1803 pos0(ess',theta); pos7(s_slab,-90);
1804 x2+x7=2x0=w; x7-x2=if serifs: u else: 0 fi; top y2l=cap_height+o; bot y7r=-o;
1805 y0=.52cap_height; lft x3l=hround u; rt x6r=hround(w-u);
1806 x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
1807 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
1808 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
1809 filldraw stroke super_arc.e(2,3) & z3e{down}
1810 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
1811 if serifs: pos1(hair,180); pos8(hair,180);
1812 rt x1l=hround(w-1.5u); lft x8r=hround u;
1813 bot y1=vround 2/3cap_height+1; top y8=vround 1/3cap_height-1;
1814 filldraw stroke z1e{x2-x1,10(y2-y1)}....{left}z2e; % upper arc
1815 filldraw stroke z7e{left}....{up}z8e; % lower arc
1816 path upper_arc, lower_arc;
1817 upper_arc=z1{x2-x1,10(y2-y1)}....{left}z2;
1818 lower_arc=z7{left}....{up}z8;
1819 pos10(.3[fine.breadth,cap_hair],0);
1820 pos9(.3[fine.breadth,cap_hair],0);
1821 x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
1822 x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
1823 numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
1824 filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle; % upper barb
1825 t:=xpart(lower_arc intersectiontimes(z9r--z8'));
1826 filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle; % lower barb
1827 else: pos1(1.2flare,-100); pos8(1.2flare,-100);
1828 x1l=good.x(x1l+w-1.75u-rt x1); lft x8r=hround .8u;
1829 top y1l=vround .93cap_height+o; bot y8r=vround .1cap_height-o;
1830 filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
1831 filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
1832 math_fit(0,.5ic#);
1833 pickup rule.nib;
1834 z100=(hround w/2,.52cap_height); z101=z100+(0,radius); z103=z100-(0,radius);
1835 z102=z100+(radius,0); z104=z100-(radius,0);
1836 draw z101...z102...z103...z104...cycle;
1837 penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10,100,101,102,103,104);
1838 endchar;
1839 endgroup;
1840
1841
1842 cmchar "Pitchfork symbol";
1843 beginchar(oct"164",12u#,asc_height#,0);
1844 italcorr .8asc_height#*slant-.5u#;
1845 adjust_fit(0,0); pickup rule.nib; autorounded;
1846 lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
1847 y3=good.y .7h+o; bot y1=-o; y2=y4=2/3[y1,y3]; y5=y1;
1848 draw z1---z2...z3...z4---z5; % stems and cap
1849 x6=x7=good.x w/2; y6=y1; y7=h+o;
1850 draw z6--z7; % stem
1851 penlabels(1,2,3,4,5,6,7); endchar;
1852
1853 cmchar "Dotted plus sign";
1854 beginchar(oct"165",14u#,8u#+math_axis#,6u#-math_axis#);
1855 adjust_fit(0,0); pickup rule.nib;
1856 x1=x2=good.x .5w; top y1=h-2.5rule_thickness+eps; .5[y1,y2]=math_axis;
1857 lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
1858 draw z1--z2; % stem
1859 draw z3--z4; % crossbar
1860 x5=x1; y5=h+o;
1861 if square_dots:
1862 filldraw unitsquare shifted (-.5,-.5) scaled 1.5rule_thickness shifted z5;
1863 else:
1864 pickup pencircle scaled 2.5rule_thickness;
1865 drawdot z5;
1866 fi
1867 penlabels(1,2,3,4,5); endchar;
1868
1869 cmchar "Inverted similarity sign";
1870 compute_spread(.45x_height#,.55x_height#);
1871 beginchar(oct"166",14u#,v_center(spread#+rule_thickness#));
1872 adjust_fit(0,0);
1873 pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
1874 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
1875 lft x1=hround(u); x2=4u; x3=w-x2; x4=w-x1;
1876 bot y2=bot y4=-d; top y1=top y3=h;
1877 draw z1{down}...z2{right}..{right}z3...{down}z4; % stroke
1878 labels(1,2,3,4); endchar;
1879
1880 cmchar "Inverted similar or equal sign";
1881 compute_spread(.45x_height#,.55x_height#);
1882 beginchar(oct"167",14u#,v_center(2spread#+rule_thickness#));
1883 adjust_fit(0,0);
1884 pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
1885 if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
1886 lft x1=hround(u); x2=4u; x3=w-x2; x4=w-x1;
1887 bot y2=bot y4=floor math_axis; top y1=top y3=h;
1888 draw z1{down}...z2{right}..{right}z3...{down}z4; % stroke
1889 pickup rule.nib; lft x5=hround u-eps; x6=w-x5; y5=y6=math_axis-spread;
1890 draw z5--z6; % bar
1891 labels(1,2,3,4,5,6); endchar;
1892
1893 cmchar "Iron cross";
1894 beginchar(oct"172",15u#,asc_height#,0); adjust_fit(0,0);
1895 pickup pencircle scaled .5rule_thickness;
1896 numeric cross_tension; cross_tension=.9;
1897 numeric cross_foot; cross_foot=4u;
1898 y0=.5[y1,y2]; x0=hround w/2;
1899 x1=x2=x0; bot y1=-o; lft x1l=3.5u; x1r=w-x1l; y1l=y1r=y1;
1900 top y2=h+o; x2r=x1l; x2l=x1r; y2l=y2r=y2;
1901 y3=y4=y0; x3=x0+eps; x4+x3=2x0;
1902 path p; p=z1l--z1r..tension cross_tension..z3..tension cross_tension
1903 ..z2l--z2r..tension cross_tension..z4..tension cross_tension..
1904 z1l..cycle;
1905 filldraw p;
1906 p:=p shifted -z0; p:=p rotated 90; p:=p shifted z0;
1907 filldraw p;
1908 penlabels(0,1,2,3,4); endchar;
1909
1910 cmchar "Bourbaki C symbol";
1911 beginchar(oct"173",9u#, 1.1body_height#, 0);
1912 adjust_fit(0,0); pickup pencircle scaled 2rule_thickness;
1913 lft x4=lft x5=u; x1=x2=x8=x7=w-x4; x3=x6=hround
1914 w/2;
1915 bot y6=-o; top y3=h+o; y2=y4=y3-1.8u; y5=y7=y6+1.8u;
1916 y1=y2-2u; y8=y7+2u;
1917 draw z1--z2{up}..{left}z3..{down}z4--z5{down}..z6{right}..{up}z7--z8;
1918 labels(1,2,3,4,5,6,7,8); endchar;
1919
1920 cmchar "Bourbaki T symbol";
1921 beginchar(oct "174", 10u#, x_height#, desc_depth#);
1922 adjust_fit(0,0); pickup pencircle scaled 2rule_thickness;
1923 lft x1=u; x2=w-x1; top y1=top y2=h; x3=x4=hround w/2; y3=y1;
1924 bot y4=-1.1d;
1925 draw z1--z2; draw z3--z4;
1926 labels(1,2,3,4); endchar;
1927
1928 cmchar "Circle-in-a-circle operator";
1929 beginarithchar(oct"175"); pickup light_rule.nib; autorounded;
1930 lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
1931 circle_points; draw_circle; % circle
1932 pickup rule.nib;
1933 numeric x[],y[];
1934 lft x6=hround 4.5u; x2=w-x6; y2=math_axis;
1935 top y8=y2+.5(rt x2-lft x6); circle_points; draw_circle;
1936 labels(1,2,3,4,5,6,7,8); endchar;
1937
1938 cmchar "Asterisk-in-a-circle";
1939 beginarithchar(oct"176");
1940 pickup light_rule.nib; autorounded;
1941 y2=math_axis; top y8=6u+math_axis;
1942 lft x6=hround w/2 - 6u; x2=w-x6;
1943 circle_points; draw_circle; % circle
1944 numeric x[], y[];
1945 numeric ast_flare; ast_flare=hround .7[thin_join,stem];
1946 x0=.5w; y0=math_axis; for d=-150 step 60 until 150:
1947 z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
1948 numeric theta; theta=angle(z[d]-z0);
1949 fill z0+.5(0,-thin_join)rotated theta
1950 ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
1951 ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
1952 ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
1953 labels(0,[-150],[-90],[-30],30,90,150); endchar;
1954
1955 cmchar "Bar-in-a-circle operator";
1956 beginarithchar(oct"177"); pickup light_rule.nib; autorounded;
1957 lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
1958 circle_points; draw_circle; % circle
1959 y9=y10=y2; x9=x6+3u; x10=w-x9;
1960 draw z9--z10;
1961 labels(1,2,3,4,5,6,7,8,9,10); endchar;
1962