Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/ebbraces.mf

raw
1 % ebbraces.mf
2 % [= exbraces.mf, changed by Walter Schmidt, see (CMBR)]
3 %
4 % (c) Copyright 1995, 1996, 1997 J"org Knappen
5 % (c) Copyright 1990, 1992 Norbert Schwarz
6 %
7 % This file is part of the EC Bright fonts version 1.0 Patchlevel 3
8 %
9 %
10 % Please read the files 00readme.txt, 00inst.txt, 00error.txt, and
11 % copyrite.txt for further information
12 %
13 % Content:
14 %
15 % braces and some special characters
16 %
17 version_check(1,0); % |version_check| was introduced in dc1.3
18
19 ecchar "Circumflex (hat)";
20 beginchar(oct"136",11u#,min(asc_height#,2x_height#),0);
21 if serifs: italcorr .5[x_height#,h#]*slant+.5hair#-1.75u#;
22 adjust_fit(0,0);
23 pickup crisp.nib; pos2(.5[vair,curve],90); top y2r=.75[x_height,h]; x2=.5w;
24 x1=w-x3=good.x 2.25u; y1=y3=.25[x_height,y2];
25 pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
26 filldraw stroke z1e--z2e--z3e; % diagonals
27 else: italcorr 2/3[x_height#,h#]*slant-.5stem#+.5vair#-.75u#;
28 adjust_fit(0,0);
29 pickup fine.nib; pos1(vair,0); pos3(vair,0); x1=w-x3;
30 pos2(stem,0); top y2=2/3[x_height,h]; x2=.5w; bot y1=bot y3=vround x_height-eps;
31 lft x1l=hround(rt x2r-3.25u-.5vair);
32 z0=whatever[z1r,z2r]=whatever[z2l,z3l];
33 y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=w-x4l;
34 filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
35 penlabels(0,1,2,3,4); endchar;
36
37
38
39 ecchar "Tilde (squiggle)";
40 beginchar(oct"176",11u#,min(asc_height#,
41 10/7x_height#+.5dot_size#),0);
42 italcorr h#*slant-u#;
43 adjust_fit(0,0);
44 if serifs: numeric theta; theta=angle(1/6(6u-vair),1/4(h-x_height));
45 pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
46 pos1(vair,theta+90); pos2(vair,theta+90);
47 pos3(vair,theta+90); pos4(vair,theta+90);
48 z2-z1=z4-z3=(mid_width-crisp)*dir theta;
49 lft x1r=w-rt x4l=hround 1.5u; top y4r=h;
50 bot y1l=vround(bot y1l+min(2/3[x_height,h],y3l-.25vair)-top y1r);
51 pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
52 filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
53 --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
54 else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
55 pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
56 lft x1r=w-rt x5l=hround 1.5u; x2-x1=x3-x2=x4-x3=x5-x4;
57 bot y1=bot y4l=vround(.75[x_height,h]-vair);
58 top y2r=top y5=h; y3=.5[y2,y4];
59 filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
60 penlabels(1,2,3,4,5); endchar;
61
62 ecchar "Compound word mark";
63 beginchar(oct"027",0,x_height#,0);
64 zero_width;
65 endchar;
66
67 ecchar "Left parenthesis";
68 beginchar("(",7u# if monospace: -u# fi,body_height#,paren_depth#);
69 italcorr body_height#*slant-.5u#;
70 adjust_fit(0,0); pickup fine.nib;
71 pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
72 rt x1r=rt x3r=hround(w-u); lft x2l=hround(x1-4u if monospace: +4/3u fi);
73 top y1=h; y2=.5[y1,y3]=math_axis;
74 filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
75 ...{3(x3e-x2e),y3-y2}z3e; % arc
76 penlabels(1,2,3); endchar;
77
78 ecchar "Right parenthesis";
79 beginchar(")",7u# if monospace: -u# fi,body_height#,paren_depth#);
80 italcorr math_axis#*slant-.5u#;
81 adjust_fit(0,0); pickup fine.nib;
82 pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
83 lft x1l=lft x3l=hround u; rt x2r=hround(x1+4u if monospace: -4/3u fi);
84 top y1=h; y2=.5[y1,y3]=math_axis;
85 filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
86 ...{3(x3e-x2e),y3-y2}z3e; % arc
87 penlabels(1,2,3); endchar;
88
89
90 ecchar "Less than sign";% (CMBR)
91 compute_spread(5/4sym_height#,3/2sym_height#);
92 beginchar("<",11u#,v_center(spread#+rule_thickness#));
93 italcorr h#*slant-u#;
94 adjust_fit(0,0); pickup extra_rule.nib;
95 lft x2=hround 1.5u-eps; x1=x3=w-x2;
96 y1-y3=spread; y2=.5[y1,y3]=math_axis;
97 draw z1--z2--z3; % diagonals
98 labels(1,2,3); endchar;
99
100 ecchar "Vertical line";
101 beginchar(oct"174",5u#,body_height#,paren_depth#);
102 italcorr body_height#*slant+.5rule_thickness#-2u#;
103 adjust_fit(0,0); pickup rule.nib;
104 x1=x2=good.x .5w; top y1=h+eps; bot y2=-d-eps;
105 draw z1--z2; % stem
106 labels(1,2); endchar;
107
108
109 ecchar "Greater than sign";% (CMBR)
110 compute_spread(5/4sym_height#,3/2sym_height#);
111 beginchar(">",11u#,v_center(spread#+rule_thickness#));
112 italcorr math_axis#*slant-u#;
113 adjust_fit(0,0); pickup extra_rule.nib;
114 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2;
115 y1-y3=spread; y2=.5[y1,y3]=math_axis;
116 draw z1--z2--z3; % diagonals
117 labels(1,2,3); endchar;
118
119 ecchar "Left bracket";
120 numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
121 beginchar("[",wd#,body_height#,paren_depth#);
122 italcorr body_height#*slant;
123 adjust_fit(0,0);
124 numeric top_thickness,side_thickness;
125 % if hefty:
126 top_thickness=vair;
127 side_thickness=max(crisp.breadth,stem-stem_corr);
128 % else: top_thickness=side_thickness=rule_thickness; fi;
129 pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
130 top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5side_thickness)-1-eps;
131 filldraw stroke z1e--z2e; % stem
132 pos3(top_thickness,90); pos4(top_thickness,90);
133 pos5(top_thickness,90); pos6(top_thickness,90);
134 x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
135 filldraw stroke z3e--z4e; % upper bar
136 filldraw stroke z5e--z6e; % lower bar
137 penlabels(1,2,3,4,5,6); endchar;
138
139 ecchar "Right bracket";
140 numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
141 beginchar("]",wd#,body_height#,paren_depth#);
142 italcorr body_height#*slant-2u#+.5if hefty:stem# else:rule_thickness# fi;
143 adjust_fit(0,0);
144 numeric top_thickness,side_thickness;
145 %if hefty:
146 top_thickness=vair;
147 side_thickness=max(crisp.breadth,stem-stem_corr);
148 % else: top_thickness=side_thickness=rule_thickness; fi;
149 pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
150 top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5side_thickness)+1+eps;
151 filldraw stroke z1e--z2e; % stem
152 pos3(top_thickness,90); pos4(top_thickness,90);
153 pos5(top_thickness,90); pos6(top_thickness,90);
154 x3=x5=x1r; lft x4=lft x6=floor .4u-eps; y3r=y4r=y1; y5l=y6l=y2;
155 filldraw stroke z3e--z4e; % upper bar
156 filldraw stroke z5e--z6e; % lower bar
157 penlabels(1,2,3,4,5,6); endchar;
158
159
160 ecchar "Reverse slash (backslash)";
161 beginchar(oct"134",9u#,body_height#,paren_depth#);
162 adjust_fit(0,0); pickup extra_rule.nib;
163 lft x1=hround u-eps; top y1=h+eps;
164 rt x2=hround(w-u)+eps; bot y2=-d-eps;
165 draw z1--z2; % diagonal
166 labels(1,2); endchar;
167
168 ecchar "Left curly brace";
169 beginchar(oct"173",9u#,body_height#,paren_depth#);
170 italcorr body_height#*slant+.5vair#-u#;
171 adjust_fit(0,0); pickup fine.nib;
172 forsuffixes $=1,1',4,4',7,7': pos$(vair,0); endfor
173 forsuffixes $=2,3,5,6: pos$(stem,0); endfor
174 x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
175 lft x4l=hround(1.5u-.5vair); lft x2l=hround(.5w-.5stem);
176 top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
177 y1-y2=y3-y4=(y1-y4)/4; y1-y1'=y4-y4'=y7'-y7=vair-fine;
178 filldraw z1l{left}...z2l---z3l...{left}z4l
179 --z4'l{right}...z5l---z6l...{right}z7l
180 --z7r--z7'r{left}...z6r---z5r...{left}.5[z4r,z4'r]{right}
181 ...z3r---z2r...{right}z1'r--z1r--cycle; % stroke
182 penlabels(1,2,3,4,5,6,7); endchar;
183
184 ecchar "Right curly brace";
185 beginchar(oct"175",9u#,body_height#,paren_depth#);
186 italcorr math_axis#*slant+.5vair#-u#;
187 adjust_fit(0,0); pickup fine.nib;
188 forsuffixes $=1,1',4,4',7,7': pos$(vair,0); endfor
189 forsuffixes $=2,3,5,6: pos$(stem,0); endfor
190 x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
191 rt x4r=hround(w-1.5u+.5vair); rt x2r=hround(.5w+.5stem);
192 top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
193 y1-y2=y3-y4=(y1-y4)/4; y1-y1'=y4-y4'=y7'-y7=vair-fine;
194 filldraw z1r{right}...z2r---z3r...{right}z4r
195 --z4'r{left}...z5r---z6r...{left}z7r
196 --z7l--z7'l{right}...z6l---z5l...{right}.5[z4l,z4'l]{left}
197 ...z3l---z2l...{left}z1'l--z1l--cycle; % stroke
198 penlabels(1,2,3,4,5,6,7); endchar;
199
200
201
202
203 ecchar "Underbar";
204 compute_spread((5/8+.45)*x_height#,(3/4+.55)*x_height#);
205 beginchar(oct"137",14u#,0,spread#-math_axis#+.5rule_thickness#);
206 adjust_fit(0,0); pickup rule.nib;
207 lft x1=hround 1.5u-eps; x2=w-x1; bot y1=bot y2=-d;
208 draw z1--z2; % bar
209 labels(1,2); endchar;
210
211 iff not monospace:
212 ecchar "Hyphenchar";
213 beginchar(oct"177",3u#,x_height#,0);
214 italcorr .5x_height#*slant-.5u#;
215 adjust_fit(0,0);
216 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
217 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
218 top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(2w-u)+eps;
219 lft x1=hround .2u-eps;
220 filldraw stroke z1e--z2e; % bar
221 penlabels(1,2); endchar;
222
223 iff monospace:
224 ecchar "Hyphenchar";
225 beginchar(oct"177",3u#,x_height#,0);
226 italcorr .5x_height#*slant-.5u#;
227 adjust_fit(0,0);
228 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
229 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
230 top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
231 x2=w-x1;
232 filldraw stroke z1e--z2e; % bar
233 penlabels(1,2); endchar;
234
235 iff hefty: % Sans or typewriter
236 ecchar "Blank-space sign";
237 beginchar(oct"040",9u#,x_height#,.5desc_depth#);
238 italcorr bar_height#*slant-.25u#;
239 adjust_fit(0,0);
240 numeric thin_vair#; thin_vair#=.7vair#;
241 define_whole_blacker_pixels(thin_vair);
242 h:=bar_height;
243 forsuffixes $=1,2,3,4: penpos$(thin_vair,0); endfor
244 penpos0(thin_vair,90); x0=.5w; y0l=vround(-d-.5thin_vair);
245 x1=x2; x3=x4=w-x1; lft x1l=hround .75u;
246 y1=y4=h; y2=y3=y0;
247 fill z1l---z2l...(x2,y0l)---(x3,y0l)...z3r---z4r
248 ..z4l---(x3l,y0r)--(x2r,y0r)---z1r..cycle; % the stroke
249 penlabels(0,1,2,3,4); endchar;
250
251 iff not hefty: % Other than the above mentioned
252 ecchar "Blank-space sign"; % jk
253 beginchar(oct"040",9u#,x_height#,.5desc_depth#);
254 italcorr bar_height#*slant-.25u#;
255 adjust_fit(0,0);
256 numeric shaved_stem; shaved_stem=hround .9[vair,.85cap_stem];
257 if shaved_stem<crisp.breadth: shaved_stem:=crisp.breadth; fi
258 pickup crisp.nib;
259 pos1(shaved_stem,-90); pos2(hair,0);
260 bot y1r=-d; x1=.5w; rt x2r=hround(w-.75u); y2=good.y(y1l+.5beak)+eps;
261 arm(1,2,a,beak_darkness,2beak_jut); % lower right arm and beak
262 pos3(hair,180); x3=w-x2; y3=y2;
263 arm(1,3,b,beak_darkness,-2beak_jut); % lower left arm and beak
264 math_fit(0,.5ic#);
265 penlabels(1,2,3); endchar;
266
267 endinput;