Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/bgreeku.mf

raw
1 % Computer Modern Greek caps, analogous to the uppercase Roman letters.
2 % changed for CM Bright [1995/10/01 v0.997 WaS]
3
4 % Character codes \0000 through \0012 are generated,
5 % using plain \TeX's standard text font layout conventions.
6
7 cmchar "Uppercase Greek Gamma";
8 beginchar(oct"000",11u#-width_adj#,cap_height#,0);
9 italcorr cap_height#*slant-beak_jut#-.25u#;
10 adjust_fit(cap_serif_fit#,0);
11 h:=vround(h-stem_corr);
12 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
13 lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); top y1=h; bot y2=0;
14 filldraw stroke z1e--z2e; % stem
15 pickup crisp.nib; pos3(slab,90); pos4(hair,0);
16 top y3r=h; x3=x1; rt x4r=hround(w-.75u); y4=good.y(y3l-beak)-eps;
17 arm(3,4,e,beak_darkness,beak_jut); % arm and beak
18 if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
19 dish_serif(2,1,c,1/3,cap_jut,d,1/3,1.25cap_jut); fi % lower serif
20 math_fit(0,ic#-2.5u#); penlabels(1,2,3,4); endchar;
21
22 cmchar "Uppercase Greek Delta";
23 %beginchar(oct"001",15u#,cap_height#,0);
24 beginchar(oct"001",12u#,cap_height#,0);% (WaS)
25 adjust_fit(0,0);
26 numeric left_stem,alpha;
27 left_stem=cap_hair if hefty: -3stem_corr fi;
28 x1l=w-x4r=.75u; y1=y4=0;
29 x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
30 alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
31 penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
32 penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
33 fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle; % triangle
34 z0=whatever[z1r,z2r]=whatever[z3l,z4l];
35 y5=y6=cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
36 if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
37 unfill z0+.5right{down}...{z4-z3}z6--z5{z2-z1}
38 ...{up}z0+.5left--cycle; % counter
39 else: unfill z0--z5--z6--cycle; fi % counter
40 penlabels(0,1,2,3,4,5,6); endchar;
41
42 cmchar "Uppercase Greek Theta";
43 beginchar(oct"002",14u#,cap_height#,0);
44 italcorr .7cap_height#*slant-.5u#;
45 adjust_fit(0,0);
46 numeric light_curve; light_curve=hround(cap_curve-2stem_corr);
47 penpos1(vair,90); penpos3(vround(vair+.5vair_corr),-90);
48 penpos2(light_curve,180); penpos4(light_curve,0);
49 if monospace: x2r=hround 1.5u;
50 interim superness:=sqrt superness; % make |"O"|, not |"0"|
51 else: x2r=hround u; fi
52 x4r=w-x2r; x1=x3=.5w; y1r=h+o; y2=y4=.5h-vair_corr; y3r=-o;
53 penstroke pulled_super_arc.e(1,2)(.5superpull)
54 & pulled_super_arc.e(2,3)(.5superpull)
55 & pulled_super_arc.e(3,4)(.5superpull)
56 & pulled_super_arc.e(4,1)(.5superpull) & cycle; % bowl
57 pickup crisp.nib; pos5(cap_vstem,90); pos6(cap_vstem,90);
58 lft x5=w-rt x6=hround(x2l+u)+1; y5=y6=.5[y1l,y3l];
59 filldraw stroke z5e--z6e; % bar
60 if serifs: pos7(hair,0); pos8(hair,0); pos9(hair,0); pos10(hair,0);
61 x7l=x8l=x5; x9r=x10r=x6;
62 y7-y5r=y9-y6r=y5l-y8=y6l-y10=vround .05h;
63 filldraw stroke z7e--z8e; % left serif
64 filldraw stroke z9e--z10e; fi % right serif
65 math_fit(-.3cap_height#*slant-.5u#,ic#-.5u#);
66 penlabels(1,2,3,4,5,6,7,8,9,10); endchar;
67
68 cmchar "Uppercase Greek Lambda";
69 beginchar(oct"003",12u#,cap_height#,0);
70 adjust_fit(cap_serif_fit#,cap_serif_fit#);
71 numeric left_stem,outer_jut,alpha;
72 left_stem=cap_hair if hefty: -3stem_corr fi;
73 outer_jut=.7cap_jut; x1l=w-x4r=l+letter_fit+outer_jut+.5u; y1=y4=0;
74 x2-x1=x4-x3; x3r=x2r+apex_corr; y2=y3=h+apex_o+apex_oo;
75 alpha=diag_ratio(2,left_stem,y2-y1,x4r-x1l-apex_corr);
76 penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
77 penpos3(alpha*cap_stem,0); penpos4(alpha*cap_stem,0);
78 z0=whatever[z1r,z2r]=whatever[z3l,z4l];
79 if y0<h-cap_notch_cut: y0:=h-cap_notch_cut;
80 fill z0+.5right{down}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
81 --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
82 ...{up}z0+.5left--cycle; % left and right diagonals
83 else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
84 --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
85 if serifs: numeric inner_jut; pickup tiny.nib;
86 prime_points_inside(1,2); prime_points_inside(4,3);
87 if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut: inner_jut=cap_jut;
88 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
89 dish_serif(1',2,a,1/2,outer_jut,b,.6,inner_jut)(dark); % left serif
90 dish_serif(4',3,c,1/2,inner_jut,d,1/3,outer_jut); fi % right serif
91 penlabels(0,1,2,3,4,5,6); endchar;
92
93 cmchar "Uppercase Greek Xi";
94 beginchar(oct"004",12u#,cap_height#,0);
95 italcorr cap_height#*slant-.35u#;
96 adjust_fit(0,0);
97 h:=vround(h-2stem_corr);
98 numeric shaved_stem; shaved_stem=hround .9[vair,.85cap_stem];
99 if shaved_stem<crisp.breadth: shaved_stem:=crisp.breadth; fi
100 pickup crisp.nib; pos1(shaved_stem,90); pos2(hair,0);
101 top y1r=h; x1=.5w; rt x2r=hround(w-.85u); y2=good.y(y1l-4/9beak)-eps;
102 arm(1,2,a,.4beak_darkness,.3beak_jut); % upper right arm and beak
103 pos3(hair,180); x3=w-x2; y3=y2;
104 arm(1,3,b,.4beak_darkness,-.3beak_jut); % upper left arm and beak
105 pos4(shaved_stem,-90); pos5(hair,0);
106 bot y4r=0; x4=.5w; rt x5r=hround(w-.75u); y5=good.y(y4l+.5beak)+eps;
107 arm(4,5,c,.4beak_darkness,.3beak_jut); % lower right arm and beak
108 pos6(hair,180); x6=w-x5; y6=y5;
109 arm(4,6,d,.4beak_darkness,-.3beak_jut); % lower left arm and beak
110 pos7(shaved_stem,90); pos8(shaved_stem,90);
111 lft x7=w-rt x8=hround if serifs: 2.5 else: 2 fi\\ u;
112 top y7r=top y8r=vround(.52h+.5shaved_stem);
113 filldraw stroke z7e--z8e; % middle bar
114 if serifs: numeric xjut;
115 if bot y2>top y7r+.75cap_jut: xjut=.5cap_jut;
116 else: bot y2=top y7r+1.5xjut; fi
117 pos11(hair,0); pos12(hair,0); y11=y12;
118 pos13(hair,0); pos14(hair,0); y13=y14;
119 lft x11l=lft x13l=w-rt x12r=w-rt x14r=hround 2.5u;
120 top y11-bot y13=shaved_stem+2xjut; .5[y11,y13]=y7;
121 filldraw stroke z11e--z13e; filldraw stroke z12e--z14e; fi % middle serifs
122 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,11,12,13,14); endchar;
123
124 cmchar "Uppercase Greek Pi";
125 beginchar(oct"005",13u#+width_adj#,cap_height#,0);
126 italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
127 adjust_fit(cap_serif_fit#,cap_serif_fit#); pickup tiny.nib;
128 h:=vround(h-stem_corr);
129 pos1(cap_stem,0); pos2(cap_stem,0); pos3(cap_stem,0); pos4(cap_stem,0);
130 lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
131 top y1=top y3=h; bot y2=bot y4=0;
132 filldraw stroke z1e--z2e; % left stem
133 filldraw stroke z3e--z4e; % right stem
134 penpos5(cap_bar,90); penpos6(cap_bar,90);
135 x5=x1; x6=x3; y5r=y6r=h;
136 fill stroke z5e--z6e; % bar
137 if serifs: numeric inner_jut;
138 if rt x1r+cap_jut+.5u+1<=lft x3l-cap_jut: inner_jut=cap_jut;
139 else: rt x1r+inner_jut+.5u+1=lft x3l-inner_jut; fi
140 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,eps); % upper left serif
141 dish_serif(2,1,c,1/3,cap_jut,d,1/3,inner_jut); % lower left serif
142 nodish_serif(3,4,e,1/3,eps,f,1/3,cap_jut); % upper right serif
143 dish_serif(4,3,g,1/3,inner_jut,h,1/3,cap_jut); fi % lower right serif
144 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
145
146 cmchar "Uppercase Greek Sigma";
147 beginchar(oct"006",13u#,cap_height#,0);
148 italcorr cap_height#*slant-beak_jut#-.5u#;
149 adjust_fit(0,0);
150 numeric bot_arm_thickness;
151 bot_arm_thickness=Vround .25[slab,cap_vstem];
152 pickup tiny.nib; lft x1l=hround u; x1l=x2l=x4l;
153 top y1=h; bot y2=h-slab-eps; bot y4=0; x3l-x1l=4/11(w-2u); y3=.5h;
154 numeric alpha[]; alpha1=((x3l-x1l)++(y2-y3))/(y2-y3);
155 penpos1(alpha1*(cap_stem-tiny),0); penpos2(alpha1*(cap_stem-tiny),0);
156 penpos3(alpha1*(cap_stem-tiny),0);
157 alpha2=diag_ratio(1,cap_hair-tiny,y3-y4,x3r-x4l);
158 penpos4(alpha2*(cap_hair-tiny),0);
159 z0=whatever[z2l,z3l]=z4l+whatever*(z3r-z4r);
160 filldraw z1l--z2l--z0--z4l--z4r--z3r--z2r--z1r--cycle; % diagonals
161 pickup crisp.nib; pos5(slab,90); pos6(hair,0);
162 top y5r=h; x5=x1; rt x6r=hround(w-u); y6=good.y(y5l-beak)-eps;
163 arm(5,6,a,beak_darkness,beak_jut); % upper arm and beak
164 pos7(bot_arm_thickness,-90); pos8(hair,0);
165 bot y7r=0; z7l=whatever[z4,z3]; x7r:=x4; x8=x6; y8=good.y(y7l+beak)+eps;
166 arm(7,8,b,beak_darkness,beak_jut); % lower arm and beak
167 math_fit(0,.5ic#); penlabels(0,1,2,3,4,5,6,7,8); endchar;
168
169 cmchar "Uppercase Greek Upsilon";
170 beginchar(oct"007",14u#,cap_height#,0);
171 italcorr .8cap_height#*slant-.5u#;
172 adjust_fit(0,0);
173 pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
174 lft x1l=lft x2l=hround(.5w-.5cap_stem); y1=.5h; bot y2=0;
175 filldraw stroke z1e--z2e; % stem
176 penpos3(.6cap_stem,0); penpos4(.75cap_curve,90); penpos5(cap_hair,180);
177 z3l=lft z1l; x5r=hround u; y5=bot .8h; x4=.61803[x3l,x5l]; y4r=h+o;
178 penpos5'(cap_hair,180); x5'=x5; y5'=h;
179 fill z3r{up}...z4r{left}...{down}diag_end(5'r,5r,1,1,5l,5'l){up}
180 ...{right}z4l...{down}z3l--cycle; % left arc
181 penpos6(.6cap_stem,0); penpos7(.75cap_curve,-90); penpos8(cap_hair,-180);
182 z6r=rt z1r; x8=w-x5; y8=y5; x7=w-x4; y7=y4;
183 penpos8'(cap_hair,-180); x8'=x8; y8'=h;
184 fill z6r{up}...z7r{right}...{down}diag_end(8'r,8r,1,1,8l,8'l){up}
185 ...{left}z7l...{down}z6l--cycle; % right arc
186 if serifs: dish_serif(2,1,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut); fi % serif
187 math_fit(-.8cap_height#*slant-.5u#,ic#-2.5u#);
188 penlabels(1,2,3,4,5,6,7,8); endchar;
189
190 cmchar "Uppercase Greek Phi";
191 beginchar(oct"010",13u#,cap_height#,0);
192 italcorr .5cap_height#*slant-.5u#;
193 adjust_fit(0,0);
194 numeric shaved_stem,light_curve;
195 shaved_stem=cap_stem-hround 2stem_corr;
196 light_curve=cap_curve-hround stem_corr;
197 pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
198 lft x1l=lft x2l=hround(.5w-.5shaved_stem); top y1=h; bot y2=0;
199 filldraw stroke z1e--z2e; % stem
200 penpos3(vair,90); penpos5(vair,-90);
201 penpos4(light_curve,180); penpos6(light_curve,0);
202 x4r=hround u; x6r=w-x4r; x3=x5=.5w;
203 y3r=vround(.85h if serifs:-slab fi); y4=y6=.5[y3,y5];
204 y5r=vround(.15h if serifs:+slab fi);
205 penstroke pulled_arc.e(3,4) & pulled_arc.e(4,5)
206 & pulled_arc.e(5,6) & pulled_arc.e(6,3) & cycle; % bowl
207 if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut); % upper serif
208 dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi % lower serif
209 math_fit(-.5cap_height#*slant-.5u#,ic#); penlabels(1,2,3,4,5,6); endchar;
210
211 cmchar "Uppercase Greek Psi";
212 beginchar(oct"011",14u#,cap_height#,0);
213 italcorr .8cap_height#*slant-.5u#;
214 adjust_fit(0,0);
215 numeric shaved_stem;
216 shaved_stem=cap_stem-hround 2stem_corr;
217 pickup tiny.nib; pos1(shaved_stem,0); pos2(shaved_stem,0);
218 lft x1l=lft x2l=hround(.5w-.5shaved_stem); top y1=h; bot y2=0;
219 filldraw stroke z1e--z2e; % stem
220 pos3(shaved_stem,-180); pos4(shaved_stem,-180);
221 pos5(vair,-90); x5=x1; bot y5r=vround(.15h if serifs:+slab fi);
222 pos6(shaved_stem,0); pos7(shaved_stem,0);
223 lft x3r=hround u; x7=w-x3; lft x4r=hround(3u-.5shaved_stem); x6=w-x4;
224 pos3'(vair,90); pos7'(vair,90); z3'r=z3r; z7'r=z7r;
225 y3=y7; y4=y6=.6h; y3=good.y(y3+.84h if serifs:-slab fi-y3');
226 interim superness:=more_super;
227 filldraw z3'l{right}...z4r{down} & super_arc.r(4,5)
228 & super_arc.r(5,6) & z6r{up}...z7'l{right}
229 --z7r---z7l...z6l{down} & super_arc.l(6,5)
230 & super_arc.l(5,4) & z4l{up}...z3l---z3r--cycle; % stroke
231 if serifs: dish_serif(1,2,a,1/3,1.25cap_jut,b,1/3,1.25cap_jut); % upper serif
232 dish_serif(2,1,c,1/3,1.25cap_jut,d,1/3,1.25cap_jut); fi % lower serif
233 math_fit(-.8cap_height#*slant-.5u#,.4cap_height#*slant-1.25u#);
234 penlabels(1,2,3,4,5,6,7); endchar;
235
236 cmchar "Uppercase Greek Omega";
237 beginchar(oct"012",13u#,cap_height#,0);
238 italcorr .75cap_height#*slant-.5u#;
239 adjust_fit(0,0);
240 pickup tiny.nib; pos1(vair,90); pos2(cap_curve,180);
241 pos3(vair,180); pos4(cap_curve,0); pos5(vair,0);
242 x1=.5w; top y1r=h+o; lft x2r=hround u; y2=y4=2/3h; x4=w-x2;
243 rt x3l=hround(1/3(w+.5u)+.5hair); bot y3=bot y5=0; x5=w-x3;
244 filldraw stroke z3e{up}...{up}z2e
245 & pulled_super_arc.e(2,1)(.5superpull)
246 & pulled_super_arc.e(1,4)(.5superpull)
247 & z4e{down}...{down}z5e; % bowl
248 numeric arm_thickness; path p; p=z3{up}...{up}z2;
249 arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
250 pickup crisp.nib; pos6(arm_thickness,-90); pos7(fudged.hair,-180);
251 bot y6r=0; x6=x3; lft x7r=hround .8u; y7=good.y(y6l+.5beak)+eps;
252 (x,y)=p intersectionpoint((0,y6l)--(w,y6l)); x6l:=x;
253 arm(6,7,a,.5beak_darkness,-1.2beak_jut); % left arm and beak
254 pos8(arm_thickness,-90); pos9(fudged.hair,0);
255 y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
256 arm(8,9,b,.5beak_darkness,1.2beak_jut); % right arm and beak
257 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;