Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/ttsymbol.mf

raw
1 % ttsymbol.mf
2 %
3 % (c) Copyright 1995, 1996, 1997 J"org Knappen
4 % (c) Copyright 2000 J"org Knappen, Walter Schmidt
5 %
6 % This file is part of the CM bright fonts v1.0f
7 %
8 % Miscellaneous symbols for the TS1 encoding,
9 % to be used for the `Typewriter Light' typefaces.
10 %
11 % Heavily borrowing from existent fonts, like Computer Modern, AMS symbols
12 % and wasy symbols
13
14 version_check(1,0); % |version_check| was introduced in dc1.3
15
16 ecchar"Single straight base quote"; % jk
17 beginchar(oct"015",7u#,asc_height#,0);
18 numeric shifth_down;
19 adjust_fit(0,0);
20 x1=x2=.5w;
21 y2=max(.5[bar_height,x_height]+.5vair,h-x_height)-the_shift;
22 if serifs:
23 y1=flare/2; the_shift=h-.5stem-y1;
24 pickup crisp.nib;
25 pos1(flare,0); pos2(vair,0);
26 filldraw circ_stroke (z1e--z2e); % stem and bulb
27 else:
28 top y1=stem; the_shift=h-y1;
29 pickup fine.nib;
30 pos1(stem,0); pos2(vair,0);
31 filldraw stroke z1e--z2e; % stem
32 fi
33 charht:=dot_size#; chardp:=desc_depth#;
34 penlabels(1,2,3,4);
35 endchar;
36
37 ecchar"Double straight base quotes"; % from pl_cud (plfonts)
38 beginchar(oct"022",9u#,asc_height#,0);
39 numeric top_width#,spread#,shifth_down;
40 top_width#=if serifs: flare# else: stem# fi;
41 spread#=max(3u#,top_width#+.5u#); define_pixels(spread);
42 adjust_fit(0,0);
43 numeric the_shift;
44 x1=x2; x3=x4=w-x1; x3-x1=spread+2; y1=y3;
45 y2=y4=max(.5[bar_height,x_height]+.5vair,h-x_height)-the_shift;
46 if serifs:
47 y1=flare/2; the_shift=h-.5stem-y1;
48 pickup crisp.nib;
49 pos1(flare,0); pos2(vair,0); pos3(flare,0); pos4(vair,0);
50 filldraw circ_stroke (z1e--z2e); % left stem and bulb
51 filldraw circ_stroke (z3e--z4e); % right stem and bulb
52 else:
53 top y1=stem; the_shift=h-y1;
54 pickup fine.nib;
55 pos1(stem,0); pos2(vair,0); pos3(stem,0); pos4(vair,0);
56 filldraw stroke z1e--z2e; % left stem
57 filldraw stroke z3e--z4e; % right stem
58 fi
59 charht:=dot_size#; chardp:=desc_depth#;
60 penlabels(1,2,3,4);
61 endchar;
62
63 ecchar "twelve u dash";
64 beginchar(oct"025",12u#,x_height#,0);
65 italcorr .61803x_height#*slant+.5u#;
66 adjust_fit(letter_fit#,letter_fit#);
67 pickup crisp.nib; pos1(vair,90); pos2(vair,90);
68 top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
69 filldraw stroke z1e--z2e; % bar
70 penlabels(1,2); endchar;
71
72 ecchar "three quarters em dash";
73 beginchar(oct"026",13.5u#,x_height#,0);
74 italcorr .61803x_height#*slant+.5u#;
75 adjust_fit(letter_fit#,letter_fit#);
76 pickup crisp.nib; pos1(vair,90); pos2(vair,90);
77 top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
78 filldraw stroke z1e--z2e; % bar
79 penlabels(1,2); endchar;
80
81 ecchar "Capital compound word mark";
82 beginchar(oct"027",0,cap_height#,0);
83 zero_width;
84 endchar;
85
86 ecchar "Leftward arrow"; % from sym.mf (cmfonts)
87 compute_spread(.45x_height#,.55x_height#);
88 beginchar(oct"030",18u#,v_center(spread#+rule_thickness#));
89 adjust_fit(0,0); pickup crisp.nib;
90 pos1(rule_thickness,90); pos2(rule_thickness,90);
91 pos3(rule_thickness,0); pos4(rule_thickness,0);
92 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft x0=hround u;
93 y3-y0=y0-y4=if monospace:.24 else:.36 fi asc_height+eps;
94 x3=x4=x0+if monospace:3u else:4u fi+eps;
95 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
96 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
97 z9=.2[.5[z3,z4],z0];
98 numeric t; path p; p=z4r{z9-z4}..z6r;
99 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
100 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
101 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
102 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
103 penlabels(0,1,2,3,4,5,6,9); endchar;
104
105 ecchar "Rightward arrow"; % from sym.mf (cmfonts)
106 compute_spread(.45x_height#,.55x_height#);
107 beginchar(oct"031",18u#,v_center(spread#+rule_thickness#));
108 adjust_fit(0,0); pickup crisp.nib;
109 pos1(rule_thickness,90); pos2(rule_thickness,90);
110 pos3(rule_thickness,0); pos4(rule_thickness,0);
111 y0=y1=y2=math_axis; x1-.5rule_thickness=hround u; rt x0=hround(w-u);
112 y3-y0=y0-y4=if monospace:.24 else:.36 fi asc_height+eps;
113 x3=x4=x0-if monospace:3u else:4u fi-eps;
114 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
115 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
116 z9=.2[.5[z3,z4],z0];
117 numeric t; path p; p=z4l{z9-z4}..z6r;
118 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
119 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
120 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
121 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
122 penlabels(0,1,2,3,4,5,6,9); endchar;
123
124 ecchar"Tie accent"; % from italms (cmfonts)
125 beginchar(oct"032",5u#,asc_height#,0);
126 italcorr 4/9[x_height#,asc_height#]*slant+4.5u#+2letter_fit#+.5hair#;
127 adjust_fit(if monospace:2u#,2u# else:serif_fit#,serif_fit# fi);
128 pickup fine.nib; pos1(hair,180); pos2(vround 1/5[vair,stem],90);
129 pos3(hair,0);
130 lft x1r=hround(.5w-.5hair); x2=.5[x1,x3];
131 rt x3r=hround(w+4u+2letter_fit+.5hair);
132 y1=y3=4/9[x_height,asc_height]; top y2r=vround 8/9[x_height,asc_height];
133 filldraw stroke super_arc.e(1,2) & super_arc.e(2,3); % arc
134 penlabels(1,2,3); endchar;
135
136 ecchar"New tie accent"; % centered
137 beginchar(oct"034",9u#,asc_height#,0);
138 italcorr 4/9[x_height#,asc_height#]*slant+4.5u#+2letter_fit#+.5hair#;
139 adjust_fit(if monospace:2u#,2u# else:serif_fit#,serif_fit# fi);
140 pickup fine.nib; pos1(hair,180); pos2(vround 1/5[vair,stem],90);
141 pos3(hair,0);
142 lft x1r=w-rt x3r=hround(2u-.5vair); x2=.5w;
143 y1=y3=4/9[x_height,asc_height]; top y2r=vround 8/9[x_height,asc_height];
144 filldraw stroke super_arc.e(1,2) & super_arc.e(2,3); % arc
145 penlabels(1,2,3); endchar;
146
147 ecchar "Ascender height compound word mark";
148 beginchar(oct"037",0,asc_height#,0);
149 zero_width;
150 endchar;
151
152 iff not variant_g: % not italic
153 ecchar"Blank symbol"; % jk
154 beginchar(oct"040",10u#+serif_fit#,asc_height#,0);
155 italcorr .5x_height#*slant+min(.5curve#-u#,-.25u#);
156 adjust_fit(serif_fit#,0);
157 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
158 pos0'(stem',0); pos0(stem,0); z0l=z0'l; x0'=x1; x0=x2;
159 lft x1l=hround(2.5u-.5stem'); top y1=h;
160 numeric edge; edge=rt x2r;
161 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
162 pos4(vair,90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
163 rt x3l=max(rt x3l-(lft x3r-tiny.lft x2l),1/3[rt x2,edge]);
164 y3=1/8[bar_height,x_height];
165 x4l=w-.5(w-serif_fit)+.5u; top y4r=x_height+oo;
166 rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
167 x6l=x4l-.2u; bot y6r=-oo;
168 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
169 (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x4,x5r]);
170 (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x6,x5r]);
171 filldraw stroke z3e{up}...pulled_arc.e(4,5)&pulled_arc.e(5,6)...{up}z7e; % bowl
172 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
173 y2=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{left}...{up}z7l));
174 pickup tiny.nib; filldraw stroke z1e--z0'e--z0e--z2e; % stem
175 pickup crisp.nib; pos8(hair,0); pos7'(stem,0);
176 z7'=z2; x8l=x7'l; bot y8=0;
177 filldraw stroke z7'e--z8e; % point
178 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); fi % upper serif
179 put_cross(.5stem+if serifs: .9max(limit_dist,jut) else: 1.8u fi,.5stem+3u);
180 penlabels(0,1,2,3,4,5,6,7,8); endchar;
181
182 iff variant_g: % italic
183 ecchar"Blank symbol"; % jk
184 beginchar(oct"040",8u#,asc_height#,0);
185 italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
186 adjust_fit(0,0); pickup tiny.nib;
187 pos1(stem,0); pos2(stem,0); x1=x2;
188 lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_height;
189 filldraw stroke z1e--z2e; % stem
190 sloped_serif.l(1,2,a,1/3,jut,serif_drop); % serif
191 pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
192 pos4(curve,0); pos5(vair,90); pos0(hair,180);
193 z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
194 bot y3r=-oo; top y5r=x_height+oo; y4=y2;
195 filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
196 & pulled_arc.e(4,5) & super_arc.e(5,0); % bowl
197 math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
198 put_cross(.5stem+if serifs: .9max(limit_dist,jut) else: 1.8u fi,.5stem+3u);
199 penlabels(0,1,2,3,4,5); endchar;
200
201 ecchar"Dollar sign"; % from romanp (cm)
202 beginchar("$",9u#,body_height#,body_height#-asc_height#);
203 italcorr fig_height#*slant-.5u#; % same as for digits
204 adjust_fit(0,0);
205 numeric theta; theta=90-angle(50u,asc_height); slope:=-asc_height/50u;
206 pickup fine.nib; pos2(slab,-90);
207 pos0(cap_stem,theta); pos7(slab,-90);
208 x2=x0=x7=.5w; top y2l=asc_height+oo; bot y7r=-oo;
209 y0=.52asc_height; lft x3l=hround u; rt x6r=hround(w-u);
210 x3r-x3l=x6r-x6l=hround .35[slab,cap_stem]-fine;
211 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
212 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
213 filldraw stroke super_arc.e(2,3) & z3e{down}
214 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
215 if serifs: pos1(hair,0); pos8(hair,180);
216 pos10(flare,0); pos9(flare,180);
217 rt x1r=hround(w-u); lft x8r=hround u; y1=.5[y0,y2]; y8=.5[y0,y7];
218 {{less_tense; pos2'(slab,90); z2'=z2; bulb(2',1,10); % upper arc and bulb
219 bulb(7,8,9)}}; % lower arc and bulb
220 else: pos1(.6[slab,flare],-100); pos8(flare,-100);
221 rt x1l=hround(w-1.3u); lft x8r=hround .8u;
222 top y1l=vround .92asc_height+oo; bot y8r=vround .1asc_height-oo;
223 filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
224 filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
225 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
226 lft x12l=lft x11l=hround(.5w-.5bar); top y12=h; bot y11=-d;
227 filldraw stroke z12e--z11e; % vertical crossbar
228 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12); endchar;
229
230
231 ecchar "Straight single quote"; % from romsub (cm)
232 beginchar(oct"047",5u#,asc_height#,0);
233 italcorr asc_height#*slant+.5 if serifs: flare# else: stem# fi -2u#;
234 adjust_fit(0,0);
235 x1=x2=.5w; y2=max(.5[bar_height,x_height]+.5vair,h-x_height);
236 if serifs: pickup crisp.nib; pos1(flare,0); pos2(vair,0);
237 y1+.5stem=h; filldraw circ_stroke z1e--z2e; % stem and bulb
238 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
239 top y1=h; filldraw stroke z1e--z2e; fi % stem
240 penlabels(1,2); endchar;
241
242 ecchar "Comma";
243 beginchar(",",5u#,pdot_diam#,comma_depth#);
244 adjust_fit(0,0);
245 x1-.5pdot_diam=hround(.5w-.5pdot_diam); y1-.5pdot_diam=0;
246 comma(1,a,pdot_diam,.2u,comma_depth); % dot and tail
247 penlabels(1); endchar;
248
249 ecchar "Double hyphen or short equals sign"; % jk
250 compute_spread(.45x_height#,.55x_height#);
251 beginchar(oct"055",6u#,v_center(spread#+rule_thickness#));
252 italcorr h#*slant-.5u#;
253 adjust_fit(0,0);
254 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
255 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
256 pos3(thickness,90); pos4(thickness,90);
257 y1=y2; y3=y4;
258 top y1=vround .5h+.5thickness+.5spread;
259 top y3=vround .5h+.5thickness-.5spread;
260 rt x2=hround(w-u)+eps;
261 if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
262 x3=x1; x4=x2;
263 filldraw stroke z1e--z2e; % upper bar
264 filldraw stroke z3e--z4e; % lower bar
265 penlabels(1,2,3,4); endchar;
266
267 ecchar "Period";
268 beginchar(".",5u#,pdot_diam#,0);
269 adjust_fit(0,0); pickup fine.nib;
270 pos1(pdot_diam,0); pos2(pdot_diam,90);
271 lft x1l=hround(.5w-.5pdot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
272 penlabels(1,2); endchar;
273
274 ecchar "Asterisk at the axis"; % from mathsy
275 beginchar(oct"052",9u#,v_center(x_height#));
276 adjust_fit(0,0);
277 numeric ast_flare; ast_flare=hround .7[thin_join,stem];
278 x0=.5w; y0=h-.5x_height;
279 for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
280 numeric theta; theta=angle(z[d]-z0);
281 fill z0+.5(0,-thin_join)rotated theta
282 ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
283 ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
284 ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
285 labels(0,[-150],[-90],[-30],30,90,150); endchar;
286
287 ecchar "Fraction"; % from punct (cm)" Virgule (slash)"
288 beginchar("/",9u#,body_height#,paren_depth#);
289 italcorr body_height#*slant-.5u#;
290 adjust_fit(0,0); pickup rule.nib;
291 rt x1=hround(w-u)+eps; top y1=h+eps;
292 lft x2=hround u-eps; bot y2=-d-eps;
293 draw z1--z2; % diagonal
294 penlabels(1,2); endchar;
295
296 ecchar "Left angle bracket";
297 beginchar(oct"074",7u#,body_height#,paren_depth#);
298 adjust_fit(0,0); pickup rule.nib;
299 rt x1=hround(w-u)+eps; x1=x3; lft x2=hround 2u-1-eps;
300 top y1=h+eps; .5[y1,y3]=y2=math_axis;
301 draw z1--z2--z3; % diagonals
302 labels(1,2,3); endchar;
303
304 ecchar "Minus sign";
305 beginarithchar("="); pickup extra_rule.nib;
306 lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
307 draw z3--z4; % crossbar
308 labels(1,2,3,4); endchar;
309
310 ecchar "Right angle bracket";
311 beginchar(oct"076",7u#,body_height#,paren_depth#);
312 adjust_fit(0,0); pickup rule.nib;
313 rt(w-x1)=hround(w-u)+eps; x1=x3; lft(w-x2)=hround 2u-1-eps;
314 top y1=h+eps; .5[y1,y3]=y2=math_axis;
315 draw z1--z2--z3; % diagonals
316 labels(1,2,3); endchar;
317
318 ecchar"Mho sign (turned Omega)"; % from lasy
319 beginchar(oct"115",13u#,cap_height#,0);
320 italcorr cap_height#*slant-.35u#; %italcorr .75cap_height#*slant-.5u#;
321 adjust_fit(0,0);
322 pickup tiny.nib; pos1(vair,-90); pos2(cap_curve,0);
323 pos3(vair,0); pos4(cap_curve,180); pos5(vair,180);
324 x1=.5w; bot y1r=0-o; lft x4r=hround u; y2=y4=1/3h; x2=w-x4;
325 rt x5l=hround(1/3(w+.5u)+.5hair); top y3=top y5=h; x3=w-x5;
326 filldraw stroke z3e{down}...{down}z2e
327 & pulled_super_arc.e(2,1)(.5superpull)
328 & pulled_super_arc.e(1,4)(.5superpull)
329 & z4e{up}...{up}z5e; % bowl
330 numeric arm_thickness; path p; p=z3{down}...{down}z2;
331 arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
332 pickup crisp.nib; pos6(arm_thickness,90); pos7(fudged.hair,0);
333 top y6r=h; x6=x3; rt x7r=hround (w-.8u); y7=good.y(y6l-.5beak)+eps;
334 (x,y)=p intersectionpoint((0,y6l)--(w+h,y6l)); x6l:=x;
335 arm(6,7,a,.5beak_darkness,1.2beak_jut); % right arm and beak
336 pos8(arm_thickness,90); pos9(fudged.hair,180);
337 y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
338 arm(8,9,b,.5beak_darkness,-1.2beak_jut); % left arm and beak
339 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
340
341 ecchar"Big circle for copyright, etc";
342 beginchar("O",20u#,body_height#,max(paren_depth#,desc_depth#)); autorounded;
343 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
344 if .5w <> good.x .5w: change_width; fi
345 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
346 circle_points; draw_circle; % circle
347 labels(1,2,3,4,5,6,7,8); endchar;
348
349 ecchar"Ohm sign (ISO 6937)"; % from greeku (cmfonts)
350 beginchar(oct"127",13u#,cap_height#,0);
351 italcorr .75cap_height#*slant-.5u#;
352 adjust_fit(0,0);
353 pickup tiny.nib; pos1(vair,90); pos2(cap_curve,180);
354 pos3(vair,180); pos4(cap_curve,0); pos5(vair,0);
355 x1=.5w; top y1r=h+o; lft x2r=hround u; y2=y4=2/3h; x4=w-x2;
356 rt x3l=hround(1/3(w+.5u)+.5hair); bot y3=bot y5=0; x5=w-x3;
357 filldraw stroke z3e{up}...{up}z2e
358 & pulled_super_arc.e(2,1)(.5superpull)
359 & pulled_super_arc.e(1,4)(.5superpull)
360 & z4e{down}...{down}z5e; % bowl
361 numeric arm_thickness; path p; p=z3{up}...{up}z2;
362 arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
363 pickup crisp.nib; pos6(arm_thickness,-90); pos7(fudged.hair,-180);
364 bot y6r=0; x6=x3; lft x7r=hround .8u; y7=good.y(y6l+.5beak)+eps;
365 (x,y)=p intersectionpoint((0,y6l)--(w,y6l)); x6l:=x;
366 arm(6,7,a,.5beak_darkness,-1.2beak_jut); % left arm and beak
367 pos8(arm_thickness,-90); pos9(fudged.hair,0);
368 y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
369 arm(8,9,b,.5beak_darkness,1.2beak_jut); % right arm and beak
370 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
371
372 ecchar"Musical note (one eigth note)"; % jk
373 beginchar("n",11u#,asc_height#,0);
374 pickup rule.nib;
375 x1=3/5w; x2=x1; top y1=h; bot y2=.5bar_height;
376 lft x3=u; x5= x2; x4=x6=.5[x3,x5];
377 y3=y5=vround(.5bar_height); y4=y6-bar_height=-oo;
378 x7=x1; rt x9=w-u; x8=.5[x7,x9];
379 y7=y1; bot y9=vround(.5bar_height); y8=.5[y7,y9];
380 draw z1--z2; % stem
381 filldraw z3{down}...z4{right}...z5{up}...z6{left}...cycle; % body
382 draw z7{down}...z8...{down}z9; % flag
383 endchar;
384
385 ecchar "Left semantic bracket"; % [[ from stmaryrd
386 beginchar(oct"133",7.25u#,body_height#,paren_depth#);
387 adjust_fit(0,0);
388 pickup crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
389 top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5rule_thickness)-1-eps;
390 filldraw stroke z1e--z2e; % left stem
391 pos7(rule_thickness,0); pos8(rule_thickness,0);
392 top y7=h; bot y8=-d; lft x7l=lft x8l=hround(4.75u-.5rule_thickness)-1-eps;
393 filldraw stroke z7e--z8e; % right stem
394 pos3(rule_thickness,90); pos4(rule_thickness,90);
395 pos5(rule_thickness,90); pos6(rule_thickness,90);
396 x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
397 filldraw stroke z3e--z4e; % upper bar
398 filldraw stroke z5e--z6e; % lower bar
399 penlabels(1,2,3,4,5,6,7,8); endchar;
400
401
402 ecchar "Right semantic bracket"; % ]] from stmaryrd
403 beginchar(oct"135",7.25u#,body_height#,paren_depth#);
404 adjust_fit(0,0);
405 pickup crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
406 top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5rule_thickness)+1+eps;
407 filldraw stroke z1e--z2e; % left stem
408 pos7(rule_thickness,0); pos8(rule_thickness,0);
409 top y7=h; bot y8=-d; rt x7r=rt x8r=hround(w-4.75u+.5rule_thickness)+1+eps;
410 filldraw stroke z7e--z8e; % right stem
411 pos3(rule_thickness,90); pos4(rule_thickness,90);
412 pos5(rule_thickness,90); pos6(rule_thickness,90);
413 x3=x5=x1l; lft x4=lft x6=ceiling(.4u)-eps; y3r=y4r=y1; y5l=y6l=y2;
414 filldraw stroke z3e--z4e; % upper bar
415 filldraw stroke z5e--z6e; % lower bar
416 penlabels(1,2,3,4,5,6,7,8); endchar;
417
418 ecchar "Upward arrow"; % from sym
419 beginchar(oct"136",9u#,asc_height#,asc_depth#);
420 italcorr .76asc_height#*slant+.5crisp#-u#;
421 adjust_fit(0,0); pickup crisp.nib;
422 pos1(rule_thickness,0); pos2(rule_thickness,0);
423 pos3(rule_thickness,90); pos4(rule_thickness,90);
424 lft x1l=hround(.5w-.5rule_thickness); y1-.5rule_thickness=-d;
425 x0=x1=x2; top y0=h; x0-x3=x4-x0=if monospace:3u else:4u fi+eps;
426 y3=y4=y0-if monospace:.24 else:.36 fi asc_height-eps;
427 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
428 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
429 z9=.2[.5[z3,z4],z0];
430 %numeric t; path p; p=z4l{z9-z4}..z6r;
431 numeric t; path p; p=z4l{z9-z4}..z6l;
432 t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
433 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
434 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3l{z9-z3}..z5r)
435 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
436 penlabels(0,1,2,3,4,5,6,9); endchar;
437
438 ecchar "Downward arrow"; % from sym
439 beginchar(oct"137",9u#,asc_height#,asc_depth#);
440 adjust_fit(0,0); pickup crisp.nib;
441 pos1(rule_thickness,0); pos2(rule_thickness,0);
442 pos3(rule_thickness,90); pos4(rule_thickness,90);
443 lft x1l=hround(.5w-.5rule_thickness); y1+.5rule_thickness=h;
444 x0=x1=x2; bot y0=-d; x0-x3=x4-x0=if monospace:3u else:4u fi+eps;
445 y3=y4=y0+if monospace:.24 else:.36 fi asc_height+eps;
446 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
447 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
448 z9=.2[.5[z3,z4],z0];
449 numeric t; path p; p=z4r{z9-z4}..z6r;
450 %t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
451 t=xpart(p intersectiontimes((x2l,-d)--(x2l,h))); y2=ypart point t of p;
452 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
453 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
454 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
455 penlabels(0,1,2,3,4,5,6,9); endchar;
456
457 ecchar"Backwards tick mark"; % from accent (cmfonts, grave accent)
458 beginchar(oct"140",9u#,min(asc_height#,2x_height#),0);
459 adjust_fit(0,0);
460 if serifs: pickup crisp.nib; x1-.5stem=hround 2u; x2=2/3[x1,w-x1];
461 y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
462 numeric theta; theta=angle(z2-z1)+90;
463 pos1(stem,theta); pos2(hair,theta);
464 filldraw circ_stroke z1e--z2e; % diagonal
465 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
466 lft x1l=hround 1.5u; rt x2r=hround(.5w+.25u+.5vair);
467 top y1=h; bot y2=vround 2/3[h,x_height];
468 filldraw stroke z1e--z2e; fi % diagonal
469 penlabels(1,2); endchar;
470
471 ecchar "Low lying tilde (squiggle)";
472 beginchar(oct"176",11u#,min(bar_height#,2/7x_height#),0);
473 italcorr h#*slant-u#;
474 adjust_fit(0,0);
475 if serifs: numeric theta;
476 theta=angle(1/8(7u if monospace: /expansion_factor fi-vair),1/4acc_height);
477 % theta=angle(1/6(6u-vair),1/4h);
478 pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
479 pos1(vair,theta+90); pos2(vair,theta+90);
480 pos3(vair,theta+90); pos4(vair,theta+90);
481 z2-z1=z4-z3=(mid_width-crisp)*dir theta;
482 lft x1r=w-rt x4l=hround 1.5u; top y4r=h;
483 bot y1l=0;
484 pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
485 filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
486 --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
487 else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
488 pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
489 lft x1r=w-rt x5l=hround 1.5u; x2-x1=x3-x2=x4-x3=x5-x4;
490 bot y1=bot y4l=0;
491 top y2r=top y5=h; y3=.5[y2,y4];
492 filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
493 penlabels(1,2,3,4,5); endchar;
494
495 iff not monospace:
496 ecchar "Double hyphen-hyphenchar"; % jk
497 compute_spread(.45x_height#,.55x_height#);
498 beginchar(oct"177",3u#,v_center(spread#+rule_thickness#));
499 italcorr h#*slant-.5u#;
500 adjust_fit(0,0);
501 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
502 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
503 pos3(thickness,90); pos4(thickness,90);
504 y1=y2; y3=y4;
505 top y1=vround .5h+.5thickness+.5spread;
506 top y3=vround .5h+.5thickness-.5spread;
507 rt x2=hround(2w-u)+eps;
508 lft x1=hround .2u-eps;
509 x3=x1; x4=x2;
510 filldraw stroke z1e--z2e; % upper bar
511 filldraw stroke z3e--z4e; % lower bar
512 penlabels(1,2,3,4); endchar;
513
514 iff monospace:
515 ecchar "Double hyphen-hyphenchar"; % jk
516 compute_spread(.45x_height#,.55x_height#);
517 beginchar(oct"177",6u#,v_center(spread#+rule_thickness#));
518 italcorr h#*slant-.5u#;
519 adjust_fit(0,0);
520 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
521 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
522 pos3(thickness,90); pos4(thickness,90);
523 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
524 rt x2=hround(w-u)+eps;
525 if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
526 x3=x1; x4=x2;
527 filldraw stroke z1e--z2e; % upper bar
528 filldraw stroke z3e--z4e; % lower bar
529 penlabels(1,2,3,4); endchar;
530
531 ecchar"Breve";
532 beginchar(oct"200",11u#,min(asc_height#,2x_height#),0);
533 italcorr h#*slant+.5vair#-1.5u#;
534 adjust_fit(0,0);
535 pickup crisp.nib; pos1(vair,-180); pos3(vair,0);
536 top y1=top y3=h; lft x1r=w-rt x3r=hround(2u-.5vair);
537 numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
538 pos2(mid_thickness,-90); x2=.5w;
539 bot y2r=vround max(x_height+o+tiny,1/3[x_height,h]+o-.5mid_thickness);
540 filldraw stroke z1e{down}...z2e{right}...{up}z3e; % stroke
541 penlabels(1,2,3); endchar;
542
543 ecchar "Hachek (Caron)";
544 beginchar(oct"201",11u#,min(asc_height#,2x_height#),0);
545 h':=vround min(asc_height,2x_height); % height of circumflex being inverted
546 if serifs: italcorr h#*slant+.5hair#-1.75u#;
547 adjust_fit(0,0);
548 pickup crisp.nib; pos2'(.5[vair,curve],90); top y2'r=h;
549 pos2(.5[vair,curve],90); x2=.5w;
550 x1=w-x3=good.x 2.25u; top y1=top y3=h; y1-y2=.5(y2'-x_height);
551 pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
552 filldraw stroke z1e--z2e--z3e; % diagonals
553 else: italcorr h#*slant-.5stem#+.5vair#-.75u#;
554 adjust_fit(0,0);
555 pickup fine.nib; pos1(vair,0); pos3(vair,0); x1=w-x3;
556 pos2(stem,0); bot y2=vround(1/12[x_height,h']+o); x2=.5w;
557 top y1=top y3=h+o; lft x1l=hround(rt x2r-3.25u-.5vair);
558 z0=whatever[z1r,z2r]=whatever[z2l,z3l];
559 y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=w-x4l;
560 filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
561 penlabels(0,1,2,3,4); endchar;
562
563 ecchar"Double tick mark (inch sign)"; % from accent (hungarian long umlaut)
564 beginchar(oct"202",9u#,min(asc_height#,2x_height#),0);
565 italcorr h#*slant-u#;
566 adjust_fit(0,0);
567 x3-x1=x4-x2=hround 3u; y3=y1; y4=y2;
568 if serifs: pickup crisp.nib; x3+.5stem=hround(w-1.5u); x2=2.5u;
569 y1+.5stem=h; y2=max(2/3[h,x_height],x_height+o+hair);
570 numeric theta; theta=angle(z2-z1)+90;
571 pos1(stem,theta); pos2(hair,theta);
572 pos3(stem,theta); pos4(hair,theta);
573 filldraw circ_stroke z1e--z2e; % left diagonal
574 filldraw circ_stroke z3e--z4e; % right diagonal
575 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
576 pos3(stem,0); pos4(vair,0);
577 rt x3r=hround(w-1.5u); lft x4l=hround(.5w+u-.5vair);
578 top y1=h; bot y2=vround 2/3[h,x_height];
579 filldraw stroke z1e--z2e; % left diagonal
580 filldraw stroke z3e--z4e; fi % right diagonal
581 penlabels(1,2,3,4); endchar;
582
583 ecchar"Double backwards tick mark"; % jk
584 beginchar(oct"203",9u#,min(asc_height#,2x_height#),0);
585 adjust_fit(0,0);
586 x3-x1=x4-x2=hround 3u; y3=y1; y4=y2;
587 if serifs: pickup crisp.nib; x1-.5stem=hround 1.5u; x2=3.5u;
588 y1+.5stem=h; y2=max(2/3[h,x_height],x_height+o+hair);
589 numeric theta; theta=angle(z2-z1)+90;
590 pos1(stem,theta); pos2(hair,theta);
591 pos3(stem,theta); pos4(hair,theta);
592 filldraw circ_stroke z1e--z2e; % left diagonal
593 filldraw circ_stroke z3e--z4e; % right diagonal
594 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
595 pos3(stem,0); pos4(vair,0);
596 lft x1l=hround 1.5u; rt x2r=hround(.5w-u+.5vair);
597 top y1=h; bot y2=vround 2/3[h,x_height];
598 filldraw stroke z1e--z2e; % left diagonal
599 filldraw stroke z3e--z4e; fi % right diagonal
600 penlabels(1,2,3,4); endchar;
601
602
603 ecchar "Dagger mark"; % from mathsy
604 beginchar(oct"204",8u#,asc_height#,desc_depth#);
605 adjust_fit(0,0); pickup fine.nib;
606 pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
607 pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
608 x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); center_on(x1);
609 x5-.5stem=hround u; x6=w-x5;
610 y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
611 y5+.5stem=floor(x_height+.5stem);
612 filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e; % stem
613 filldraw circ_stroke z5e{right}..{right}z2'e; % left bulb
614 filldraw circ_stroke z6e{left}..{left}z2'e; % right bulb
615 penlabels(1,2,3,4,5,6); endchar;
616
617 ecchar "Double dagger mark"; % from mathsy
618 beginchar(oct"205",8u#,asc_height#,desc_depth#);
619 adjust_fit(0,0); pickup fine.nib;
620 pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
621 pos4(stem,90); pos2'(thin_join,90); pos5(stem,90); z2'=z2;
622 x1=x2=x3; x1-.5stem=hround(.5w-.5stem); center_on(x1);
623 x4-.5stem=hround u; x5=w-x4;
624 y1+.5stem=h+oo; y2=y4=y5=.5[y1,y3]; y3-.5stem=ceiling(.5[-d,h]);
625 filldraw circ_stroke z1e{down}..{down}z2e; % top stem
626 filldraw circ_stroke z3e{up}..{up}z2e; % upper middle stem
627 filldraw circ_stroke z4e{right}..{right}z2'e; % top left bulb
628 filldraw circ_stroke z5e{left}..{left}z2'e; % top right bulb
629 pos6(stem,0); pos7(thin_join,0); pos8(stem,0);
630 pos9(stem,90); pos7'(thin_join,90); pos0(stem,90); z7'=z7;
631 x6=x7=x8=x1; x9=x4; x0=x5;
632 y6=y3-stem-1; y7=y9=y0=.5[y6,y8]; y8-.5stem=-d-oo;
633 filldraw circ_stroke z6e{down}..{down}z7e; % lower middle stem
634 filldraw circ_stroke z8e{up}..{up}z7e; % bottom stem
635 filldraw circ_stroke z9e{right}..{right}z7'e; % bottom left bulb
636 filldraw circ_stroke z0e{left}..{left}z7'e; % bottom right bulb
637 penlabels(1,2,3,4,5,6,7,8,9,0); endchar;
638
639 ecchar "Double vertical line (norm or cardinality)"; % from mathsy
640 % Change (jk): Made the two lines as close as in \P
641 beginchar(oct"206",9u#,body_height#,paren_depth#);
642 adjust_fit(0,0); pickup rule.nib;
643 x1=x2; top y1=h; .5[y1,y2]=math_axis;
644 x3=x4=w-x1; y3=y1; y4=y2;
645 x3-x1=ceiling(rule_thickness+1.25u);
646 draw z1--z2; draw z3--z4; % stems
647 labels(1,2,3,4); endchar;
648
649 ecchar "Per mill sign"; % by Emma Pease
650 beginchar(oct"207",15u#+max(6u#,2fudge*(hair#+stem#)),
651 body_height#,body_height#-asc_height#);
652 italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
653 adjust_fit(0,0); pickup fine.nib;
654 numeric left_curve,right_curve;
655 left_curve=hround 5/6[fudged.hair,fudged.stem];
656 right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
657 pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
658 top y1r=h; lft x2r=hround u; rt x4r=hround(.5(w-6u)-1.5u);
659 bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
660 x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
661 filldraw stroke pulled_super_arc.e(1,2)(superpull)
662 & pulled_super_arc.e(2,3)(superpull); % left half of upper bowl
663 filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
664 %
665 pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
666 bot y7r=-d; rt x8r=hround(w-7u); lft x6r=hround(.5(w-6u)+1.5u);
667 top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
668 x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
669 filldraw stroke pulled_super_arc.e(5,6)(superpull)
670 & pulled_super_arc.e(6,7)(superpull); % left half of lower bowl
671 filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
672 %
673 pos13(vair,90); pos14(left_curve,180); pos15(vair,270);
674 pos16(right_curve,360);
675 bot y15r=-d; rt x16r=hround(w-u); lft x14r=hround(.5(w-6u)+1.5u+6u);
676 top y13r=vround(if monospace: .3 else: .5 fi\\ asc_height);
677 x13=x15=.5[x14,x16]; y14=y16=.5[y13,y15];
678 filldraw stroke pulled_super_arc.e(13,14)(superpull)
679 & pulled_super_arc.e(14,15)(superpull); % left half of lower bowl
680 filldraw stroke super_arc.e(15,16) & super_arc.e(16,13); % right half of lower bowl
681 %
682 pickup rule.nib; top y9=h; bot y10=-d;
683 if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
684 draw z9--z10; % diagonal
685 else: rt x9=hround(w-6u-2.5u); lft x10=hround 2.5u; draw z9--z10; % diagonal
686 pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
687 pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
688 path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
689 filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi % link
690 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16); endchar;
691
692 ecchar "Bullet"; % from mathsy
693 beginchar(oct"210",9u#,v_center(7u#));
694 adjust_fit(0,0); pickup rule.nib; autorounded;
695 if .5w <> good.x .5w: change_width; fi
696 lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
697 filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
698 ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle; % circle and interior
699 labels(1,2,3,4,5,6,7,8); endchar;
700
701 ecchar"Centigrade sign";
702 if serifs: beginchar(oct"211",13u#,cap_height#,0);
703 italcorr cap_height#*slant-.5u#;
704 adjust_fit(4u#,0);
705 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
706 pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
707 rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
708 top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
709 bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
710 y5=max(good.y .95(h-y1),y4l+eps);
711 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
712 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
713 filldraw stroke z1e{x2-x1,10(y2-y1)}
714 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
715 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
716 x1r-x1'=2cap_curve-fine; y1'=y1;
717 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
718 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
719 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
720 else: beginchar(oct"211",11.5u#,cap_height#,0);
721 italcorr cap_height#*slant-.5u#;
722 adjust_fit(4u#,0);
723 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
724 pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
725 rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
726 lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
727 top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
728 bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
729 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
730 & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
731 penlabels(1,1',2,3,4,5,6);
732 clearxy;
733 pickup rule.nib; autorounded;
734 lft x6=-4u; rt x2=0; top y8=h; y8-y2=x2-x8;
735 circle_points; draw_circle; % circle
736 labels(1,2,3,4,5,6,7,8);
737 math_fit(-.3cap_height#*slant-.5u#,.5ic#);
738 endchar;
739
740 ecchar "Oldstyle dollar sign"; % based on romanp (cm)
741 beginchar(oct"212",11u#,body_height#,body_height#-asc_height#);
742 italcorr fig_height#*slant-.5u#; % same as for digits
743 adjust_fit(0,0);
744 numeric theta; theta=90-angle(50u,asc_height); slope:=-asc_height/50u;
745 pickup fine.nib; pos2(slab,-90);
746 pos0(cap_stem,theta); pos7(slab,-90);
747 x2=x0=x7=.5w; top y2l=asc_height+oo; bot y7r=-oo;
748 y0=.52asc_height; lft x3l=hround u; rt x6r=hround(w-u);
749 x3r-x3l=x6r-x6l=hround .35[slab,cap_stem]-fine;
750 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
751 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
752 filldraw stroke super_arc.e(2,3) & z3e{down}
753 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
754 if serifs: pos1(hair,0); pos8(hair,180);
755 pos10(flare,0); pos9(flare,180);
756 rt x1r=hround(w-u); lft x8r=hround u; y1=.5[y0,y2]; y8=.5[y0,y7];
757 {{less_tense; pos2'(slab,90); z2'=z2; bulb(2',1,10); % upper arc and bulb
758 bulb(7,8,9)}}; % lower arc and bulb
759 else: pos1(.6[slab,flare],-100); pos8(flare,-100);
760 rt x1l=hround(w-1.3u); lft x8r=hround .8u;
761 top y1l=vround .92asc_height+oo; bot y8r=vround .1asc_height-oo;
762 filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
763 filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
764 pickup crisp.nib; pos12(bar,0); pos11(bar,0); pos13(bar,0); pos14(bar,0);
765 x11=x12; x13=x14=w-x11; x13-x11=ceiling(rule_thickness+1.25u);
766 top y12=top y14=h; bot y11=bot y13=-d;
767 filldraw stroke z12e--z11e; % left vertical crossbar
768 filldraw stroke z14e--z13e; %right vertical crossbar
769 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
770
771 ecchar "Oldstyle cent sign"; % jk, based on cm `c'
772 beginchar(oct"213",9u#,x_height#+.5desc_depth#,.5desc_depth#);
773 italcorr x_height#*slant-.2u#;
774 adjust_fit(0,0);
775 pickup fine.nib; pos2(vair',90); pos4(vair',270);
776 x2=x4=.5(w+u); top y2r=vround(x_height+1.5oo); bot y4r=-oo;
777 pos3(curve,180); lft x3r=hround max(.6u,1.35u-.5curve); y3=.5x_height;
778 if serifs: pos1(hair,0); pos0(flare,0);
779 y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,x_height]-.5flare);
780 rt x1r=hround(w-.7u); bulb(2,1,0); % bulb
781 pos5(hair,0); rt x5r=hround(w-.5u);
782 y5=max(good.y(.5bar_height-.9),y4l+vair');
783 (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
784 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
785 & pulled_super_arc.e(3,4)(.5superpull)
786 ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e; % arc and lower terminal
787 else: pos1(4/7[vair',flare],80);
788 rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
789 filldraw stroke term.e(2,1,right,.8,4); % upper terminal
790 pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
791 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
792 forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
793 if angle direction 1 of p.e>75:
794 p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
795 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
796 & pulled_super_arc.e(3,4)(.5superpull) & p.e; fi % arc and lower terminal
797 pickup crisp.nib;
798 x7=x3; x6=w-x7; y6=h; y7=-d;
799 numeric theta; theta=angle(z7-z6)-90;
800 pos6(vair,theta); pos7(vair,theta);
801 filldraw stroke z6e--z7e; % diagonal
802 penlabels(0,1,2,3,4,5,6,7); endchar;
803
804 iff variant_g: % I use this as marker for italic fonts
805 ecchar "Italic florin sign (italic letter f)"; % from itall (cm)
806 beginchar(oct"214",max(1.5u#,stem#)+max(3.5u#,2flare#),
807 asc_height#,desc_depth#);
808 italcorr asc_height#*slant+.75u#;
809 adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
810 numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
811 pos0(flare,0); pos1(hair,0); pos2(vair,90);
812 pos3(.5[hair,stem],180); pos4(stem,theta+90);
813 pos5(stem,theta-90); pos6(.5[hair,stem],0);
814 pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
815 rt x1r=hround(w+.25u); lft x8r=hround-.35u; x2=.6[x1,x4]; x7=.6[x8,x5];
816 y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
817 y4=.25[x_height,h]; y5=.5[-d,y4];
818 z4=whatever[z88,z89]; z5=whatever[z88,z89];
819 x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
820 bulb(2,1,0); bulb(7,8,9); % bulbs
821 filldraw stroke z2e{left}...z3e...{z89-z88}z4e; % upper arc
822 filldraw z4r--z5l--z5r--z4l--cycle; % stem
823 filldraw stroke z5e{z89-z88}...z6e...{left}z7e; % lower arc
824 pickup crisp.nib; pos20(bar,90); pos21(bar,90);
825 top y20r=top y21r=x_height;
826 lft x20=lft x4r-.5stem-u; rt x21=rt x4l+.5stem+1.5u;
827 filldraw stroke z20e--z21e; % crossbar
828 math_fit(desc_depth#*slant+u#,x_height#*slant);
829 penlabels(0,1,2,3,4,5,6,7,8,9,20,21,88,89); endchar;
830
831
832 iff not variant_g:
833 ecchar "Florin sign (The letter f)"; % from romanl (cm)
834 beginchar(oct"214",5.5u#,asc_height#,0);
835 italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
836 adjust_fit(stem_shift#,if monospace: .5u# else:-stem_shift# fi);
837 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
838 pickup fine.nib; numeric bulb_diam;
839 if serifs: bulb_diam=hround .8[stem,flare];
840 pos2(bulb_diam,0); y2+.5bulb_diam=.9[x_height,h+oo];
841 if monospace: rt x2r=hround(w-.5u)+1 else: lft x2l=hround(w-.75u+.5) fi;
842 else: pos2(5/7[vair,flare],90); top y2r=h;
843 rt x2=hround(if monospace:w-.5u else:w+.75u fi); fi
844 f_stroke(1,2,a,b,c,jut,if not monospace:1.25fi\\ jut); % stem, terminal, serif
845 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
846 pos3(bar,90); pos4(bar,90);
847 rt x4=hround(w-if monospace:.75u+1 else:1/3u fi);
848 filldraw stroke z3e--z4e; % bar
849 penlabels(1,2,3,4); endchar;
850
851 ecchar"Colon sign or Cedi sign"; % Panamese or Ghanese currency
852 if serifs: beginchar(oct"215",13u#,body_height#,body_height#-asc_height#);
853 italcorr cap_height#*slant-.5u#;
854 adjust_fit(0,0);
855 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
856 pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
857 rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
858 numeric hh; hh=cap_height;
859 top y2r=hh+o; bot y4r=-o; y3=.5[y2,y4];
860 bot y1=min(vround max(.6hh,x_height-.5vair),bot y2l-eps);
861 y5=max(good.y .95(hh-y1),y4l+eps);
862 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
863 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
864 filldraw stroke z1e{x2-x1,10(y2-y1)}
865 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
866 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=hh+o;
867 x1r-x1'=2cap_curve-fine; y1'=y1;
868 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
869 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
870 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
871 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
872 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
873 filldraw stroke z12e--z11e; % vertical crossbar
874 else: beginchar(oct"215",11.5u#,body_height#,body_height#-asc_height#);
875 italcorr cap_height#*slant-.5u#;
876 adjust_fit(0,0);
877 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
878 pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
879 rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
880 lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
881 numeric hh; hh=cap_height;
882 top y1r=vround .95hh+o; top y2r=hh+o; y3=.5hh;
883 bot y4r=-o; bot y5r=vround .08hh-o; y5l:=good.y y5l; x5l:=good.x x5l;
884 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
885 & super_arc.e(3,4) & term.e(4,5,right,.8,4); % arc and terminals
886 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
887 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
888 filldraw stroke z12e--z11e; % vertical crossbar
889 fi
890 math_fit(-.3cap_height#*slant-.5u#,.5ic#);
891 penlabels(1,1',2,3,4,5,6,11,12); endchar;
892
893 ecchar"Won sign"; % Korean currency
894 beginchar(oct"216",18u#,cap_height#,0);
895 italcorr cap_height#*slant+.25u#;
896 adjust_fit(cap_serif_fit#,cap_serif_fit#);
897 numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
898 outer_jut=.7cap_jut; x1l=w-x8r=l+letter_fit+outer_jut+.25u;
899 stem1=fudged.cap_stem-stem_corr;
900 stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
901 stem2=stem4 if hefty:-2stem_corr fi;
902 stem3=stem1 if hefty:-2stem_corr fi;
903 x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
904 y1=y8=h; y2=y3=y6=y7=-apex_o; y4=y5=if monospace: vround .6 fi\\ h;
905 mid_corr=if monospace or hefty:-apex_corr else: 1/3jut fi;
906 alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
907 penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
908 penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
909 penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
910 penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
911 x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r+mid_corr| $\approx$ |x4r|
912 z23=whatever[z1r,z2r]=whatever[z3l,z4l];
913 z45=whatever[z3r,z4r]=whatever[z5l,z6l];
914 z67=whatever[z5r,z6r]=whatever[z7l,z8l]; upper_notch=y4-cap_notch_cut;
915 fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
916 ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
917 --(x45,upper_notch)+.5right{down} else: z45&z45 fi
918 ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
919 ...if y67>cap_notch_cut:(x67,cap_notch_cut)+.5right{down}
920 --(x67,cap_notch_cut)+.5left{up} else: z67&z67 fi
921 ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
922 ...if y23>cap_notch_cut:(x23,cap_notch_cut)+.5right{down}
923 --(x23,cap_notch_cut)+.5left{up} else: z23&z23 fi
924 ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle; % diagonals
925 if serifs: numeric inner_jut[]; pickup tiny.nib;
926 prime_points_inside(1,2); prime_points_inside(5,6);
927 prime_points_inside(8,7);
928 if monospace: inner_jut1=inner_jut4=1.5cap_jut;
929 elseif hefty: inner_jut1=inner_jut4=cap_jut;
930 else: fill diag_end(6r,5r,1,1,5l,6l)
931 --.5[z5l,z6l]--.5[z5r,z6r]--cycle; % middle stem
932 inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
933 if rt x1'r+cap_jut+.5u+1<=lft x5'l-.7cap_jut: inner_jut1=cap_jut;
934 else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
935 if rt x5'r+cap_jut+.5u+1<=lft x8'l-1.1cap_jut: inner_jut3=cap_jut;
936 else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
937 dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi % middle serif
938 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut1); % left serif
939 dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); fi % right serif
940 pickup extra_rule.nib;
941 x9=x11=x1l; x10=x12=x8r; y9=y10;
942 top y9=bar_height; y11=y12; draw z9--z10;
943 y11-y9=spread; draw z11--z12; % crossing bars
944 math_fit(.75u#-cap_height#*slant,ic#-2.5u#);
945 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,23,45,67); endchar;
946
947 ecchar"Naira sign"; % Nigerian currency
948 beginchar(oct"217",13u#+width_adj#,cap_height#,0);
949 italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+
950 min(.5cap_stem#,u#);
951 adjust_fit(cap_serif_fit#+.25u#,cap_serif_fit#+.25u#);
952 numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
953 pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
954 pos3(thin_stem,0); pos4(thin_stem,0);
955 pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
956 x1=x2; x3=x4; x1l=w-x3r;
957 rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
958 filldraw stroke z1e--z2e; % left stem
959 filldraw stroke z3e--z4e; % right stem
960 if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
961 x5l=x1; x6r=x4; y5=h; y6=0;
962 numeric upper_notch,lower_notch;
963 upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
964 x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
965 fill z5l..
966 if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
967 {z6-z5}diag_in(5l,6l,1,6r)--z6r..
968 if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
969 {z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonal
970 else: penpos5(whatever,0); penpos6(whatever,90);
971 z5l=z1l; z6l=z4l;
972 z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
973 z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
974 filldraw stroke z5e..z6e; fi % diagonal
975 if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
976 else: serif(5,6,a,1/3,-cap_jut); fi % upper left serif
977 dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
978 dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi % upper right serif
979 pickup extra_rule.nib;
980 x8=x10=0; x9=x11=w; y10=y11;
981 top y8=bar_height; y8=y9; draw z8--z9;
982 y10-y8=spread; draw z10--z11; % crossing bars
983 math_fit(0,max(.5ic#-.5u#,0));
984 penlabels(1,1',2,3,4,4',5,6,7,8,9,10,11); endchar;
985
986 ecchar"Guarani sign"; % Currency of Paraguay
987 if serifs: beginchar(oct"220",14u#,body_height#,body_height#-asc_height#);
988 italcorr cap_height#*slant-1.5u#-.5cap_serif_fit#;
989 adjust_fit(0,.5cap_serif_fit#);
990 numeric hh; hh=cap_height;
991 pickup tiny.nib; pos0(cap_stem,0); pos7(cap_stem,0);
992 rt x0r=hround(w-2u); y0=good.y(.1[bar_height,x_height]+1); x7=x0;
993 pickup fine.nib;
994 if hefty: bot y7=0; pos5(cap_stem,0); x5=x0; top y5=tiny.top y0;
995 else: pos5(cap_hair,0); pos8(cap_stem,0);
996 y7=.5bar_height; z5l=z8l; z8=z7; x9=x8r; bot y9=0;
997 filldraw z8l{down}..{4(x9-x8),y9-y8}z9--z8r--cycle; fi % spur
998 pos1(cap_hair,0); pos2(cap_band,90);
999 pos3(cap_curve,180); pos4(cap_band,270);
1000 rt x1r=hround(w-2u); lft x3r=hround u; x2=x4=.55[x3,x1];
1001 top y2r=hh+o; bot y4r=-o; y3=.5[y2,y4];
1002 bot y1=min(vround max(.6hh,x_height-.5vair),bot y2l-eps);
1003 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
1004 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
1005 filldraw stroke z1e{x2-x1,10(y2-y1)}
1006 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...z5e{up}; % arc
1007 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=hh+o;
1008 x1r-x1'=2cap_curve-fine; y1'=y1;
1009 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
1010 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
1011 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
1012 pickup tiny.nib; filldraw stroke z0e--z7e; % stem
1013 dish_serif(0,7,a,1/3,max(cap_jut,2.25u),b,1/3,1.25u); % serif
1014 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
1015 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
1016 filldraw stroke z12e--z11e; % vertical crossbar
1017 math_fit(-.3cap_height#*slant-.5u#,ic#);
1018 else: beginchar(oct"220",14u#,body_height#,body_height#-asc_height#);
1019 italcorr cap_height#*slant-.5u#;
1020 adjust_fit(0,0);
1021 numeric hh; hh=cap_height;
1022 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
1023 pos3(cap_curve,180); pos4(slab,270); pos5(flare,270);
1024 rt x1r=hround(w-1.35u); x2=x4=.5w+u;
1025 lft x3r=hround max(u,2u-.5cap_curve); rt x5l=hround(w-1.2u);
1026 top y1r=vround .93hh+o; top y2r=hh+o; y3=.5hh;
1027 bot y4r=-o; bot y5r=vround .07hh-o;
1028 filldraw stroke rterm.e(2,1,right,.9,4)&super_arc.e(2,3)
1029 & super_arc.e(3,4) & term.e(4,5,right,1,4); % arc and terminals
1030 pos0(stem,0); pos7(stem,0);
1031 z7r=z5r; x0=x7; top y0=1+vround .35[bar_height,x_height];
1032 filldraw stroke z0e--z7e; % stem
1033 pos8(cap_bar,90); pos9(cap_bar,90);
1034 z0r=z9r; y8=y9; lft x8=hround x4;
1035 filldraw stroke z8e--z9e; % bar
1036 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
1037 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
1038 filldraw stroke z12e--z11e; % vertical crossbar
1039 math_fit(-.3cap_height#*slant-.5u#,.5ic#); fi
1040 penlabels(0,1,1',2,3,4,5,6,7,8,9,11,12); endchar;
1041
1042 ecchar"Peso sign";
1043 beginchar(oct"221",12u#,cap_height#,0);
1044 italcorr .75cap_height#*slant-.5u#;
1045 adjust_fit(cap_serif_fit#+.25u#,0);
1046 pickup tiny.nib; penpos1(cap_stem'-tiny,0); penpos2(cap_stem-tiny,0);
1047 pos0(cap_stem',0); pos0'(cap_stem,0);
1048 lft x1l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
1049 x1l=x2l=x0l=x0'l; y0=y0'=y7;
1050 penpos3(cap_band,90); penpos4(cap_band,90);
1051 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1052 penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
1053 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1054 x7=x2; y7l=vround .5h; x4=x6=.5w+.75u; x5r=hround(w-u);
1055 x4l:=x6l:=x4-.25cap_curve;
1056 filldraw stroke z1e--z0e--z0'e--z2e; % stem
1057 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1058 if serifs: nodish_serif(1,0,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1059 dish_serif(2,0',c,1/3,cap_jut,d,1/3,cap_jut); fi % lower serif
1060 pickup extra_rule.nib;
1061 x8=0; x9=.5[x1r,x5r]; top y8=bar_height; y8=y9; draw z8--z9;
1062 math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7); labels(8,9);
1063 endchar;
1064
1065 ecchar "Lira sign"; %
1066 compute_spread(.35x_height#,.45x_height#);
1067 beginchar(oct"222",12u#,asc_height#,0);
1068 adjust_fit(0,.75asc_height#*slant-.5u#); pickup fine.nib;
1069 pos0(flare,0); pos1(hair,0); pos2(vair,90); pos3(stem,180);
1070 pos4(stem,180); pos4'(stem,0); pos5(vair,-90); z4'=z4;
1071 x2=2/3w-.5u; rt x3l=rt x4l=hround(.5w-u+.5stem); x5=2.5u;
1072 y1=y3=.75h; top y2=h+oo; y4=.25h; bot y5r=-oo;
1073 rt x1r=hround(w-1.5u); bulb(2,1,0); % bulb
1074 filldraw stroke pulled_arc.e(2,3)..z4e; % stem
1075 numeric light_stem; light_stem=2/3[vair,vstem];
1076 pos6(.5[hair,light_stem],-180); pos7(light_stem,-300);
1077 pos8(light_stem,-300); pos9(hair,-180);
1078 lft x6r=hround u; x7=3u; x8=w-3.5u; rt x9l=hround(w-u);
1079 y6=.4[y5,y7]; top y7r=vround .2h; bot y8l=-oo; y9=good.y .2h;
1080 filldraw stroke pulled_arc.e(4',5)...z6e{up}...z7e{right}
1081 ..{right}z8e...{up}z9e; % loop and arm
1082 pickup extra_rule.nib;
1083 x10=3u; x11=w-4.5u; x12=3u; x13=w-4.5u;
1084 top y12=bar_height;
1085 y11=y10; y13=y12; y10-y12=spread;
1086 draw z10--z11; % upper bar
1087 draw z12--z13; % lower bar
1088 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
1089
1090 ecchar"Recipe sign";
1091 beginchar(oct"223",if serifs: 12u#+.5max(2u#,cap_curve#)
1092 else:12.5u#-.5width_adj# fi,cap_height#,0);
1093 italcorr .75cap_height#*slant- if serifs: 1.75 else: .5 fi\\ u#;
1094 adjust_fit(cap_serif_fit#,0);
1095 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1096 lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
1097 filldraw stroke z1e--z2e; % stem
1098 penpos3(cap_band,90); penpos4(cap_band,90);
1099 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1100 penpos6(vair,-90); penpos7(vair,-90);
1101 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1102 x7=x2; y7l=vround(.5h+.5vair); x4=x6;
1103 if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
1104 else: x4=.5w+.5u; x5r=hround(w-u); fi
1105 x4l:=x6l:=x4-.125cap_curve;
1106 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1107 if serifs: pos6'(vair,-90); pos0(cap_stem,180);
1108 pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
1109 z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
1110 y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
1111 bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
1112 filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up}; % tail
1113 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1114 dish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); % lower serif
1115 else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
1116 x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
1117 fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi % tail
1118 x1:=x8;
1119 put_cross(.5cap_stem+if serifs: .9max(limit_dist,cap_jut) else: .8u fi,
1120 .5cap_stem+if serifs: 3u else: 4u fi);
1121 math_fit(0,.75ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
1122
1123 iff not variant_g: % not italic
1124 ecchar"Interrobang";
1125 beginchar(oct"224",8.5u#,asc_height#,0);
1126 italcorr .8asc_height#*slant;
1127 adjust_fit(0,0);
1128 pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
1129 lft x7l=hround(.5w-.25u-.5dot_size); bot y8l=0; z7=z8; % dot(7,8); % dot
1130 numeric bot_width;
1131 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1132 pickup fine.nib; pos2(vair,90); pos3(curve,0);
1133 pos4(vair,-90); pos5(bot_width,0); pos6(bot_width,0);
1134 x2=x4=x5=x6=x7; rt x3r=hround(w-u); bot y6=1+.25[top y8r,x_height];
1135 top y2r=hround .9h+oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
1136 {{interim superness:=more_super;
1137 filldraw stroke pulled_super_arc.e(2,3)(superpull)
1138 & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}}; % arc and stem
1139 if serifs: pos1(hair,180); pos0(flare,180);
1140 lft x1r=hround u; y1=y3; bulb(2,1,0); % bulb
1141 else: pos1(Vround 5/7[vair,flare],110);
1142 lft x1r=hround u; top y1r=vround .9[y6,top y2r];
1143 filldraw stroke term.e(2,1,left,1,4); fi % terminal
1144 penlabels(0,1,2,3,4,5,6,7,8);
1145 clearxy;
1146 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1147 lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
1148 numeric bot_width;
1149 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1150 pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
1151 x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
1152 if square_dots: top y1=h;
1153 filldraw stroke z1e--z2e; % stem
1154 else: top z0=(x1,h+o); y1+.5dot_size=h+o;
1155 filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
1156 penlabels(0,1,2,3,4); endchar;
1157
1158 iff not variant_g: % not italic
1159 ecchar"Gnaborretni";
1160 beginchar(oct"225",8.5u#,asc_height#-desc_depth#,desc_depth#);
1161 adjust_fit(0,0);
1162 pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
1163 lft x7l=hround(.5w-.25u-.5dot_size); top y8r=h; z7=z8; % dot(7,8); % dot
1164 numeric top_width;
1165 top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1166 pickup fine.nib; pos2(vair,270); pos3(curve,180);
1167 pos4(vair,90); pos5(top_width,180); pos6(top_width,180);
1168 x2=x4=x5=x6=x7; lft x3r=hround u; top y6=.25[bot y8l,h-x_height]-1;
1169 bot y2r=hround .1asc_height-d-oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
1170 {{interim superness:=more_super;
1171 filldraw stroke pulled_super_arc.e(2,3)(superpull)
1172 & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}}; % arc and stem
1173 if serifs: pos1(hair,0); pos0(flare,0);
1174 rt x1r=hround(w-u); y1=y3; bulb(2,1,0); % bulb
1175 else: pos1(Vround 5/7[vair,flare],-70);
1176 rt x1r=hround(w-u); bot y1r=vround .9[y6,bot y2r];
1177 filldraw stroke term.e(2,1,right,1,4); fi % terminal
1178 penlabels(0,1,2,3,4,5,6,7,8);
1179 clearxy;
1180 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1181 lft x3l=hround(.5w-.5dot_size); top y4r=h; z3=z4; dot(3,4); % dot
1182 numeric top_width;
1183 top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1184 pickup fine.nib; pos1(dot_size,0); pos2(top_width,0);
1185 x1=x2=x3; top y2=.25[bot y4l,h-x_height]-1;
1186 if square_dots: bot y1=-d;
1187 filldraw stroke z1e--z2e; % stem
1188 else: bot z0=(x1,-d-o); y1-.5dot_size=-d-o;
1189 filldraw z1l...z0...z1r---z2r--z2l---cycle; fi % stem and bulb
1190 penlabels(0,1,2,3,4); endchar;
1191
1192 iff variant_g: % italic
1193 ecchar"Interrobang";
1194 beginchar(oct"224",9u#,asc_height#,0);
1195 italcorr asc_height#*slant-u#;
1196 adjust_fit(0,0);
1197 adjust_fit(0,0); pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
1198 lft x10l=hround(.5w-.5dot_size); bot y11l=0; z10=z11; % dot(10,11); % dot
1199 pickup fine.nib; pos1(flare,180); pos2(hair,180); pos3(vair,90);
1200 lft x1r=hround u; x3=.5w;
1201 y1-.5flare=x_height; top y3r=hround .9h+o; bulb(3,2,1); % bulb
1202 pos8(vair,-90); x8=.5w; bot y8r=.25[top y11r,x_height]+1;
1203 numeric theta; theta=90+angle(10u,y3-y8); slope:=(y3-y8)/10u;
1204 pos3'(vair,-90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
1205 rt x4l=hround(w-1.5u); lft x7r=hround 1/3w;
1206 x4l-x4r=x7l-x7r=hround .5[vair,vstem]-fine;
1207 ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
1208 ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
1209 pos9(hair,0); rt x9r=hround(2/3w+.5hair); y9=good.y .5[y8,y0];
1210 filldraw stroke super_arc.e(3',4) & z4e{down}
1211 ..z5e---z6e..z7e{down} & super_arc.e(7,8)...{up}z9e; % main stroke
1212 penlabels(0,1,2,3,4,5,6,7,8,9,10,11);
1213 clearxy;
1214 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1215 lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
1216 numeric bot_width;
1217 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1218 pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
1219 x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
1220 if square_dots: top y1=h;
1221 filldraw stroke z1e--z2e; % stem
1222 else: top z0=(x1,h+o); y1+.5dot_size=h+o;
1223 filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
1224 penlabels(0,1,2,3,4); endchar;
1225
1226 iff variant_g: % italic
1227 ecchar"Gnaborretni";
1228 beginchar(oct"225",9u#,asc_height#-desc_depth#,desc_depth#);
1229 adjust_fit(0,0);
1230 pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
1231 lft x10l=hround(.5w-.5dot_size); top y11r=h; z10=z11; % dot(10,11); % dot
1232 pickup fine.nib; pos1(flare,0); pos2(hair,0); pos3(vair,-90);
1233 rt x1r=hround(w-u); x3=.5w; y1+.5flare=asc_height-x_height-d;
1234 bot y3r=hround .1asc_height-d-o; bulb(3,2,1); % bulb
1235 pos8(vair,90); x8=.5w; top y8r=.25[bot y11l,y1+.5flare]-1;
1236 numeric theta; theta=angle(10u,y8-y3)-90; slope:=(y8-y3)/10u;
1237 pos3'(vair,90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
1238 lft x4l=hround 1.5u; rt x7r=hround 2/3w;
1239 x4r-x4l=x7r-x7l=hround .5[vair,vstem]-fine;
1240 ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
1241 ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
1242 pos9(hair,180); lft x9r=hround(1/3w-.5hair); y9=good.y .5[y8,y0];
1243 filldraw stroke super_arc.e(3',4) & z4e{up}
1244 ..z5e---z6e..z7e{up} & super_arc.e(7,8)...{down}z9e; % main stroke
1245 penlabels(0,1,2,3,4,5,6,7,8,9,10,11);
1246 clearxy;
1247 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1248 lft x3l=hround(.5w-.5dot_size); top y4r=h; z3=z4; dot(3,4); % dot
1249 numeric top_width;
1250 top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1251 pickup fine.nib; pos1(dot_size,0); pos2(top_width,0);
1252 x1=x2=x3; top y2=.25[bot y4l,h-x_height]-1;
1253 if square_dots: bot y1=-d;
1254 filldraw stroke z1e--z2e; % stem
1255 else: bot z0=(x1,-d-o); y1-.5dot_size=-d-o;
1256 filldraw z1l...z0...z1r---z2r--z2l---cycle; fi % stem and bulb
1257 penlabels(0,1,2,3,4); endchar;
1258
1259 iff not variant_g: % not italic
1260 ecchar"Dong sign"; % Vietnamese currency
1261 beginchar(oct"226",10u#+serif_fit#,body_height#,0);
1262 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
1263 adjust_fit(0,serif_fit#);
1264 numeric hh; hh=asc_height;
1265 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
1266 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
1267 rt x1r=hround(w-2.5u+.5stem'); top y1=hh;
1268 numeric edge; edge=lft x2l;
1269 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
1270 pos4(vair,90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
1271 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),1/3[lft x2,edge]);
1272 y3=1/8[bar_height,x_height];
1273 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo if monospace: -hair fi;
1274 lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height if monospace: -.5hair fi;
1275 x6l=x4l-.2u; bot y6r=-oo;
1276 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
1277 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
1278 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
1279 filldraw stroke z3e{up}...pulled_arc.e(4,5)
1280 & pulled_arc.e(5,6)...{up}z7e; % bowl
1281 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
1282 pickup tiny.nib; bot y2=if serifs:-min(oo,serif_drop) else: 0 fi;
1283 filldraw stroke z1e--z0'e--z0e--z2e; % stem
1284 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); % upper serif
1285 sloped_serif.r(2,0,b,1/3,jut,min(oo,serif_drop)); fi % lower serif
1286 %
1287 pos8(bar,90); pos9(bar,90);
1288 x8=.5[x4,x5];
1289 if serifs: x9=x2r+jut; else: x9=w; fi
1290 if serifs: y8=y9=.5[y.a2-.5slab,y4+.5vair];
1291 else: y8=y9=.5[x_height,asc_height-serif_drop]; fi
1292 filldraw stroke z8e--z9e;
1293 currentpicture:=currentpicture shifted (0,body_height-asc_height);
1294 pickup rule.nib;
1295 x10=x5; x11=x9; top y10=0; y10=y11;
1296 draw z10--z11;
1297 penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
1298
1299 iff variant_g: %italic
1300 ecchar"Italic Dong sign"; % Vietnamese currency
1301 beginchar(oct"226",9u#,body_height#,0);
1302 italcorr max(1/3x_height#*slant+.5hair#+.5u#,
1303 h#*slant+.5stem#-2u#) if math_fitting:-.5u# fi;
1304 adjust_fit(0,0); pickup fine.nib;
1305 pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
1306 x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
1307 x4+.5stem=hround(w-2.5u+.5stem);
1308 top y1r=x_height+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
1309 filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
1310 & pulled_arc.e(2,3) & super_arc.e(3,0); % bowl
1311 x5=x0; x7=w; hook_out(5,6,7); % closing hook
1312 pickup tiny.nib; pos5'(stem,0); pos4(stem,0);
1313 z5'=z5; top y4=h; filldraw stroke z4e--z5'e; % stem
1314 sloped_serif.l(4,5',a,1/3,jut,serif_drop); % serif
1315 math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
1316 % the bar
1317 pos8(bar,90); pos9(bar,90);
1318 x8=x1; % .5[x1,x4];
1319 x9=x6;
1320 y8=y9=.5[y.a2-.5slab,y1+.5vair];
1321 filldraw stroke z8e--z9e;
1322 currentpicture:=currentpicture shifted (0,body_height-asc_height);
1323 pickup rule.nib;
1324 x10=x2; x11=x9; top y10=0; y10=y11;
1325 draw z10--z11;
1326 penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
1327
1328 ecchar"Trademark"; % jk, design based on logo font
1329 beginchar(oct"227",12u#,body_height#,0);
1330 italcorr .7body_height#;
1331 adjust_fit(0,0);
1332 numeric ww, hh; ww=.5w; hh=vround .5body_height;
1333 pickup pencircle xscaled hair yscaled vair;
1334 lft x1=-eps; x2=ww-x1; x3=x4=.5ww;
1335 y1=y2=y3; top y1=hh; bot y4=-o;
1336 draw z1--z2; draw z3--z4;
1337 labels(1,2,3,4);
1338 clearxy;
1339 x1=x2=hround(ww+u); x4=x5=hround(w-u); x3=hround .5[x1,x4];
1340 y1=y5; y2=y4; bot y1=-o;
1341 top y2=hh+o; y3=vround (y1+.5bar_height);
1342 draw z1--z2--z3--z4--z5;
1343 labels(1,2,3,4,5);
1344 currentpicture:=currentpicture shifted (0,hh);
1345 endchar;
1346
1347 ecchar"Per ten thousand sign"; % Yannis, Unicode Computer Modern
1348 beginchar(oct"230",9u#+max(6u#,2fudge*(hair#+stem#)),
1349 body_height#,body_height#-asc_height#);
1350 italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
1351 adjust_fit(0,
1352 2*(.5*(9u#+max(6u#,2fudge*(hair#+stem#)))
1353 -2.5u#+5/6[fudged.hair#,fudged.stem#]));
1354 pickup fine.nib;
1355 numeric left_curve,right_curve;
1356 left_curve=hround 5/6[fudged.hair,fudged.stem];
1357 right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
1358 pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
1359 top y1r=h; lft x2r=hround u; rt x4r=hround(.5w-1.5u);
1360 bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
1361 x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
1362 pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
1363 bot y7r=-d; rt x8r=hround(w-u); lft x6r=hround(.5w+1.5u);
1364 top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
1365 x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
1366 filldraw stroke pulled_super_arc.e(5,6)(superpull)
1367 & pulled_super_arc.e(6,7)(superpull); % left half of lower bowl
1368 filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
1369 hihi:=(.5*(9u#+max(6u#,2fudge*(hair#+stem#)))
1370 -2.5u#+5/6[fudged.hair#,fudged.stem#])
1371 if monospace: *expansion_factor fi *hppp;
1372 picture petit_zero; petit_zero := currentpicture;
1373 pickup rule.nib; top y9=h; bot y10=-d;
1374 if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
1375 draw z9--z10; % diagonal
1376 else: rt x9=hround(w-2.5u); lft x10=hround 2.5u; draw z9--z10; % diagonal
1377 pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
1378 pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
1379 path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
1380 filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi % link
1381 pickup fine.nib;
1382 filldraw stroke pulled_super_arc.e(1,2)(superpull)
1383 & pulled_super_arc.e(2,3)(superpull); % left half of upper bowl
1384 filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
1385 addto currentpicture also (petit_zero shifted (hihi,0));
1386 addto currentpicture also (petit_zero shifted (2hihi,0));
1387 picture petit_zero; % Release resources allocated to the picture variable
1388 penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
1389
1390 ecchar "Alternate pilcrow sign"; % one vertical bar only
1391 beginchar(oct"231",8.5u#,asc_height#,desc_depth#);
1392 adjust_fit(0,0); pickup rule.nib; autorounded;
1393 top y1=h; bot y6=-d-eps; y4=y9=y1;
1394 y3=y5=good.y .5[y1,y6];
1395 lft x2=hround u; y2=.5[y1,y3]; rt x9=hround(w-.5u); x4=x5=x6=good.x(x9-1.5u);
1396 x1=x3=min(.5w,x4);
1397 filldraw z4..z1{left}...z2{down}...{right}z5--cycle; % filled bowl
1398 draw z9--z4--z6; % left stem and upper serif
1399 if serifs:
1400 x11=x9; x10-x6=x4-x9;
1401 bot y10=-d-eps; y10=y11;
1402 draw z10--z11; % lower serif
1403 fi
1404 labels(1,2,3,4,5,6,9,10,11); endchar;
1405
1406 ecchar"Baht sign"; % currency of Thailand
1407 beginchar(oct"232",12.5u#,body_height#,body_height#-asc_height#);
1408 italcorr .75cap_height#*slant-.5u#;
1409 adjust_fit(cap_serif_fit#,0);
1410 numeric hh; hh=cap_height;
1411 numeric left_stem,right_curve,middle_weight;
1412 left_stem=cap_stem-hround 2stem_corr; middle_weight=.6vair+.5;
1413 pickup tiny.nib; pos1(left_stem,0); pos2(left_stem,0);
1414 lft x1l=lft x2l=hround max(2u,3u-.5left_stem); top y1=hh; bot y2=0;
1415 filldraw stroke z1e--z2e; % stem
1416 penpos3(cap_band,90); penpos4(cap_band,90);
1417 penpos6(middle_weight,-90); penpos7(middle_weight,-90);
1418 penpos8(middle_weight,90); penpos9(middle_weight,90);
1419 penpos5(right_curve-stem_corr,0); penpos10(right_curve,0);
1420 penpos11(cap_band,-90); penpos12(cap_band,-90);
1421 z3r=top z1; y4=y3; y5=.5[y4,y6]; y6=y7; y7l-y8l=vair;
1422 z12r=bot z2; y11=y12; y10=.5[y11,y9]; y8=y9; .5[y7l,y8l]=.52hh;
1423 x4=x6; x9=x11=x4+.5u; x7=x8=x1; x9l:=x4+.25u;
1424 x5r=hround(w-1.5u); x10r=hround(w-u);
1425 if serifs: right_curve=cap_curve-stem_corr; x4=.5[x1,w-1.5u];
1426 else: right_curve=cap_curve-3stem_corr; x4=.5[x1,w-2.5u];
1427 x4l:=x4l-.5u; x9l:=x9l-.5u; fi
1428 x6l:=x6l-.5u; x11l:=x11l-.5u;
1429 fill stroke z3e..super_arc.e(4,5) & super_arc.e(5,6)..z7e; % upper lobe
1430 fill stroke z8e..super_arc.e(9,10) & super_arc.e(10,11)..z12e; % lower lobe
1431 if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1432 nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi % lower serif
1433 pickup crisp.nib; pos13(bar,0); pos14(bar,0);
1434 rt x13r=rt x14r=rt x4; top y13=h; bot y14=-d;
1435 filldraw stroke z13e--z14e; % vertical crossbar
1436 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
1437
1438 ecchar"Numero sign"; % from wncyr
1439 beginchar(oct"233",15u#+width_adj#,cap_height#,0);
1440 italcorr cap_height#*slant
1441 -cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
1442 adjust_fit(cap_serif_fit#
1443 if serifs: +.5(flare#+(cap_stem#-stem#)) fi ,cap_serif_fit#);
1444 w:=if serifs: 10u else: 11u fi;
1445 numeric thin_stem;
1446 thin_stem=hround(fudged.hair+stem_corr);
1447 pickup tiny.nib;
1448 pos1(thin_stem,0); pos2(thin_stem,0);
1449 pos3(thin_stem,0); pos4(thin_stem,0);
1450 top y1=h;
1451 if serifs: top y3=.79h; bot y2=.21h;
1452 else: top y3=h; bot y2=0; fi
1453 bot y4=0;
1454 x1=x2; x3=x4; x1l=w-x3r;
1455 rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
1456 x91=x2-.75flare; bot y91r=-oo; x92=w-x91;
1457 top y92l=h+oo;
1458 pos91(thin_stem,-90); pos92(thin_stem,-90);
1459 if serifs:
1460 filldraw stroke z1e--z2e & pulled_arc.e(2,91); % left stem
1461 filldraw stroke z4e--z3e & pulled_arc.e(3,92); % right stem
1462 else:
1463 filldraw stroke z1e--z2e; filldraw stroke z4e--z3e; % stems
1464 fi
1465 if hefty:
1466 penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
1467 x5l=x1; x6r=x4; y5=h; y6=0;
1468 numeric upper_notch,lower_notch;
1469 upper_notch=h-cap_notch_cut;
1470 lower_notch=cap_notch_cut;
1471 x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l;
1472 z4'=whatever[z5r,z6r];
1473 fill z5l..
1474 if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
1475 {z6-z5}diag_in(5l,6l,1,6r)--z6r..
1476 if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
1477 {z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonal
1478 else:
1479 penpos5(whatever,0); penpos6(whatever,90);
1480 z5l=z1l; z6l=z4l;
1481 z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
1482 z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
1483 filldraw stroke z5e--z6e; % diagonal
1484 fi
1485 if serifs:
1486 if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
1487 else: serif(5,6,a,1/3,-cap_jut); fi % upper left serif
1488 fi
1489 pickup tiny.nib;
1490 if serifs:
1491 x93=x2-1.5flare;
1492 y93=.75flare;
1493 pos95(flare+(cap_stem-stem),-180);
1494 x94=x3+1.5flare;
1495 y94=h-y93;
1496 pos96(flare+(cap_stem-stem),0);
1497 pos92'(thin_stem,90);
1498 z92'=z92;
1499 pos93(cap_hair,-180);
1500 pos94(cap_hair,0);
1501 bulb(91,93,95); bulb(92',94,96);
1502 fi
1503 w:=15u;
1504 penpos71(vair,90); penpos73(vair',-90); penpos72(.8curve,180);
1505 penpos74(.8curve,0); x72r=hround max(.5u,1.25u-.4curve)+9.5u;
1506 x74r=w-x72r+9u; x71=x73=12u; y71r=h-3u+vround 1.5oo; y73r=x_height-3u-oo;
1507 y72=y74=.5[h,x_height]-3u-vair_corr; y72l:=y74l:=.52[h,x_height]-3u;
1508 penstroke pulled_arc.e(71,72) & pulled_arc.e(72,73) & pulled_arc.e(73,74) &
1509 pulled_arc.e(74,71) & cycle;
1510 x81=max(lft x72r,x73-(lft w-x73));
1511 x82=min(rt x74r,lft w); y81=y82=.8x_height-3u;
1512 pos81(bar,90); pos82(bar,90);
1513 filldraw stroke z81e--z82e;
1514 math_fit(0,max(.5ic#-.5u#,0));
1515 penlabels(1,1',2,3,4,4',5,6,7); endchar;
1516
1517 ecchar "Abzueglich sign"; % jk
1518 beginchar(oct"234",9u#,body_height#,0);
1519 italcorr body_height#*slant-.5u#;
1520 adjust_fit(0,0); pickup rule.nib;
1521 rt x1=hround(w-u)+eps; top y1=h+eps;
1522 lft x2=hround u-eps; bot y2=-eps;
1523 draw z1--z2; % diagonal
1524 x3=w-x5=good.x (lft x1 - .5dot_size);
1525 bot y4 = good.y .5dot_size;
1526 top y6 = good.y h-.5dot_size;
1527 pos3(dot_size,0); pos4(dot_size,90); z3=z4;
1528 pos5(dot_size,0); pos6(dot_size,90); z5=z6;
1529 dot(3,4); dot(5,6); % dots
1530 penlabels(1,2,3,4,5,6); endchar;
1531
1532 ecchar"Aestimated sign (large e)"; % jk
1533 beginchar(oct"235",(11.25u#+max(.75u#,.5cap_curve#)),cap_height#,0);
1534 italcorr .76cap_height#*slant+.5min(curve#-1.5u#,0);
1535 adjust_fit(if monospace: .25u#,.5u# else: 0,0 fi);
1536 numeric left_curve,right_curve;
1537 left_curve=right_curve+3stem_corr=cap_curve if not serifs: -1.5stem_corr fi;
1538 if right_curve<tiny.breadth: right_curve:=tiny.breadth; fi
1539 if left_curve<tiny.breadth: left_curve:=tiny.breadth; fi
1540 pickup tiny.nib;
1541 pos1(right_curve,0); pos2(vair,90); pos3(left_curve,180);
1542 y1=good.y .52h; top y2r=h+vround 1.5oo; y0l=bot y1;
1543 rt x1r=hround min(w-.5u,w-u+.5right_curve);
1544 lft x3r=hround max(.5u,1.25u-.5left_curve); x2=.5w+.25u;
1545 {{interim superness:=more_super;
1546 filldraw stroke super_arc.e(1,2)}}; % right bowl
1547 y3=.5[y2,y4]; bot y4r=-oo; x4=x2+.25u;
1548 if serifs: pos4(vair',270); pos5(hair,360);
1549 y5=max(good.y(.5bar_height-.9),y4l+vair); x5r=x1r;
1550 (x,y4l)=whatever[z4r,z5]; x4l:=min(x,x4l+.5u);
1551 filldraw stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
1552 ...{x5-x4,5(y5-y4)}z5e; % left bowl, arc, and terminal
1553 else: pos4(vair,270);
1554 filldraw stroke super_arc.e(2,3) & super_arc.e(3,4); % left bowl and arc
1555 pickup fine.nib; pos4'(vair,270); z4=z4';
1556 pos5(.5[vair,flare],275); rt x5r=hround(w-.6u);
1557 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
1558 filldraw stroke term.e(4',5,right,1,4); fi % terminal
1559 path testpath; testpath=super_arc.r(2,3) & super_arc.r(3,4);
1560 y1'r=y0r=y0l+.6[thin_join,vair]; y1'l=y0l; x1'l=x1'r=x1;
1561 forsuffixes $=l,r:
1562 x0$=xpart(((0,y0$)--(x1,y0$)) intersectionpoint testpath); endfor
1563 fill stroke z0e--z1'e; % crossbar
1564 penlabels(0,1,2,3,4,5); endchar;
1565
1566 ecchar "Open bullet"; % derived from Circle operator
1567 beginchar(oct"236",9u#,v_center(7u#));
1568 adjust_fit(0,0); pickup rule.nib; autorounded;
1569 if .5w <> good.x .5w: change_width; fi
1570 lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
1571 circle_points; draw_circle; % circle
1572 labels(1,2,3,4,5,6,7,8); endchar;
1573
1574 ecchar"Servicemark"; % jk, design based on logo font
1575 beginchar(oct"237",12u#,body_height#,0);
1576 italcorr .7body_height#;
1577 adjust_fit(0,0);
1578 numeric ww, hh; ww=.5w; hh=vround .5body_height;
1579 pickup pencircle xscaled hair yscaled vair;
1580 x3=x8= u;
1581 x2=x4=.382[x3,ww-x3];
1582 x1=ww-x3;
1583 x5=x7=.618[x3,ww-x3];
1584 x6=.5[ww-x3,lft ww];
1585 top y1=hh; y4=good.y .55hh; bot y8=0;
1586 y1=y2; y3=.5[y2,y4]; y4=y5; y6=.5[y5,y7]; y7=y8;
1587 draw z1--z2; draw z4--z5; draw z7--z8;
1588 super_crescent(2,3,4);
1589 super_crescent(5,6,7);
1590 labels(1,2,3,4,5,6,7,8);
1591 clearxy;
1592 x1=x2=hround(ww+u); x4=x5=hround(w-u); x3=hround .5[x1,x4];
1593 y1=y5; y2=y4; bot y1=-o;
1594 top y2=hh+o; y3=vround (y1+.5bar_height);
1595 draw z1--z2--z3--z4--z5;
1596 labels(1,2,3,4,5);
1597 currentpicture:=currentpicture shifted (0,hh);
1598 endchar;
1599
1600 ecchar "Left square bracket with quill"; % from Haralambous/Plaice
1601 beginchar(oct"240",9u#,body_height#,paren_depth#);
1602 italcorr math_axis#*slant+.5vair#-u#;
1603 adjust_fit(if monospace: -1.5u#,u# else: -2.5u#,0 fi);
1604 pickup fine.nib;
1605 forsuffixes $=1,1',4,4',7,7',11,11',17,17':
1606 pos$(vair,0); endfor
1607 forsuffixes $=2,3,5,6: pos$(stem,0); endfor
1608 x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
1609 rt x4r=hround(w-1.5u+.5vair); rt x2r=hround(.5w+.5stem);
1610 top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
1611 y1-y2=y3-y4=(y1-y4)/4;
1612 y1-y1'=y4-y4'=y7'-y7=y11-y11'=y17-y17'=vair-fine;
1613 x11=x11'=x17=x17'; x11-x2=x2-x1; y11=y1; y17=y7;
1614 filldraw z11'l{left}...z2r---z3r...{right}z4r
1615 --z4'r{left}...z5r---z6r...{right}z17l
1616 --z17r--z17'r{left}...z6l---z5l...{right}.5[z4l,z4'l]{left}
1617 ...z3l---z2l...{right}z11r--z11'r--cycle; % stroke
1618 penlabels(1,2,3,4,5,6,7); endchar;
1619
1620 ecchar "Right square bracket with quill"; % from Haralambous/Plaice
1621 beginchar(oct"241",9u#,body_height#,paren_depth#);
1622 italcorr body_height#*slant+.5vair#-u#;
1623 adjust_fit(if monospace: u#,-1.5u# else: 0,-2.5u# fi);
1624 pickup fine.nib;
1625 forsuffixes $=1,1',4,4',7,7',11,11',17,17':
1626 pos$(vair,0); endfor
1627 forsuffixes $=2,3,5,6: pos$(stem,0); endfor
1628 x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
1629 lft x4l=hround(1.5u-.5vair); lft x2l=hround(.5w-.5stem);
1630 top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
1631 y1-y2=y3-y4=(y1-y4)/4; y1-y1'=y4-y4'=y7'-y7=vair-fine;
1632 x11=x11'; x17=x17';
1633 y11=y1; y17=y7;
1634 x1-x2=x2-x11; x17=x11; y11-y11'=y17'-y17=vair-fine;
1635 filldraw z11'r{right}...z2l---z3l...{left}z4l
1636 --z4'l{right}...z5l---z6l...{left}z17'r
1637 --z17'l--z17l{right}...z6r---z5r...{left}.5[z4r,z4'r]{right}
1638 ...z3r---z2r...{left}z11l--z11'l--cycle; % stroke
1639 penlabels(1,2,3,4,5,6,7); endchar;
1640
1641 ecchar "Cent sign"; % from wasychr (wasy)
1642 % Modified height and depth (jk)
1643 % Modified: Bar instead of broken bar
1644 beginchar(oct"242",9u#,x_height#+.5desc_depth#,.5desc_depth#);
1645 italcorr x_height#*slant-.2u#;
1646 adjust_fit(0,0);
1647 pickup fine.nib; pos2(vair',90); pos4(vair',270);
1648 x2=x4=.5(w+u); top y2r=vround(x_height+1.5oo); bot y4r=-oo;
1649 pos3(curve,180); lft x3r=hround max(.6u,1.35u-.5curve); y3=.5x_height;
1650 if serifs: pos1(hair,0); pos0(flare,0);
1651 y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,x_height]-.5flare);
1652 rt x1r=hround(w-.7u); bulb(2,1,0); % bulb
1653 pos5(hair,0); rt x5r=hround(w-.5u);
1654 y5=max(good.y(.5bar_height-.9),y4l+vair');
1655 (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
1656 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
1657 & pulled_super_arc.e(3,4)(.5superpull)
1658 ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e; % arc and lower terminal
1659 else: pos1(4/7[vair',flare],80);
1660 rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
1661 filldraw stroke term.e(2,1,right,.8,4); % upper terminal
1662 pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
1663 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
1664 forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
1665 if angle direction 1 of p.e>75:
1666 p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
1667 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
1668 & pulled_super_arc.e(3,4)(.5superpull) & p.e; fi % arc and lower terminal
1669 pickup crisp.nib;
1670 x6=x7=x8=x9=x2; y7=y2; y8=y4; bot y9=-d; y6-y7 = y8-y9;
1671 pos6(bar,0); pos7(bar,0);
1672 pos8(bar,0); pos9(bar,0);
1673 filldraw stroke z6e--z9e; % bar
1674 %filldraw stroke z6e--z7e; % upper bar
1675 %filldraw stroke z8e--z9e; % lower bar
1676 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
1677
1678 ecchar "Sterling sign"; % from italp (cm)
1679 % already contains bug fix found by Yannis Haralambous
1680 beginchar(oct"243",12u#,asc_height#,0);
1681 adjust_fit(0,.75asc_height#*slant-.5u#); pickup fine.nib;
1682 pos0(flare,0); pos1(hair,0); pos2(vair,90); pos3(stem,180);
1683 pos4(stem,180); pos4'(stem,0); pos5(vair,-90); z4'=z4;
1684 x2=2/3w-.5u; rt x3l=rt x4l=hround(.5w-u+.5stem); x5=2.5u;
1685 y1=y3=.75h; top y2=h+oo; y4=.25h; bot y5r=-oo;
1686 rt x1r=hround(w-1.5u); bulb(2,1,0); % bulb
1687 filldraw stroke pulled_arc.e(2,3)..z4e; % stem
1688 numeric light_stem; light_stem=2/3[vair,vstem];
1689 pos6(.5[hair,light_stem],-180); pos7(light_stem,-300);
1690 pos8(light_stem,-300); pos9(hair,-180);
1691 lft x6r=hround u; x7=3u; x8=w-3.5u; rt x9l=hround(w-u);
1692 y6=.4[y5,y7]; top y7r=vround .2h; bot y8l=-oo; y9=good.y .2h;
1693 filldraw stroke pulled_arc.e(4',5)...z6e{up}...z7e{right}
1694 ..{right}z8e...{up}z9e; % loop and arm
1695 pos10(bar,90); pos11(bar,90); x10=3u; x11=w-4.5u;
1696 top y10r=top y11r=vround(.5h+.5bar); filldraw stroke z10e--z11e; % bar
1697 penlabels(1,2,3,4,5,6,7,8,9,10,11); endchar;
1698
1699 ecchar "Currency sign"; % from rsym (wasy)
1700 beginchar(oct"244",1.13 min(asc_height#,9/7x_height#)+2u#,
1701 min(asc_height#,9/7x_height#),0);
1702 italcorr x_height#*slant;
1703 adjust_fit(if monospace: u#,u# else: 0,0 fi);
1704 pickup rule.nib; autorounded;
1705 x4 = good.x .5w; x2-x6=y8-y4; y2=good.y .5h; bot y4=-oo;
1706 circle_points;
1707 z9 = 1.30[z5,z1];
1708 z10 = 1.30[z7,z3];
1709 z11 = 1.30[z1,z5];
1710 z12 = 1.30[z3,z7];
1711 draw_circle;
1712 draw z1--z9;
1713 draw z3--z10;
1714 draw z5--z11;
1715 draw z7--z12;
1716 labels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
1717
1718
1719 ecchar "Yen symbol"; % from asymbols (msam)
1720 % Change (jk): Use correct pen for horizontal bars
1721 compute_spread(.45x_height#, .55x_height#);
1722 beginchar(oct"245",13u#,cap_height#,0); %% adapted from "Y"
1723 italcorr cap_height#*slant+.45u#;
1724 adjust_fit(cap_serif_fit#,cap_serif_fit#); numeric
1725 left_stem,right_stem,outer_jut,dy,alpha;
1726 left_stem=cap_stem-stem_corr; right_stem=min(cap_hair if
1727 hefty:-2stem_corr fi,left_stem); outer_jut=.75cap_jut;
1728 x1l=w-x4r=l+letter_fit+outer_jut+.05u;
1729 x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h;
1730 y2=y3=y5=.4h; dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
1731 penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
1732 penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
1733 penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
1734 z0=whatever[z1r,z2r]=whatever[z3l,z4l]; if
1735 y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
1736 fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
1737 --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
1738 ...{down}z0+.5left--cycle; % diagonals and stem
1739 else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
1740 --diag_end(5r,6r,1,1,6l,5l)--z5l
1741 --diag_end(2l,1l,1,1,1r,0)--cycle; fi % diagonals & stem
1742 if serifs: numeric inner_jut; pickup tiny.nib;
1743 prime_points_inside(1,2); prime_points_inside(4,3);
1744 prime_points_inside(6,5);
1745 if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut:
1746 inner_jut=cap_jut;
1747 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
1748 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut); % upper left serif
1749 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); % upper right serif
1750 dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi % lower serif
1751 pickup extra_rule.nib;
1752 x7=x9=x1l; x8=x10=x4r; y9=y10;
1753 top y7=bar_height; y7=y8; draw z7--z8;
1754 y9-y7=spread; draw z9--z10; % crossing bars
1755 penlabels(0,1,2,3,4,5,6,1',2',3',4',5',6',7,8,9,10); endchar;
1756
1757 ecchar "Broken vertical bar"; % jk
1758 beginchar(oct"246",3u#,body_height#,paren_depth#);
1759 italcorr body_height#*slant - u#;
1760 adjust_fit(0,0); pickup rule.nib;
1761 top y1=h; .5[y1,y4]=math_axis;
1762 compute_spread(.45x_height#,.55x_height#); y2-y3=spread;
1763 .5[y2,y3]=math_axis;
1764 x1=x2=x3=x4=good.x .5w;
1765 draw z1--z2; draw z3--z4;
1766 labels(1,2,3,4); endchar;
1767
1768 ecchar "Section sign"; % from mathsy, renovated (jk)
1769 beginchar(oct"247",6.5u#+max(1.5u#,stem#),asc_height#,desc_depth#);
1770 adjust_fit(0,0); pickup fine.nib;
1771 numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
1772 numeric ess'; ess'=max(fine.breadth,cap_ess);
1773 numeric sstem; sstem=hround .5[s_slab,ess']-fine;
1774 if sstem < fine.breadth: sstem:=fine.breadth; fi
1775 pos2(vair,90); pos3(sstem,180);
1776 pos4(ess',270); pos4'(vair,270);
1777 pos5'(sstem,0); pos5(sstem,180);
1778 pos6(ess',90); pos6'(vair,90); pos7(sstem,0);
1779 pos8(vair,-90);
1780 top y2r=h+oo; bot y8r=-d-oo;
1781 y3=.52[y4,y2]; y5=.52[y4,y6]; y7=.52[y6,y8]; y5'=.52[y6,y4];
1782 y2-y4=y4-y6=y6-y8;
1783 bot z4'=bot z4; top z6'=top z6;
1784 lft x3r=hround 1.25u;
1785 x2=x4=x6=x8=.5w; x5=x7=w-x3; x5'=x3;
1786 if serifs:
1787 pos0(stem,0); pos1(hair,0); pos9(hair,-180); pos10(stem,-180);
1788 rt x1r=hround(w-1.5u); x9=w-x1; y2-y1=y9-y8=(y2-y8)/8;
1789 bulb(2,1,0); bulb(8,9,10); % bulbs
1790 else:
1791 pos1(.6[slab,flare],-100); pos9(flare,-100); pos2'(vair,-90);
1792 rt x1l=hround(w-1.3u); lft x9r=hround .8u; z2'=z2;
1793 top y1l=vround .92asc_height+oo; bot y9r=vround .1asc_height-d-oo;
1794 filldraw stroke term.e(2',1,right,.9,4); % upper arc and terminal
1795 filldraw stroke term.e(8,9,left,.9,4); % lower arc and terminal
1796 fi
1797 filldraw stroke z2e{left}...z3e{down}...z4e{3(x5-x3),y5-y3}
1798 ...z5e{down}...{left}z6'e; % upper stroke
1799 filldraw stroke z4'e{left}...z5'e{down}...z6e{3(x7-x5'),y7-y5'}
1800 ...z7e{down}...{left}z8e; % upper stroke
1801 penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
1802
1803 ecchar "Umlaut (double dot) accent"; % from accent (cm)
1804 numeric dot_diam#,dot_diam;
1805 dot_diam#=max(dot_size#,cap_curve#);
1806 beginchar(oct"250",9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
1807 dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
1808 italcorr h#*slant+.5dot_diam#-2.25u#;
1809 adjust_fit(0,0);
1810 pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
1811 x1=x2=2.75u; top y2r=h+1;
1812 if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
1813 y1=.5[y2l,y2r]; dot(1,2); % left dot
1814 pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
1815 dot(3,4); % right dot
1816 penlabels(1,2,3,4); endchar;
1817
1818 ecchar"Copyright";
1819 beginchar(oct"251",20u#,body_height#,max(paren_depth#,desc_depth#));
1820 autorounded;
1821 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1822 if .5w <> good.x .5w: change_width; fi
1823 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1824 circle_points; draw_circle; % circle
1825 labels(1,2,3,4,5,6,7,8);
1826 clearxy; autorounding:=0;
1827 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-6u);
1828 rr=hround(.5w+5u);
1829 if serifs:
1830 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
1831 pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
1832 rt x1r=rt x5r=hround(rr-u); lft x3r=hround(ll+u); x2=x4=.55[x3,x1];
1833 top y2r=hh+o; bot y4r=-o; y3=.5[y2,y4];
1834 bot y1=min(vround max(.6hh,.7x_height-.5vair),bot y2l-eps);
1835 y5=max(good.y .95(hh-y1),y4l+eps);
1836 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
1837 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
1838 filldraw stroke z1e{x2-x1,10(y2-y1)}
1839 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
1840 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=hh+o;
1841 x1r-x1'=2cap_curve-fine; y1'=y1;
1842 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
1843 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
1844 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
1845 else:
1846 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
1847 pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
1848 rt x1r=hround(rr-1.1u); x2=x4=.5w+1.25u;
1849 lft x3r=ll+hround max(u,2u-.5cap_curve); rt x5r=hround(rr-.9u);
1850 top y1r=vround .95hh+o; top y2r=hh+o; y3=.5hh;
1851 bot y4r=-o; bot y5r=vround .08hh-o; y5l:=good.y y5l; x5l:=good.x x5l;
1852 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
1853 & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
1854 penlabels(1,1',2,3,4,5,6); endchar;
1855
1856 ecchar"Copyleft";
1857 beginchar(oct"253",20u#,body_height#,max(paren_depth#,desc_depth#));
1858 autorounded;
1859 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1860 if .5w <> good.x .5w: change_width; fi
1861 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1862 circle_points; draw_circle; % circle
1863 labels(1,2,3,4,5,6,7,8);
1864 clearxy; autorounding:=0;
1865 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-5u);
1866 rr=hround(.5w+6u);
1867 if serifs:
1868 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,-90);
1869 pos3(cap_curve,-180); pos4(cap_band,-270); pos5(hair,-360);
1870 lft x1l=lft x5l=hround(ll+u); rt x3l=hround(rr-u); x2=x4=.55[x3,x1];
1871 top y2l=hh+o; bot y4l=-o; y3=.5[y2,y4];
1872 bot y1=min(vround max(.6hh,.7x_height-.5vair),bot y2r-eps);
1873 y5=max(good.y .95(hh-y1),y4r+eps);
1874 (x2r',y2r)=whatever[z2l,z1r]; x2r:=min(x2r',x2r+.5u);
1875 (x4r',y4r)=whatever[z4l,z5r]; x4r:=min(x4r',x4r+.5u);
1876 filldraw stroke z1e{x2-x1,10(y2-y1)}
1877 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
1878 pos6(.3[fine.breadth,cap_hair],0); x6l=x1l; top y6=hh+o;
1879 x1l-x1'=2cap_curve-fine; y1'=y1;
1880 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{right};
1881 numeric t; t=xpart(upper_arc intersectiontimes (z6r--z1'));
1882 filldraw z1l--z6l--z6r--subpath(t,0) of upper_arc--cycle; % barb
1883 else:
1884 pickup fine.nib; pos1(1.2flare,-80); pos2(slab,-90);
1885 pos3(cap_curve,-180); pos4(slab,-270); pos5(flare,-275);
1886 lft x1l=hround(ll+1.1u); x2=x4=.5w-1.25u;
1887 rt x3l=rr-hround max(u,2u-.5cap_curve); lft x5l=hround(ll+.9u);
1888 top y1l=vround .95hh+o; top y2l=hh+o; y3=.5hh;
1889 bot y4l=-o; bot y5l=vround .08hh-o; y5r:=good.y y5r; x5r:=good.x x5r;
1890 filldraw stroke rterm.e(2,1,left,.9,4) & super_arc.e(2,3)
1891 & super_arc.e(3,4) & term.e(4,5,left,.8,4); fi % arc and terminals
1892 penlabels(1,1',2,3,4,5,6); endchar;
1893
1894 ecchar "Logical not sign"; % from sym
1895 beginchar(oct"254",12u#,x_height#,0);
1896 italcorr x_height#*slant-.5u#;
1897 adjust_fit(0,0); pickup rule.nib;
1898 lft x1=hround u-eps; x2=x3=w-x1;
1899 y1=y2=good.y .5[bar_height,h]; y2-y3=1.2(h-bar_height);
1900 draw z1--z2--z3; % bar and stem
1901 labels(1,2,3); endchar;
1902
1903 ecchar"Circled P"; % Sound recording copyright sign % jk
1904 beginchar(oct"255",20u#,body_height#,max(paren_depth#,desc_depth#));
1905 autorounded;
1906 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1907 if .5w <> good.x .5w: change_width; fi
1908 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1909 circle_points; draw_circle; % circle
1910 labels(1,2,3,4,5,6,7,8);
1911 clearxy; autorounding:=0;
1912 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-6u);
1913 rr=hround(.5w+6u);
1914 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1915 pos0(cap_stem',0); pos0'(cap_stem,0);
1916 lft x1l=ll+hround max(2u,3u-.5cap_stem'); top y1=hh; bot y2=0;
1917 x1l=x2l=x0l=x0'l; y0=y0'=y7;
1918 penpos3(cap_band,90); penpos4(cap_band,90);
1919 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1920 penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
1921 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1922 x7=x2; y7l=vround(.5hh); x4=x6=.5w+.75u; x5r=hround(rr-u);
1923 x4l:=x6l:=x4-.25cap_curve;
1924 filldraw stroke z1e--z2e; % stem
1925 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1926 if serifs:
1927 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1928 dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower serif
1929 fi
1930 penlabels(0,1,2,3,4,5,6); endchar;
1931
1932 ecchar"Registered"; % jk
1933 beginchar(oct"256",20u#,body_height#,max(paren_depth#,desc_depth#));
1934 autorounded;
1935 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1936 if .5w <> good.x .5w: change_width; fi
1937 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1938 circle_points; draw_circle; % circle
1939 labels(1,2,3,4,5,6,7,8);
1940 clearxy; autorounding:=0;
1941 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-6u);
1942 rr=hround(.5w+6u);
1943 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1944 lft x1l=lft x2l=ll+hround max(2u,3u-.5cap_stem'); top y1=hh; bot y2=0;
1945 filldraw stroke z1e--z2e; % stem
1946 penpos3(cap_band,90); penpos4(cap_band,90);
1947 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1948 penpos6(vair,-90); penpos7(vair,-90);
1949 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1950 x7=x2; y7l=vround(.5hh+.5vair); x4=x6;
1951 if serifs: x4=.5w-.5u; x5r=hround(rr-2.25u);
1952 else: x4=.5w+.5u; x5r=hround(rr-u); fi
1953 x4l:=x6l:=x4-.125cap_curve;
1954 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1955 if serifs: pos6'(vair,-90); pos0(cap_stem,180);
1956 pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
1957 z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
1958 y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
1959 bot y9r=-o; rt x10r=hround(rr-.25u); y10=1/3[y2,y7];
1960 filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up}; % tail
1961 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1962 dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower serif
1963 else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
1964 x8=x6+.5u; y8=y6; x9r=hround(rr-.5u); y9=0;
1965 fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi % tail
1966 penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
1967
1968 ecchar"High bar (Macron)"; % jk
1969 beginchar(oct"257",14u#,min(asc_height#,2x_height#),0);
1970 adjust_fit(0,0); pickup rule.nib;
1971 lft x1=hround 1.5u-eps; x2=w-x1; top y1=top y2=h;
1972 draw z1--z2; % bar
1973 labels(1,2); endchar;
1974
1975 ecchar "Plus-or-minus sign"; % from sym
1976 beginarithchar(oct"261"); pickup rule.nib;
1977 numeric shiftup; shiftup=vround 1.5u;
1978 x1=x2=.5w; lft x3=lft x5=hround u-eps; x4=x6=w-x3;
1979 .5[y1,y2]=y3=y4=math_axis+shiftup; top y1=h+shiftup; y5=y6=y2;
1980 draw z1--z2; % stem
1981 draw z3--z4; % plus bar
1982 draw z5--z6; % minus bar
1983 labels(1,2,3,4,5,6); endchar;
1984
1985 ecchar"Degree sign"; % Yannis, Unicode Computer Modern
1986 beginchar(oct"260",4u#,cap_height#,0);
1987 adjust_fit(if monospace: 1.5u#,1.5u# else: u#,u# fi);
1988 pickup rule.nib; autorounded;
1989 if .5w <> good.x .5w: change_width; fi
1990 lft x6=0; x2=w-x6; top y8=h; y8-y2=x2-x8;
1991 circle_points; draw_circle; % circle
1992 labels(1,2,3,4,5,6,7,8); endchar;
1993
1994 ecchar"Tick mark"; % from accent (cmfonts, acute accent)
1995 beginchar(oct"264",9u#,min(asc_height#,2x_height#),0);
1996 italcorr h#*slant-if serifs: 1.5 fi u#;
1997 adjust_fit(0,0);
1998 if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
1999 y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
2000 numeric theta; theta=angle(z2-z1)+90;
2001 pos1(stem,theta); pos2(hair,theta);
2002 filldraw circ_stroke z1e--z2e; % diagonal
2003 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
2004 rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
2005 top y1=h; bot y2=vround 2/3[h,x_height];
2006 filldraw stroke z1e--z2e; fi % diagonal
2007 penlabels(1,2); endchar;
2008
2009 iff not variant_g:
2010 ecchar"Micro sign"; % jk, based on cm `u'
2011 beginchar(oct"265",10u#,x_height#,desc_depth#);
2012 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
2013 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
2014 numeric light_vair; light_vair=vair if hefty: -vround 2vair_corr fi;
2015 if light_vair<fine.breadth: light_vair:=fine.breadth; fi
2016 pickup tiny.nib; pos1(stem,0); pos2(stem,0); pos7(stem,0);
2017 pos3(stem,0); pos4(stem',0);
2018 lft x1l=hround(2.5u-.5stem); x1=x2=x7; x3=w-x1; x3r=x4r;
2019 if serifs: top y1=h+min(oo,serif_drop); bot y4=-min(oo,serif_drop);
2020 else: top y1=h; bot y4=0; fi
2021 pos0(stem,0); pos0'(stem',0);
2022 x0=x3; x0'=x4; y0=y0'; bot y7=-d;
2023 penpos2'(stem-fine,-180); z2'=z2; y3=y1; y2=.5bar_height;
2024 penpos5(max(eps,light_vair-fine),-90); penpos6(thin_join-fine,0);
2025 y6=y0=2/3bar_height;
2026 filldraw stroke z1e--z7e; % left stem
2027 filldraw stroke z3e..z0e--z0'e..z4e; % right stem
2028 pickup fine.nib; bot y5r=-oo; x5l=.5w-.25u; lft x6l=tiny.lft x0l;
2029 (x,y5r)=whatever[z5l,z6l]; x5r:=max(x,.5[x5,x2'r]);
2030 filldraw stroke {{interim superness:=hein_super;
2031 pulled_arc.e(2',5)}} & z5e{right}...{up}z6e; % arc
2032 if serifs: sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper left serif
2033 sloped_serif.l(3,0,b,1/3,jut,serif_drop); % upper right serif
2034 sloped_serif.r(4,0',c,1/3,jut,min(oo,serif_drop)); % lower right serif
2035 pickup crisp.nib;
2036 dish_serif(7,1,d,1/3,jut,e,1/3,jut); fi % lower left serif
2037 penlabels(1,2,3,4,5,7); labels(6); endchar;
2038
2039 iff variant_g: % This triggers italics
2040 ecchar "Micro sign"; % from greekl (cm)
2041 beginchar(oct"265",9u#,x_height#,desc_depth#);
2042 italcorr 1/3x_height#*slant+.5hair#+.5u#;
2043 adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
2044 pos1(stem,-180); pos2(stem,-180); x1=x2=x3; lft x1r=hround(1.5u-.5stem);
2045 y1+.5stem=h+oo; y2-.5stem=-d-o;
2046 filldraw z1r---z2r..z2l---z1l..cycle; % left stem
2047 pos3(stem,-180); pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
2048 pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
2049 x5=x6=x7; x9=w; hook_out(7,8,9); % closing hook
2050 y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
2051 filldraw stroke super_arc.e(3,4)...{up}z5e; % left stem and arc
2052 filldraw circ_stroke z6e--z7e; % right stem
2053 math_fit(desc_depth#*slant+.5stem#-u#,ic#);
2054 penlabels(1,2,3,4,5,6,7,8,9); endchar;
2055
2056 ecchar "Paragraph mark"; % from mathsy
2057 beginchar(oct"266",11u#,asc_height#,desc_depth#);
2058 adjust_fit(0,0); pickup rule.nib; autorounded;
2059 top y1=h; bot y6=-d-eps; y4=y7=y9=y1;
2060 y8=y6; y3=y5=good.y .5[y1,y6];
2061 x7-x4=ceiling(rule_thickness+1.25u);
2062 lft x2=hround u; y2=.5[y1,y3]; x4=x5=x6; rt x9=hround(w-.5u);
2063 x7=x8=good.x(x9-1.5u); x1=x3=min(.5w,x4);
2064 filldraw z4..z1{left}...z2{down}...{right}z5--cycle; % filled bowl
2065 draw z9--z4--z6; % left stem and upper serif
2066 draw z7--z8; % right stem
2067 if serifs:
2068 x11=x9; x10-x8=x4-x9;
2069 bot y10=-d-eps; y10=y11;
2070 draw z10--z11; % lower serif
2071 fi
2072 labels(1,2,3,4,5,6,7,8,9,10,11); endchar;
2073
2074 ecchar "Centered dot"; % reengineered for catalan l.l
2075 beginchar(oct"267",(11u#-width_adj#-2max(2u#+.5cap_stem#,3u#)),
2076 x_height#,0);
2077 adjust_fit(0,0);
2078 pickup fine.nib;
2079 pos1(udot_diam,0); pos2(udot_diam,90);
2080 lft x1l=hround(.5w-.5udot_diam); y1+.5udot_diam=vround(bar_height+.5udot_diam);
2081 z1=z2; dot(1,2); % dot
2082 penlabels(1,2); endchar;
2083
2084 ecchar "Reference mark"; % From Haralambous/Plaice
2085 beginchar(oct"270",1/3[x_height#,asc_height#],
2086 1/3[x_height#,asc_height#],0);
2087 italcorr .5x_height#*slant-.5u#;
2088 adjust_fit(if monospace:
2089 -1/3[x_height#,asc_height#] + mono_charwd#,
2090 -1/3[x_height#,asc_height#] + mono_charwd#
2091 else: u#,u# fi);
2092 pickup rule.nib;
2093 Dot_size:=min(dot_size,max(1,.25h-rule_thickness));
2094 lft x1=0; top y1=h;
2095 x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=.5h; y2=y4;
2096 draw z1--z2; draw z3--z4; % diagonals
2097 top z1'=.5[top z1,top z3]-(0,.5Dot_size);
2098 rt z3'=.5[rt z3,rt z2]-(.5Dot_size,0);
2099 bot z2'=.5[bot z2,bot z4]+(0,.5Dot_size);
2100 lft z4'=.5[lft z4,lft z1]+(.5Dot_size,0);
2101 z1'=z1''; z2'=z2''; z3'=z3''; z4'=z4'';
2102 penpos1'(Dot_size,0);
2103 penpos1''(Dot_size,90); dot(1',1'');
2104 penpos2'(Dot_size,0);
2105 penpos2''(Dot_size,90); dot(2',2'');
2106 penpos3'(Dot_size,0);
2107 penpos3''(Dot_size,90); dot(3',3'');
2108 penpos4'(Dot_size,0);
2109 penpos4''(Dot_size,90); dot(4',4'');
2110 labels(1,2,3,4,1',2',3',4',1'',2'',3'',4'',1'r,1'l,1''r,1''l);
2111 endchar;
2112
2113 ecchar"Root sign"; % textsurd, from wnri
2114 beginchar(oct"273",8.5u#,body_height#,paren_depth#-rule_thickness#);
2115 italcorr body_height#*slant;
2116 adjust_fit(0,-letter_fit#);
2117 pickup rule.nib;
2118 w':=7u;
2119 x1=good.x (1/9w'+2.5u); x2=good.x (.65w'+2.5u);
2120 bot y1=-.5d; bot y2=asc_height;
2121 draw z1--z2; % diagonal
2122 pickup crisp.nib;
2123 pos3(if hefty: else: .7 fi max(curve,rule_thickness),0);
2124 x3l=1.5[x2,x1]; y3=.5[y1,y2];
2125 pos4(rule_thickness,0); x4=x1; bot y4=-.5d;
2126 pos5(vair,-45); x5l=good.x(x3l-u); z5l=whatever[z3r,z2];
2127 z6=z5r+whatever*(z2-z3r)=whatever[z3l,z4l];
2128 z7=whatever[z1,z2]=z3r+whatever*(z4l-z3l);
2129 filldraw z5r--z6--z4l--z4--z7--z3r--z5l--cycle; % left diagonal and serif
2130 x8=x2+2u; y8=y2;
2131 pickup rule.nib;
2132 draw z2--z8;
2133 penlabels(1,2,3,4,5,6,7,8);
2134 endchar;
2135
2136 ecchar "Euro currency sign"; % derived from the letter C (WaS)
2137 if serifs: beginchar(oct"277",14u#,cap_height#,0); % 1u# wider than C
2138 italcorr cap_height#*slant-.5u#;
2139 adjust_fit(0,0);
2140 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
2141 pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
2142 rt x1r=rt x5r=hround(w-u); lft x3r=hround 2u; x2=x4=.55[x3,x1];
2143 top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
2144 bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
2145 y5=max(good.y .95(h-y1),y4l+eps);
2146 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
2147 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
2148 filldraw stroke z1e{x2-x1,10(y2-y1)}
2149 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
2150 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
2151 x1r-x1'=2cap_curve-fine; y1'=y1;
2152 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
2153 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
2154 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
2155 else: beginchar(oct"277",12.5u#,cap_height#,0); % 1u# wider than C
2156 italcorr cap_height#*slant-.5u#;
2157 adjust_fit(0,0);
2158 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
2159 pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
2160 rt x1r=hround(w-.9u); x2=x4=.5w+1.25u;
2161 lft x3r=hround (max(u,2u-.5cap_curve)+u); rt x5r=hround(w-1.1u);
2162 top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
2163 bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
2164 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
2165 & super_arc.e(3,4) & term.e(4,5,right,.8,4); % arc and terminals
2166 fi
2167 % middle bars:
2168 pos7(slab,69); pos8(slab,69);
2169 pos9(slab,69); pos10(slab,69);
2170 % Unterkante oberer Balken:
2171 bot y7l=vround(y3+if hefty: .5vair else: min(vair, .06h) fi +eps);
2172 % Oberkante unterer Balken:
2173 top y9r=vround(y3-if hefty: .5vair else: min(vair, .06h) fi);
2174 y8=y7;
2175 y10=y9;
2176 x7=x9=hround u;
2177 rt x8r=hround(w - if serifs: 3 else: 2.5 fi u);
2178 rt x10r = rt x8r -
2179 ((slab + if hefty: vair else: 2min(vair, .06h) fi) * sind 21);
2180 filldraw stroke z7e--z8e; % upper bar
2181 filldraw stroke z9e--z10e;% lower bar
2182
2183 math_fit(-.3cap_height#*slant-.5u#,.5ic#);
2184
2185 penlabels(1,1',2,3,4,5,6,7,8,9,10); endchar;
2186
2187
2188 ecchar "Times operator"; % from mathsy
2189 beginarithchar(oct"326"); pickup rule.nib;
2190 x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
2191 x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
2192 draw z1--z2; draw z3--z4; % diagonals
2193 labels(1,2,3,4); endchar;
2194
2195 ecchar "Elementary division operator"; % from mathsy
2196 beginarithchar(oct"366"); pickup rule.nib;
2197 numeric del; del=dot_size-currentbreadth;
2198 x3-.5del=good.x(.5w-.5del); center_on(x3);
2199 y3+.5del=good.y(math_axis+math_spread[.5x_height,.6x_height]+.5del);
2200 lft x1=hround u-eps; x2=w-x1; y1=y2=math_axis;
2201 draw z1--z2; % bar
2202 pos3(dot_size,0); pos4(dot_size,90); z3=z4;
2203 pos5(dot_size,0); pos6(dot_size,90); z5=z6; x5=x3; .5[y3,y5]=math_axis;
2204 dot(3,4); dot(5,6); % dots
2205 penlabels(1,2,3,4,5,6); endchar;
2206
2207
2208 endinput;