| 1 |
% Based on the Computer Modern source file bigdel.mf by D E Knuth. |
| 2 |
|
| 3 |
% Edited by Ariel Barton to produce better sans serif symbols |
| 4 |
|
| 5 |
% Date: 2013/03/22 |
| 6 |
|
| 7 |
% This file contains series of large delimiters for math extension fonts. |
| 8 |
|
| 9 |
% The sizes are `{\tt\char`\\big}' (|2dh#|), `{\tt\char`\\Big}' (|3dh#|), |
| 10 |
% `{\tt\char`\\bigg}' (|4dh#|), and `{\tt\char`\\Bigg}' (|5dh#|), |
| 11 |
% followed in most cases by an extensible character that can grow |
| 12 |
% arbitrarily large in |dh#| steps, |
| 13 |
% where |dh#| is 60\% of the font design size. |
| 14 |
% (For example, a 10-point font will have large delimiters in sizes |
| 15 |
% 12$\,$pt, 18$\,$pt, 24$\,$pt, 30$\,$pt, 36$\,$pt, 42$\,$pt, etc.) |
| 16 |
|
| 17 |
% Character codes \0000--\0105 and \0150--\0177 are generated. |
| 18 |
|
| 19 |
charlist oct"000": oct"020": oct"022": oct"040": oct"060"; % left parentheses |
| 20 |
charlist oct"001": oct"021": oct"023": oct"041": oct"061"; % right parentheses |
| 21 |
charlist oct"002": oct"150": oct"024": oct"042": oct"062"; % left brackets |
| 22 |
charlist oct"003": oct"151": oct"025": oct"043": oct"063"; % right brackets |
| 23 |
charlist oct"004": oct"152": oct"026": oct"044": oct"064"; % left floors |
| 24 |
charlist oct"005": oct"153": oct"027": oct"045": oct"065"; % right floors |
| 25 |
charlist oct"006": oct"154": oct"030": oct"046": oct"066"; % left ceilings |
| 26 |
charlist oct"007": oct"155": oct"031": oct"047": oct"067"; % right ceilings |
| 27 |
charlist oct"010": oct"156": oct"032": oct"050": oct"070"; % left braces |
| 28 |
charlist oct"011": oct"157": oct"033": oct"051": oct"071"; % right braces |
| 29 |
charlist oct"012": oct"104": oct"034": oct"052"; % left angle brackets |
| 30 |
charlist oct"013": oct"105": oct"035": oct"053"; % right angle brackets |
| 31 |
charlist oct"016": oct"056": oct"036": oct"054"; % slashes |
| 32 |
charlist oct"017": oct"057": oct"037": oct"055"; % backslashes |
| 33 |
charlist oct"160": oct"161": oct"162": oct"163": oct"164"; % radical signs |
| 34 |
|
| 35 |
extensible oct"014": 0,0,0,oct"014"; % vertical line |
| 36 |
extensible oct"015": 0,0,0,oct"015"; % double vertical line |
| 37 |
extensible oct"060": oct"060",0,oct"100",oct"102"; % left parenthesis |
| 38 |
extensible oct"061": oct"061",0,oct"101",oct"103"; % right parenthesis |
| 39 |
extensible oct"062": oct"062",0,oct"064",oct"066"; % left bracket |
| 40 |
extensible oct"063": oct"063",0,oct"065",oct"067"; % right bracket |
| 41 |
extensible oct"064": 0,0,oct"064",oct"066"; % left floor bracket |
| 42 |
extensible oct"065": 0,0,oct"065",oct"067"; % right floor bracket |
| 43 |
extensible oct"066": oct"062",0,0,oct"066"; % left ceiling bracket |
| 44 |
extensible oct"067": oct"063",0,0,oct"067"; % right ceiling bracket |
| 45 |
extensible oct"070": oct"070",oct"074",oct"072",oct"076"; % left brace |
| 46 |
extensible oct"071": oct"071",oct"075",oct"073",oct"076"; % right brace |
| 47 |
extensible oct"072": oct"070",0,oct"072",oct"076"; % sharp left parenthesis |
| 48 |
extensible oct"073": oct"071",0,oct"073",oct"076"; % sharp right parenthesis |
| 49 |
extensible oct"074": 0,0,0,oct"077"; % arrow extension modules only |
| 50 |
extensible oct"075": 0,0,0,oct"167"; % double arrow extension modules only |
| 51 |
extensible oct"076": 0,0,0,oct"076"; % brace extension modules only |
| 52 |
extensible oct"077": oct"170",0,oct"171",oct"077"; % updownarrow |
| 53 |
extensible oct"100": oct"070",0,oct"073",oct"076"; % left moustache |
| 54 |
extensible oct"101": oct"071",0,oct"072",oct"076"; % right moustache |
| 55 |
extensible oct"102": 0,0,0,oct"102"; % left parenthesis extension modules only |
| 56 |
extensible oct"103": 0,0,0,oct"103"; % right parenthesis extension modules only |
| 57 |
extensible oct"164": oct"166",0,oct"164",oct"165"; % radical sign |
| 58 |
extensible oct"167": oct"176",0,oct"177",oct"167"; % double updownarrow |
| 59 |
extensible oct"170": oct"170",0,0,oct"077"; % uparrow |
| 60 |
extensible oct"171": 0,0,oct"171",oct"077"; % downarrow |
| 61 |
extensible oct"176": oct"176",0,0,oct"167"; % double uparrow |
| 62 |
extensible oct"177": 0,0,oct"177",oct"167"; % double downarrow |
| 63 |
|
| 64 |
cmchar "\big left parenthesis"; |
| 65 |
beginchar(oct"000",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 66 |
adjust_fit(1.5u#,-.25u#); left_paren(min(rule_thickness,hair),stem); endchar; |
| 67 |
|
| 68 |
cmchar "\Big left parenthesis"; |
| 69 |
beginchar(oct"020",9u#,rule_thickness#,3dh#-rule_thickness#); |
| 70 |
adjust_fit(2u#,-.25u#); left_paren(rule_thickness,if hefty: stem+0.5bigdw else:.5[stem,bold] fi); endchar; |
| 71 |
|
| 72 |
cmchar "\bigg left parenthesis"; |
| 73 |
beginchar(oct"022",11u#,rule_thickness#,4dh#-rule_thickness#); |
| 74 |
adjust_fit(2.5u#,-.25u#); left_paren(rule_thickness+.2dw,if hefty: stem+bigdw else: bold fi); endchar; |
| 75 |
|
| 76 |
cmchar "\Bigg left parenthesis"; |
| 77 |
beginchar(oct"040",11.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 78 |
adjust_fit(3u#,-.25u#); left_paren(rule_thickness+.4dw,if hefty: stem+2bigdw else: bold+dw fi); endchar; |
| 79 |
|
| 80 |
cmchar "Extensible left parenthesis---top"; |
| 81 |
beginchar(oct"060",12u#,rule_thickness#,3dh#-rule_thickness#); |
| 82 |
adjust_fit(4u#,-.25u#); pickup fine.nib; |
| 83 |
numeric min_breadth,max_breadth; |
| 84 |
min_breadth=rule_thickness+.6dw; max_breadth=if hefty: stem+3bigdw else: bold+2dw fi; |
| 85 |
pos1(hround min_breadth,0); pos2(hround max_breadth,0); |
| 86 |
rt x1r=hround(w-1.25u+.5min_breadth); lft x2l=hround 1.25u; |
| 87 |
top y1=h-1; y2=-d-eps; |
| 88 |
filldraw stroke z1e{3(x2e-x1e),y2-y1}...{down}z2e; % upper arc |
| 89 |
penlabels(1,2); endchar; |
| 90 |
|
| 91 |
cmchar "Extensible left parenthesis---bottom"; |
| 92 |
beginchar(oct"100",12u#,rule_thickness#,3dh#-rule_thickness#); |
| 93 |
adjust_fit(4u#,-.25u#); pickup fine.nib; |
| 94 |
numeric min_breadth,max_breadth; |
| 95 |
min_breadth=rule_thickness+.6dw; max_breadth=if hefty: stem+3bigdw else: bold+2dw fi; |
| 96 |
pos3(hround min_breadth,0); pos2(hround max_breadth,0); |
| 97 |
rt x3r=hround(w-1.25u+.5min_breadth); lft x2l=hround 1.25u; |
| 98 |
bot y3=1-d; y2=h+eps; |
| 99 |
filldraw stroke z3e{3(x2e-x3e),y2-y3}...{up}z2e; % lower arc |
| 100 |
penlabels(2,3); endchar; |
| 101 |
|
| 102 |
cmchar "Extensible left parenthesis---extension module"; |
| 103 |
beginchar(oct"102",12u#,0,dh#); |
| 104 |
adjust_fit(4u#,-.25u#); pickup fine.nib; |
| 105 |
numeric max_breadth; max_breadth=if hefty: stem+3bigdw else: bold+2dw fi; |
| 106 |
pos2(hround max_breadth,0); pos2'(hround max_breadth,0); |
| 107 |
lft x2l=lft x2'l=hround 1.25u; y2=h+eps; y2'=-d-eps; |
| 108 |
filldraw stroke z2e--z2'e; % link |
| 109 |
penlabels(2,2'); endchar; |
| 110 |
|
| 111 |
cmchar "\big right parenthesis"; |
| 112 |
beginchar(oct"001",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 113 |
adjust_fit(-.25u#,1.5u#); right_paren(min(rule_thickness,hair),stem); endchar; |
| 114 |
|
| 115 |
cmchar "\Big right parenthesis"; |
| 116 |
beginchar(oct"021",9u#,rule_thickness#,3dh#-rule_thickness#); |
| 117 |
adjust_fit(-.25u#,2u#); right_paren(rule_thickness,if hefty: stem+0.5bigdw else: .5[stem,bold] fi); endchar; |
| 118 |
|
| 119 |
cmchar "\bigg right parenthesis"; |
| 120 |
beginchar(oct"023",11u#,rule_thickness#,4dh#-rule_thickness#); |
| 121 |
adjust_fit(-.25u#,2.5u#); right_paren(rule_thickness+.2dw,if hefty: stem+bigdw else: bold fi); endchar; |
| 122 |
|
| 123 |
cmchar "\Bigg right parenthesis"; |
| 124 |
beginchar(oct"041",11.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 125 |
adjust_fit(-.25u#,3u#); right_paren(rule_thickness+.4dw,if hefty: stem+2bigdw else: bold+dw fi); endchar; |
| 126 |
|
| 127 |
cmchar "Extensible right parenthesis---top"; |
| 128 |
beginchar(oct"061",12u#,rule_thickness#,3dh#-rule_thickness#); |
| 129 |
adjust_fit(-.25u#,4u#); pickup fine.nib; |
| 130 |
numeric min_breadth,max_breadth; |
| 131 |
min_breadth=rule_thickness+.6dw; max_breadth=if hefty: stem+3bigdw else: bold+2dw fi; |
| 132 |
pos1(hround min_breadth,0); pos2(hround max_breadth,0); |
| 133 |
lft x1l=hround(1.25u-.5min_breadth); rt x2r=hround(w-1.25u); |
| 134 |
top y1=h-1; y2=-d-eps; |
| 135 |
filldraw stroke z1e{3(x2e-x1e),y2-y1}...{down}z2e; % upper arc |
| 136 |
penlabels(1,2); endchar; |
| 137 |
|
| 138 |
cmchar "Extensible right parenthesis---bottom"; |
| 139 |
beginchar(oct"101",12u#,rule_thickness#,3dh#-rule_thickness#); |
| 140 |
adjust_fit(-.25u#,4u#); pickup fine.nib; |
| 141 |
numeric min_breadth,max_breadth; |
| 142 |
min_breadth=rule_thickness+.6dw; max_breadth=if hefty: stem+3bigdw else: bold+2dw fi; |
| 143 |
pos3(hround min_breadth,0); pos2(hround max_breadth,0); |
| 144 |
lft x3l=hround(1.25u-.5min_breadth); rt x2r=hround(w-1.25u); |
| 145 |
bot y3=1-d; y2=h+eps; |
| 146 |
filldraw stroke z3e{3(x2e-x3e),y2-y3}...{up}z2e; % lower arc |
| 147 |
penlabels(2,3); endchar; |
| 148 |
|
| 149 |
cmchar "Extensible right parenthesis---extension module"; |
| 150 |
beginchar(oct"103",12u#,0,dh#); |
| 151 |
adjust_fit(-.25u#,4u#); pickup fine.nib; |
| 152 |
numeric max_breadth; max_breadth=if hefty: stem+3bigdw else: bold+2dw fi; |
| 153 |
pos2(hround max_breadth,0); pos2'(hround max_breadth,0); |
| 154 |
rt x2r=rt x2'r=hround(w-1.25u); y2=h+eps; y2'=-d-eps; |
| 155 |
filldraw stroke z2e--z2'e; % link |
| 156 |
penlabels(2,2'); endchar; |
| 157 |
|
| 158 |
cmchar "\big left bracket"; |
| 159 |
beginchar(oct"002",6u#,rule_thickness#,2dh#-rule_thickness#); |
| 160 |
adjust_fit(1.5u#,0); left_bracket(rule_thickness,true,true); endchar; |
| 161 |
|
| 162 |
cmchar "\Big left bracket"; |
| 163 |
beginchar(oct"150",6.5u#,rule_thickness#,3dh#-rule_thickness#); |
| 164 |
adjust_fit(2u#,0); left_bracket(.25[rule_thickness,stem],true,true); endchar; |
| 165 |
|
| 166 |
cmchar "\bigg left bracket"; |
| 167 |
beginchar(oct"024",7u#,rule_thickness#,4dh#-rule_thickness#); |
| 168 |
adjust_fit(2.5u#,0); left_bracket(.5[rule_thickness,stem],true,true); endchar; |
| 169 |
|
| 170 |
cmchar "\Bigg left bracket"; |
| 171 |
beginchar(oct"042",7.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 172 |
adjust_fit(3u#,0); left_bracket(.75[rule_thickness,stem],true,true); endchar; |
| 173 |
|
| 174 |
cmchar "Extensible left bracket---top"; |
| 175 |
beginchar(oct"062",8u#,rule_thickness#,3dh#-rule_thickness#); |
| 176 |
adjust_fit(4u#,0); pickup crisp.nib; |
| 177 |
pos1(stem,0); pos2(stem,0); |
| 178 |
top y1=h-1; y2=-d-eps; lft x1l=lft x2l=hround(2.5u-.5stem); |
| 179 |
filldraw stroke z1e--z2e; % stem |
| 180 |
pos3(stem,90); pos4(stem,90); |
| 181 |
x3=x1l; rt x4=hround(w-.75u+.5stem); y3r=y4r=y1; |
| 182 |
filldraw stroke z3e--z4e; % upper bar |
| 183 |
penlabels(1,2,3,4); endchar; |
| 184 |
|
| 185 |
cmchar "Extensible left bracket---bottom"; |
| 186 |
beginchar(oct"064",8u#,rule_thickness#,3dh#-rule_thickness#); |
| 187 |
adjust_fit(4u#,0); pickup crisp.nib; |
| 188 |
pos1(stem,0); pos2(stem,0); |
| 189 |
y1=h+eps; bot y2=1-d; lft x1l=lft x2l=hround(2.5u-.5stem); |
| 190 |
filldraw stroke z1e--z2e; % stem |
| 191 |
pos5(stem,90); pos6(stem,90); |
| 192 |
x5=x1l; rt x6=hround(w-.75u+.5stem); y5l=y6l=y2; |
| 193 |
filldraw stroke z5e--z6e; % lower bar |
| 194 |
penlabels(1,2,5,6); endchar; |
| 195 |
|
| 196 |
cmchar "Extensible left bracket---extension module"; |
| 197 |
beginchar(oct"066",8u#,0,dh#); |
| 198 |
adjust_fit(4u#,0); pickup crisp.nib; |
| 199 |
pos1(stem,0); pos2(stem,0); |
| 200 |
y1=h+1+eps; bot y2=-d-1-eps; lft x1l=lft x2l=hround(2.5u-.5stem); |
| 201 |
filldraw stroke z1e--z2e; % stem |
| 202 |
penlabels(1,2); endchar; |
| 203 |
|
| 204 |
cmchar "\big right bracket"; |
| 205 |
beginchar(oct"003",6u#,rule_thickness#,2dh#-rule_thickness#); |
| 206 |
adjust_fit(0,1.5u#); right_bracket(rule_thickness,true,true); endchar; |
| 207 |
|
| 208 |
cmchar "\Big right bracket"; |
| 209 |
beginchar(oct"151",6.5u#,rule_thickness#,3dh#-rule_thickness#); |
| 210 |
adjust_fit(0,2u#); right_bracket(.25[rule_thickness,stem],true,true); endchar; |
| 211 |
|
| 212 |
cmchar "\bigg right bracket"; |
| 213 |
beginchar(oct"025",7u#,rule_thickness#,4dh#-rule_thickness#); |
| 214 |
adjust_fit(0,2.5u#); right_bracket(.5[rule_thickness,stem],true,true); endchar; |
| 215 |
|
| 216 |
cmchar "\Bigg right bracket"; |
| 217 |
beginchar(oct"043",7.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 218 |
adjust_fit(0,3u#); right_bracket(.75[rule_thickness,stem],true,true); endchar; |
| 219 |
|
| 220 |
cmchar "Extensible right bracket---top"; |
| 221 |
beginchar(oct"063",8u#,rule_thickness#,3dh#-rule_thickness#); |
| 222 |
adjust_fit(0,4u#); pickup crisp.nib; |
| 223 |
pos1(stem,0); pos2(stem,0); |
| 224 |
top y1=h-1; y2=-d-eps; rt x1r=rt x2r=hround(w-2.5u+.5stem); |
| 225 |
filldraw stroke z1e--z2e; % stem |
| 226 |
pos3(stem,90); pos4(stem,90); |
| 227 |
x3=x1r; lft x4=hround(.75u-.5stem); y3r=y4r=y1; |
| 228 |
filldraw stroke z3e--z4e; % upper bar |
| 229 |
penlabels(1,2,3,4); endchar; |
| 230 |
|
| 231 |
cmchar "Extensible right bracket---bottom"; |
| 232 |
beginchar(oct"065",8u#,rule_thickness#,3dh#-rule_thickness#); |
| 233 |
adjust_fit(0,4u#); pickup crisp.nib; |
| 234 |
pos1(stem,0); pos2(stem,0); |
| 235 |
y1=h+eps; bot y2=1-d; rt x1r=rt x2r=hround(w-2.5u+.5stem); |
| 236 |
filldraw stroke z1e--z2e; % stem |
| 237 |
pos5(stem,90); pos6(stem,90); |
| 238 |
x5=x1r; lft x6=hround(.75u-.5stem); y5l=y6l=y2; |
| 239 |
filldraw stroke z5e--z6e; % lower bar |
| 240 |
penlabels(1,2,5,6); endchar; |
| 241 |
|
| 242 |
cmchar "Extensible right bracket---extension module"; |
| 243 |
beginchar(oct"067",8u#,0,dh#); |
| 244 |
adjust_fit(0,4u#); pickup crisp.nib; |
| 245 |
pos1(stem,0); pos2(stem,0); |
| 246 |
y1=h+1+eps; bot y2=-d-1-eps; rt x1r=rt x2r=hround(w-2.5u+.5stem); |
| 247 |
filldraw stroke z1e--z2e; % stem |
| 248 |
penlabels(1,2); endchar; |
| 249 |
|
| 250 |
cmchar "\big left floor bracket"; |
| 251 |
beginchar(oct"004",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 252 |
adjust_fit(1.5u#,0); left_bracket(rule_thickness,false,true); endchar; |
| 253 |
|
| 254 |
cmchar "\Big left floor bracket"; |
| 255 |
beginchar(oct"152",7.5u#,rule_thickness#,3dh#-rule_thickness#); |
| 256 |
adjust_fit(2u#,0); left_bracket(.25[rule_thickness,stem],false,true); endchar; |
| 257 |
|
| 258 |
cmchar "\bigg left floor bracket"; |
| 259 |
beginchar(oct"026",8u#,rule_thickness#,4dh#-rule_thickness#); |
| 260 |
adjust_fit(2.5u#,0); left_bracket(.5[rule_thickness,stem],false,true); endchar; |
| 261 |
|
| 262 |
cmchar "\Bigg left floor bracket"; |
| 263 |
beginchar(oct"044",8.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 264 |
adjust_fit(3u#,0); left_bracket(.75[rule_thickness,stem],false,true); endchar; |
| 265 |
|
| 266 |
cmchar "\big right floor bracket"; |
| 267 |
beginchar(oct"005",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 268 |
adjust_fit(0,1.5u#); right_bracket(rule_thickness,false,true); endchar; |
| 269 |
|
| 270 |
cmchar "\Big right floor bracket"; |
| 271 |
beginchar(oct"153",7.5u#,rule_thickness#,3dh#-rule_thickness#); |
| 272 |
adjust_fit(0,2u#); right_bracket(.25[rule_thickness,stem],false,true); endchar; |
| 273 |
|
| 274 |
cmchar "\bigg right floor bracket"; |
| 275 |
beginchar(oct"027",8u#,rule_thickness#,4dh#-rule_thickness#); |
| 276 |
adjust_fit(0,2.5u#); right_bracket(.5[rule_thickness,stem],false,true); endchar; |
| 277 |
|
| 278 |
cmchar "\Bigg right floor bracket"; |
| 279 |
beginchar(oct"045",8.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 280 |
adjust_fit(0,3u#); right_bracket(.75[rule_thickness,stem],false,true); endchar; |
| 281 |
|
| 282 |
cmchar "\big left ceiling bracket"; |
| 283 |
beginchar(oct"006",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 284 |
adjust_fit(1.5u#,0); left_bracket(rule_thickness,true,false); endchar; |
| 285 |
|
| 286 |
cmchar "\Big left ceiling bracket"; |
| 287 |
beginchar(oct"154",7.5u#,rule_thickness#,3dh#-rule_thickness#); |
| 288 |
adjust_fit(2u#,0); left_bracket(.25[rule_thickness,stem],true,false); endchar; |
| 289 |
|
| 290 |
cmchar "\bigg left ceiling bracket"; |
| 291 |
beginchar(oct"030",8u#,rule_thickness#,4dh#-rule_thickness#); |
| 292 |
adjust_fit(2.5u#,0); left_bracket(.5[rule_thickness,stem],true,false); endchar; |
| 293 |
|
| 294 |
cmchar "\Bigg left ceiling bracket"; |
| 295 |
beginchar(oct"046",8.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 296 |
adjust_fit(3u#,0); left_bracket(.75[rule_thickness,stem],true,false); endchar; |
| 297 |
|
| 298 |
cmchar "\big right ceiling bracket"; |
| 299 |
beginchar(oct"007",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 300 |
adjust_fit(0,1.5u#); right_bracket(rule_thickness,true,false); endchar; |
| 301 |
|
| 302 |
cmchar "\Big right ceiling bracket"; |
| 303 |
beginchar(oct"155",7.5u#,rule_thickness#,3dh#-rule_thickness#); |
| 304 |
adjust_fit(0,2u#); right_bracket(.25[rule_thickness,stem],true,false); endchar; |
| 305 |
|
| 306 |
cmchar "\bigg right ceiling bracket"; |
| 307 |
beginchar(oct"031",8u#,rule_thickness#,4dh#-rule_thickness#); |
| 308 |
adjust_fit(0,2.5u#); right_bracket(.5[rule_thickness,stem],true,false); endchar; |
| 309 |
|
| 310 |
cmchar "\Bigg right ceiling bracket"; |
| 311 |
beginchar(oct"047",8.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 312 |
adjust_fit(0,3u#); right_bracket(.75[rule_thickness,stem],true,false); endchar; |
| 313 |
|
| 314 |
cmchar "\big left curly brace"; |
| 315 |
beginchar(oct"010",9u#,rule_thickness#,2dh#-rule_thickness#); |
| 316 |
adjust_fit(.75u#,.75u#); left_curly(min(hair,rule_thickness),stem); endchar; |
| 317 |
|
| 318 |
cmchar "\Big left curly brace"; |
| 319 |
beginchar(oct"156",10u#,rule_thickness#,3dh#-rule_thickness#); |
| 320 |
adjust_fit(u#,u#); left_curly(rule_thickness, if hefty: stem+0.5bigdw else: .5[stem,bold] fi); endchar; |
| 321 |
|
| 322 |
cmchar "\bigg left curly brace"; |
| 323 |
beginchar(oct"032",11u#,rule_thickness#,4dh#-rule_thickness#); |
| 324 |
adjust_fit(1.25u#,1.25u#); left_curly(rule_thickness+.2dw,if hefty: stem+bigdw else: bold fi); endchar; |
| 325 |
|
| 326 |
cmchar "\Bigg left curly brace"; |
| 327 |
beginchar(oct"050",11.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 328 |
adjust_fit(1.5u#,1.5u#); left_curly(rule_thickness+.4dw, if hefty: stem+2bigdw else: bold+dw fi); endchar; |
| 329 |
|
| 330 |
cmchar "Extensible left curly brace---top"; |
| 331 |
beginchar(oct"070",12u#,0,1.5dh#); |
| 332 |
adjust_fit(2u#,2u#); pickup fine.nib; |
| 333 |
numeric min_breadth; min_breadth=hround(rule_thickness+.6dw); |
| 334 |
pos1(min_breadth,0); pos1'(min_breadth,0); |
| 335 |
pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0); |
| 336 |
rt x1r=rt x1'r=hround(w-1.5u+.5min_breadth); |
| 337 |
lft x2l=lft x3l=hround(.5w-.5heavy_rule_thickness); |
| 338 |
top y1=h-1; y3=-d-eps; y2=.5[y1,y3]; y1-y1'=min_breadth-fine; |
| 339 |
filldraw z1l{3(x2l-x1l),y2-y1}...z2l---z3l |
| 340 |
--z3r---z2r...{3(x1r-x2r),y1'-y2}z1'r--z1r--cycle; % stroke |
| 341 |
penlabels(1,2,3); endchar; |
| 342 |
|
| 343 |
cmchar "Extensible left curly brace---bottom"; |
| 344 |
beginchar(oct"072",12u#,0,1.5dh#); |
| 345 |
adjust_fit(2u#,2u#); pickup fine.nib; |
| 346 |
numeric min_breadth; min_breadth=hround(rule_thickness+.6dw); |
| 347 |
pos7(min_breadth,0); pos7'(min_breadth,0); |
| 348 |
pos5(heavy_rule_thickness,0); pos6(heavy_rule_thickness,0); |
| 349 |
rt x7r=rt x7'r=hround(w-1.5u+.5min_breadth); |
| 350 |
lft x5l=lft x6l=hround(.5w-.5heavy_rule_thickness); |
| 351 |
y5=h+eps; bot y7=1-d; y6=.5[y5,y7]; y7'-y7=min_breadth-fine; |
| 352 |
filldraw z5l---z6l...{3(x7l-x6l),y7-y6}z7l |
| 353 |
--z7r--z7'r{3(x6r-x7r),y6-y7'}...z6r---z5r--cycle; % stroke |
| 354 |
penlabels(5,6,7); endchar; |
| 355 |
|
| 356 |
cmchar "Extensible left curly brace---middle"; |
| 357 |
beginchar(oct"074",12u#,0,3dh#); |
| 358 |
adjust_fit(2u#,2u#); pickup fine.nib; |
| 359 |
numeric min_breadth; min_breadth=hround(rule_thickness+.6dw); |
| 360 |
pos4(min_breadth,0); pos4'(min_breadth,0); |
| 361 |
forsuffixes $=2,3,5,6: pos$(heavy_rule_thickness,0); endfor |
| 362 |
lft x4l=lft x4'l=hround(1.5u-.5min_breadth); |
| 363 |
x2=x3=x5=x6; lft x2l=hround(.5w-.5heavy_rule_thickness); |
| 364 |
y2=h+eps; y6=-d-eps; .5[y4,y4']=.5[y2,y6]=.5[y3,y5]; |
| 365 |
y3-y4=(y2-y6)/4; y4-y4'=min_breadth-fine; |
| 366 |
filldraw z2l---z3l...{3(x4l-x3l),y4-y3}z4l |
| 367 |
--z4'l{3(x5l-x4l),y5-y4'}...z5l---z6l--z6r---z5r |
| 368 |
...{3(x4r-x5r),.5[y4,y4']-y5}.5[z4r,z4'r]{3(x3r-x4r),y3-.5[y4,y4']} |
| 369 |
...z3r---z2r--cycle; % stroke |
| 370 |
penlabels(2,3,4,5,6); endchar; |
| 371 |
|
| 372 |
cmchar "Extensible curly brace---extension module"; |
| 373 |
beginchar(oct"076",12u#,0,.5dh#); |
| 374 |
adjust_fit(2u#,2u#); pickup fine.nib; |
| 375 |
pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0); |
| 376 |
lft x2l=lft x3l=hround(.5w-.5heavy_rule_thickness); y2=h+eps; y3=-d-eps; |
| 377 |
filldraw stroke z2e--z3e; % stem |
| 378 |
penlabels(2,3); endchar; |
| 379 |
|
| 380 |
cmchar "\big right curly brace"; |
| 381 |
beginchar(oct"011",9u#,rule_thickness#,2dh#-rule_thickness#); |
| 382 |
adjust_fit(.75u#,.75u#); right_curly(min(hair,rule_thickness),stem); endchar; |
| 383 |
|
| 384 |
cmchar "\Big right curly brace"; |
| 385 |
beginchar(oct"157",10u#,rule_thickness#,3dh#-rule_thickness#); |
| 386 |
adjust_fit(u#,u#); right_curly(rule_thickness, if hefty: stem+0.5bigdw else: .5[stem,bold] fi); endchar; |
| 387 |
|
| 388 |
cmchar "\bigg right curly brace"; |
| 389 |
beginchar(oct"033",11u#,rule_thickness#,4dh#-rule_thickness#); |
| 390 |
adjust_fit(1.25u#,1.25u#); right_curly(rule_thickness+.2dw,if hefty: stem+bigdw else: bold fi); endchar; |
| 391 |
|
| 392 |
cmchar "\Bigg right curly brace"; |
| 393 |
beginchar(oct"051",11.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 394 |
adjust_fit(1.5u#,1.5u#); right_curly(rule_thickness+.4dw, if hefty: stem+2bigdw else: bold+dw fi); endchar; |
| 395 |
|
| 396 |
cmchar "Extensible right curly brace---top"; |
| 397 |
beginchar(oct"071",12u#,0,1.5dh#); |
| 398 |
adjust_fit(2u#,2u#); pickup fine.nib; |
| 399 |
numeric min_breadth; min_breadth=hround(rule_thickness+.6dw); |
| 400 |
pos1(min_breadth,0); pos1'(min_breadth,0); |
| 401 |
pos2(heavy_rule_thickness,0); pos3(heavy_rule_thickness,0); |
| 402 |
lft x1l=lft x1'l=hround(1.5u-.5min_breadth); |
| 403 |
lft x2l=lft x3l=hround(.5w-.5heavy_rule_thickness); |
| 404 |
top y1=h-1; y3=-d-eps; y2=.5[y1,y3]; y1-y1'=min_breadth-fine; |
| 405 |
filldraw z1r{3(x2r-x1r),y2-y1}...z2r---z3r |
| 406 |
--z3l---z2l...{3(x1l-x2l),y1'-y2}z1'l--z1l--cycle; % stroke |
| 407 |
penlabels(1,2,3); endchar; |
| 408 |
|
| 409 |
cmchar "Extensible right curly brace---bottom"; |
| 410 |
beginchar(oct"073",12u#,0,1.5dh#); |
| 411 |
adjust_fit(2u#,2u#); pickup fine.nib; |
| 412 |
numeric min_breadth; min_breadth=hround(rule_thickness+.6dw); |
| 413 |
pos7(min_breadth,0); pos7'(min_breadth,0); |
| 414 |
pos5(heavy_rule_thickness,0); pos6(heavy_rule_thickness,0); |
| 415 |
lft x7l=lft x7'l=hround(1.5u-.5min_breadth); |
| 416 |
lft x5l=lft x6l=hround(.5w-.5heavy_rule_thickness); |
| 417 |
y5=h+eps; bot y7=1-d; y6=.5[y5,y7]; y7'-y7=min_breadth-fine; |
| 418 |
filldraw z5r---z6r...{3(x7r-x6r),y7-y6}z7r |
| 419 |
--z7l--z7'l{3(x6l-x7l),y6-y7'}...z6l---z5l--cycle; % stroke |
| 420 |
penlabels(5,6,7); endchar; |
| 421 |
|
| 422 |
cmchar "Extensible right curly brace---middle"; |
| 423 |
beginchar(oct"075",12u#,0,3dh#); |
| 424 |
adjust_fit(2u#,2u#); pickup fine.nib; |
| 425 |
numeric min_breadth; min_breadth=hround(rule_thickness+.6dw); |
| 426 |
pos4(min_breadth,0); pos4'(min_breadth,0); |
| 427 |
forsuffixes $=2,3,5,6: pos$(heavy_rule_thickness,0); endfor |
| 428 |
rt x4r=rt x4'r=hround(w-1.5u+.5min_breadth); |
| 429 |
x2=x3=x5=x6; lft x2l=hround(.5w-.5heavy_rule_thickness); |
| 430 |
y2=h+eps; y6=-d-eps; .5[y4,y4']=.5[y2,y6]=.5[y3,y5]; |
| 431 |
y3-y4=(y2-y6)/4; y4-y4'=min_breadth-fine; |
| 432 |
filldraw z2r---z3r...{3(x4r-x3r),y4-y3}z4r |
| 433 |
--z4'r{3(x5r-x4r),y5-y4'}...z5r---z6r--z6l---z5l |
| 434 |
...{3(x4l-x5l),.5[y4,y4']-y5}.5[z4l,z4'l]{3(x3l-x4l),y3-.5[y4,y4']} |
| 435 |
...z3l---z2l--cycle; % stroke |
| 436 |
penlabels(2,3,4,5,6); endchar; |
| 437 |
|
| 438 |
cmchar "Horizontal curly brace tip---down and left"; |
| 439 |
beginchar(oct"172",.75dh#,3rule_thickness#,0); |
| 440 |
adjust_fit(0,0); pickup fine.nib; |
| 441 |
numeric min_breadth; min_breadth=vround(rule_thickness+.6dw); |
| 442 |
pos1(min_breadth,90); pos1'(min_breadth,90); |
| 443 |
pos2(heavy_rule_thickness,90); |
| 444 |
bot y2l=0; bot y1l=bot y1'l=vround(y2-4.5u-.5min_breadth); |
| 445 |
.5[x1,x1']=-eps; x2=w+shrink_fit+eps; x1'-x1=min_breadth-fine; |
| 446 |
filldraw z1r{x2-x1,3(y2r-y1r)}...{right}z2r |
| 447 |
--z2l{left}...{x1'-x2,3(y1-y2)}z1'l--z1l--cycle; % stroke |
| 448 |
penlabels(1,2); endchar; |
| 449 |
|
| 450 |
cmchar "Horizontal curly brace tip---down and right"; |
| 451 |
beginchar(oct"173",.75dh#,3rule_thickness#,0); |
| 452 |
adjust_fit(0,0); pickup fine.nib; |
| 453 |
numeric min_breadth; min_breadth=vround(rule_thickness+.6dw); |
| 454 |
pos1(min_breadth,90); pos1'(min_breadth,90); |
| 455 |
pos2(heavy_rule_thickness,90); |
| 456 |
bot y2l=0; bot y1l=bot y1'l=vround(y2-4.5u-.5min_breadth); |
| 457 |
.5[x1,x1']=w+shrink_fit+eps; x2=-eps; x1-x1'=min_breadth-fine; |
| 458 |
filldraw z1r{x2-x1,3(y2r-y1r)}...{left}z2r |
| 459 |
--z2l{right}...{x1'-x2,3(y1-y2)}z1'l--z1l--cycle; % stroke |
| 460 |
penlabels(1,2); endchar; |
| 461 |
|
| 462 |
cmchar "Horizontal curly brace tip---up and left"; |
| 463 |
beginchar(oct"174",.75dh#,3rule_thickness#,0); |
| 464 |
adjust_fit(0,0); pickup fine.nib; |
| 465 |
numeric min_breadth; min_breadth=vround(rule_thickness+.6dw); |
| 466 |
pos1(min_breadth,90); pos1'(min_breadth,90); |
| 467 |
pos2(heavy_rule_thickness,90); |
| 468 |
bot y2l=0; top y1r=top y1'r=vround(y2+4.5u+.5min_breadth); |
| 469 |
.5[x1,x1']=-eps; x2=w+shrink_fit+eps; x1'-x1=min_breadth-fine; |
| 470 |
filldraw z1l{x2-x1,3(y2l-y1l)}...{right}z2l |
| 471 |
--z2r{left}...{x1'-x2,3(y1-y2)}z1'r--z1r--cycle; % stroke |
| 472 |
penlabels(1,2); endchar; |
| 473 |
|
| 474 |
cmchar "Horizontal curly brace tip---up and right"; |
| 475 |
beginchar(oct"175",.75dh#,3rule_thickness#,0); |
| 476 |
adjust_fit(0,0); pickup fine.nib; |
| 477 |
numeric min_breadth; min_breadth=vround(rule_thickness+.6dw); |
| 478 |
pos1(min_breadth,90); pos1'(min_breadth,90); |
| 479 |
pos2(heavy_rule_thickness,90); |
| 480 |
bot y2l=0; top y1r=top y1'r=vround(y2+4.5u+.5min_breadth); |
| 481 |
.5[x1,x1']=w+shrink_fit+eps; x2=-eps; x1-x1'=min_breadth-fine; |
| 482 |
filldraw z1l{x2-x1,3(y2l-y1l)}...{left}z2l |
| 483 |
--z2r{right}...{x1'-x2,3(y1-y2)}z1'r--z1r--cycle; % stroke |
| 484 |
penlabels(1,2); endchar; |
| 485 |
|
| 486 |
cmchar "\big left angle bracket"; |
| 487 |
beginchar(oct"012",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 488 |
adjust_fit(.75u#,.75u#); left_angle(rule_thickness); endchar; |
| 489 |
|
| 490 |
cmchar "\Big left angle bracket"; |
| 491 |
beginchar(oct"104",9u#,rule_thickness#,3dh#-rule_thickness#); |
| 492 |
adjust_fit(u#,u#); left_angle(.25[rule_thickness,stem]); endchar; |
| 493 |
|
| 494 |
cmchar "\bigg left angle bracket"; |
| 495 |
beginchar(oct"034",11u#,rule_thickness#,4dh#-rule_thickness#); |
| 496 |
adjust_fit(1.25u#,1.25u#); left_angle(.5[rule_thickness,stem]); endchar; |
| 497 |
|
| 498 |
cmchar "\Bigg left angle bracket"; |
| 499 |
beginchar(oct"052",11.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 500 |
adjust_fit(1.5u#,1.5u#); left_angle(.75[rule_thickness,stem]); endchar; |
| 501 |
|
| 502 |
cmchar "\big right angle bracket"; |
| 503 |
beginchar(oct"013",7u#,rule_thickness#,2dh#-rule_thickness#); |
| 504 |
adjust_fit(.75u#,.75u#); right_angle(rule_thickness); endchar; |
| 505 |
|
| 506 |
cmchar "\Big right angle bracket"; |
| 507 |
beginchar(oct"105",9u#,rule_thickness#,3dh#-rule_thickness#); |
| 508 |
adjust_fit(u#,u#); right_angle(.25[rule_thickness,stem]); endchar; |
| 509 |
|
| 510 |
cmchar "\bigg right angle bracket"; |
| 511 |
beginchar(oct"035",11u#,rule_thickness#,4dh#-rule_thickness#); |
| 512 |
adjust_fit(1.25u#,1.25u#); right_angle(.5[rule_thickness,stem]); endchar; |
| 513 |
|
| 514 |
cmchar "\Bigg right angle bracket"; |
| 515 |
beginchar(oct"053",11.5u#,rule_thickness#,5dh#-rule_thickness#); |
| 516 |
adjust_fit(1.5u#,1.5u#); right_angle(.75[rule_thickness,stem]); endchar; |
| 517 |
|
| 518 |
cmchar "\big slash"; |
| 519 |
beginchar(oct"016",10.4u#,rule_thickness#,2dh#-rule_thickness#); |
| 520 |
big_slash(rule_thickness+.2dw); endchar; |
| 521 |
|
| 522 |
cmchar "\Big slash"; |
| 523 |
beginchar(oct"056",14.6u#,rule_thickness#,3dh#-rule_thickness#); |
| 524 |
big_slash(rule_thickness+.6dw); endchar; |
| 525 |
|
| 526 |
cmchar "\bigg slash"; |
| 527 |
beginchar(oct"036",18.8u#,rule_thickness#,4dh#-rule_thickness#); |
| 528 |
big_slash(rule_thickness+dw); endchar; |
| 529 |
|
| 530 |
cmchar "\Bigg slash"; |
| 531 |
beginchar(oct"054",23u#,rule_thickness#,5dh#-rule_thickness#); |
| 532 |
big_slash(rule_thickness+1.5dw); endchar; |
| 533 |
|
| 534 |
cmchar "\big backslash"; |
| 535 |
beginchar(oct"017",10.4u#,rule_thickness#,2dh#-rule_thickness#); |
| 536 |
big_blash(rule_thickness+.2dw); endchar; |
| 537 |
|
| 538 |
cmchar "\Big backslash"; |
| 539 |
beginchar(oct"057",14.6u#,rule_thickness#,3dh#-rule_thickness#); |
| 540 |
big_blash(rule_thickness+.6dw); endchar; |
| 541 |
|
| 542 |
cmchar "\bigg backslash"; |
| 543 |
beginchar(oct"037",18.8u#,rule_thickness#,4dh#-rule_thickness#); |
| 544 |
big_blash(rule_thickness+dw); endchar; |
| 545 |
|
| 546 |
cmchar "\Bigg backslash"; |
| 547 |
beginchar(oct"055",23u#,rule_thickness#,5dh#-rule_thickness#); |
| 548 |
big_blash(rule_thickness+1.5dw); endchar; |
| 549 |
|
| 550 |
cmchar "Extensible vertical line---extension module"; |
| 551 |
beginchar(oct"014",6u#,0,dh#); |
| 552 |
adjust_fit(0,0); pickup pencircle scaled(rule_thickness+.2dw); |
| 553 |
x1=x2=good.x .5w; y1=eps; y2=-d-eps; |
| 554 |
draw z1--z2; % stem |
| 555 |
labels(1,2); endchar; |
| 556 |
|
| 557 |
cmchar "Extensible double vertical line---extension module"; |
| 558 |
beginchar(oct"015",10u#,0,dh#); |
| 559 |
adjust_fit(0,0); pickup pencircle scaled(rule_thickness+.2dw); |
| 560 |
x1=x2=good.x .3w; x3=x4=w-x1; y1=y3=eps; y2=y4=-d-eps; |
| 561 |
draw z1--z2; draw z3--z4; % stems |
| 562 |
labels(1,2,3,4); endchar; |
| 563 |
|
| 564 |
cmchar "Extensible vertical arrow--top"; |
| 565 |
beginchar(oct"170",12u#,0,dh#); |
| 566 |
adjust_fit(0,0); pickup crisp.nib; |
| 567 |
numeric thickness,barr; |
| 568 |
thickness=hround(rule_thickness+.2dw); barr=Vround .6[bar,thickness]; |
| 569 |
pos1(thickness,0); pos2(thickness,0); pos3(barr,90); pos4(barr,90); |
| 570 |
lft x1l=hround(.5w-.5thickness); y1=-d-eps; |
| 571 |
x0=x1=x2; top y0=h; x0-x3=x4-x0=4u+eps; |
| 572 |
y3=y4=y0-.29asc_height-eps; |
| 573 |
pos5(barr,angle(z4-z0)); z5l=z0; |
| 574 |
pos6(barr,angle(z3-z0)); z6l=z0; |
| 575 |
z9=.381966[.5[z3,z4],z0]; |
| 576 |
numeric t; path p; p=z4l{z9-z4}..z6r; |
| 577 |
t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p; |
| 578 |
filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r) |
| 579 |
--z1r--z1l--subpath (t,0) of\\(z3l{z9-z3}..z5r) |
| 580 |
--z3r{z9-z3}..z0 & cycle; % arrowhead and stem |
| 581 |
penlabels(0,1,2,3,4,5,6,9); endchar; |
| 582 |
|
| 583 |
cmchar "Extensible vertical arrow--bottom"; |
| 584 |
beginchar(oct"171",12u#,0,dh#); |
| 585 |
adjust_fit(0,0); pickup crisp.nib; |
| 586 |
numeric thickness,barr; |
| 587 |
thickness=hround(rule_thickness+.2dw); barr=Vround .6[bar,thickness]; |
| 588 |
pos1(thickness,0); pos2(thickness,0); pos3(barr,90); pos4(barr,90); |
| 589 |
lft x1l=hround(.5w-.5thickness); y1=h+eps; |
| 590 |
x0=x1=x2; bot y0=-d; x0-x3=x4-x0=4u+eps; |
| 591 |
y3=y4=y0+.29asc_height+eps; |
| 592 |
pos5(barr,angle(z4-z0)); z5l=z0; |
| 593 |
pos6(barr,angle(z3-z0)); z6l=z0; |
| 594 |
z9=.381966[.5[z3,z4],z0]; |
| 595 |
numeric t; path p; p=z4r{z9-z4}..z6r; |
| 596 |
t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p; |
| 597 |
filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r) |
| 598 |
--z1r--z1l--subpath (t,0) of\\(z3r{z9-z3}..z5r) |
| 599 |
--z3l{z9-z3}..z0 & cycle; % arrowhead and stem |
| 600 |
penlabels(0,1,2,3,4,5,6,9); endchar; |
| 601 |
|
| 602 |
cmchar "Extensible vertical arrow--extension module"; |
| 603 |
beginchar(oct"077",12u#,0,dh#); |
| 604 |
adjust_fit(0,0); pickup crisp.nib; |
| 605 |
numeric thickness; thickness=hround(rule_thickness+.2dw); |
| 606 |
pos1(thickness,0); pos2(thickness,0); |
| 607 |
lft x1l=hround(.5w-.5thickness); x2=x1; y1=h+1+eps; y2=-d-1-eps; |
| 608 |
filldraw stroke z1e--z2e; % stem |
| 609 |
penlabels(1,2); endchar; |
| 610 |
|
| 611 |
cmchar "Extensible double vertical arrow--top"; |
| 612 |
beginchar(oct"176",14u#,0,dh#); |
| 613 |
adjust_fit(0,0); pickup crisp.nib; |
| 614 |
numeric thickness; thickness=Vround(rule_thickness+.2dw); |
| 615 |
pos1(thickness,0); pos2(thickness,0); pos7(thickness,0); pos8(thickness,0); |
| 616 |
y1=y2=-d-eps; y7=y8=h; top y0=h+eps; x1=x7; x2=x8; |
| 617 |
rt x1r=hround(.5w+2u+.5thickness); .5[x1,x2]=x0=good.x .5w; |
| 618 |
filldraw stroke z1e--z7e; filldraw stroke z2e--z8e; % bars |
| 619 |
pos3(thickness,90); pos4(thickness,90); |
| 620 |
x2-x3=x4-x1=4u+eps; y3=y4=y0-.48asc_height-eps; |
| 621 |
pos5(thickness,angle(z4-z0)); z5l=z0; |
| 622 |
pos6(thickness,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0]; |
| 623 |
erase filldraw z0..{z3-z9}z3--(x3,h) |
| 624 |
--(x4,h)--z4{z9-z4}..z0 & cycle; % erase excess |
| 625 |
numeric t; path p; p=z4l{z9-z4}..z6r; |
| 626 |
t=xpart(p intersectiontimes((x0,-d)--(x0,h))); |
| 627 |
filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r) |
| 628 |
--subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle; % arrowhead |
| 629 |
penlabels(0,1,2,3,4,5,6,7,8,9); endchar; |
| 630 |
|
| 631 |
cmchar "Extensible double vertical arrow--bottom"; |
| 632 |
beginchar(oct"177",14u#,0,dh#); |
| 633 |
adjust_fit(0,0); pickup crisp.nib; |
| 634 |
numeric thickness; thickness=Vround(rule_thickness+.2dw); |
| 635 |
pos1(thickness,0); pos2(thickness,0); pos7(thickness,0); pos8(thickness,0); |
| 636 |
y1=y2=h+eps; y7=y8=-d; bot y0=-d-eps; x1=x7; x2=x8; |
| 637 |
rt x1r=hround(.5w+2u+.5thickness); .5[x1,x2]=x0=good.x .5w; |
| 638 |
filldraw stroke z1e--z7e; filldraw stroke z2e--z8e; % bars |
| 639 |
pos3(thickness,90); pos4(thickness,90); |
| 640 |
x2-x3=x4-x1=4u+eps; y3=y4=y0+.48asc_height-eps; |
| 641 |
pos5(thickness,angle(z4-z0)); z5l=z0; |
| 642 |
pos6(thickness,angle(z3-z0)); z6l=z0; z9=.381966[.5[z3,z4],z0]; |
| 643 |
erase filldraw z0..{z3-z9}z3--(x3,-d) |
| 644 |
--(x4,-d)--z4{z9-z4}..z0 & cycle; % erase excess |
| 645 |
numeric t; path p; p=z4r{z9-z4}..z6r; |
| 646 |
t=xpart(p intersectiontimes((x0,-d)--(x0,h))); |
| 647 |
filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r) |
| 648 |
--subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle; % arrowhead |
| 649 |
penlabels(0,1,2,3,4,5,6,7,8,9); endchar; |
| 650 |
|
| 651 |
cmchar "Extensible double vertical arrow--extension module"; |
| 652 |
beginchar(oct"167",14u#,0,dh#); |
| 653 |
adjust_fit(0,0); pickup crisp.nib; |
| 654 |
numeric thickness; thickness=Vround(rule_thickness+.2dw); |
| 655 |
pos1(thickness,0); pos2(thickness,0); pos7(thickness,0); pos8(thickness,0); |
| 656 |
y1=y2=h+1+eps; y7=y8=-d-1-eps; x1=x7; x2=x8; |
| 657 |
rt x1r=hround(.5w+2u+.5thickness); .5[x1,x2]=good.x .5w; |
| 658 |
filldraw stroke z1e--z7e; filldraw stroke z2e--z8e; % bars |
| 659 |
penlabels(1,2,7,8); endchar; |
| 660 |
|
| 661 |
cmchar "\big radical sign"; |
| 662 |
beginchar(oct"160",18u#,rule_thickness#,2dh#-rule_thickness#); |
| 663 |
big_sqrt; endchar; |
| 664 |
|
| 665 |
cmchar "\Big radical sign"; |
| 666 |
beginchar(oct"161",18u#,rule_thickness#,3dh#-rule_thickness#); |
| 667 |
big_sqrt; endchar; |
| 668 |
|
| 669 |
cmchar "\bigg radical sign"; |
| 670 |
beginchar(oct"162",18u#,rule_thickness#,4dh#-rule_thickness#); |
| 671 |
big_sqrt; endchar; |
| 672 |
|
| 673 |
cmchar "\Bigg radical sign"; |
| 674 |
beginchar(oct"163",18u#,rule_thickness#,5dh#-rule_thickness#); |
| 675 |
big_sqrt; endchar; |
| 676 |
|
| 677 |
cmchar "Extensible radical sign---bottom"; |
| 678 |
beginchar(oct"164",19u#,0,3dh#); |
| 679 |
adjust_fit(0,-letter_fit#); pickup rule.nib; |
| 680 |
x1=x2=good.x(w-6u); bot y1=1-d; y2=h+eps; |
| 681 |
draw z1--z2; % diagonal |
| 682 |
pickup crisp.nib; pos3(max(curve,rule_thickness),0); |
| 683 |
x3l=good.x 3u; y3=.9[y1,y2]; |
| 684 |
pos4(rule_thickness,0); x4=x1; bot y4=-d; |
| 685 |
pos5(vair,-45); x5l=good.x(x3l-u); z5l=whatever[z3r,(x2,body_height)]; |
| 686 |
z6=z5r+whatever*((x2,body_height)-z3r)=whatever[z3l,z4l]; |
| 687 |
z7=whatever[z1,z2]=z3r+whatever*(z4l-z3l); |
| 688 |
filldraw z5r--z6--z4l--z4--z7--z3r--z5l--cycle; % left diagonal and serif |
| 689 |
penlabels(1,2,3,4,5,6,7); endchar; |
| 690 |
|
| 691 |
cmchar "Extensible radical sign---extension module"; |
| 692 |
beginchar(oct"165",19u#,0,dh#); |
| 693 |
adjust_fit(0,-letter_fit#); pickup rule.nib; |
| 694 |
x1=x2=good.x(w-6u); y1=-d-eps; y2=h+eps; |
| 695 |
draw z1--z2; % stem |
| 696 |
labels(1,2); endchar; |
| 697 |
|
| 698 |
cmchar "Extensible radical sign---top"; |
| 699 |
beginchar(oct"166",19u#,rule_thickness#,dh#-rule_thickness#); |
| 700 |
adjust_fit(0,-letter_fit#); pickup rule.nib; |
| 701 |
x1=x2=good.x(w-6u); x3=good.x(w+.5); y1=-d-eps; bot y2=bot y3=0; |
| 702 |
draw z1--z2--z3; % stem and link |
| 703 |
labels(1,2,3); endchar; |