Debian Codegraph @

texmf-dist/fonts/source/public/sansmathfonts/sans-IPiXi.mf

raw
1 font_coding_scheme:="The letters I, Pi, Xi";
2 mode_setup; font_setup;
3
4 cmchar "The letter I"; % Added serifs
5 beginchar("I",
6 if known I_cap_jut: (cap_stem#+2I_cap_jut#+2u#),
7 else: max(6u#,4u#+cap_stem#), fi
8 cap_height#,0);
9 italcorr cap_height#*slant-.25u#;
10 adjust_fit(cap_serif_fit#,cap_serif_fit#);
11 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
12 lft x1l=lft x2l=hround(.5w-.5cap_stem); top y1=h; bot y2=0;
13 filldraw stroke z1e--z2e; % stem
14 if serifs: dish_serif(1,2,a,1/3,1.05cap_jut,b,1/3,1.05cap_jut); % upper serif
15 dish_serif(2,1,c,1/3,1.05cap_jut,d,1/3,1.05cap_jut); fi % lower serif
16 if known I_cap_jut: if I_cap_jut > 0:
17 pos3(slab,90); pos4(slab,90);
18 rt x4r=(w-u); x3=w-x4;
19 top y4r = top y3r = h;
20 filldraw stroke z4e--z3e;
21 pos5(slab,90); pos6(slab,90);
22 x5=x3; x6=x4; y5=y6; bot y5l=0;
23 filldraw stroke z5e--z6e;
24 fi fi
25 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
26
27 cmchar "Uppercase Greek Pi";
28 beginchar(oct"005",13u#+width_adj#,cap_height#,0);
29 italcorr
30 if hefty: cap_height#*slant
31 else: cap_height#*slant-cap_serif_fit#+I_cap_jut#-2.5u#+min(.5cap_stem#,u#) fi;
32 adjust_fit(cap_serif_fit#,cap_serif_fit#); pickup tiny.nib;
33 h:=vround(h-stem_corr);
34 pos1(cap_stem,0); pos2(cap_stem,0); pos3(cap_stem,0); pos4(cap_stem,0);
35 lft x1l=lft x2l=hround if hefty: u+I_cap_jut else: max(2u,3u-.5cap_stem) fi;
36 x3=x4=w-x1;
37 top y1=top y3=h; bot y2=bot y4=0;
38 filldraw stroke z1e--z2e; % left stem
39 filldraw stroke z3e--z4e; % right stem
40 penpos5(cap_bar,90); penpos6(cap_bar,90);
41 x5=x1; x6=x3; y5r=y6r=h;
42 fill stroke z5e--z6e; % bar
43 if serifs: numeric inner_jut;
44 if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
45 else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
46 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,eps); % upper left serif
47 dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
48 nodish_serif(3,4,e,1/3,eps,f,1/3,cap_jut); % upper right serif
49 dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); % lower right serif
50 else:
51 nodish_serif(1,2,a,1/3,I_cap_jut,b,1/3,eps); % upper left serif
52 nodish_serif(3,4,e,1/3,eps,f,1/3,I_cap_jut); % upper right serif
53 fi
54 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
55
56 cmchar "Uppercase Greek Xi";
57 beginchar(oct"004",12u#,cap_height#,0);
58 italcorr cap_height#*slant-.35u#;
59 adjust_fit(0,0);
60 h:=vround(h-2stem_corr);
61 numeric shaved_stem; shaved_stem=hround .9[vair,.85cap_stem];
62 if shaved_stem<crisp.breadth: shaved_stem:=crisp.breadth; fi
63 pickup crisp.nib; pos1(shaved_stem,90); pos2(if hefty: vair else: hair fi,0);
64 top y1r=h; x1=.5w; rt x2r=hround(w-.85u); y2=good.y(y1l-4/9I_beak)-eps;
65 pos3(if hefty: vair else: hair fi,180); x3=w-x2; y3=y2;
66 pos4(shaved_stem,-90); pos5(if hefty: vair else: hair fi,0);
67 bot y4r=0; x4=.5w; rt x5r=hround(w-.75u); y5=good.y(y4l+.5I_beak)+eps;
68 pos6(if hefty: vair else: hair fi,180); x6=w-x5; y6=y5;
69 begingroup save serifs; boolean serifs; serifs = true;
70 arm(1,2,a,.4beak_darkness,.3 beak_jut); % upper right arm and beak
71 arm(1,3,b,.4beak_darkness,-.3 beak_jut); % upper left arm and beak
72 arm(4,5,c,.4beak_darkness,.3beak_jut); % lower right arm and beak
73 arm(4,6,d,.4beak_darkness,-.3beak_jut); % lower left arm and beak
74 endgroup;
75 pos7(shaved_stem,90); pos8(shaved_stem,90);
76 lft x7=w-rt x8=hround if serifs: 2.5 else: 2 fi\\ u;
77 top y7r=top y8r=vround(.52h+.5shaved_stem);
78 filldraw stroke z7e--z8e; % middle bar
79 if serifs: numeric xjut;
80 if bot y2>top y7r+.75cap_jut: xjut=.5cap_jut;
81 else: bot y2=top y7r+1.5xjut; fi
82 pos11(hair,0); pos12(hair,0); y11=y12;
83 pos13(hair,0); pos14(hair,0); y13=y14;
84 lft x11l=lft x13l=w-rt x12r=w-rt x14r=hround 2.5u;
85 top y11-bot y13=shaved_stem+2xjut; .5[y11,y13]=y7;
86 filldraw stroke z11e--z13e; filldraw stroke z12e--z14e; fi % middle serifs
87 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,11,12,13,14); endchar;
88
89
90 font_slant slant; font_x_height x_height#;
91 if monospace: font_normal_space 9u#; % no stretching or shrinking
92 font_quad 18u#;
93 font_extra_space 9u#;
94 else: font_normal_space 6u#+2letter_fit#;
95 font_normal_stretch 3u#; font_normal_shrink 2u#;
96 font_quad 18u#+4letter_fit#;
97 font_extra_space 2u#;
98 k#:=-.5u#;
99 ligtable "I": "I" kern -k#; % Richard III
100 fi
101 bye.