Debian Codegraph @

texmf-dist/fonts/source/public/sansmathfonts/sans-greekl.mf

raw
1 % Based on the Computer Modern source file greekl.mf by D E Knuth.
2
3 % Edited by Ariel Barton to produce better sans serif symbols
4
5 % Date: 2013/03/22
6
7 % Character codes \0013--\0047 are generated.
8
9 cmchar "Lowercase Greek alpha";
10 beginchar(oct"013",11u#,x_height#,0);
11 italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.5u#);
12 adjust_fit(0,0); pickup fine.nib;
13 pos1(vair,-90); pos2(curve,-180); pos3(vair,-270);
14 z4=(w-3.25u,9/16h); z5=(w-2.75u,.5[vair,y4]);
15 numeric theta; theta=angle(z4-z5)-90;
16 pos4(if hefty: stem else: stem' fi,theta);
17 pos5(if hefty: stem else: stem' fi,theta);
18 pos6(vair,90);
19 if serifs:
20 pos7(hair,180); pos0(hair,0);
21 rt x0r=hround(w-u);
22 top y0=vround .8[bar_height,h];
23 else:
24 pos7(if hefty: vair else: hair fi,145);
25 pos0(if hefty: vair else: hair fi,-15);
26 rt x0r=hround(w-0.7u);
27 top y0l=vround .9[bar_height,h];
28 fi
29 x1=x3=.5w-u; lft x2r=hround(1.5u-.5curve);
30 x6=w-u; x7l=hround(w+.5hair-epsilon);
31 bot y1r=bot y6l=-oo;
32 y2=.5[y1,y3]; top y3r=h+oo; y7l=1/4bar_height;
33 filldraw stroke z0e{down}...pulled_arc.e(1,2) & pulled_arc.e(2,3)
34 ...z4e---z5e...z6e{right}...if serifs: {up} fi z7e; % diagonal, bowl, and hook
35 math_fit(-.3x_height#*slant+.5curve#-u#,1/3x_height#*slant+.5hair#+.5u#);
36 penlabels(0,1,2,3,4,5,6,7); endchar;
37
38 cmchar "Lowercase Greek beta";
39 beginchar(oct"014",9.5u#,asc_height#,desc_depth#);
40 italcorr .5[x_height#,asc_height#]*slant-u#;
41 adjust_fit(0,0); pickup fine.nib;
42 pos0(hair,180); pos1(hair,180); pos2(vair,90);
43 pos3(.8[if hefty: vair else: hair fi,stem],0);
44 pos4(if hefty: 0.9 fi vair,-90);
45 pos6(if hefty: 0.9 fi vair,-270);
46 pos7(if hefty: 0.8[vair,stem] else: stem fi,-360); pos8(vair,-450);
47 pos9(if hefty: vair else: hair fi,-540);
48 x0=x1; x1l=x9l; lft x0r=hround(1.5u-.5hair);
49 if serifs:
50 pos5(hair,-180);
51 x2=x4=x6=x8=.5w-.25u;
52 rt x5l=hround(x4-u);
53 top y6r-bot y4r=vstem+eps;
54 y5=.5[y4,y6];
55 top y6r=x_height;
56 else:
57 pos5(vair,-90);
58 pos5'(vair,-270);
59 z5 = z5';
60 x2=x8=.5w-.25u;
61 x5 = x1l;
62 x4=x6=0.4[x5,x2];
63 y6l = y5r;
64 y5=.5[y4l,y6l];
65 top y5l=x_height;
66 fi
67 rt x3r=hround(w-1.75u); rt x7r=hround(w-u);
68 if serifs:fi
69 bot y0=-d; y1=x_height; top y2r=h+oo; y3=.5[y2,y4];
70 bot y8r=-oo; y7=y9=.55[y6,y8];
71 if serifs: if y6l<y4l: y6l:=y4l:=y5; fi fi
72 filldraw stroke z0e---z1e...pulled_arc.e(2,3) &
73 if serifs: pulled_arc.e(3,4) ...{up}z5e
74 else: z3e{down}..z4e---z5e fi; % stem and upper bowl
75 filldraw stroke
76 if serifs: z5e{up}...pulled_arc.e(6,7)
77 else: z5'e---z6e..z7e{down} fi
78 & pulled_arc.e(7,8)...{up}z9e; % lower bowl
79 math_fit(desc_depth#*slant+.5hair#-u#,.7x_height#*slant+.5curve#-1.5u#);
80 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
81
82 cmchar "Lowercase Greek gamma";
83 beginchar(oct"015",10u#,x_height#,desc_depth#);
84 italcorr x_height#*slant-.5u#;
85 adjust_fit(0,0); pickup fine.nib;
86 if serifs:
87 pos1(hair,180);
88 pos4(hair,0); pos6(hair,-180); pos5(vair,-90);
89 pos7(hair,-180);
90 bot y5r=-d-o;
91 rt x4r=hround(w-2u);
92 rt x4r-lft x6r=hround 1/3[hair,stem]+eps;
93 else:
94 pos1(hair,170);
95 pos4(0.8vair,0); pos6(vair,-180); pos5(vair,0); pos5'(vair,-180);
96 pos7(vair,-180);
97 z5 = z5';
98 bot y5=-d;
99 rt x6l=hround(w-2u);
100 x4l=x6r;
101 fi
102 pos2(vstem+dw,90);
103 bot y1r=.5772156649h; top y2r=h+oo; y4=y6=-.5d;
104 top y7=h;
105 lft x1r=hround(.5u-.5hair); x2=3u; x5=.5[x4,x6];
106 rt x7l=hround(w-u);
107 if serifs: if x4l<x6l: x4l:=x6l:=x5; fi fi
108 pos3(if hefty: 0.9vair else: hair fi,angle(z4-z2)+90);
109 x3=superness[x2,x4]; y3=superness[y4,y2];
110 filldraw stroke z1e{up}...z2e{right}...z3e{z4-z2}
111 ...z4e{down} if serifs: ...{left}z5e else: ---z5e fi; % arc
112 filldraw stroke if serifs: z5e{left}... else: z5'e--- fi
113 z6e{up}..{2(x7-x6),y7-y6}z7e; % stem
114 math_fit(-.5772156649x_height#*slant,ic#-u#);
115 penlabels(1,2,3,4,5,6,7); endchar;
116
117 cmchar "Lowercase Greek delta";
118 beginchar(oct"016",8u#,asc_height#,0);
119 italcorr .9asc_height#*slant+.5hair#-1.5u#;
120 adjust_fit(0,0); pickup fine.nib;
121 x0=-u; y0=1.1h;
122 numeric light_flare;
123 light_flare= if serifs: 2/3[vair,flare] else: vair fi;
124 if serifs: x1=w-2u-.5light_flare;
125 else: x1=w-2u-.25light_flare; fi
126 y1=h-.5light_flare;
127 numeric theta; theta=angle (z1-z0);
128 pos1(light_flare,theta-90);
129 pos2(.2[vair,light_flare],-90); pos3(vair,theta);
130 x2=x3+u; y2=h;
131 x4=x6=.5w+.5u; top y8r=x_height+oo; z4=z8;
132 pos6(vair,-90); pos7(if hefty: 0.5[vair,stem] else: stem fi,-180); pos8(vair,-270);
133 pos4(stem,angle(z4-z0)+90);
134 if serifs: pos5(stem,30);
135 else: pos5(stem,0); fi
136 z3=.5[.5[z1,z4],z0];
137 y5+.1x_height=y7=.5[y6,y8]; bot y6r=-oo;
138 lft x7r=hround(1.4u-.5stem); rt x5r=hround(w-u);
139 filldraw stroke z1e{z0-z1e}....z2e....z3e{(z0-z1)rotated 90}
140 ...z4e{z4e-.8[z4,z0]}
141 ....z5e{down}...pulled_arc.e(6,7) & pulled_arc.e(7,8); % hook and bowl
142 if serifs: filldraw z1r{z1r-z0}...z1l{z0-z1l}--cycle; fi % bulb
143 math_fit(-.3x_height#*slant+.5curve#-u#,.7x_height#*slant-.5u#);
144 penlabels(0,1,2,3,4,5,6,7,8); endchar;
145
146 cmchar "Lowercase Greek epsilon";
147 beginchar(oct"017",8u#,x_height#,0);
148 italcorr x_height#*slant+.5hair#-2u#;
149 adjust_fit(0,0); pickup fine.nib;
150 if serifs:
151 pos0(bar,90); pos4(hair,300);
152 x0=x1+u; x6=x0; x3=.5[x0,x1];
153 top y0r=top y1r=h;
154 else:
155 pos0(if hefty: vair else: hair fi,75); pos4(if hefty: vair else: hair fi,310);
156 x6=x1+u; x3=.5[x6,x1]; x0=x6+bar/2;
157 top y1r=h;
158 y0 = 0.3[y1,y1l];
159 fi
160 pos1(bar,90); pos2(curve,180);
161 pos3(vair,270); pos6(bar,90); pos7(bar,90);
162 x1=.5w+.5u; lft x2r=hround(1.5u-.5curve);
163 x4r=good.x(w-u); x5=w+.5u; z7=z2l;
164 y2=y5=y6=bar_height; bot y3r=-oo;
165 path p; p=z3r{right}...{up}z5;
166 numeric t; t=ypart(((x4r,y3r)--(x4r,y5))intersectiontimes p);
167 y4r=ypart point t of p;
168 filldraw sans_circ_stroke z0e..pulled_arc.e(1,2) & pulled_arc.e(2,3)
169 ...z4e{direction t of p}; % arc
170 filldraw sans_circ_stroke z6e--z7e; % bar
171 math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
172 penlabels(0,1,2,3,4,5,6,7); endchar;
173
174 cmchar "Lowercase Greek zeta";
175 beginchar(oct"020",9u#,asc_height#,desc_depth#);
176 italcorr .75[x_height#,asc_height#]*slant-1.5u#;
177 adjust_fit(0,0); pickup fine.nib;
178 top y0=h;
179 if serifs:
180 pos0(hair,-360); pos1(vair,-270); pos2(hair,-180); pos3(vair,-90);
181 pos8(vair,-135);
182 top y3l=bot y1l+vstem+eps=vround(y0-.25(h-x_height));
183 x1=x3=.5[x0,x2];
184 y2=.5[y1,y3];
185 lft x0l=hround 3.5u;
186 else:
187 pos0(vair,-360); pos1(0.8vair,-270); pos2(vair,-270); pos3(0.9vair,-90);
188 pos8(vair,-125);
189 pos2'(vair,-90);
190 z2' = z2;
191 x1=x3=.8[x0,x2];
192 top y2r=vround(y0-.4(h-x_height));
193 y2l=y3r; y2r=y1r;
194 lft x0l=hround 3u;
195 fi
196 numeric theta; theta=90-angle(25u,x_height); slope:=-x_height/25u;
197 pos6(stem,theta); pos7(vair,-90);
198 rt x2l=hround max(rt x0r,w-2u)+eps;
199 if serifs: if y1r>y3r: y1r:=y3r:=y2; fi fi
200 lft x4l=hround u; x4r-x4l=(hround .6[vair,stem])-fine;
201 x6+.5u=x7=w-2u; x8=.5w+.75u;
202 y6=-.1d; y8=-3/4d-oo; bot y7r=-d-oo;
203 ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
204 y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
205 if serifs:
206 filldraw circ_stroke z0e{down}...z1e{right}...{up}z2e; % opening hook
207 filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}
208 ...z6e---z5e....{up}z4e
209 ..tension 1 and atleast1.5..{right}z3e...{down}z2e; % main stroke
210 else:
211 filldraw stroke z0e{down}...z1e{right}--z2e; % opening hook
212 filldraw stroke z8e{x7-x8,2(y7-y8)}...z7e{right}
213 ...z6e---z5e....{up}z4e
214 ..tension 1 and atleast1.5..{right}z3e---z2'e; % main stroke
215 fi
216 math_fit(-.2asc_height#*slant-.5u#,0);
217 penlabels(0,1,2,3,4,5,6,7,8); endchar;
218
219 cmchar "Lowercase Greek eta";
220 beginchar(oct"021",9u#,x_height#,desc_depth#);
221 italcorr .8x_height#*slant+.5stem#-u#;
222 adjust_fit(0,0); pickup fine.nib;
223 x0=0; x1l=x2l; pos2(stem,0); lft x2l=hround(2.5u-.5stem);
224 if serifs: y2-.5stem=-oo;
225 else: y2 = 0; fi
226 hook_in(0,a,1); % opening hook
227 filldraw sans_circ_stroke z2e--z1e; % left stem
228 x4+.5stem=hround(w-1.5u+.5stem); ital_arch(2,3,4); % arch
229 pos5(stem,0); x5=x4;
230 if serifs: y5-.5stem=-d-o;
231 else: y5=-d; fi
232 filldraw sans_circ_stroke z5e--z4e; % right stem
233 math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
234 penlabels(0,a,1,2,3,4,5); endchar;
235
236 cmchar "Lowercase Greek theta";
237 beginchar(oct"022",8.25u#,asc_height#,0);
238 italcorr .7asc_height#*slant+.5curve#-u#;
239 adjust_fit(0,0); pickup fine.nib;
240 pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
241 x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
242 top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
243 filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
244 & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
245 pos2'(bar,90); pos4'(bar,90); z2'=z2l; z4'=z4l;
246 filldraw stroke z2'e--z4'e; % bar
247 math_fit(-.3asc_height#*slant-u#+.5curve#,ic#-.5u#);
248 penlabels(1,2,3,4); endchar;
249
250 cmchar "Lowercase Greek iota";
251 beginchar(oct"023",5u#,x_height#,0);
252 italcorr 1/3x_height#*slant+.5hair#+.5u#;
253 adjust_fit(if monospace: u#,u# else: 0,0 fi); pickup fine.nib;
254 pos1(stem,0); lft x1l=hround(1.5u-.5stem);
255 if serifs: y1+.5stem=h+oo;
256 else: y1=h; fi
257 x2=x1-.25u; x4=w; hook_out(2,3,4)(skewed); % closing hook
258 filldraw sans_circ_stroke z1e{down}...{-u,-x_height}z2e; % stem
259 math_fit(0,ic#); penlabels(1,2,3,4); endchar;
260
261 cmchar "Lowercase Greek kappa";
262 beginchar(oct"024",9u#,x_height#,0);
263 italcorr 1/3x_height#*slant+.5hair#+.5u#;
264 adjust_fit(0,0); pickup fine.nib;
265 pos1(stem,0); pos2(stem,0); pos3(vair,90);
266 if serifs:
267 pos4(vair,90);
268 pos9(hair,180);
269 x4+.5flare=hround(w-1.5u);
270 y9=1/3x_height;
271 else:
272 pos4(hair,90);
273 pos9(vair,180);
274 x4r=hround(w-1.6u);
275 y9=1/5x_height;
276 fi
277 pos5(flare,90);
278 x1=x2=x3; lft x1l=hround(1.5u-.5stem);
279 if serifs:
280 y1+.5stem=h+oo; y2-.5stem=-oo;
281 filldraw z1l---z2l..z2r---z1r..cycle; % stem
282 else:
283 y1=h; y2=0;
284 filldraw stroke z1e--z2e;
285 fi
286 y3=bar_height; top y4r=h; z5r=z4r;
287 path p,q; p=z3l{right}..{right}z4l; q=z5r{right}..z5l{left}...cycle;
288 numeric t; t=ypart(p intersectiontimes q);
289 filldraw stroke z3e{right}..{right}z4e; % upper diagonal
290 if serifs: filldraw subpath(0,t) of q--cycle; fi % bulb
291 pos7(if hefty: 0.6[vair,stem] else: stem fi,0); pos8(vair,90);
292 x9+.5hair=hround(w+.5hair-epsilon);
293 lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
294 filldraw stroke z3e{right}...z7e{down}
295 ...z8e{right}...{up}z9e; % lower diagonal
296 math_fit(0,ic#); penlabels(1,2,3,4,5,7,8,9); endchar;
297
298 cmchar "Lowercase Greek lambda";
299 beginchar(oct"025",10.5u#,asc_height#,0);
300 adjust_fit(0,0); pickup fine.nib;
301 pos1(vair,90); lft x1=hround .1u; top y1r=h;
302 x2=x1+2u; y2=.7[x_height,h]; x3=w-2u;
303 if serifs:
304 bot y4=-oo;
305 z4-(.25u,0)=whatever[z2,z3]; pos4(stem,0);
306 y3=max(.07h,y4+eps);
307 numeric theta; theta=angle(z2-z3)-90;
308 pos2(stem,theta); pos3(stem,theta);
309 filldraw circ_stroke z1e{right}...z2e---z3e
310 ...{2(x4e-x3e),y4e-y3e}z4e; % long diagonal
311 y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
312 x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
313 filldraw circ_stroke z6e--z5e; % short diagonal
314 else:
315 bot y4=0;
316 y3=max(.07h,y4+eps);
317 z4-(.25u,0)=whatever[z2,z3];
318 y4l = y4r = y4;
319 numeric theta; theta=angle(z2-z3)-90;
320 pos2(stem',theta); pos3(stem',theta);
321 z4l = whatever[z3l,z2l]; z4r = whatever[z3r,z2r];
322 filldraw stroke z1e{right}...z2e---z4e; % long diagonal
323 y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
324 x6=1.7u; y6-.5stem=-oo;
325 z5l=whatever[z2,z3]; z5l=whatever[z5,z6]+z6l-z6;
326 z5=0.5[z5r,z5l];
327 pos6(0.6[vair,stem],angle(z5-z6)-90);
328 z6'=whatever[z5,z6];
329 z6'l=whatever[z5l,z6l];
330 z6'r=whatever[z5r,z6r];
331 y6'=y6'r=y6'l=0;
332 filldraw stroke z6'e--z5e; % short diagonal
333 fi
334 penlabels(1,2,3,4,5,6);
335 endchar;
336
337 cmchar "Lowercase Greek mu";
338 beginchar(oct"026",if hefty: 9.5u# else: 9u# fi,x_height#,desc_depth#);
339 italcorr 1/3x_height#*slant+.5hair#+.5u#;
340 adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
341 pos1(stem,-180); pos2(stem,-180); x1=x2; x1l=x3l;
342 lft x1r=hround(1.5u-.5stem);
343 if serifs: y1+.5stem=h+oo; y2-.5stem=-d-o; y6+.5stem=h;
344 else: y1=y6=h; y2=-d; fi
345 if serifs: filldraw z1r---z2r..z2l---z1l..cycle; % left stem
346 else: filldraw z1r--z2r--z2l--z1l--cycle; fi
347 pos3(if hefty: vair else: stem fi,-180); pos4(vair,-90); pos5(hair,0); x4=.5[x1,x6];
348 pos6(stem,0); rt x6r=hround(6.5u+.5stem);
349 x5=x6=x7; x9=w;
350 hook_out(7,8,9);
351 y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
352 filldraw stroke super_arc.e(3,4)...{up}z5e; % left stem and arc
353 filldraw sans_circ_stroke z6e--z7e; % right stem
354 math_fit(desc_depth#*slant+.5stem#-u#,ic#);
355 penlabels(1,2,3,4,5,6,7,8,9); endchar;
356
357 cmchar "Lowercase Greek nu";
358 beginchar(oct"027",8.5u#,x_height#,0);
359 italcorr x_height#*slant+.5stem#-u#;
360 adjust_fit(0,0); pickup fine.nib;
361 pos3(vair,-90); pos4(stem,0); bot y3r=0;
362 if serifs: y4+.5stem=h+oo;
363 else: y4 = h; fi
364 x3-.5stem=hround(1.5u-.5stem); x4+.5stem=hround(w-1.5u+.5stem);
365 filldraw sans_circ_stroke z4e{down}...{-36u,-h}z3e; % diagonal
366 pickup tiny.nib; pos1(stem,0); pos2(stem,0);
367 top y1=h+min(oo,serif_drop); bot y2=0; x1=x2=x3;
368 z=((z4{down}...{-36u,-h}z3)intersectionpoint((x2r,0)--(x2r,h)));
369 filldraw z1l--z2l...(x3,y2l)...z--z1r--cycle; % stem
370 if serifs: sloped_serif.l(1,2,a,1/3,jut,serif_drop); fi % upper left serif
371 math_fit(0,ic#-1/3x_height#*slant-.5u#); penlabels(1,2,3,4); endchar;
372
373 cmchar "Lowercase Greek xi";
374 beginchar(oct"030",9u#,asc_height#,desc_depth#);
375 italcorr .75[x_height#,asc_height#]*slant-2u#;
376 adjust_fit(0,0); pickup fine.nib;
377 if serifs:
378 pos10(hair,-720); pos12(hair,-540); pos2(hair,-180); pos8(vair,-135);
379 top y13l=bot y11l+vstem+eps=vround(y10-.25(h-x_height));
380 top y3l=vround .5h=bot y1l+vstem+eps;
381 lft x10l=hround 1/3w;
382 x11=x13=.5[x10,x12];
383 else:
384 pos10(vair,-720); pos8(vair,-125);
385 pos12(vair,-630); pos12'(vair,-450);
386 pos2(vair,-270); pos2'(vair,-90);
387 z12'=z12; z2 = z2';
388 top y13l=top y11r=(y10-.33(h-x_height));
389 top y3l=vround .5h;
390 y3 = y1;
391 lft x10l=hround 1/4w;
392 x11=x13=.8[x10,x12];
393 fi
394 pos11(vair,-630); pos13(vair,-450);
395 rt x12l=hround(w-2.5u);
396 top y10=h;
397 y12=.5[y11,y13];
398 if serifs: if y11r>y13r: y11r:=y13r:=y12; fi fi
399 pos0(curve,-360); pos1(vair,-270); pos3(vair,-90);
400 numeric theta; theta=90-angle(22u,x_height); slope:=-x_height/22u;
401 pos6(stem,theta); pos7(vair,-90);
402 lft x0l=hround u; x1=x3=x11; x2=x12;
403 y0=.5[y13,y1]; y2=.5[y1,y3];
404 if serifs: if y1r>y3r: y1r:=y3r:=y2; fi fi
405 lft x4l=hround u; x4r-x4l=hround .5[vair,stem]-fine;
406 x6=x7=w-2u; x8=.5w+.5u; y6=-.3d; bot y7r=-d-oo; y8=max(-3/4d-oo,y7l);
407 ellipse_set(3l,4l,5l,6l); ellipse_set(3r,4r,5r,6r);
408 y4l:=.9[y6,y4l]; y4=y4r:=.9[y6,y4r];
409 if serifs:
410 filldraw circ_stroke z10e{down}...z11e{right}...{up}z12e;
411 % opening hook
412 filldraw stroke z12e{up}...z13e{left}...z0e{down}
413 ...z1e{right}...{up}z2e; % upper arc
414 filldraw circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
415 ---z5e...{up}z4e...{right}z3e...{down}z2e; % main stroke
416 else:
417 filldraw stroke z10e{down}...z11e{right}---z12e;
418 % opening hook
419 filldraw stroke z12'e---z13e{left}...z0e{down}
420 ...z1e---z2e; % upper arc
421 filldraw stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
422 ---z5e...{up}z4e...z3e---z2'e; % main stroke
423 fi
424 math_fit(-.2asc_height#*slant-.5u#,0);
425 penlabels(0,1,2,3,4,5,6,7,8,10,11,12,13); endchar;
426
427 cmchar "Lowercase Greek pi";
428 beginchar(oct"031",10u#,x_height#,0);
429 italcorr x_height#*slant+.5stem#-u#;
430 adjust_fit(0,0); pi_stroke; % hook and bar
431 pos4(if hefty: vair else: hair fi,0);
432 pos6(if hefty: vair else: hair fi,0);
433 x4=3.5u; x6=w-4u; y4=y6=y2;
434 x5=3u; x7=w-2.5u;
435 y5=y7=.5stem-oo;
436 pair v[]; v1=(z4-z5) xscaled 3.14159; v2=(z6-z7) xscaled 3.14159;
437 pos5(if hefty: vair else: hair fi,angle v1-90);
438 pos7(if hefty: vair else: hair fi,angle v2-90);
439 if serifs:
440 filldraw circ_stroke z5e{v1}...{up}z4e; % left stem
441 filldraw circ_stroke z7e{v2}...{up}z6e; % right stem
442 else:
443 z8l = z5l + whatever*v1;
444 z8r = z5r + whatever*v1;
445 z9 = z7 + whatever*v2;
446 pos9(if hefty: vair else: stem fi,angle v2-90);
447 y8r = y8l = 0; y9l = -oo;
448 filldraw stroke z8e{v1}...{up}z4e; % left stem
449 filldraw stroke z9e{v2}...{up}z6e; % right stem
450 fi
451 math_fit(-.7x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
452 penlabels(1,2,3,4,5,6,7,8,9); endchar;
453
454 cmchar "Lowercase Greek rho";
455 beginchar(oct"032",8.25u#,x_height#,desc_depth#);
456 italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
457 adjust_fit(0,0); pickup fine.nib;
458 pos1(stem,180); pos2(stem,180); pos3(vair,90);
459 pos4(if hefty: 0.7[vair,curve] else: curve fi,0); pos5(vair,-90); pos6(if hefty: vair else: hair fi,-180);
460 lft x2r=hround(1.5u-.5stem); x1=x2; x2l=x6l; x3=x5=.5[x2,x4];
461 rt x4r=hround(w-1.5u+.5curve);
462 if serifs: y1-.5stem=-d-o;
463 else: y1=-d; fi
464 y2=y4=y6=.5[y3,y5]; top y3r=h+oo; bot y5r=-oo;
465 filldraw sans_circ_stroke z1e..pulled_arc.e(2,3) & pulled_arc.e(3,4)
466 & pulled_arc.e(4,5) & pulled_arc.e(5,6); % stem and bowl
467 math_fit(desc_depth#*slant+.5stem#-u#,ic#);
468 penlabels(1,2,3,4,5,6); endchar;
469
470 cmchar "Lowercase Greek sigma";
471 beginchar(oct"033",10.25u#,x_height#,0);
472 italcorr x_height#*slant+.5stem#-u#;
473 adjust_fit(0,0); pickup fine.nib;
474 pos1(vstem,90);
475 pos2(stem,0);
476 pos3(if hefty: 0.9 fi vair,-90);
477 pos4(stem,-180); pos5(vstem,-270); pos6(vstem,-270);
478 x1=x3=x5=.5[x2,x4]; rt x2r=hround(w-2.5u);
479 lft x4r=hround(1.5u-.5curve);
480 if serifs: x6=w-1.5u; else: x6=w-1.2u; fi
481 top y6r=h; y2=y4=.5[y1,y3]; bot y3r=-oo; y5l=y6l=y1l;
482 filldraw sans_circ_stroke z6e..pulled_arc.e(5,4) & pulled_arc.e(4,3)
483 & pulled_arc.e(3,2) & pulled_arc.e(2,1); % ear and bowl
484 math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
485 penlabels(1,2,3,4,5,6); endchar;
486
487 cmchar "Lowercase Greek tau";
488 beginchar(oct"034",9u#,x_height#,0);
489 italcorr x_height#*slant+.5stem#-u#;
490 adjust_fit(0,0); pi_stroke; % hook and bar
491 pos4(if hefty: vair else: hair fi,0); pos5(stem,0);
492 x4=x5; x5-.5stem=hround(.5w-.5u-.5stem); y4=y2;
493 if serifs: y5-.5stem=-oo; else: y5=0; fi
494 filldraw sans_circ_stroke z5e--z4e; % stem
495 math_fit(-.7x_height#*slant+.5hair#+.5u#,-.5u#);
496 penlabels(1,2,3,4,5); endchar;
497
498 cmchar "Lowercase Greek upsilon";
499 beginchar(oct"035",9u#,x_height#,0);
500 italcorr x_height#*slant;
501 adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
502 x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
503 hook_in(0,1,2)(skewed); % opening hook
504 pos2'(if hefty: vair else: stem fi,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
505 x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
506 filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
507 ..tension atleast 1.05..{up}z5e; % left stem and arc
508 v_bulb(5,6); % closing bulb
509 math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
510 penlabels(0,1,2,3,4,5,6); endchar;
511
512 cmchar "Lowercase Greek phi";
513 beginchar(oct"036",11u#,asc_height#,desc_depth#);
514 italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
515 adjust_fit(0,0); pickup fine.nib;
516 numeric light_curve; light_curve=hround(.5[stem,curve]-2stem_corr);
517 pos1(vair,90); pos2(light_curve,180); pos3(vair,270); pos4(light_curve,360);
518 x1=x3=.5w; lft x2r=hround(1.5u-.5light_curve); x4=w-x2;
519 top y1r=x_height+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
520 filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
521 & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
522 pos5(hair,0); pos6(hair,0); x5=x6=.5w; top y5=h; bot y6=-d-oo;
523 filldraw stroke z5e--z6e; % stem
524 math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
525 penlabels(1,2,3,4,5,6); endchar;
526
527 cmchar "Lowercase Greek chi";
528 beginchar(oct"037",11u#,x_height#,desc_depth#);
529 italcorr x_height#*slant+.5hair#-1.5u#;
530 adjust_fit(0,0); pickup fine.nib;
531 if hefty: pos1(vair,180); pos6(vair,180);
532 else: pos1(hair,180); pos6(hair,180); fi
533 pos2(vair,80); pos5(vair,80);
534 x1-.5hair=hround-.5hair; x6=w-x1; x2=w-x5=u;
535 y1=y2l-h/8; top y2r=h+oo; bot y5l=-d-oo; y6=y5r+h/8;
536 z0=.5[z2,z5]; z2'=z2l+(.5u,0); z5'=z5r-(.5u,0);
537 numeric theta; theta=angle(z5'-z2')+90;
538 pos3(if hefty: stem' else: stem fi,theta);
539 pos4(if hefty: stem' else: stem fi,theta);
540 y3r=y2r-h/8; y4l=y5l+h/8; z3l=whatever[z2',z0]; z4r=whatever[z0,z5'];
541 filldraw stroke z1e{up}...z2e{right}...z3e{z4r-z3l}
542 ..z4e{z4r-z3l}...{right}z5e...{up}z6e; % major diagonal and hooks
543 if serifs:
544 x8=w-x7=2u; y7+.5hair=h; y8-.5hair=-d;
545 numeric theta; theta=angle(z7-z8)-90;
546 pos7(hair,theta); pos8(hair,theta);
547 filldraw z7l---z8l..z8r---z7r..cycle; % minor diagonal
548 else:
549 x8=w-x7=2u; y7=h; y8=-d;
550 numeric theta; theta=angle(z7-z8)-90;
551 pos7(hair/cosd(theta),0); pos8(hair/cosd(theta),0);
552 filldraw stroke z7e--z8e;
553 fi
554 math_fit((desc_depth#-x_height#)*slant+ic#,ic#);
555 penlabels(0,1,2,2',3,4,5',5,6,7,8); endchar;
556
557 cmchar "Lowercase Greek psi";
558 beginchar(oct"040",11u#,asc_height#,desc_depth#);
559 italcorr x_height#*slant;
560 adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
561 x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
562 hook_in(0,1,2)(skewed); % opening hook
563 pos2'(if hefty: vair else: stem fi,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
564 x4=.5w+u; rt x5r=hround(w-.5u);
565 y3=.7[y4,y5]; bot y4r=-oo; y5=.57x_height;
566 filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
567 ..tension atleast 1.05..{up}z5e; % left stem and arc
568 v_bulb(5,6); % closing bulb
569 pos7(hair,0); pos8(hair,0); x7=x8=.5w+.5u; top y7=h; bot y8=-d-oo;
570 filldraw stroke z7e--z8e; % stem
571 math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
572 penlabels(0,1,2,3,4,5,6,7,8); endchar;
573
574 cmchar "Lowercase Greek omega";
575 beginchar(oct"041",11u#,x_height#,0);
576 italcorr x_height#*slant;
577 adjust_fit(0,0); pickup fine.nib;
578 pos2(hair,-180); lft x2r=hround.5u; y2=y4=y6=y8=bar_height;
579 if serifs:
580 y1+.5hair=h;
581 x1=x2+.75u; pos1(hair+dw,angle(2(x1-x2),y1-y2)+90);
582 pos4(hair,0); pos5(vair,90); pos6(hair,180);
583 rt x4r-lft x6r=min(stem,2hair)+2eps;
584 top y5r=vround(.2[y4,h]+.5vair);
585 else:
586 y1r = h;
587 x1=x2+.75u+hair/4; pos1(hair+dw,angle(2(x1-x2),y1r-y2r)+90);
588 pos4(vair,0); pos5(vair,0); pos6(vair,180); pos5'(vair,180);
589 z4 = z6; z5=z5';
590 top y5r=y4+0.7u;
591 fi
592 pos3(vstem+dw,-90); pos7(vstem+dw,270); pos8(hair,360);
593 bot y3r=bot y7r=-oo;
594 x3=.5[x2,x4]; x7-.25u=.5[x6,x8]; rt x8r=hround(w-.5u);
595 x5+.5stem=hround(.5w+.5stem)+eps;
596 x5=.5[x4,x6];
597 if serifs: if x4l<x6l: x4l:=x6l:=x5; fi fi
598 if serifs:
599 filldraw scirc_stroke z1e{2(x2-x1),y2-y1}...z2e{down}...z3e{right}
600 ...{up}z4e...{left}z5e; % left arc
601 filldraw stroke z5e{left}...z6e{down}...z7e{right}...{up}z8e; % right arc
602 v_bulb(8,9); % closing bulb
603 else:
604 filldraw stroke z1e{2(x2-x1),y2-y1}...z2e{down}...z3e{right}
605 ...z4e---z5e; % left arc
606 filldraw stroke z5'e---z6e...z7e{right}...{up}z8e; % right arc
607 y9r=x_height; x9+.5curve=w-u-hair/4;
608 pos9(curve,15); filldraw stroke z8e{up}..z9e;
609 fi
610 math_fit(-bar_height#*slant,2/3ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
611
612 cmchar "Variant lowercase Greek epsilon";
613 beginchar(oct"042",8u#,x_height#,0);
614 italcorr x_height#*slant-.5u#;
615 adjust_fit(0,0); pickup fine.nib;
616 numeric light_vstem; light_vstem=Vround 2/3[vair,vstem];
617 if serifs:
618 x1+.5light_vstem=hround(w-u);
619 x9+.5vair=hround(w-.5u);
620 pos5(hair,360);
621 top y6r-bot y4r=vstem+eps; if y6l<y4l: y6l:=y4l:=y5; fi
622 else:
623 x1+.25light_vstem=hround(w-u);
624 x9+.25vair=hround(w-.5u);
625 pos5(vair,270); pos5'(vair,450); z5=z5';
626 y6=y4;
627 fi
628 pos2(light_vstem,90); x2=x8=.5w+.5u; top y2r=h+o;
629 y1=.2[y2,bar_height];
630 pos1(light_vstem,angle(x1-x2,2(y1-y2))+90); pos3(hair,180); pos4(vair,270);
631 pos6(vair,450); pos7(hair,540); pos8(light_vstem,630);
632 lft x3r=hround u;
633 rt x5r=hround(w-2.5u); x7=x3;
634 if serifs: x4=x6=.5w; else: x4=x6=x5-.5u; fi
635 y3=.5[y2,y4]; y5=bar_height=.5[y4,y6]; y7=.5[y6,y8]; bot y8r=-o;
636 y9=1/3[y8,bar_height];
637 pos9(vair,angle(x8-x9,2(y8-y9))+90);
638 if serifs:
639 filldraw circ_stroke z1e{x2-x1,2(y2-y1)}...pulled_super_arc.e(2,3)(.5superpull)
640 & super_arc.e(3,4)...{up}z5e; % upper arc
641 filldraw circ_stroke z9e{x8-x9,8(y8-y9)}...pulled_arc.e(8,7)
642 & super_arc.e(7,6)...{down}z5e; % lower arc
643 else:
644 filldraw stroke z1e{x2-x1,2(y2-y1)}...pulled_super_arc.e(2,3)(.5superpull)
645 & super_arc.e(3,4)---z5e; % upper arc
646 filldraw stroke z9e{x8-x9,8(y8-y9)}...pulled_arc.e(8,7)
647 & super_arc.e(7,6)---z5'e; % lower arc
648 fi
649 math_fit(-.5bar_height#*slant-.5u#,ic#);
650 penlabels(1,2,3,4,5,6,7,8,9); endchar;
651
652 cmchar "Variant lowercase Greek theta";
653 beginchar(oct"043",9u#,asc_height#,0);
654 italcorr .5[bar_height#,x_height#]*slant+.5vair#+.5u#;
655 adjust_fit(0,0); pickup fine.nib;
656 numeric light_curve; light_curve=hround .5[stem,curve];
657 x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2); % opening hook
658 pos2'(if hefty: vair else: stem fi,-180); z2'=z2; pos3(stem,-180); pos4(vair,-90);
659 pos5(light_curve,0); pos6(vair,90); pos7(hair,180); pos8(vair,270);
660 x3=x2; x4=x6=.5[x3,x5]; rt x5r=hround(w-1.5u+.5light_curve);
661 lft x7r=hround(3.25u-.5hair); x8+.5vair=hround(w+.5vair-epsilon);
662 y3=.4x_height; bot y4r=-oo; y5=.5[y4,y6]; top y6r=h+oo;
663 y7=.5[x_height,h]; y8=.5[bar_height,x_height];
664 filldraw stroke z2'e..{{interim superness:=hein_super; super_arc.e(3,4)}}
665 & pulled_arc.e(4,5) & pulled_arc.e(5,6)
666 ...{down}z7e...{4(x8-x7),y8-y7}z8e; % bowl and loop
667 math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
668 penlabels(0,a,1,2,3,4,5,6,7,8); endchar;
669
670 cmchar "Variant lowercase Greek pi";
671 beginchar(oct"044",14.5u#,x_height#,0);
672 italcorr x_height#*slant+.5stem#-u#;
673 adjust_fit(0,0); pi_stroke; % hook and bar
674 pos4(hair,-180); pos5(hair,-180); pos6(vstem,-90);
675 pos7(hair,0); pos7'(hair,-180); z7'=z7;
676 pos8(vstem,-90); pos9(hair,0); pos0(hair,0);
677 x4=x5+1.5u; lft x5r=hround 2u; x6=x4+.5u; lft x7l=hround(.5w+.25u-.5hair);
678 x8=w-4.5u; rt x9r=hround(w-1.5u); x0=x9-1.25u;
679 top y4=top y0=h; y5+.1h=y7-.1h=y9=bar_height; bot y6r=bot y8r=-oo;
680 filldraw stroke z4e{2(x5-x4),y5-y4}...z5e{down}
681 ...z6e{right}...z7e{up}; % left bowl
682 filldraw stroke z0e{2(x9-x0),y9-y0}...z9e{down}
683 ...z8e{left}...z7'e{up}; % right bowl
684 math_fit(-.7x_height#*slant+.5hair#+.5u#,ic#-.5u#);
685 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
686
687 cmchar "Variant lowercase Greek rho";
688 beginchar(oct"045",8.25u#,x_height#,desc_depth#);
689 italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
690 adjust_fit(0,0); pickup fine.nib;
691 pos2(stem,180); pos3(vair,90); pos4(curve,0); pos5(vair,-90); pos6(stem,-180);
692 lft x2r=hround(1.5u-.5stem); x2=x6; x3=x5=.5[x2,x4];
693 rt x4r=hround(w-1.5u+.5curve);
694 y2=y4=y6=.5[y3,y5]; top y3r=h+oo; bot y5r=-oo;
695 filldraw circ_stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
696 & pulled_arc.e(4,5) & pulled_arc.e(5,6); % bowl
697 pos2'(hair,-180); z2'r=z2r; pos1(vstem,-90); pos1'(vstem,90); z1'=z1;
698 pos0(hair,0); rt x0r=hround(w-u); bot y0=-d; bot y1r=vround-.9d; x1=x5;
699 interim superness:=sqrt superness;
700 filldraw stroke pulled_arc.e(0,1'); filldraw stroke pulled_arc.e(1,2'); % tail
701 math_fit(desc_depth#*slant+.5stem#-u#,ic#);
702 penlabels(0,1,2,3,4,5,6); endchar;
703
704 cmchar "Variant lowercase Greek sigma";
705 beginchar(oct"046",8u#,x_height#,.5min(desc_depth#,.5x_height#));
706 italcorr x_height#*slant-.5u#;
707 adjust_fit(0,0); pickup fine.nib;
708 numeric heavy_vair; heavy_vair=.25[vair,vstem];
709 if serifs:
710 pos1(heavy_vair,-110); pos8(vair,-135);
711 x1+.5heavy_vair=hround(w-u);
712 x8=.5w+u;
713 else:
714 pos1(heavy_vair,-125); pos8(vair,-110);
715 x1+.3heavy_vair=hround(w-u);
716 x8=.5w+.7u;
717 fi
718 pos2(vair,-90);
719 y1=.1[y2r,bar_height];
720 x2=min(.5w+u,x1r-eps); top y2l=h+oo;
721 filldraw sans_circ_stroke z1e{x2-x1,2(y2-y1)}...{left}z2e; % upper bulb
722 numeric theta; theta=90-angle(16u,x_height); slope:=-x_height/16u;
723 pos6(stem,theta); pos7(vair,-90);
724 lft x4l=hround u; x4r-x4l=(hround .5[vair,stem])-fine;
725 x6=x7=w-2u; y6=.25[y8,y2]; y8=y7+1/8d; bot y7r=-d-oo;
726 ellipse_set(2l,4l,5l,6l); ellipse_set(2r,4r,5r,6r); y4=y4r;
727 filldraw sans_circ_stroke z8e{x7-x8,2(y7-y8)}...z7e{right}...z6e
728 ---z5e...{up}z4e...{right}z2e; % main stroke
729 math_fit(-.5x_height#*slant-.5u#,0); penlabels(1,2,4,5,6,7,8); endchar;
730
731 cmchar "Variant lowercase Greek phi";
732 beginchar(oct"047",11u#,x_height#,desc_depth#);
733 italcorr .7x_height#*slant;
734 adjust_fit(0,0); pickup fine.nib;
735 pos1(if hefty: vair else: hair fi,-180); x1=x2+.75u; top y1=h;
736 pos2(if hefty: vair else: hair fi,-180);
737 lft x2r=hround .5u; y2=bar_height;
738 pos3(if hefty: vair else: vstem fi,-90); x3=.5(w+u); bot y3r=-oo;
739 pos4(if hefty: vair else: hair fi,0); rt x4r=hround(w-.5u); y4=y2;
740 pos5(vstem,90); x5=.52[x6,x4]; top y5r=h+oo;
741 pos6(hair,180); x6=x7; y6=1/3h;
742 pos7(stem,180); lft x7r=hround(.5w-.5u-.5stem);
743 if serifs: y7-.5stem=-d-o; else: y7=-d; fi
744 filldraw sans_circ_stroke z7e---z6e...{right}z5e...{down}z4e...{left}z3e
745 ...{up}z2e...{3(x1-x2),y1-y2}z1e; % bowl and stem
746 math_fit(-.3x_height#*slant,ic#); penlabels(1,2,3,4,5,6,7); endchar;