Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/tbsymbol.mf

raw
1 % tbsymbol.mf
2 % [= txsymbol.mf, changed by Walter Schmidt, see (CMBR)]
3 %
4 % (c) Copyright 1995, 1996, 1997 J"org Knappen
5 % (c) Copyright 2000 J"org Knappen, Walter Schmidt
6 %
7 % This file is part of EC Bright fonts version 1.0f
8 %
9 % Miscellaneous symbols for the TS1 encoding,
10 % to be used for making the CM Bright typefaces.
11 %
12 % Heavily borrowing from existent fonts, like Computer Modern, AMS symbols
13 % and wasy symbols
14
15 version_check(1,0); % |version_check| was introduced in dc1.3
16
17 ecchar"Single straight base quote"; % jk
18 beginchar(oct"015",7u#,asc_height#,0);
19 numeric shifth_down;
20 adjust_fit(0,0);
21 x1=x2=.5w;
22 y2=max(.5[bar_height,x_height]+.5vair,h-x_height)-the_shift;
23 if serifs:
24 y1=flare/2; the_shift=h-.5stem-y1;
25 pickup crisp.nib;
26 pos1(flare,0); pos2(vair,0);
27 filldraw circ_stroke (z1e--z2e); % stem and bulb
28 else:
29 top y1=stem; the_shift=h-y1;
30 pickup fine.nib;
31 pos1(stem,0); pos2(vair,0);
32 filldraw stroke z1e--z2e; % stem
33 fi
34 charht:=dot_size#; chardp:=desc_depth#;
35 penlabels(1,2,3,4);
36 endchar;
37
38 ecchar"Double straight base quotes"; % from pl_cud (plfonts)
39 beginchar(oct"022",9u#,asc_height#,0);
40 numeric top_width#,spread#,shifth_down;
41 top_width#=if serifs: flare# else: stem# fi;
42 spread#=max(3u#,top_width#+.5u#); define_pixels(spread);
43 adjust_fit(0,0);
44 numeric the_shift;
45 x1=x2; x3=x4=w-x1; x3-x1=spread+2; y1=y3;
46 y2=y4=max(.5[bar_height,x_height]+.5vair,h-x_height)-the_shift;
47 if serifs:
48 y1=flare/2; the_shift=h-.5stem-y1;
49 pickup crisp.nib;
50 pos1(flare,0); pos2(vair,0); pos3(flare,0); pos4(vair,0);
51 filldraw circ_stroke (z1e--z2e); % left stem and bulb
52 filldraw circ_stroke (z3e--z4e); % right stem and bulb
53 else:
54 top y1=stem; the_shift=h-y1;
55 pickup fine.nib;
56 pos1(stem,0); pos2(vair,0); pos3(stem,0); pos4(vair,0);
57 filldraw stroke z1e--z2e; % left stem
58 filldraw stroke z3e--z4e; % right stem
59 fi
60 charht:=dot_size#; chardp:=desc_depth#;
61 penlabels(1,2,3,4);
62 endchar;
63
64 ecchar "twelve u dash";
65 beginchar(oct"025",12u#,x_height#,0);
66 italcorr .61803x_height#*slant+.5u#;
67 adjust_fit(letter_fit#,letter_fit#);
68 pickup crisp.nib; pos1(vair,90); pos2(vair,90);
69 top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
70 filldraw stroke z1e--z2e; % bar
71 penlabels(1,2); endchar;
72
73 ecchar "three quarters em dash";
74 beginchar(oct"026",13.5u#,x_height#,0);
75 italcorr .61803x_height#*slant+.5u#;
76 adjust_fit(letter_fit#,letter_fit#);
77 pickup crisp.nib; pos1(vair,90); pos2(vair,90);
78 top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
79 filldraw stroke z1e--z2e; % bar
80 penlabels(1,2); endchar;
81
82 ecchar "Capital compound word mark";
83 beginchar(oct"027",0,cap_height#,0);
84 zero_width;
85 endchar;
86
87 ecchar "Leftward arrow"; % from sym.mf (cmfonts)
88 compute_spread(.45x_height#,.55x_height#);
89 beginchar(oct"030",18u#,v_center(spread#+rule_thickness#));
90 adjust_fit(0,0); pickup crisp.nib;
91 pos1(rule_thickness,90); pos2(rule_thickness,90);
92 pos3(rule_thickness,0); pos4(rule_thickness,0);
93 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-u); lft x0=hround u;
94 y3-y0=y0-y4=if monospace:.24 else:.36 fi asc_height+eps;
95 x3=x4=x0+if monospace:3u else:4u fi+eps;
96 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
97 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
98 z9=.2[.5[z3,z4],z0];
99 numeric t; path p; p=z4r{z9-z4}..z6r;
100 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
101 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
102 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3r{z9-z3}..z5r)
103 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
104 penlabels(0,1,2,3,4,5,6,9); endchar;
105
106 ecchar "Rightward arrow"; % from sym.mf (cmfonts)
107 compute_spread(.45x_height#,.55x_height#);
108 beginchar(oct"031",18u#,v_center(spread#+rule_thickness#));
109 adjust_fit(0,0); pickup crisp.nib;
110 pos1(rule_thickness,90); pos2(rule_thickness,90);
111 pos3(rule_thickness,0); pos4(rule_thickness,0);
112 y0=y1=y2=math_axis; x1-.5rule_thickness=hround u; rt x0=hround(w-u);
113 y3-y0=y0-y4=if monospace:.24 else:.36 fi asc_height+eps;
114 x3=x4=x0-if monospace:3u else:4u fi-eps;
115 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
116 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
117 z9=.2[.5[z3,z4],z0];
118 numeric t; path p; p=z4l{z9-z4}..z6r;
119 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
120 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
121 --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
122 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
123 penlabels(0,1,2,3,4,5,6,9); endchar;
124
125 ecchar"Tie accent"; % from italms (cmfonts)
126 beginchar(oct"032",5u#,asc_height#,0);
127 italcorr 4/9[x_height#,asc_height#]*slant+4.5u#+2letter_fit#+.5hair#;
128 adjust_fit(if monospace:2u#,2u# else:serif_fit#,serif_fit# fi);
129 pickup fine.nib; pos1(hair,180); pos2(vround 1/5[vair,stem],90);
130 pos3(hair,0);
131 lft x1r=hround(.5w-.5hair); x2=.5[x1,x3];
132 rt x3r=hround(w+4u+2letter_fit+.5hair);
133 y1=y3=4/9[x_height,asc_height]; top y2r=vround 8/9[x_height,asc_height];
134 filldraw stroke super_arc.e(1,2) & super_arc.e(2,3); % arc
135 penlabels(1,2,3); endchar;
136
137 ecchar"New tie accent"; % centered
138 beginchar(oct"034",9u#,asc_height#,0);
139 italcorr 4/9[x_height#,asc_height#]*slant+4.5u#+2letter_fit#+.5hair#;
140 adjust_fit(if monospace:2u#,2u# else:serif_fit#,serif_fit# fi);
141 pickup fine.nib; pos1(hair,180); pos2(vround 1/5[vair,stem],90);
142 pos3(hair,0);
143 lft x1r=w-rt x3r=hround(2u-.5vair); x2=.5w;
144 y1=y3=4/9[x_height,asc_height]; top y2r=vround 8/9[x_height,asc_height];
145 filldraw stroke super_arc.e(1,2) & super_arc.e(2,3); % arc
146 penlabels(1,2,3); endchar;
147
148 ecchar "Ascender height compound word mark";
149 beginchar(oct"037",0,asc_height#,0);
150 zero_width;
151 endchar;
152
153 iff not variant_g: % not italic
154 ecchar"Blank symbol"; % jk
155 beginchar(oct"040",10u#+serif_fit#,asc_height#,0);
156 italcorr .5x_height#*slant+min(.5curve#-u#,-.25u#);
157 adjust_fit(serif_fit#,0);
158 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
159 pos0'(stem',0); pos0(stem,0); z0l=z0'l; x0'=x1; x0=x2;
160 lft x1l=hround(2.5u-.5stem'); top y1=h;
161 numeric edge; edge=rt x2r;
162 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
163 pos4(vair,90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
164 rt x3l=max(rt x3l-(lft x3r-tiny.lft x2l),1/3[rt x2,edge]);
165 y3=1/8[bar_height,x_height];
166 x4l=w-.5(w-serif_fit)+.5u; top y4r=x_height+oo;
167 rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
168 x6l=x4l-.2u; bot y6r=-oo;
169 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
170 (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x4,x5r]);
171 (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x6,x5r]);
172 filldraw stroke z3e{up}...pulled_arc.e(4,5)&pulled_arc.e(5,6)...{up}z7e; % bowl
173 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
174 y2=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{left}...{up}z7l));
175 pickup tiny.nib; filldraw stroke z1e--z0'e--z0e--z2e; % stem
176 pickup crisp.nib; pos8(hair,0); pos7'(stem,0);
177 z7'=z2; x8l=x7'l; bot y8=0;
178 filldraw stroke z7'e--z8e; % point
179 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); fi % upper serif
180 put_cross(.5stem+if serifs: .9max(limit_dist,jut) else: 1.8u fi,.5stem+3u);
181 penlabels(0,1,2,3,4,5,6,7,8); endchar;
182
183 iff variant_g: % italic
184 ecchar"Blank symbol"; % jk
185 beginchar(oct"040",8u#,asc_height#,0);
186 italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
187 adjust_fit(0,0); pickup tiny.nib;
188 pos1(stem,0); pos2(stem,0); x1=x2;
189 lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_height;
190 filldraw stroke z1e--z2e; % stem
191 sloped_serif.l(1,2,a,1/3,jut,serif_drop); % serif
192 pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
193 pos4(curve,0); pos5(vair,90); pos0(hair,180);
194 z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
195 bot y3r=-oo; top y5r=x_height+oo; y4=y2;
196 filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
197 & pulled_arc.e(4,5) & super_arc.e(5,0); % bowl
198 math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
199 put_cross(.5stem+if serifs: .9max(limit_dist,jut) else: 1.8u fi,.5stem+3u);
200 penlabels(0,1,2,3,4,5); endchar;
201
202 ecchar"Dollar sign"; % from romanp (cm)
203 beginchar("$",9u#,body_height#,body_height#-asc_height#);
204 italcorr fig_height#*slant-.5u#; % same as for digits
205 adjust_fit(0,0);
206 numeric theta; theta=90-angle(50u,asc_height); slope:=-asc_height/50u;
207 pickup fine.nib; pos2(slab,-90);
208 pos0(cap_stem,theta); pos7(slab,-90);
209 x2=x0=x7=.5w; top y2l=asc_height+oo; bot y7r=-oo;
210 y0=.52asc_height; lft x3l=hround u; rt x6r=hround(w-u);
211 x3r-x3l=x6r-x6l=hround .35[slab,cap_stem]-fine;
212 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
213 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
214 filldraw stroke super_arc.e(2,3) & z3e{down}
215 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
216 if serifs: pos1(hair,0); pos8(hair,180);
217 pos10(flare,0); pos9(flare,180);
218 rt x1r=hround(w-u); lft x8r=hround u; y1=.5[y0,y2]; y8=.5[y0,y7];
219 {{less_tense; pos2'(slab,90); z2'=z2; bulb(2',1,10); % upper arc and bulb
220 bulb(7,8,9)}}; % lower arc and bulb
221 else: pos1(.6[slab,flare],-100); pos8(flare,-100);
222 rt x1l=hround(w-1.3u); lft x8r=hround .8u;
223 top y1l=vround .92asc_height+oo; bot y8r=vround .1asc_height-oo;
224 filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
225 filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
226 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
227 lft x12l=lft x11l=hround(.5w-.5bar); top y12=h; bot y11=-d;
228 filldraw stroke z12e--z11e; % vertical crossbar
229 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12); endchar;
230
231
232 ecchar "Straight single quote"; % from romsub (cm)
233 beginchar(oct"047",5u#,asc_height#,0);
234 italcorr asc_height#*slant+.5 if serifs: flare# else: stem# fi -2u#;
235 adjust_fit(0,0);
236 x1=x2=.5w; y2=max(.5[bar_height,x_height]+.5vair,h-x_height);
237 if serifs: pickup crisp.nib; pos1(flare,0); pos2(vair,0);
238 y1+.5stem=h; filldraw circ_stroke z1e--z2e; % stem and bulb
239 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
240 top y1=h; filldraw stroke z1e--z2e; fi % stem
241 penlabels(1,2); endchar;
242
243 ecchar "Comma";
244 beginchar(",",5u#,pdot_diam#,comma_depth#);
245 adjust_fit(0,0);
246 x1-.5pdot_diam=hround(.5w-.5pdot_diam); y1-.5pdot_diam=0;
247 comma(1,a,pdot_diam,.2u,comma_depth); % dot and tail
248 penlabels(1); endchar;
249
250 ecchar "Double hyphen or short equals sign"; % jk % (CMBR)
251 compute_spread(.45sym_height#,.55sym_height#);
252 beginchar(oct"055",6u#,v_center(spread#+rule_thickness#));
253 italcorr h#*slant-.5u#;
254 adjust_fit(0,0);
255 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
256 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
257 pos3(thickness,90); pos4(thickness,90);
258 y1=y2; y3=y4;
259 top y1=vround .5h+.5thickness+.5spread;
260 top y3=vround .5h+.5thickness-.5spread;
261 rt x2=hround(w-u)+eps;
262 if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
263 x3=x1; x4=x2;
264 filldraw stroke z1e--z2e; % upper bar
265 filldraw stroke z3e--z4e; % lower bar
266 penlabels(1,2,3,4); endchar;
267
268 ecchar "Period";
269 beginchar(".",5u#,pdot_diam#,0);
270 adjust_fit(0,0); pickup fine.nib;
271 pos1(pdot_diam,0); pos2(pdot_diam,90);
272 lft x1l=hround(.5w-.5pdot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
273 penlabels(1,2); endchar;
274
275 ecchar "Asterisk at the axis"; % from mathsy % (CMBR)
276 beginchar(oct"052",9u#,v_center(sym_height#));
277 adjust_fit(0,0);
278 numeric ast_flare; ast_flare=hround .7[thin_join,stem];
279 x0=.5w; y0=h-.5sym_height;
280 for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5sym_u yscaled sym_height;
281 numeric theta; theta=angle(z[d]-z0);
282 fill z0+.5(0,-thin_join)rotated theta
283 ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
284 ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
285 ---z0+.5(0,thin_join)rotated theta--cycle; endfor % diagonal at angle |d|
286 labels(0,[-150],[-90],[-30],30,90,150); endchar;
287
288 ecchar "Fraction"; % from punct (cm)" Virgule (slash)"
289 beginchar("/",9u#,body_height#,paren_depth#);
290 italcorr body_height#*slant-.5u#;
291 adjust_fit(0,0); pickup rule.nib;
292 rt x1=hround(w-u)+eps; top y1=h+eps;
293 lft x2=hround u-eps; bot y2=-d-eps;
294 draw z1--z2; % diagonal
295 penlabels(1,2); endchar;
296
297 ecchar "Left angle bracket";
298 beginchar(oct"074",7u#,body_height#,paren_depth#);
299 adjust_fit(0,0); pickup rule.nib;
300 rt x1=hround(w-u)+eps; x1=x3; lft x2=hround 2u-1-eps;
301 top y1=h+eps; .5[y1,y3]=y2=math_axis;
302 draw z1--z2--z3; % diagonals
303 labels(1,2,3); endchar;
304
305 ecchar "Minus sign";
306 beginarithchar("="); pickup extra_rule.nib;
307 lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
308 draw z3--z4; % crossbar
309 labels(1,2,3,4); endchar;
310
311 ecchar "Right angle bracket";
312 beginchar(oct"076",7u#,body_height#,paren_depth#);
313 adjust_fit(0,0); pickup rule.nib;
314 rt(w-x1)=hround(w-u)+eps; x1=x3; lft(w-x2)=hround 2u-1-eps;
315 top y1=h+eps; .5[y1,y3]=y2=math_axis;
316 draw z1--z2--z3; % diagonals
317 labels(1,2,3); endchar;
318
319 ecchar"Mho sign (turned Omega)"; % from lasy
320 beginchar(oct"115",13u#,cap_height#,0);
321 italcorr cap_height#*slant-.35u#; %italcorr .75cap_height#*slant-.5u#;
322 adjust_fit(0,0);
323 pickup tiny.nib; pos1(vair,-90); pos2(cap_curve,0);
324 pos3(vair,0); pos4(cap_curve,180); pos5(vair,180);
325 x1=.5w; bot y1r=0-o; lft x4r=hround u; y2=y4=1/3h; x2=w-x4;
326 rt x5l=hround(1/3(w+.5u)+.5hair); top y3=top y5=h; x3=w-x5;
327 filldraw stroke z3e{down}...{down}z2e
328 & pulled_super_arc.e(2,1)(.5superpull)
329 & pulled_super_arc.e(1,4)(.5superpull)
330 & z4e{up}...{up}z5e; % bowl
331 numeric arm_thickness; path p; p=z3{down}...{down}z2;
332 arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
333 pickup crisp.nib; pos6(arm_thickness,90); pos7(fudged.hair,0);
334 top y6r=h; x6=x3; rt x7r=hround (w-.8u); y7=good.y(y6l-.5beak)+eps;
335 (x,y)=p intersectionpoint((0,y6l)--(w+h,y6l)); x6l:=x;
336 arm(6,7,a,.5beak_darkness,1.2beak_jut); % right arm and beak
337 pos8(arm_thickness,90); pos9(fudged.hair,180);
338 y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
339 arm(8,9,b,.5beak_darkness,-1.2beak_jut); % left arm and beak
340 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
341
342 ecchar"Big circle for copyright, etc";% (CMBR)
343 %beginchar("O",20u#,body_height#,max(paren_depth#,desc_depth#)); autorounded;
344 beginchar("O",circ_w#,body_height#,max(paren_depth#,desc_depth#)); autorounded;
345 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
346 if .5w <> good.x .5w: change_width; fi
347 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
348 circle_points; draw_circle; % circle
349 labels(1,2,3,4,5,6,7,8); endchar;
350
351 ecchar"Ohm sign (ISO 6937)"; % from greeku (cmfonts)
352 beginchar(oct"127",13u#,cap_height#,0);
353 italcorr .75cap_height#*slant-.5u#;
354 adjust_fit(0,0);
355 pickup tiny.nib; pos1(vair,90); pos2(cap_curve,180);
356 pos3(vair,180); pos4(cap_curve,0); pos5(vair,0);
357 x1=.5w; top y1r=h+o; lft x2r=hround u; y2=y4=2/3h; x4=w-x2;
358 rt x3l=hround(1/3(w+.5u)+.5hair); bot y3=bot y5=0; x5=w-x3;
359 filldraw stroke z3e{up}...{up}z2e
360 & pulled_super_arc.e(2,1)(.5superpull)
361 & pulled_super_arc.e(1,4)(.5superpull)
362 & z4e{down}...{down}z5e; % bowl
363 numeric arm_thickness; path p; p=z3{up}...{up}z2;
364 arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
365 pickup crisp.nib; pos6(arm_thickness,-90); pos7(fudged.hair,-180);
366 bot y6r=0; x6=x3; lft x7r=hround .8u; y7=good.y(y6l+.5beak)+eps;
367 (x,y)=p intersectionpoint((0,y6l)--(w,y6l)); x6l:=x;
368 arm(6,7,a,.5beak_darkness,-1.2beak_jut); % left arm and beak
369 pos8(arm_thickness,-90); pos9(fudged.hair,0);
370 y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
371 arm(8,9,b,.5beak_darkness,1.2beak_jut); % right arm and beak
372 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
373
374 ecchar"Musical note (one eigth note)"; % jk
375 beginchar("n",11u#,asc_height#,0);
376 pickup rule.nib;
377 x1=3/5w; x2=x1; top y1=h; bot y2=.5bar_height;
378 lft x3=u; x5= x2; x4=x6=.5[x3,x5];
379 y3=y5=vround(.5bar_height); y4=y6-bar_height=-oo;
380 x7=x1; rt x9=w-u; x8=.5[x7,x9];
381 y7=y1; bot y9=vround(.5bar_height); y8=.5[y7,y9];
382 draw z1--z2; % stem
383 filldraw z3{down}...z4{right}...z5{up}...z6{left}...cycle; % body
384 draw z7{down}...z8...{down}z9; % flag
385 endchar;
386
387 ecchar "Left semantic bracket"; % [[ from stmaryrd
388 beginchar(oct"133",7.25u#,body_height#,paren_depth#);
389 adjust_fit(0,0);
390 pickup crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
391 top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5rule_thickness)-1-eps;
392 filldraw stroke z1e--z2e; % left stem
393 pos7(rule_thickness,0); pos8(rule_thickness,0);
394 top y7=h; bot y8=-d; lft x7l=lft x8l=hround(4.75u-.5rule_thickness)-1-eps;
395 filldraw stroke z7e--z8e; % right stem
396 pos3(rule_thickness,90); pos4(rule_thickness,90);
397 pos5(rule_thickness,90); pos6(rule_thickness,90);
398 x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
399 filldraw stroke z3e--z4e; % upper bar
400 filldraw stroke z5e--z6e; % lower bar
401 penlabels(1,2,3,4,5,6,7,8); endchar;
402
403
404 ecchar "Right semantic bracket"; % ]] from stmaryrd
405 beginchar(oct"135",7.25u#,body_height#,paren_depth#);
406 adjust_fit(0,0);
407 pickup crisp.nib; pos1(rule_thickness,0); pos2(rule_thickness,0);
408 top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5rule_thickness)+1+eps;
409 filldraw stroke z1e--z2e; % left stem
410 pos7(rule_thickness,0); pos8(rule_thickness,0);
411 top y7=h; bot y8=-d; rt x7r=rt x8r=hround(w-4.75u+.5rule_thickness)+1+eps;
412 filldraw stroke z7e--z8e; % right stem
413 pos3(rule_thickness,90); pos4(rule_thickness,90);
414 pos5(rule_thickness,90); pos6(rule_thickness,90);
415 x3=x5=x1l; lft x4=lft x6=ceiling(.4u)-eps; y3r=y4r=y1; y5l=y6l=y2;
416 filldraw stroke z3e--z4e; % upper bar
417 filldraw stroke z5e--z6e; % lower bar
418 penlabels(1,2,3,4,5,6,7,8); endchar;
419
420 ecchar "Upward arrow"; % from sym
421 beginchar(oct"136",9u#,asc_height#,asc_depth#);
422 italcorr .76asc_height#*slant+.5crisp#-u#;
423 adjust_fit(0,0); pickup crisp.nib;
424 pos1(rule_thickness,0); pos2(rule_thickness,0);
425 pos3(rule_thickness,90); pos4(rule_thickness,90);
426 lft x1l=hround(.5w-.5rule_thickness); y1-.5rule_thickness=-d;
427 x0=x1=x2; top y0=h; x0-x3=x4-x0=if monospace:3u else:4u fi+eps;
428 y3=y4=y0-if monospace:.24 else:.36 fi asc_height-eps;
429 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
430 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
431 z9=.2[.5[z3,z4],z0];
432 %numeric t; path p; p=z4l{z9-z4}..z6r;
433 numeric t; path p; p=z4l{z9-z4}..z6l;
434 t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
435 filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
436 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3l{z9-z3}..z5r)
437 --z3r{z9-z3}..z0 & cycle; % arrowhead and stem
438 penlabels(0,1,2,3,4,5,6,9); endchar;
439
440 ecchar "Downward arrow"; % from sym
441 beginchar(oct"137",9u#,asc_height#,asc_depth#);
442 adjust_fit(0,0); pickup crisp.nib;
443 pos1(rule_thickness,0); pos2(rule_thickness,0);
444 pos3(rule_thickness,90); pos4(rule_thickness,90);
445 lft x1l=hround(.5w-.5rule_thickness); y1+.5rule_thickness=h;
446 x0=x1=x2; bot y0=-d; x0-x3=x4-x0=if monospace:3u else:4u fi+eps;
447 y3=y4=y0+if monospace:.24 else:.36 fi asc_height+eps;
448 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
449 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
450 z9=.2[.5[z3,z4],z0];
451 numeric t; path p; p=z4r{z9-z4}..z6r;
452 %t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
453 t=xpart(p intersectiontimes((x2l,-d)--(x2l,h))); y2=ypart point t of p;
454 filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
455 --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
456 --z3l{z9-z3}..z0 & cycle; % arrowhead and stem
457 penlabels(0,1,2,3,4,5,6,9); endchar;
458
459 ecchar"Backwards tick mark"; % from accent (cmfonts, grave accent)
460 beginchar(oct"140",9u#,min(asc_height#,2x_height#),0);
461 adjust_fit(0,0);
462 if serifs: pickup crisp.nib; x1-.5stem=hround 2u; x2=2/3[x1,w-x1];
463 y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
464 numeric theta; theta=angle(z2-z1)+90;
465 pos1(stem,theta); pos2(hair,theta);
466 filldraw circ_stroke z1e--z2e; % diagonal
467 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
468 lft x1l=hround 1.5u; rt x2r=hround(.5w+.25u+.5vair);
469 top y1=h; bot y2=vround 2/3[h,x_height];
470 filldraw stroke z1e--z2e; fi % diagonal
471 penlabels(1,2); endchar;
472
473 ecchar "Low lying tilde (squiggle)";
474 beginchar(oct"176",11u#,min(bar_height#,2/7x_height#),0);
475 italcorr h#*slant-u#;
476 adjust_fit(0,0);
477 if serifs: numeric theta;
478 theta=angle(1/8(7u if monospace: /expansion_factor fi-vair),1/4acc_height);
479 % theta=angle(1/6(6u-vair),1/4h);
480 pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
481 pos1(vair,theta+90); pos2(vair,theta+90);
482 pos3(vair,theta+90); pos4(vair,theta+90);
483 z2-z1=z4-z3=(mid_width-crisp)*dir theta;
484 lft x1r=w-rt x4l=hround 1.5u; top y4r=h;
485 bot y1l=0;
486 pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
487 filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
488 --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
489 else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
490 pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
491 lft x1r=w-rt x5l=hround 1.5u; x2-x1=x3-x2=x4-x3=x5-x4;
492 bot y1=bot y4l=0;
493 top y2r=top y5=h; y3=.5[y2,y4];
494 filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
495 penlabels(1,2,3,4,5); endchar;
496
497 iff not monospace:
498 ecchar "Double hyphen-hyphenchar"; % jk % (CMBR)
499 compute_spread(.45sym_height#,.55sym_height#);
500 beginchar(oct"177",3u#,v_center(spread#+rule_thickness#));
501 italcorr h#*slant-.5u#;
502 adjust_fit(0,0);
503 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
504 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
505 pos3(thickness,90); pos4(thickness,90);
506 y1=y2; y3=y4;
507 top y1=vround .5h+.5thickness+.5spread;
508 top y3=vround .5h+.5thickness-.5spread;
509 rt x2=hround(2w-u)+eps;
510 lft x1=hround .2u-eps;
511 x3=x1; x4=x2;
512 filldraw stroke z1e--z2e; % upper bar
513 filldraw stroke z3e--z4e; % lower bar
514 penlabels(1,2,3,4); endchar;
515
516 iff monospace:
517 ecchar "Double hyphen-hyphenchar"; % jk
518 compute_spread(.45x_height#,.55x_height#);
519 beginchar(oct"177",6u#,v_center(spread#+rule_thickness#));
520 italcorr h#*slant-.5u#;
521 adjust_fit(0,0);
522 numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
523 pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
524 pos3(thickness,90); pos4(thickness,90);
525 y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
526 rt x2=hround(w-u)+eps;
527 if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
528 x3=x1; x4=x2;
529 filldraw stroke z1e--z2e; % upper bar
530 filldraw stroke z3e--z4e; % lower bar
531 penlabels(1,2,3,4); endchar;
532
533 ecchar"Breve";
534 beginchar(oct"200",11u#,min(asc_height#,2x_height#),0);
535 italcorr h#*slant+.5vair#-1.5u#;
536 adjust_fit(0,0);
537 pickup crisp.nib; pos1(vair,-180); pos3(vair,0);
538 top y1=top y3=h; lft x1r=w-rt x3r=hround(2u-.5vair);
539 numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
540 pos2(mid_thickness,-90); x2=.5w;
541 bot y2r=vround max(x_height+o+tiny,1/3[x_height,h]+o-.5mid_thickness);
542 filldraw stroke z1e{down}...z2e{right}...{up}z3e; % stroke
543 penlabels(1,2,3); endchar;
544
545 ecchar "Hachek (Caron)";
546 beginchar(oct"201",11u#,min(asc_height#,2x_height#),0);
547 h':=vround min(asc_height,2x_height); % height of circumflex being inverted
548 if serifs: italcorr h#*slant+.5hair#-1.75u#;
549 adjust_fit(0,0);
550 pickup crisp.nib; pos2'(.5[vair,curve],90); top y2'r=h;
551 pos2(.5[vair,curve],90); x2=.5w;
552 x1=w-x3=good.x 2.25u; top y1=top y3=h; y1-y2=.5(y2'-x_height);
553 pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
554 filldraw stroke z1e--z2e--z3e; % diagonals
555 else: italcorr h#*slant-.5stem#+.5vair#-.75u#;
556 adjust_fit(0,0);
557 pickup fine.nib; pos1(vair,0); pos3(vair,0); x1=w-x3;
558 pos2(stem,0); bot y2=vround(1/12[x_height,h']+o); x2=.5w;
559 top y1=top y3=h+o; lft x1l=hround(rt x2r-3.25u-.5vair);
560 z0=whatever[z1r,z2r]=whatever[z2l,z3l];
561 y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=w-x4l;
562 filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
563 penlabels(0,1,2,3,4); endchar;
564
565 ecchar"Double tick mark (inch sign)"; % from accent (hungarian long umlaut)
566 beginchar(oct"202",9u#,min(asc_height#,2x_height#),0);
567 italcorr h#*slant-u#;
568 adjust_fit(0,0);
569 x3-x1=x4-x2=hround 3u; y3=y1; y4=y2;
570 if serifs: pickup crisp.nib; x3+.5stem=hround(w-1.5u); x2=2.5u;
571 y1+.5stem=h; y2=max(2/3[h,x_height],x_height+o+hair);
572 numeric theta; theta=angle(z2-z1)+90;
573 pos1(stem,theta); pos2(hair,theta);
574 pos3(stem,theta); pos4(hair,theta);
575 filldraw circ_stroke z1e--z2e; % left diagonal
576 filldraw circ_stroke z3e--z4e; % right diagonal
577 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
578 pos3(stem,0); pos4(vair,0);
579 rt x3r=hround(w-1.5u); lft x4l=hround(.5w+u-.5vair);
580 top y1=h; bot y2=vround 2/3[h,x_height];
581 filldraw stroke z1e--z2e; % left diagonal
582 filldraw stroke z3e--z4e; fi % right diagonal
583 penlabels(1,2,3,4); endchar;
584
585 ecchar"Double backwards tick mark"; % jk
586 beginchar(oct"203",9u#,min(asc_height#,2x_height#),0);
587 adjust_fit(0,0);
588 x3-x1=x4-x2=hround 3u; y3=y1; y4=y2;
589 if serifs: pickup crisp.nib; x1-.5stem=hround 1.5u; x2=3.5u;
590 y1+.5stem=h; y2=max(2/3[h,x_height],x_height+o+hair);
591 numeric theta; theta=angle(z2-z1)+90;
592 pos1(stem,theta); pos2(hair,theta);
593 pos3(stem,theta); pos4(hair,theta);
594 filldraw circ_stroke z1e--z2e; % left diagonal
595 filldraw circ_stroke z3e--z4e; % right diagonal
596 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
597 pos3(stem,0); pos4(vair,0);
598 lft x1l=hround 1.5u; rt x2r=hround(.5w-u+.5vair);
599 top y1=h; bot y2=vround 2/3[h,x_height];
600 filldraw stroke z1e--z2e; % left diagonal
601 filldraw stroke z3e--z4e; fi % right diagonal
602 penlabels(1,2,3,4); endchar;
603
604
605 ecchar "Dagger mark"; % from mathsy
606 beginchar(oct"204",8u#,asc_height#,desc_depth#);
607 adjust_fit(0,0); pickup fine.nib;
608 pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
609 pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
610 x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); center_on(x1);
611 x5-.5stem=hround u; x6=w-x5;
612 y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
613 y5+.5stem=floor(x_height+.5stem);
614 filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e; % stem
615 filldraw circ_stroke z5e{right}..{right}z2'e; % left bulb
616 filldraw circ_stroke z6e{left}..{left}z2'e; % right bulb
617 penlabels(1,2,3,4,5,6); endchar;
618
619 ecchar "Double dagger mark"; % from mathsy
620 beginchar(oct"205",8u#,asc_height#,desc_depth#);
621 adjust_fit(0,0); pickup fine.nib;
622 pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
623 pos4(stem,90); pos2'(thin_join,90); pos5(stem,90); z2'=z2;
624 x1=x2=x3; x1-.5stem=hround(.5w-.5stem); center_on(x1);
625 x4-.5stem=hround u; x5=w-x4;
626 y1+.5stem=h+oo; y2=y4=y5=.5[y1,y3]; y3-.5stem=ceiling(.5[-d,h]);
627 filldraw circ_stroke z1e{down}..{down}z2e; % top stem
628 filldraw circ_stroke z3e{up}..{up}z2e; % upper middle stem
629 filldraw circ_stroke z4e{right}..{right}z2'e; % top left bulb
630 filldraw circ_stroke z5e{left}..{left}z2'e; % top right bulb
631 pos6(stem,0); pos7(thin_join,0); pos8(stem,0);
632 pos9(stem,90); pos7'(thin_join,90); pos0(stem,90); z7'=z7;
633 x6=x7=x8=x1; x9=x4; x0=x5;
634 y6=y3-stem-1; y7=y9=y0=.5[y6,y8]; y8-.5stem=-d-oo;
635 filldraw circ_stroke z6e{down}..{down}z7e; % lower middle stem
636 filldraw circ_stroke z8e{up}..{up}z7e; % bottom stem
637 filldraw circ_stroke z9e{right}..{right}z7'e; % bottom left bulb
638 filldraw circ_stroke z0e{left}..{left}z7'e; % bottom right bulb
639 penlabels(1,2,3,4,5,6,7,8,9,0); endchar;
640
641 ecchar "Double vertical line (norm or cardinality)"; % from mathsy
642 % Change (jk): Made the two lines as close as in \P
643 beginchar(oct"206",9u#,body_height#,paren_depth#);
644 adjust_fit(0,0); pickup rule.nib;
645 x1=x2; top y1=h; .5[y1,y2]=math_axis;
646 x3=x4=w-x1; y3=y1; y4=y2;
647 x3-x1=ceiling(rule_thickness+1.25u);
648 draw z1--z2; draw z3--z4; % stems
649 labels(1,2,3,4); endchar;
650
651 ecchar "Per mill sign"; % by Emma Pease
652 beginchar(oct"207",15u#+max(6u#,2fudge*(hair#+stem#)),
653 body_height#,body_height#-asc_height#);
654 italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
655 adjust_fit(0,0); pickup fine.nib;
656 numeric left_curve,right_curve;
657 left_curve=hround 5/6[fudged.hair,fudged.stem];
658 right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
659 pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
660 top y1r=h; lft x2r=hround u; rt x4r=hround(.5(w-6u)-1.5u);
661 bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
662 x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
663 filldraw stroke pulled_super_arc.e(1,2)(superpull)
664 & pulled_super_arc.e(2,3)(superpull); % left half of upper bowl
665 filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
666 %
667 pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
668 bot y7r=-d; rt x8r=hround(w-7u); lft x6r=hround(.5(w-6u)+1.5u);
669 top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
670 x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
671 filldraw stroke pulled_super_arc.e(5,6)(superpull)
672 & pulled_super_arc.e(6,7)(superpull); % left half of lower bowl
673 filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
674 %
675 pos13(vair,90); pos14(left_curve,180); pos15(vair,270);
676 pos16(right_curve,360);
677 bot y15r=-d; rt x16r=hround(w-u); lft x14r=hround(.5(w-6u)+1.5u+6u);
678 top y13r=vround(if monospace: .3 else: .5 fi\\ asc_height);
679 x13=x15=.5[x14,x16]; y14=y16=.5[y13,y15];
680 filldraw stroke pulled_super_arc.e(13,14)(superpull)
681 & pulled_super_arc.e(14,15)(superpull); % left half of lower bowl
682 filldraw stroke super_arc.e(15,16) & super_arc.e(16,13); % right half of lower bowl
683 %
684 pickup rule.nib; top y9=h; bot y10=-d;
685 if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
686 draw z9--z10; % diagonal
687 else: rt x9=hround(w-6u-2.5u); lft x10=hround 2.5u; draw z9--z10; % diagonal
688 pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
689 pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
690 path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
691 filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi % link
692 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16); endchar;
693
694 ecchar "Bullet"; % from mathsy
695 beginchar(oct"210",9u#,v_center(7u#));
696 adjust_fit(0,0); pickup rule.nib; autorounded;
697 if .5w <> good.x .5w: change_width; fi
698 lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
699 filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
700 ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle; % circle and interior
701 labels(1,2,3,4,5,6,7,8); endchar;
702
703 ecchar"Centigrade sign";
704 if serifs: beginchar(oct"211",13u#,cap_height#,0);
705 italcorr cap_height#*slant-.5u#;
706 adjust_fit(4u#,0);
707 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
708 pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
709 rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
710 top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
711 bot y1=min(vround max(.6h,x_height-.5vair),bot y2l-eps);
712 y5=max(good.y .95(h-y1),y4l+eps);
713 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
714 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
715 filldraw stroke z1e{x2-x1,10(y2-y1)}
716 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
717 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=h+o;
718 x1r-x1'=2cap_curve-fine; y1'=y1;
719 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
720 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
721 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
722 else: beginchar(oct"211",11.5u#,cap_height#,0);
723 italcorr cap_height#*slant-.5u#;
724 adjust_fit(4u#,0);
725 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
726 pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
727 rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
728 lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
729 top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
730 bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
731 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
732 & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
733 penlabels(1,1',2,3,4,5,6);
734 clearxy;
735 pickup rule.nib; autorounded;
736 lft x6=-4u; rt x2=0; top y8=h; y8-y2=x2-x8;
737 circle_points; draw_circle; % circle
738 labels(1,2,3,4,5,6,7,8);
739 math_fit(-.3cap_height#*slant-.5u#,.5ic#);
740 endchar;
741
742 ecchar "Oldstyle dollar sign"; % based on romanp (cm)
743 beginchar(oct"212",11u#,body_height#,body_height#-asc_height#);
744 italcorr fig_height#*slant-.5u#; % same as for digits
745 adjust_fit(0,0);
746 numeric theta; theta=90-angle(50u,asc_height); slope:=-asc_height/50u;
747 pickup fine.nib; pos2(slab,-90);
748 pos0(cap_stem,theta); pos7(slab,-90);
749 x2=x0=x7=.5w; top y2l=asc_height+oo; bot y7r=-oo;
750 y0=.52asc_height; lft x3l=hround u; rt x6r=hround(w-u);
751 x3r-x3l=x6r-x6l=hround .35[slab,cap_stem]-fine;
752 ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
753 ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
754 filldraw stroke super_arc.e(2,3) & z3e{down}
755 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % main stroke
756 if serifs: pos1(hair,0); pos8(hair,180);
757 pos10(flare,0); pos9(flare,180);
758 rt x1r=hround(w-u); lft x8r=hround u; y1=.5[y0,y2]; y8=.5[y0,y7];
759 {{less_tense; pos2'(slab,90); z2'=z2; bulb(2',1,10); % upper arc and bulb
760 bulb(7,8,9)}}; % lower arc and bulb
761 else: pos1(.6[slab,flare],-100); pos8(flare,-100);
762 rt x1l=hround(w-1.3u); lft x8r=hround .8u;
763 top y1l=vround .92asc_height+oo; bot y8r=vround .1asc_height-oo;
764 filldraw stroke term.e(2,1,right,.9,4); % upper arc and terminal
765 filldraw stroke term.e(7,8,left,1,4); fi % lower arc and terminal
766 pickup crisp.nib; pos12(bar,0); pos11(bar,0); pos13(bar,0); pos14(bar,0);
767 x11=x12; x13=x14=w-x11; x13-x11=ceiling(rule_thickness+1.25u);
768 top y12=top y14=h; bot y11=bot y13=-d;
769 filldraw stroke z12e--z11e; % left vertical crossbar
770 filldraw stroke z14e--z13e; %right vertical crossbar
771 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
772
773 ecchar "Oldstyle cent sign"; % jk, based on cm `c'
774 beginchar(oct"213",9u#,x_height#+.5desc_depth#,.5desc_depth#);
775 italcorr x_height#*slant-.2u#;
776 adjust_fit(0,0);
777 pickup fine.nib; pos2(vair',90); pos4(vair',270);
778 x2=x4=.5(w+u); top y2r=vround(x_height+1.5oo); bot y4r=-oo;
779 pos3(curve,180); lft x3r=hround max(.6u,1.35u-.5curve); y3=.5x_height;
780 if serifs: pos1(hair,0); pos0(flare,0);
781 y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,x_height]-.5flare);
782 rt x1r=hround(w-.7u); bulb(2,1,0); % bulb
783 pos5(hair,0); rt x5r=hround(w-.5u);
784 y5=max(good.y(.5bar_height-.9),y4l+vair');
785 (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
786 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
787 & pulled_super_arc.e(3,4)(.5superpull)
788 ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e; % arc and lower terminal
789 else: pos1(4/7[vair',flare],80);
790 rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
791 filldraw stroke term.e(2,1,right,.8,4); % upper terminal
792 pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
793 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
794 forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
795 if angle direction 1 of p.e>75:
796 p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
797 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
798 & pulled_super_arc.e(3,4)(.5superpull) & p.e; fi % arc and lower terminal
799 pickup crisp.nib;
800 x7=x3; x6=w-x7; y6=h; y7=-d;
801 numeric theta; theta=angle(z7-z6)-90;
802 pos6(vair,theta); pos7(vair,theta);
803 filldraw stroke z6e--z7e; % diagonal
804 penlabels(0,1,2,3,4,5,6,7); endchar;
805
806 iff variant_g: % I use this as marker for italic fonts
807 ecchar "Italic florin sign (italic letter f)"; % from itall (cm)
808 beginchar(oct"214",max(1.5u#,stem#)+max(3.5u#,2flare#),
809 asc_height#,desc_depth#);
810 italcorr asc_height#*slant+.75u#;
811 adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
812 numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
813 pos0(flare,0); pos1(hair,0); pos2(vair,90);
814 pos3(.5[hair,stem],180); pos4(stem,theta+90);
815 pos5(stem,theta-90); pos6(.5[hair,stem],0);
816 pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
817 rt x1r=hround(w+.25u); lft x8r=hround-.35u; x2=.6[x1,x4]; x7=.6[x8,x5];
818 y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
819 y4=.25[x_height,h]; y5=.5[-d,y4];
820 z4=whatever[z88,z89]; z5=whatever[z88,z89];
821 x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
822 bulb(2,1,0); bulb(7,8,9); % bulbs
823 filldraw stroke z2e{left}...z3e...{z89-z88}z4e; % upper arc
824 filldraw z4r--z5l--z5r--z4l--cycle; % stem
825 filldraw stroke z5e{z89-z88}...z6e...{left}z7e; % lower arc
826 pickup crisp.nib; pos20(bar,90); pos21(bar,90);
827 top y20r=top y21r=x_height;
828 lft x20=lft x4r-.5stem-u; rt x21=rt x4l+.5stem+1.5u;
829 filldraw stroke z20e--z21e; % crossbar
830 math_fit(desc_depth#*slant+u#,x_height#*slant);
831 penlabels(0,1,2,3,4,5,6,7,8,9,20,21,88,89); endchar;
832
833
834 iff not variant_g:
835 ecchar "Florin sign (The letter f)"; % from romanl (cm)
836 beginchar(oct"214",5.5u#,asc_height#,0);
837 italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
838 adjust_fit(stem_shift#,if monospace: .5u# else:-stem_shift# fi);
839 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
840 pickup fine.nib; numeric bulb_diam;
841 if serifs: bulb_diam=hround .8[stem,flare];
842 pos2(bulb_diam,0); y2+.5bulb_diam=.9[x_height,h+oo];
843 if monospace: rt x2r=hround(w-.5u)+1 else: lft x2l=hround(w-.75u+.5) fi;
844 else: pos2(5/7[vair,flare],90); top y2r=h;
845 rt x2=hround(if monospace:w-.5u else:w+.75u fi); fi
846 f_stroke(1,2,a,b,c,jut,if not monospace:1.25fi\\ jut); % stem, terminal, serif
847 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
848 pos3(bar,90); pos4(bar,90);
849 rt x4=hround(w-if monospace:.75u+1 else:1/3u fi);
850 filldraw stroke z3e--z4e; % bar
851 penlabels(1,2,3,4); endchar;
852
853 ecchar"Colon sign or Cedi sign"; % Panamese or Ghanese currency
854 if serifs: beginchar(oct"215",13u#,body_height#,body_height#-asc_height#);
855 italcorr cap_height#*slant-.5u#;
856 adjust_fit(0,0);
857 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
858 pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
859 rt x1r=rt x5r=hround(w-u); lft x3r=hround u; x2=x4=.55[x3,x1];
860 numeric hh; hh=cap_height;
861 top y2r=hh+o; bot y4r=-o; y3=.5[y2,y4];
862 bot y1=min(vround max(.6hh,x_height-.5vair),bot y2l-eps);
863 y5=max(good.y .95(hh-y1),y4l+eps);
864 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
865 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
866 filldraw stroke z1e{x2-x1,10(y2-y1)}
867 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
868 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=hh+o;
869 x1r-x1'=2cap_curve-fine; y1'=y1;
870 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
871 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
872 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
873 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
874 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
875 filldraw stroke z12e--z11e; % vertical crossbar
876 else: beginchar(oct"215",11.5u#,body_height#,body_height#-asc_height#);
877 italcorr cap_height#*slant-.5u#;
878 adjust_fit(0,0);
879 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
880 pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
881 rt x1r=hround(w-1.1u); x2=x4=.5w+1.25u;
882 lft x3r=hround max(u,2u-.5cap_curve); rt x5r=hround(w-.9u);
883 numeric hh; hh=cap_height;
884 top y1r=vround .95hh+o; top y2r=hh+o; y3=.5hh;
885 bot y4r=-o; bot y5r=vround .08hh-o; y5l:=good.y y5l; x5l:=good.x x5l;
886 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
887 & super_arc.e(3,4) & term.e(4,5,right,.8,4); % arc and terminals
888 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
889 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
890 filldraw stroke z12e--z11e; % vertical crossbar
891 fi
892 math_fit(-.3cap_height#*slant-.5u#,.5ic#);
893 penlabels(1,1',2,3,4,5,6,11,12); endchar;
894
895 ecchar"Won sign"; % Korean currency
896 beginchar(oct"216",18u#,cap_height#,0);
897 italcorr cap_height#*slant+.25u#;
898 adjust_fit(cap_serif_fit#,cap_serif_fit#);
899 numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
900 outer_jut=.7cap_jut; x1l=w-x8r=l+letter_fit+outer_jut+.25u;
901 stem1=fudged.cap_stem-stem_corr;
902 stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
903 stem2=stem4 if hefty:-2stem_corr fi;
904 stem3=stem1 if hefty:-2stem_corr fi;
905 x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
906 y1=y8=h; y2=y3=y6=y7=-apex_o; y4=y5=if monospace: vround .6 fi\\ h;
907 mid_corr=if monospace or hefty:-apex_corr else: 1/3jut fi;
908 alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
909 penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
910 penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
911 penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
912 penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
913 x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r+mid_corr| $\approx$ |x4r|
914 z23=whatever[z1r,z2r]=whatever[z3l,z4l];
915 z45=whatever[z3r,z4r]=whatever[z5l,z6l];
916 z67=whatever[z5r,z6r]=whatever[z7l,z8l]; upper_notch=y4-cap_notch_cut;
917 fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
918 ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
919 --(x45,upper_notch)+.5right{down} else: z45&z45 fi
920 ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
921 ...if y67>cap_notch_cut:(x67,cap_notch_cut)+.5right{down}
922 --(x67,cap_notch_cut)+.5left{up} else: z67&z67 fi
923 ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
924 ...if y23>cap_notch_cut:(x23,cap_notch_cut)+.5right{down}
925 --(x23,cap_notch_cut)+.5left{up} else: z23&z23 fi
926 ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle; % diagonals
927 if serifs: numeric inner_jut[]; pickup tiny.nib;
928 prime_points_inside(1,2); prime_points_inside(5,6);
929 prime_points_inside(8,7);
930 if monospace: inner_jut1=inner_jut4=1.5cap_jut;
931 elseif hefty: inner_jut1=inner_jut4=cap_jut;
932 else: fill diag_end(6r,5r,1,1,5l,6l)
933 --.5[z5l,z6l]--.5[z5r,z6r]--cycle; % middle stem
934 inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
935 if rt x1'r+cap_jut+.5u+1<=lft x5'l-.7cap_jut: inner_jut1=cap_jut;
936 else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
937 if rt x5'r+cap_jut+.5u+1<=lft x8'l-1.1cap_jut: inner_jut3=cap_jut;
938 else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
939 dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi % middle serif
940 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut1); % left serif
941 dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); fi % right serif
942 pickup extra_rule.nib;
943 x9=x11=x1l; x10=x12=x8r; y9=y10;
944 top y9=bar_height; y11=y12; draw z9--z10;
945 y11-y9=spread; draw z11--z12; % crossing bars
946 math_fit(.75u#-cap_height#*slant,ic#-2.5u#);
947 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,23,45,67); endchar;
948
949 ecchar"Naira sign"; % Nigerian currency
950 beginchar(oct"217",13u#+width_adj#,cap_height#,0);
951 italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+
952 min(.5cap_stem#,u#);
953 adjust_fit(cap_serif_fit#+.25u#,cap_serif_fit#+.25u#);
954 numeric thin_stem; thin_stem=hround(fudged.hair+stem_corr);
955 pickup tiny.nib; pos1(thin_stem,0); pos2(thin_stem,0);
956 pos3(thin_stem,0); pos4(thin_stem,0);
957 pickup tiny.nib; top y1=top y3=h; bot y2=bot y4=0;
958 x1=x2; x3=x4; x1l=w-x3r;
959 rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
960 filldraw stroke z1e--z2e; % left stem
961 filldraw stroke z3e--z4e; % right stem
962 if hefty: penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
963 x5l=x1; x6r=x4; y5=h; y6=0;
964 numeric upper_notch,lower_notch;
965 upper_notch=h-cap_notch_cut; lower_notch=cap_notch_cut;
966 x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l; z4'=whatever[z5r,z6r];
967 fill z5l..
968 if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
969 {z6-z5}diag_in(5l,6l,1,6r)--z6r..
970 if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
971 {z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonal
972 else: penpos5(whatever,0); penpos6(whatever,90);
973 z5l=z1l; z6l=z4l;
974 z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
975 z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
976 filldraw stroke z5e..z6e; fi % diagonal
977 if serifs: if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
978 else: serif(5,6,a,1/3,-cap_jut); fi % upper left serif
979 dish_serif(2,1,b,1/2,cap_jut,c,1/2,cap_jut)(dark); % lower left serif
980 dish_serif(3,4,e,1/2,cap_jut,f,1/2,cap_jut)(dark); fi % upper right serif
981 pickup extra_rule.nib;
982 x8=x10=0; x9=x11=w; y10=y11;
983 top y8=bar_height; y8=y9; draw z8--z9;
984 y10-y8=spread; draw z10--z11; % crossing bars
985 math_fit(0,max(.5ic#-.5u#,0));
986 penlabels(1,1',2,3,4,4',5,6,7,8,9,10,11); endchar;
987
988 ecchar"Guarani sign"; % Currency of Paraguay
989 if serifs: beginchar(oct"220",14u#,body_height#,body_height#-asc_height#);
990 italcorr cap_height#*slant-1.5u#-.5cap_serif_fit#;
991 adjust_fit(0,.5cap_serif_fit#);
992 numeric hh; hh=cap_height;
993 pickup tiny.nib; pos0(cap_stem,0); pos7(cap_stem,0);
994 rt x0r=hround(w-2u); y0=good.y(.1[bar_height,x_height]+1); x7=x0;
995 pickup fine.nib;
996 if hefty: bot y7=0; pos5(cap_stem,0); x5=x0; top y5=tiny.top y0;
997 else: pos5(cap_hair,0); pos8(cap_stem,0);
998 y7=.5bar_height; z5l=z8l; z8=z7; x9=x8r; bot y9=0;
999 filldraw z8l{down}..{4(x9-x8),y9-y8}z9--z8r--cycle; fi % spur
1000 pos1(cap_hair,0); pos2(cap_band,90);
1001 pos3(cap_curve,180); pos4(cap_band,270);
1002 rt x1r=hround(w-2u); lft x3r=hround u; x2=x4=.55[x3,x1];
1003 top y2r=hh+o; bot y4r=-o; y3=.5[y2,y4];
1004 bot y1=min(vround max(.6hh,x_height-.5vair),bot y2l-eps);
1005 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
1006 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
1007 filldraw stroke z1e{x2-x1,10(y2-y1)}
1008 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...z5e{up}; % arc
1009 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=hh+o;
1010 x1r-x1'=2cap_curve-fine; y1'=y1;
1011 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
1012 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
1013 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
1014 pickup tiny.nib; filldraw stroke z0e--z7e; % stem
1015 dish_serif(0,7,a,1/3,max(cap_jut,2.25u),b,1/3,1.25u); % serif
1016 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
1017 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
1018 filldraw stroke z12e--z11e; % vertical crossbar
1019 math_fit(-.3cap_height#*slant-.5u#,ic#);
1020 else: beginchar(oct"220",14u#,body_height#,body_height#-asc_height#);
1021 italcorr cap_height#*slant-.5u#;
1022 adjust_fit(0,0);
1023 numeric hh; hh=cap_height;
1024 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
1025 pos3(cap_curve,180); pos4(slab,270); pos5(flare,270);
1026 rt x1r=hround(w-1.35u); x2=x4=.5w+u;
1027 lft x3r=hround max(u,2u-.5cap_curve); rt x5l=hround(w-1.2u);
1028 top y1r=vround .93hh+o; top y2r=hh+o; y3=.5hh;
1029 bot y4r=-o; bot y5r=vround .07hh-o;
1030 filldraw stroke rterm.e(2,1,right,.9,4)&super_arc.e(2,3)
1031 & super_arc.e(3,4) & term.e(4,5,right,1,4); % arc and terminals
1032 pos0(stem,0); pos7(stem,0);
1033 z7r=z5r; x0=x7; top y0=1+vround .35[bar_height,x_height];
1034 filldraw stroke z0e--z7e; % stem
1035 pos8(cap_bar,90); pos9(cap_bar,90);
1036 z0r=z9r; y8=y9; lft x8=hround x4;
1037 filldraw stroke z8e--z9e; % bar
1038 pickup crisp.nib; pos12(bar,0); pos11(bar,0);
1039 lft x12l=lft x11l=hround(x2-.5bar); top y12=h; bot y11=-d;
1040 filldraw stroke z12e--z11e; % vertical crossbar
1041 math_fit(-.3cap_height#*slant-.5u#,.5ic#); fi
1042 penlabels(0,1,1',2,3,4,5,6,7,8,9,11,12); endchar;
1043
1044 ecchar"Peso sign";
1045 beginchar(oct"221",12u#,cap_height#,0);
1046 italcorr .75cap_height#*slant-.5u#;
1047 adjust_fit(cap_serif_fit#+.25u#,0);
1048 pickup tiny.nib; penpos1(cap_stem'-tiny,0); penpos2(cap_stem-tiny,0);
1049 pos0(cap_stem',0); pos0'(cap_stem,0);
1050 lft x1l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
1051 x1l=x2l=x0l=x0'l; y0=y0'=y7;
1052 penpos3(cap_band,90); penpos4(cap_band,90);
1053 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1054 penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
1055 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1056 x7=x2; y7l=vround .5h; x4=x6=.5w+.75u; x5r=hround(w-u);
1057 x4l:=x6l:=x4-.25cap_curve;
1058 filldraw stroke z1e--z0e--z0'e--z2e; % stem
1059 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1060 if serifs: nodish_serif(1,0,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1061 dish_serif(2,0',c,1/3,cap_jut,d,1/3,cap_jut); fi % lower serif
1062 pickup extra_rule.nib;
1063 x8=0; x9=.5[x1r,x5r]; top y8=bar_height; y8=y9; draw z8--z9;
1064 math_fit(0,ic#-2.5u#); penlabels(0,1,2,3,4,5,6,7); labels(8,9);
1065 endchar;
1066
1067 ecchar "Lira sign"; %
1068 compute_spread(.35x_height#,.45x_height#);
1069 beginchar(oct"222",12u#,asc_height#,0);
1070 adjust_fit(0,.75asc_height#*slant-.5u#); pickup fine.nib;
1071 pos0(flare,0); pos1(hair,0); pos2(vair,90); pos3(stem,180);
1072 pos4(stem,180); pos4'(stem,0); pos5(vair,-90); z4'=z4;
1073 x2=2/3w-.5u; rt x3l=rt x4l=hround(.5w-u+.5stem); x5=2.5u;
1074 y1=y3=.75h; top y2=h+oo; y4=.25h; bot y5r=-oo;
1075 rt x1r=hround(w-1.5u); bulb(2,1,0); % bulb
1076 filldraw stroke pulled_arc.e(2,3)..z4e; % stem
1077 numeric light_stem; light_stem=2/3[vair,vstem];
1078 pos6(.5[hair,light_stem],-180); pos7(light_stem,-300);
1079 pos8(light_stem,-300); pos9(hair,-180);
1080 lft x6r=hround u; x7=3u; x8=w-3.5u; rt x9l=hround(w-u);
1081 y6=.4[y5,y7]; top y7r=vround .2h; bot y8l=-oo; y9=good.y .2h;
1082 filldraw stroke pulled_arc.e(4',5)...z6e{up}...z7e{right}
1083 ..{right}z8e...{up}z9e; % loop and arm
1084 pickup extra_rule.nib;
1085 x10=3u; x11=w-4.5u; x12=3u; x13=w-4.5u;
1086 top y12=bar_height;
1087 y11=y10; y13=y12; y10-y12=spread;
1088 draw z10--z11; % upper bar
1089 draw z12--z13; % lower bar
1090 penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
1091
1092 ecchar"Recipe sign";
1093 beginchar(oct"223",if serifs: 12u#+.5max(2u#,cap_curve#)
1094 else:12.5u#-.5width_adj# fi,cap_height#,0);
1095 italcorr .75cap_height#*slant- if serifs: 1.75 else: .5 fi\\ u#;
1096 adjust_fit(cap_serif_fit#,0);
1097 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1098 lft x1l=lft x2l=hround max(2u,3u-.5cap_stem'); top y1=h; bot y2=0;
1099 filldraw stroke z1e--z2e; % stem
1100 penpos3(cap_band,90); penpos4(cap_band,90);
1101 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1102 penpos6(vair,-90); penpos7(vair,-90);
1103 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1104 x7=x2; y7l=vround(.5h+.5vair); x4=x6;
1105 if serifs: x4=.5w-.5u; x5r=hround(w-2.25u);
1106 else: x4=.5w+.5u; x5r=hround(w-u); fi
1107 x4l:=x6l:=x4-.125cap_curve;
1108 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1109 if serifs: pos6'(vair,-90); pos0(cap_stem,180);
1110 pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
1111 z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
1112 y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
1113 bot y9r=-o; rt x10r=hround(w-.05u); y10=1/4[y2,y7];
1114 filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up}; % tail
1115 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1116 dish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); % lower serif
1117 else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
1118 x8=x6+.5u; y8=y6; x9r=hround(w-.5u); y9=0;
1119 fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi % tail
1120 x1:=x8;
1121 put_cross(.5cap_stem+if serifs: .9max(limit_dist,cap_jut) else: .8u fi,
1122 .5cap_stem+if serifs: 3u else: 4u fi);
1123 math_fit(0,.75ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
1124
1125 iff not variant_g: % not italic
1126 ecchar"Interrobang";
1127 beginchar(oct"224",8.5u#,asc_height#,0);
1128 italcorr .8asc_height#*slant;
1129 adjust_fit(0,0);
1130 pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
1131 lft x7l=hround(.5w-.25u-.5dot_size); bot y8l=0; z7=z8; % dot(7,8); % dot
1132 numeric bot_width;
1133 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1134 pickup fine.nib; pos2(vair,90); pos3(curve,0);
1135 pos4(vair,-90); pos5(bot_width,0); pos6(bot_width,0);
1136 x2=x4=x5=x6=x7; rt x3r=hround(w-u); bot y6=1+.25[top y8r,x_height];
1137 top y2r=hround .9h+oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
1138 {{interim superness:=more_super;
1139 filldraw stroke pulled_super_arc.e(2,3)(superpull)
1140 & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}}; % arc and stem
1141 if serifs: pos1(hair,180); pos0(flare,180);
1142 lft x1r=hround u; y1=y3; bulb(2,1,0); % bulb
1143 else: pos1(Vround 5/7[vair,flare],110);
1144 lft x1r=hround u; top y1r=vround .9[y6,top y2r];
1145 filldraw stroke term.e(2,1,left,1,4); fi % terminal
1146 penlabels(0,1,2,3,4,5,6,7,8);
1147 clearxy;
1148 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1149 lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
1150 numeric bot_width;
1151 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1152 pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
1153 x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
1154 if square_dots: top y1=h;
1155 filldraw stroke z1e--z2e; % stem
1156 else: top z0=(x1,h+o); y1+.5dot_size=h+o;
1157 filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
1158 penlabels(0,1,2,3,4); endchar;
1159
1160 iff not variant_g: % not italic
1161 ecchar"Gnaborretni";
1162 beginchar(oct"225",8.5u#,asc_height#-desc_depth#,desc_depth#);
1163 adjust_fit(0,0);
1164 pickup tiny.nib; pos7(dot_size,0); pos8(dot_size,90);
1165 lft x7l=hround(.5w-.25u-.5dot_size); top y8r=h; z7=z8; % dot(7,8); % dot
1166 numeric top_width;
1167 top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1168 pickup fine.nib; pos2(vair,270); pos3(curve,180);
1169 pos4(vair,90); pos5(top_width,180); pos6(top_width,180);
1170 x2=x4=x5=x6=x7; lft x3r=hround u; top y6=.25[bot y8l,h-x_height]-1;
1171 bot y2r=hround .1asc_height-d-oo; y3=.75[y6,y2]; y4=.5[y6,y2]; y5=.1[y6,y2];
1172 {{interim superness:=more_super;
1173 filldraw stroke pulled_super_arc.e(2,3)(superpull)
1174 & subpath (0,1) of super_arc.e(3,4) .. z5e---z6e\\}}; % arc and stem
1175 if serifs: pos1(hair,0); pos0(flare,0);
1176 rt x1r=hround(w-u); y1=y3; bulb(2,1,0); % bulb
1177 else: pos1(Vround 5/7[vair,flare],-70);
1178 rt x1r=hround(w-u); bot y1r=vround .9[y6,bot y2r];
1179 filldraw stroke term.e(2,1,right,1,4); fi % terminal
1180 penlabels(0,1,2,3,4,5,6,7,8);
1181 clearxy;
1182 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1183 lft x3l=hround(.5w-.5dot_size); top y4r=h; z3=z4; dot(3,4); % dot
1184 numeric top_width;
1185 top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1186 pickup fine.nib; pos1(dot_size,0); pos2(top_width,0);
1187 x1=x2=x3; top y2=.25[bot y4l,h-x_height]-1;
1188 if square_dots: bot y1=-d;
1189 filldraw stroke z1e--z2e; % stem
1190 else: bot z0=(x1,-d-o); y1-.5dot_size=-d-o;
1191 filldraw z1l...z0...z1r---z2r--z2l---cycle; fi % stem and bulb
1192 penlabels(0,1,2,3,4); endchar;
1193
1194 iff variant_g: % italic
1195 ecchar"Interrobang";
1196 beginchar(oct"224",9u#,asc_height#,0);
1197 italcorr asc_height#*slant-u#;
1198 adjust_fit(0,0);
1199 adjust_fit(0,0); pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
1200 lft x10l=hround(.5w-.5dot_size); bot y11l=0; z10=z11; % dot(10,11); % dot
1201 pickup fine.nib; pos1(flare,180); pos2(hair,180); pos3(vair,90);
1202 lft x1r=hround u; x3=.5w;
1203 y1-.5flare=x_height; top y3r=hround .9h+o; bulb(3,2,1); % bulb
1204 pos8(vair,-90); x8=.5w; bot y8r=.25[top y11r,x_height]+1;
1205 numeric theta; theta=90+angle(10u,y3-y8); slope:=(y3-y8)/10u;
1206 pos3'(vair,-90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
1207 rt x4l=hround(w-1.5u); lft x7r=hround 1/3w;
1208 x4l-x4r=x7l-x7r=hround .5[vair,vstem]-fine;
1209 ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
1210 ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
1211 pos9(hair,0); rt x9r=hround(2/3w+.5hair); y9=good.y .5[y8,y0];
1212 filldraw stroke super_arc.e(3',4) & z4e{down}
1213 ..z5e---z6e..z7e{down} & super_arc.e(7,8)...{up}z9e; % main stroke
1214 penlabels(0,1,2,3,4,5,6,7,8,9,10,11);
1215 clearxy;
1216 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1217 lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4); % dot
1218 numeric bot_width;
1219 bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1220 pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
1221 x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
1222 if square_dots: top y1=h;
1223 filldraw stroke z1e--z2e; % stem
1224 else: top z0=(x1,h+o); y1+.5dot_size=h+o;
1225 filldraw z1r...z0...z1l---z2l--z2r---cycle; fi % stem and bulb
1226 penlabels(0,1,2,3,4); endchar;
1227
1228 iff variant_g: % italic
1229 ecchar"Gnaborretni";
1230 beginchar(oct"225",9u#,asc_height#-desc_depth#,desc_depth#);
1231 adjust_fit(0,0);
1232 pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
1233 lft x10l=hround(.5w-.5dot_size); top y11r=h; z10=z11; % dot(10,11); % dot
1234 pickup fine.nib; pos1(flare,0); pos2(hair,0); pos3(vair,-90);
1235 rt x1r=hround(w-u); x3=.5w; y1+.5flare=asc_height-x_height-d;
1236 bot y3r=hround .1asc_height-d-o; bulb(3,2,1); % bulb
1237 pos8(vair,90); x8=.5w; top y8r=.25[bot y11l,y1+.5flare]-1;
1238 numeric theta; theta=angle(10u,y8-y3)-90; slope:=(y8-y3)/10u;
1239 pos3'(vair,90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
1240 lft x4l=hround 1.5u; rt x7r=hround 2/3w;
1241 x4r-x4l=x7r-x7l=hround .5[vair,vstem]-fine;
1242 ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
1243 ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
1244 pos9(hair,180); lft x9r=hround(1/3w-.5hair); y9=good.y .5[y8,y0];
1245 filldraw stroke super_arc.e(3',4) & z4e{up}
1246 ..z5e---z6e..z7e{up} & super_arc.e(7,8)...{down}z9e; % main stroke
1247 penlabels(0,1,2,3,4,5,6,7,8,9,10,11);
1248 clearxy;
1249 pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
1250 lft x3l=hround(.5w-.5dot_size); top y4r=h; z3=z4; dot(3,4); % dot
1251 numeric top_width;
1252 top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
1253 pickup fine.nib; pos1(dot_size,0); pos2(top_width,0);
1254 x1=x2=x3; top y2=.25[bot y4l,h-x_height]-1;
1255 if square_dots: bot y1=-d;
1256 filldraw stroke z1e--z2e; % stem
1257 else: bot z0=(x1,-d-o); y1-.5dot_size=-d-o;
1258 filldraw z1l...z0...z1r---z2r--z2l---cycle; fi % stem and bulb
1259 penlabels(0,1,2,3,4); endchar;
1260
1261 iff not variant_g: % not italic
1262 ecchar"Dong sign"; % Vietnamese currency
1263 beginchar(oct"226",10u#+serif_fit#,body_height#,0);
1264 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
1265 adjust_fit(0,serif_fit#);
1266 numeric hh; hh=asc_height;
1267 pickup tiny.nib; pos1(stem',0); pos2(stem,0);
1268 pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
1269 rt x1r=hround(w-2.5u+.5stem'); top y1=hh;
1270 numeric edge; edge=lft x2l;
1271 pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
1272 pos4(vair,90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
1273 lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),1/3[lft x2,edge]);
1274 y3=1/8[bar_height,x_height];
1275 x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo if monospace: -hair fi;
1276 lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height if monospace: -.5hair fi;
1277 x6l=x4l-.2u; bot y6r=-oo;
1278 x7=x3; y7=min(y3,y6+y4-y3+.6vair);
1279 (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
1280 (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
1281 filldraw stroke z3e{up}...pulled_arc.e(4,5)
1282 & pulled_arc.e(5,6)...{up}z7e; % bowl
1283 y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
1284 pickup tiny.nib; bot y2=if serifs:-min(oo,serif_drop) else: 0 fi;
1285 filldraw stroke z1e--z0'e--z0e--z2e; % stem
1286 if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); % upper serif
1287 sloped_serif.r(2,0,b,1/3,jut,min(oo,serif_drop)); fi % lower serif
1288 %
1289 pos8(bar,90); pos9(bar,90);
1290 x8=.5[x4,x5];
1291 if serifs: x9=x2r+jut; else: x9=w; fi
1292 if serifs: y8=y9=.5[y.a2-.5slab,y4+.5vair];
1293 else: y8=y9=.5[x_height,asc_height-serif_drop]; fi
1294 filldraw stroke z8e--z9e;
1295 currentpicture:=currentpicture shifted (0,body_height-asc_height);
1296 pickup rule.nib;
1297 x10=x5; x11=x9; top y10=0; y10=y11;
1298 draw z10--z11;
1299 penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
1300
1301 iff variant_g: %italic
1302 ecchar"Italic Dong sign"; % Vietnamese currency
1303 beginchar(oct"226",9u#,body_height#,0);
1304 italcorr max(1/3x_height#*slant+.5hair#+.5u#,
1305 h#*slant+.5stem#-2u#) if math_fitting:-.5u# fi;
1306 adjust_fit(0,0); pickup fine.nib;
1307 pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
1308 x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
1309 x4+.5stem=hround(w-2.5u+.5stem);
1310 top y1r=x_height+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
1311 filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
1312 & pulled_arc.e(2,3) & super_arc.e(3,0); % bowl
1313 x5=x0; x7=w; hook_out(5,6,7); % closing hook
1314 pickup tiny.nib; pos5'(stem,0); pos4(stem,0);
1315 z5'=z5; top y4=h; filldraw stroke z4e--z5'e; % stem
1316 sloped_serif.l(4,5',a,1/3,jut,serif_drop); % serif
1317 math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
1318 % the bar
1319 pos8(bar,90); pos9(bar,90);
1320 x8=x1; % .5[x1,x4];
1321 x9=x6;
1322 y8=y9=.5[y.a2-.5slab,y1+.5vair];
1323 filldraw stroke z8e--z9e;
1324 currentpicture:=currentpicture shifted (0,body_height-asc_height);
1325 pickup rule.nib;
1326 x10=x2; x11=x9; top y10=0; y10=y11;
1327 draw z10--z11;
1328 penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
1329
1330 ecchar"Trademark"; % jk, design based on logo font
1331 beginchar(oct"227",12u#,body_height#,0);
1332 italcorr .7body_height#;
1333 adjust_fit(0,0);
1334 numeric ww, hh; ww=.5w; hh=vround .5body_height;
1335 pickup pencircle xscaled hair yscaled vair;
1336 lft x1=-eps; x2=ww-x1; x3=x4=.5ww;
1337 y1=y2=y3; top y1=hh; bot y4=-o;
1338 draw z1--z2; draw z3--z4;
1339 labels(1,2,3,4);
1340 clearxy;
1341 x1=x2=hround(ww+u); x4=x5=hround(w-u); x3=hround .5[x1,x4];
1342 y1=y5; y2=y4; bot y1=-o;
1343 top y2=hh+o; y3=vround (y1+.5bar_height);
1344 draw z1--z2--z3--z4--z5;
1345 labels(1,2,3,4,5);
1346 currentpicture:=currentpicture shifted (0,hh);
1347 endchar;
1348
1349 ecchar"Per ten thousand sign"; % Yannis, Unicode Computer Modern
1350 beginchar(oct"230",9u#+max(6u#,2fudge*(hair#+stem#)),
1351 body_height#,body_height#-asc_height#);
1352 italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
1353 adjust_fit(0,
1354 2*(.5*(9u#+max(6u#,2fudge*(hair#+stem#)))
1355 -2.5u#+5/6[fudged.hair#,fudged.stem#]));
1356 pickup fine.nib;
1357 numeric left_curve,right_curve;
1358 left_curve=hround 5/6[fudged.hair,fudged.stem];
1359 right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
1360 pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
1361 top y1r=h; lft x2r=hround u; rt x4r=hround(.5w-1.5u);
1362 bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
1363 x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
1364 pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
1365 bot y7r=-d; rt x8r=hround(w-u); lft x6r=hround(.5w+1.5u);
1366 top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
1367 x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
1368 filldraw stroke pulled_super_arc.e(5,6)(superpull)
1369 & pulled_super_arc.e(6,7)(superpull); % left half of lower bowl
1370 filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
1371 hihi:=(.5*(9u#+max(6u#,2fudge*(hair#+stem#)))
1372 -2.5u#+5/6[fudged.hair#,fudged.stem#])
1373 if monospace: *expansion_factor fi *hppp;
1374 picture petit_zero; petit_zero := currentpicture;
1375 pickup rule.nib; top y9=h; bot y10=-d;
1376 if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
1377 draw z9--z10; % diagonal
1378 else: rt x9=hround(w-2.5u); lft x10=hround 2.5u; draw z9--z10; % diagonal
1379 pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
1380 pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
1381 path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
1382 filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi % link
1383 pickup fine.nib;
1384 filldraw stroke pulled_super_arc.e(1,2)(superpull)
1385 & pulled_super_arc.e(2,3)(superpull); % left half of upper bowl
1386 filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
1387 addto currentpicture also (petit_zero shifted (hihi,0));
1388 addto currentpicture also (petit_zero shifted (2hihi,0));
1389 picture petit_zero; % Release resources allocated to the picture variable
1390 penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
1391
1392 ecchar "Alternate pilcrow sign"; % one vertical bar only
1393 beginchar(oct"231",8.5u#,asc_height#,desc_depth#);
1394 adjust_fit(0,0); pickup rule.nib; autorounded;
1395 top y1=h; bot y6=-d-eps; y4=y9=y1;
1396 y3=y5=good.y .5[y1,y6];
1397 lft x2=hround u; y2=.5[y1,y3]; rt x9=hround(w-.5u); x4=x5=x6=good.x(x9-1.5u);
1398 x1=x3=min(.5w,x4);
1399 filldraw z4..z1{left}...z2{down}...{right}z5--cycle; % filled bowl
1400 draw z9--z4--z6; % left stem and upper serif
1401 if serifs:
1402 x11=x9; x10-x6=x4-x9;
1403 bot y10=-d-eps; y10=y11;
1404 draw z10--z11; % lower serif
1405 fi
1406 labels(1,2,3,4,5,6,9,10,11); endchar;
1407
1408 ecchar"Baht sign"; % currency of Thailand
1409 beginchar(oct"232",12.5u#,body_height#,body_height#-asc_height#);
1410 italcorr .75cap_height#*slant-.5u#;
1411 adjust_fit(cap_serif_fit#,0);
1412 numeric hh; hh=cap_height;
1413 numeric left_stem,right_curve,middle_weight;
1414 left_stem=cap_stem-hround 2stem_corr; middle_weight=.6vair+.5;
1415 pickup tiny.nib; pos1(left_stem,0); pos2(left_stem,0);
1416 lft x1l=lft x2l=hround max(2u,3u-.5left_stem); top y1=hh; bot y2=0;
1417 filldraw stroke z1e--z2e; % stem
1418 penpos3(cap_band,90); penpos4(cap_band,90);
1419 penpos6(middle_weight,-90); penpos7(middle_weight,-90);
1420 penpos8(middle_weight,90); penpos9(middle_weight,90);
1421 penpos5(right_curve-stem_corr,0); penpos10(right_curve,0);
1422 penpos11(cap_band,-90); penpos12(cap_band,-90);
1423 z3r=top z1; y4=y3; y5=.5[y4,y6]; y6=y7; y7l-y8l=vair;
1424 z12r=bot z2; y11=y12; y10=.5[y11,y9]; y8=y9; .5[y7l,y8l]=.52hh;
1425 x4=x6; x9=x11=x4+.5u; x7=x8=x1; x9l:=x4+.25u;
1426 x5r=hround(w-1.5u); x10r=hround(w-u);
1427 if serifs: right_curve=cap_curve-stem_corr; x4=.5[x1,w-1.5u];
1428 else: right_curve=cap_curve-3stem_corr; x4=.5[x1,w-2.5u];
1429 x4l:=x4l-.5u; x9l:=x9l-.5u; fi
1430 x6l:=x6l-.5u; x11l:=x11l-.5u;
1431 fill stroke z3e..super_arc.e(4,5) & super_arc.e(5,6)..z7e; % upper lobe
1432 fill stroke z8e..super_arc.e(9,10) & super_arc.e(10,11)..z12e; % lower lobe
1433 if serifs: nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1434 nodish_serif(2,1,c,1/3,cap_jut,d,1/3,.5cap_jut); fi % lower serif
1435 pickup crisp.nib; pos13(bar,0); pos14(bar,0);
1436 rt x13r=rt x14r=rt x4; top y13=h; bot y14=-d;
1437 filldraw stroke z13e--z14e; % vertical crossbar
1438 math_fit(0,.5ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
1439
1440 ecchar"Numero sign"; % from wncyr
1441 beginchar(oct"233",15u#+width_adj#,cap_height#,0);
1442 italcorr cap_height#*slant
1443 -cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
1444 adjust_fit(cap_serif_fit#
1445 if serifs: +.5(flare#+(cap_stem#-stem#)) fi ,cap_serif_fit#);
1446 w:=if serifs: 10u else: 11u fi;
1447 numeric thin_stem;
1448 thin_stem=hround(fudged.hair+stem_corr);
1449 pickup tiny.nib;
1450 pos1(thin_stem,0); pos2(thin_stem,0);
1451 pos3(thin_stem,0); pos4(thin_stem,0);
1452 top y1=h;
1453 if serifs: top y3=.79h; bot y2=.21h;
1454 else: top y3=h; bot y2=0; fi
1455 bot y4=0;
1456 x1=x2; x3=x4; x1l=w-x3r;
1457 rt x3r=hround min(w-2u,w-3u+.5fudged.cap_stem);
1458 x91=x2-.75flare; bot y91r=-oo; x92=w-x91;
1459 top y92l=h+oo;
1460 pos91(thin_stem,-90); pos92(thin_stem,-90);
1461 if serifs:
1462 filldraw stroke z1e--z2e & pulled_arc.e(2,91); % left stem
1463 filldraw stroke z4e--z3e & pulled_arc.e(3,92); % right stem
1464 else:
1465 filldraw stroke z1e--z2e; filldraw stroke z4e--z3e; % stems
1466 fi
1467 if hefty:
1468 penpos5(fudged.cap_stem,0); penpos6(fudged.cap_stem,0);
1469 x5l=x1; x6r=x4; y5=h; y6=0;
1470 numeric upper_notch,lower_notch;
1471 upper_notch=h-cap_notch_cut;
1472 lower_notch=cap_notch_cut;
1473 x1'=rt x1r; z1'=whatever[z5l,z6l]; x4'=lft x4l;
1474 z4'=whatever[z5r,z6r];
1475 fill z5l..
1476 if y1'<upper_notch: {right}(x1'+1,upper_notch){down}... fi
1477 {z6-z5}diag_in(5l,6l,1,6r)--z6r..
1478 if y4'>lower_notch: {left}(x4'-1,lower_notch){up}... fi
1479 {z5-z6}diag_in(6r,5r,1,5l)--cycle; % diagonal
1480 else:
1481 penpos5(whatever,0); penpos6(whatever,90);
1482 z5l=z1l; z6l=z4l;
1483 z7=z6l+(max(eps,cap_stem-3stem_corr-tiny),0) rotated (angle(z5l-z6l)-90);
1484 z5r=z7+whatever*(z5l-z6l); z6r=z7+whatever*(z5l-z6l);
1485 filldraw stroke z5e--z6e; % diagonal
1486 fi
1487 if serifs:
1488 if hefty: serif(1,2,a,1/3,-cap_jut); % upper left serif
1489 else: serif(5,6,a,1/3,-cap_jut); fi % upper left serif
1490 fi
1491 pickup tiny.nib;
1492 if serifs:
1493 x93=x2-1.5flare;
1494 y93=.75flare;
1495 pos95(flare+(cap_stem-stem),-180);
1496 x94=x3+1.5flare;
1497 y94=h-y93;
1498 pos96(flare+(cap_stem-stem),0);
1499 pos92'(thin_stem,90);
1500 z92'=z92;
1501 pos93(cap_hair,-180);
1502 pos94(cap_hair,0);
1503 bulb(91,93,95); bulb(92',94,96);
1504 fi
1505 w:=15u;
1506 penpos71(vair,90); penpos73(vair',-90); penpos72(.8curve,180);
1507 penpos74(.8curve,0); x72r=hround max(.5u,1.25u-.4curve)+9.5u;
1508 x74r=w-x72r+9u; x71=x73=12u; y71r=h-3u+vround 1.5oo; y73r=x_height-3u-oo;
1509 y72=y74=.5[h,x_height]-3u-vair_corr; y72l:=y74l:=.52[h,x_height]-3u;
1510 penstroke pulled_arc.e(71,72) & pulled_arc.e(72,73) & pulled_arc.e(73,74) &
1511 pulled_arc.e(74,71) & cycle;
1512 x81=max(lft x72r,x73-(lft w-x73));
1513 x82=min(rt x74r,lft w); y81=y82=.8x_height-3u;
1514 pos81(bar,90); pos82(bar,90);
1515 filldraw stroke z81e--z82e;
1516 math_fit(0,max(.5ic#-.5u#,0));
1517 penlabels(1,1',2,3,4,4',5,6,7); endchar;
1518
1519 ecchar "Abzueglich sign"; % jk
1520 beginchar(oct"234",9u#,body_height#,0);
1521 italcorr body_height#*slant-.5u#;
1522 adjust_fit(0,0); pickup rule.nib;
1523 rt x1=hround(w-u)+eps; top y1=h+eps;
1524 lft x2=hround u-eps; bot y2=-eps;
1525 draw z1--z2; % diagonal
1526 x3=w-x5=good.x (lft x1 - .5dot_size);
1527 bot y4 = good.y .5dot_size;
1528 top y6 = good.y h-.5dot_size;
1529 pos3(dot_size,0); pos4(dot_size,90); z3=z4;
1530 pos5(dot_size,0); pos6(dot_size,90); z5=z6;
1531 dot(3,4); dot(5,6); % dots
1532 penlabels(1,2,3,4,5,6); endchar;
1533
1534 ecchar"Aestimated sign (large e)"; % jk
1535 beginchar(oct"235",(11.25u#+max(.75u#,.5cap_curve#)),cap_height#,0);
1536 italcorr .76cap_height#*slant+.5min(curve#-1.5u#,0);
1537 adjust_fit(if monospace: .25u#,.5u# else: 0,0 fi);
1538 numeric left_curve,right_curve;
1539 left_curve=right_curve+3stem_corr=cap_curve if not serifs: -1.5stem_corr fi;
1540 if right_curve<tiny.breadth: right_curve:=tiny.breadth; fi
1541 if left_curve<tiny.breadth: left_curve:=tiny.breadth; fi
1542 pickup tiny.nib;
1543 pos1(right_curve,0); pos2(vair,90); pos3(left_curve,180);
1544 y1=good.y .52h; top y2r=h+vround 1.5oo; y0l=bot y1;
1545 rt x1r=hround min(w-.5u,w-u+.5right_curve);
1546 lft x3r=hround max(.5u,1.25u-.5left_curve); x2=.5w+.25u;
1547 {{interim superness:=more_super;
1548 filldraw stroke super_arc.e(1,2)}}; % right bowl
1549 y3=.5[y2,y4]; bot y4r=-oo; x4=x2+.25u;
1550 if serifs: pos4(vair',270); pos5(hair,360);
1551 y5=max(good.y(.5bar_height-.9),y4l+vair); x5r=x1r;
1552 (x,y4l)=whatever[z4r,z5]; x4l:=min(x,x4l+.5u);
1553 filldraw stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
1554 ...{x5-x4,5(y5-y4)}z5e; % left bowl, arc, and terminal
1555 else: pos4(vair,270);
1556 filldraw stroke super_arc.e(2,3) & super_arc.e(3,4); % left bowl and arc
1557 pickup fine.nib; pos4'(vair,270); z4=z4';
1558 pos5(.5[vair,flare],275); rt x5r=hround(w-.6u);
1559 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
1560 filldraw stroke term.e(4',5,right,1,4); fi % terminal
1561 path testpath; testpath=super_arc.r(2,3) & super_arc.r(3,4);
1562 y1'r=y0r=y0l+.6[thin_join,vair]; y1'l=y0l; x1'l=x1'r=x1;
1563 forsuffixes $=l,r:
1564 x0$=xpart(((0,y0$)--(x1,y0$)) intersectionpoint testpath); endfor
1565 fill stroke z0e--z1'e; % crossbar
1566 penlabels(0,1,2,3,4,5); endchar;
1567
1568 ecchar "Open bullet"; % derived from Circle operator
1569 beginchar(oct"236",9u#,v_center(7u#));
1570 adjust_fit(0,0); pickup rule.nib; autorounded;
1571 if .5w <> good.x .5w: change_width; fi
1572 lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
1573 circle_points; draw_circle; % circle
1574 labels(1,2,3,4,5,6,7,8); endchar;
1575
1576 ecchar"Servicemark"; % jk, design based on logo font
1577 beginchar(oct"237",12u#,body_height#,0);
1578 italcorr .7body_height#;
1579 adjust_fit(0,0);
1580 numeric ww, hh; ww=.5w; hh=vround .5body_height;
1581 pickup pencircle xscaled hair yscaled vair;
1582 x3=x8= u;
1583 x2=x4=.382[x3,ww-x3];
1584 x1=ww-x3;
1585 x5=x7=.618[x3,ww-x3];
1586 x6=.5[ww-x3,lft ww];
1587 top y1=hh; y4=good.y .55hh; bot y8=0;
1588 y1=y2; y3=.5[y2,y4]; y4=y5; y6=.5[y5,y7]; y7=y8;
1589 draw z1--z2; draw z4--z5; draw z7--z8;
1590 super_crescent(2,3,4);
1591 super_crescent(5,6,7);
1592 labels(1,2,3,4,5,6,7,8);
1593 clearxy;
1594 x1=x2=hround(ww+u); x4=x5=hround(w-u); x3=hround .5[x1,x4];
1595 y1=y5; y2=y4; bot y1=-o;
1596 top y2=hh+o; y3=vround (y1+.5bar_height);
1597 draw z1--z2--z3--z4--z5;
1598 labels(1,2,3,4,5);
1599 currentpicture:=currentpicture shifted (0,hh);
1600 endchar;
1601
1602 ecchar "Left square bracket with quill"; % from Haralambous/Plaice
1603 beginchar(oct"240",9u#,body_height#,paren_depth#);
1604 italcorr math_axis#*slant+.5vair#-u#;
1605 adjust_fit(if monospace: -1.5u#,u# else: -2.5u#,0 fi);
1606 pickup fine.nib;
1607 forsuffixes $=1,1',4,4',7,7',11,11',17,17':
1608 pos$(vair,0); endfor
1609 forsuffixes $=2,3,5,6: pos$(stem,0); endfor
1610 x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
1611 rt x4r=hround(w-1.5u+.5vair); rt x2r=hround(.5w+.5stem);
1612 top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
1613 y1-y2=y3-y4=(y1-y4)/4;
1614 y1-y1'=y4-y4'=y7'-y7=y11-y11'=y17-y17'=vair-fine;
1615 x11=x11'=x17=x17'; x11-x2=x2-x1; y11=y1; y17=y7;
1616 filldraw z11'l{left}...z2r---z3r...{right}z4r
1617 --z4'r{left}...z5r---z6r...{right}z17l
1618 --z17r--z17'r{left}...z6l---z5l...{right}.5[z4l,z4'l]{left}
1619 ...z3l---z2l...{right}z11r--z11'r--cycle; % stroke
1620 penlabels(1,2,3,4,5,6,7); endchar;
1621
1622 ecchar "Right square bracket with quill"; % from Haralambous/Plaice
1623 beginchar(oct"241",9u#,body_height#,paren_depth#);
1624 italcorr body_height#*slant+.5vair#-u#;
1625 adjust_fit(if monospace: u#,-1.5u# else: 0,-2.5u# fi);
1626 pickup fine.nib;
1627 forsuffixes $=1,1',4,4',7,7',11,11',17,17':
1628 pos$(vair,0); endfor
1629 forsuffixes $=2,3,5,6: pos$(stem,0); endfor
1630 x2=x3=x5=x6; x1=x1'=x7=x7'=w-x4=w-x4';
1631 lft x4l=hround(1.5u-.5vair); lft x2l=hround(.5w-.5stem);
1632 top y1=h; bot y7=-d; .5[y4,y4']=.5[y1,y7]=.5[y2,y6]=.5[y3,y5];
1633 y1-y2=y3-y4=(y1-y4)/4; y1-y1'=y4-y4'=y7'-y7=vair-fine;
1634 x11=x11'; x17=x17';
1635 y11=y1; y17=y7;
1636 x1-x2=x2-x11; x17=x11; y11-y11'=y17'-y17=vair-fine;
1637 filldraw z11'r{right}...z2l---z3l...{left}z4l
1638 --z4'l{right}...z5l---z6l...{left}z17'r
1639 --z17'l--z17l{right}...z6r---z5r...{left}.5[z4r,z4'r]{right}
1640 ...z3r---z2r...{left}z11l--z11'l--cycle; % stroke
1641 penlabels(1,2,3,4,5,6,7); endchar;
1642
1643 ecchar "Cent sign"; % from wasychr (wasy)
1644 % Modified height and depth (jk)
1645 % Modified: Bar instead of broken bar
1646 beginchar(oct"242",9u#,x_height#+.5desc_depth#,.5desc_depth#);
1647 italcorr x_height#*slant-.2u#;
1648 adjust_fit(0,0);
1649 pickup fine.nib; pos2(vair',90); pos4(vair',270);
1650 x2=x4=.5(w+u); top y2r=vround(x_height+1.5oo); bot y4r=-oo;
1651 pos3(curve,180); lft x3r=hround max(.6u,1.35u-.5curve); y3=.5x_height;
1652 if serifs: pos1(hair,0); pos0(flare,0);
1653 y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,x_height]-.5flare);
1654 rt x1r=hround(w-.7u); bulb(2,1,0); % bulb
1655 pos5(hair,0); rt x5r=hround(w-.5u);
1656 y5=max(good.y(.5bar_height-.9),y4l+vair');
1657 (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
1658 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
1659 & pulled_super_arc.e(3,4)(.5superpull)
1660 ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e; % arc and lower terminal
1661 else: pos1(4/7[vair',flare],80);
1662 rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
1663 filldraw stroke term.e(2,1,right,.8,4); % upper terminal
1664 pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
1665 y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
1666 forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
1667 if angle direction 1 of p.e>75:
1668 p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
1669 filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
1670 & pulled_super_arc.e(3,4)(.5superpull) & p.e; fi % arc and lower terminal
1671 pickup crisp.nib;
1672 x6=x7=x8=x9=x2; y7=y2; y8=y4; bot y9=-d; y6-y7 = y8-y9;
1673 pos6(bar,0); pos7(bar,0);
1674 pos8(bar,0); pos9(bar,0);
1675 filldraw stroke z6e--z9e; % bar
1676 %filldraw stroke z6e--z7e; % upper bar
1677 %filldraw stroke z8e--z9e; % lower bar
1678 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
1679
1680 ecchar "Sterling sign"; % from italp (cm)
1681 % already contains bug fix found by Yannis Haralambous
1682 beginchar(oct"243",12u#,asc_height#,0);
1683 adjust_fit(0,.75asc_height#*slant-.5u#); pickup fine.nib;
1684 pos0(flare,0); pos1(hair,0); pos2(vair,90); pos3(stem,180);
1685 pos4(stem,180); pos4'(stem,0); pos5(vair,-90); z4'=z4;
1686 x2=2/3w-.5u; rt x3l=rt x4l=hround(.5w-u+.5stem); x5=2.5u;
1687 y1=y3=.75h; top y2=h+oo; y4=.25h; bot y5r=-oo;
1688 rt x1r=hround(w-1.5u); bulb(2,1,0); % bulb
1689 filldraw stroke pulled_arc.e(2,3)..z4e; % stem
1690 numeric light_stem; light_stem=2/3[vair,vstem];
1691 pos6(.5[hair,light_stem],-180); pos7(light_stem,-300);
1692 pos8(light_stem,-300); pos9(hair,-180);
1693 lft x6r=hround u; x7=3u; x8=w-3.5u; rt x9l=hround(w-u);
1694 y6=.4[y5,y7]; top y7r=vround .2h; bot y8l=-oo; y9=good.y .2h;
1695 filldraw stroke pulled_arc.e(4',5)...z6e{up}...z7e{right}
1696 ..{right}z8e...{up}z9e; % loop and arm
1697 pos10(bar,90); pos11(bar,90); x10=3u; x11=w-4.5u;
1698 top y10r=top y11r=vround(.5h+.5bar); filldraw stroke z10e--z11e; % bar
1699 penlabels(1,2,3,4,5,6,7,8,9,10,11); endchar;
1700
1701 ecchar "Currency sign"; % from rsym (wasy)
1702 beginchar(oct"244",1.13 min(asc_height#,9/7x_height#)+2u#,
1703 min(asc_height#,9/7x_height#),0);
1704 italcorr x_height#*slant;
1705 adjust_fit(if monospace: u#,u# else: 0,0 fi);
1706 pickup rule.nib; autorounded;
1707 x4 = good.x .5w; x2-x6=y8-y4; y2=good.y .5h; bot y4=-oo;
1708 circle_points;
1709 z9 = 1.30[z5,z1];
1710 z10 = 1.30[z7,z3];
1711 z11 = 1.30[z1,z5];
1712 z12 = 1.30[z3,z7];
1713 draw_circle;
1714 draw z1--z9;
1715 draw z3--z10;
1716 draw z5--z11;
1717 draw z7--z12;
1718 labels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
1719
1720
1721 ecchar "Yen symbol"; % from asymbols (msam)
1722 % Change (jk): Use correct pen for horizontal bars
1723 compute_spread(.45x_height#, .55x_height#);
1724 beginchar(oct"245",13u#,cap_height#,0); %% adapted from "Y"
1725 italcorr cap_height#*slant+.45u#;
1726 adjust_fit(cap_serif_fit#,cap_serif_fit#); numeric
1727 left_stem,right_stem,outer_jut,dy,alpha;
1728 left_stem=cap_stem-stem_corr; right_stem=min(cap_hair if
1729 hefty:-2stem_corr fi,left_stem); outer_jut=.75cap_jut;
1730 x1l=w-x4r=l+letter_fit+outer_jut+.05u;
1731 x2l=x5l=hround(.5w-.5left_stem); x3r=x5r; y1=y4=h;
1732 y2=y3=y5=.4h; dy=y1-y2; alpha=((x2l-x1l)++dy)/dy;
1733 penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
1734 penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
1735 penpos5(left_stem,0); penpos6(left_stem,0); x5=x6; y6=0;
1736 z0=whatever[z1r,z2r]=whatever[z3l,z4l]; if
1737 y0>y2+cap_notch_cut: y0:=y2+cap_notch_cut;
1738 fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)--z5r
1739 --diag_end(5r,6r,1,1,6l,5l)--z5l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
1740 ...{down}z0+.5left--cycle; % diagonals and stem
1741 else: fill z0--diag_end(0,4l,1,1,4r,3r)--z5r
1742 --diag_end(5r,6r,1,1,6l,5l)--z5l
1743 --diag_end(2l,1l,1,1,1r,0)--cycle; fi % diagonals & stem
1744 if serifs: numeric inner_jut; pickup tiny.nib;
1745 prime_points_inside(1,2); prime_points_inside(4,3);
1746 prime_points_inside(6,5);
1747 if rt x1'r+cap_jut+.5u+1<=lft x4'l-cap_jut:
1748 inner_jut=cap_jut;
1749 else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
1750 dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut); % upper left serif
1751 dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); % upper right serif
1752 dish_serif(6',5,e,1/3,cap_jut,f,1/3,cap_jut); fi % lower serif
1753 pickup extra_rule.nib;
1754 x7=x9=x1l; x8=x10=x4r; y9=y10;
1755 top y7=bar_height; y7=y8; draw z7--z8;
1756 y9-y7=spread; draw z9--z10; % crossing bars
1757 penlabels(0,1,2,3,4,5,6,1',2',3',4',5',6',7,8,9,10); endchar;
1758
1759 ecchar "Broken vertical bar"; % jk
1760 beginchar(oct"246",3u#,body_height#,paren_depth#);
1761 italcorr body_height#*slant - u#;
1762 adjust_fit(0,0); pickup rule.nib;
1763 top y1=h; .5[y1,y4]=math_axis;
1764 compute_spread(.45x_height#,.55x_height#); y2-y3=spread;
1765 .5[y2,y3]=math_axis;
1766 x1=x2=x3=x4=good.x .5w;
1767 draw z1--z2; draw z3--z4;
1768 labels(1,2,3,4); endchar;
1769
1770 ecchar "Section sign"; % from mathsy, renovated (jk)
1771 beginchar(oct"247",6.5u#+max(1.5u#,stem#),asc_height#,desc_depth#);
1772 adjust_fit(0,0); pickup fine.nib;
1773 numeric s_slab; s_slab=if serifs:slab else:vround .2[slab,cap_stem] fi;
1774 numeric ess'; ess'=max(fine.breadth,cap_ess);
1775 numeric sstem; sstem=hround .5[s_slab,ess']-fine;
1776 if sstem < fine.breadth: sstem:=fine.breadth; fi
1777 pos2(vair,90); pos3(sstem,180);
1778 pos4(ess',270); pos4'(vair,270);
1779 pos5'(sstem,0); pos5(sstem,180);
1780 pos6(ess',90); pos6'(vair,90); pos7(sstem,0);
1781 pos8(vair,-90);
1782 top y2r=h+oo; bot y8r=-d-oo;
1783 y3=.52[y4,y2]; y5=.52[y4,y6]; y7=.52[y6,y8]; y5'=.52[y6,y4];
1784 y2-y4=y4-y6=y6-y8;
1785 bot z4'=bot z4; top z6'=top z6;
1786 lft x3r=hround 1.25u;
1787 x2=x4=x6=x8=.5w; x5=x7=w-x3; x5'=x3;
1788 if serifs:
1789 pos0(stem,0); pos1(hair,0); pos9(hair,-180); pos10(stem,-180);
1790 rt x1r=hround(w-1.5u); x9=w-x1; y2-y1=y9-y8=(y2-y8)/8;
1791 bulb(2,1,0); bulb(8,9,10); % bulbs
1792 else:
1793 pos1(.6[slab,flare],-100); pos9(flare,-100); pos2'(vair,-90);
1794 rt x1l=hround(w-1.3u); lft x9r=hround .8u; z2'=z2;
1795 top y1l=vround .92asc_height+oo; bot y9r=vround .1asc_height-d-oo;
1796 filldraw stroke term.e(2',1,right,.9,4); % upper arc and terminal
1797 filldraw stroke term.e(8,9,left,.9,4); % lower arc and terminal
1798 fi
1799 filldraw stroke z2e{left}...z3e{down}...z4e{3(x5-x3),y5-y3}
1800 ...z5e{down}...{left}z6'e; % upper stroke
1801 filldraw stroke z4'e{left}...z5'e{down}...z6e{3(x7-x5'),y7-y5'}
1802 ...z7e{down}...{left}z8e; % upper stroke
1803 penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
1804
1805 ecchar "Umlaut (double dot) accent"; % from accent (cm)
1806 numeric dot_diam#,dot_diam;
1807 dot_diam#=max(dot_size#,cap_curve#);
1808 beginchar(oct"250",9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
1809 dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
1810 italcorr h#*slant+.5dot_diam#-2.25u#;
1811 adjust_fit(0,0);
1812 pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
1813 x1=x2=2.75u; top y2r=h+1;
1814 if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
1815 y1=.5[y2l,y2r]; dot(1,2); % left dot
1816 pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
1817 dot(3,4); % right dot
1818 penlabels(1,2,3,4); endchar;
1819
1820 ecchar"Copyright";% (CMBR)
1821 %beginchar(oct"251",20u#,body_height#,max(paren_depth#,desc_depth#));
1822 beginchar(oct"251",circ_w#,body_height#,max(paren_depth#,desc_depth#));
1823 autorounded;
1824 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1825 if .5w <> good.x .5w: change_width; fi
1826 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1827 circle_points; draw_circle; % circle
1828 labels(1,2,3,4,5,6,7,8);
1829 clearxy; autorounding:=0;
1830 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-6u);
1831 rr=hround(.5w+5u);
1832 if serifs:
1833 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,90);
1834 pos3(cap_curve,180); pos4(cap_band,270); pos5(hair,360);
1835 rt x1r=rt x5r=hround(rr-u); lft x3r=hround(ll+u); x2=x4=.55[x3,x1];
1836 top y2r=hh+o; bot y4r=-o; y3=.5[y2,y4];
1837 bot y1=min(vround max(.6hh,.7x_height-.5vair),bot y2l-eps);
1838 y5=max(good.y .95(hh-y1),y4l+eps);
1839 (x2l',y2l)=whatever[z2r,z1l]; x2l:=min(x2l',x2l+.5u);
1840 (x4l',y4l)=whatever[z4r,z5l]; x4l:=min(x4l',x4l+.5u);
1841 filldraw stroke z1e{x2-x1,10(y2-y1)}
1842 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
1843 pos6(.3[fine.breadth,cap_hair],0); x6r=x1r; top y6=hh+o;
1844 x1r-x1'=2cap_curve-fine; y1'=y1;
1845 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{left};
1846 numeric t; t=xpart(upper_arc intersectiontimes (z6l--z1'));
1847 filldraw z1r--z6r--z6l--subpath(t,0) of upper_arc--cycle; % barb
1848 else:
1849 pickup fine.nib; pos1(1.2flare,80); pos2(slab,90);
1850 pos3(cap_curve,180); pos4(slab,270); pos5(flare,275);
1851 rt x1r=hround(rr-1.1u); x2=x4=.5w+1.25u;
1852 lft x3r=ll+hround max(u,2u-.5cap_curve); rt x5r=hround(rr-.9u);
1853 top y1r=vround .95hh+o; top y2r=hh+o; y3=.5hh;
1854 bot y4r=-o; bot y5r=vround .08hh-o; y5l:=good.y y5l; x5l:=good.x x5l;
1855 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
1856 & super_arc.e(3,4) & term.e(4,5,right,.8,4); fi % arc and terminals
1857 penlabels(1,1',2,3,4,5,6); endchar;
1858
1859 ecchar"Copyleft";% (CMBR)
1860 %beginchar(oct"253",20u#,body_height#,max(paren_depth#,desc_depth#));
1861 beginchar(oct"253",circ_w#,body_height#,max(paren_depth#,desc_depth#));
1862 autorounded;
1863 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1864 if .5w <> good.x .5w: change_width; fi
1865 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1866 circle_points; draw_circle; % circle
1867 labels(1,2,3,4,5,6,7,8);
1868 clearxy; autorounding:=0;
1869 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-5u);
1870 rr=hround(.5w+6u);
1871 if serifs:
1872 pickup fine.nib; pos1(cap_hair,0); pos2(cap_band,-90);
1873 pos3(cap_curve,-180); pos4(cap_band,-270); pos5(hair,-360);
1874 lft x1l=lft x5l=hround(ll+u); rt x3l=hround(rr-u); x2=x4=.55[x3,x1];
1875 top y2l=hh+o; bot y4l=-o; y3=.5[y2,y4];
1876 bot y1=min(vround max(.6hh,.7x_height-.5vair),bot y2r-eps);
1877 y5=max(good.y .95(hh-y1),y4r+eps);
1878 (x2r',y2r)=whatever[z2l,z1r]; x2r:=min(x2r',x2r+.5u);
1879 (x4r',y4r)=whatever[z4l,z5r]; x4r:=min(x4r',x4r+.5u);
1880 filldraw stroke z1e{x2-x1,10(y2-y1)}
1881 ...pulled_arc.e(2,3) & pulled_arc.e(3,4)...{up}z5e; % arc
1882 pos6(.3[fine.breadth,cap_hair],0); x6l=x1l; top y6=hh+o;
1883 x1l-x1'=2cap_curve-fine; y1'=y1;
1884 path upper_arc; upper_arc=z1{x2-x1,10(y2-y1)}..z2{right};
1885 numeric t; t=xpart(upper_arc intersectiontimes (z6r--z1'));
1886 filldraw z1l--z6l--z6r--subpath(t,0) of upper_arc--cycle; % barb
1887 else:
1888 pickup fine.nib; pos1(1.2flare,-80); pos2(slab,-90);
1889 pos3(cap_curve,-180); pos4(slab,-270); pos5(flare,-275);
1890 lft x1l=hround(ll+1.1u); x2=x4=.5w-1.25u;
1891 rt x3l=rr-hround max(u,2u-.5cap_curve); lft x5l=hround(ll+.9u);
1892 top y1l=vround .95hh+o; top y2l=hh+o; y3=.5hh;
1893 bot y4l=-o; bot y5l=vround .08hh-o; y5r:=good.y y5r; x5r:=good.x x5r;
1894 filldraw stroke rterm.e(2,1,left,.9,4) & super_arc.e(2,3)
1895 & super_arc.e(3,4) & term.e(4,5,left,.8,4); fi % arc and terminals
1896 penlabels(1,1',2,3,4,5,6); endchar;
1897
1898 ecchar "Logical not sign"; % from sym % (CMBR)
1899 beginchar(oct"254",11u#,sym_height#,0);
1900 italcorr sym_height#*slant-.5u#;
1901 adjust_fit(0,0); pickup rule.nib;
1902 lft x1=hround u-eps; x2=x3=w-x1;
1903 y1=y2=good.y .5[bar_height,h]; y2-y3=1.2(h-bar_height);
1904 draw z1--z2--z3; % bar and stem
1905 labels(1,2,3); endchar;
1906
1907 ecchar"Circled P"; % Sound recording copyright sign % jk (CMBR)
1908 %beginchar(oct"255",20u#,body_height#,max(paren_depth#,desc_depth#));
1909 beginchar(oct"255",circ_w#,body_height#,max(paren_depth#,desc_depth#));
1910 autorounded;
1911 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1912 if .5w <> good.x .5w: change_width; fi
1913 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1914 circle_points; draw_circle; % circle
1915 labels(1,2,3,4,5,6,7,8);
1916 clearxy; autorounding:=0;
1917 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-6u);
1918 rr=hround(.5w+6u);
1919 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1920 pos0(cap_stem',0); pos0'(cap_stem,0);
1921 lft x1l=ll+hround max(2u,3u-.5cap_stem'); top y1=hh; bot y2=0;
1922 x1l=x2l=x0l=x0'l; y0=y0'=y7;
1923 penpos3(cap_band,90); penpos4(cap_band,90);
1924 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1925 penpos6(.5[vair,cap_band],-90); penpos7(.5[vair,cap_band],-90);
1926 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1927 x7=x2; y7l=vround(.5hh); x4=x6=.5w+.75u; x5r=hround(rr-u);
1928 x4l:=x6l:=x4-.25cap_curve;
1929 filldraw stroke z1e--z2e; % stem
1930 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1931 if serifs:
1932 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1933 dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower serif
1934 fi
1935 penlabels(0,1,2,3,4,5,6); endchar;
1936
1937 ecchar"Registered"; % jk (CMBR)
1938 %beginchar(oct"256",20u#,body_height#,max(paren_depth#,desc_depth#));
1939 beginchar(oct"256",circ_w#,body_height#,max(paren_depth#,desc_depth#));
1940 autorounded;
1941 adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
1942 if .5w <> good.x .5w: change_width; fi
1943 lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
1944 circle_points; draw_circle; % circle
1945 labels(1,2,3,4,5,6,7,8);
1946 clearxy; autorounding:=0;
1947 numeric hh,ll,rr; hh=vround .7cap_height; ll=hround(.5w-6u);
1948 rr=hround(.5w+6u);
1949 pickup tiny.nib; pos1(cap_stem',0); pos2(cap_stem',0);
1950 lft x1l=lft x2l=ll+hround max(2u,3u-.5cap_stem'); top y1=hh; bot y2=0;
1951 filldraw stroke z1e--z2e; % stem
1952 penpos3(cap_band,90); penpos4(cap_band,90);
1953 penpos5(cap_curve if hefty:-3stem_corr fi,0);
1954 penpos6(vair,-90); penpos7(vair,-90);
1955 z3r=top z1; y4=y3; y5=.5[y4l,y6l]; y6=y7;
1956 x7=x2; y7l=vround(.5hh+.5vair); x4=x6;
1957 if serifs: x4=.5w-.5u; x5r=hround(rr-2.25u);
1958 else: x4=.5w+.5u; x5r=hround(rr-u); fi
1959 x4l:=x6l:=x4-.125cap_curve;
1960 fill stroke z3e..pulled_arc.e(4,5) & pulled_arc.e(5,6)..z7e; % lobe
1961 if serifs: pos6'(vair,-90); pos0(cap_stem,180);
1962 pos8(cap_curve,180); pos9(vair,-90); pos10(hair,0);
1963 z6'=z6; lft x0r=lft x8r=hround(x5-2/3u-.5cap_curve);
1964 y8=1/3[y2,y7]; y0=3/5[y2,y7]; x9=.5[x8l,x10r];
1965 bot y9r=-o; rt x10r=hround(rr-.25u); y10=1/3[y2,y7];
1966 filldraw stroke z6'e{right}..z0e---z8e....z9e{right}..z10e{up}; % tail
1967 nodish_serif(1,2,a,1/3,cap_jut,b,1/3,.5cap_jut); % upper serif
1968 dish_serif(2,1,c,1/3,cap_jut,d,1/3,cap_jut); % lower serif
1969 else: penpos8(cap_stem-2stem_corr,0); penpos9(cap_stem,0);
1970 x8=x6+.5u; y8=y6; x9r=hround(rr-.5u); y9=0;
1971 fill z8l--diag_end(8l,9l,.5,1,9r,8r)--z8r--cycle; fi % tail
1972 penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
1973
1974 ecchar"High bar (Macron)"; % jk
1975 beginchar(oct"257",14u#,min(asc_height#,2x_height#),0);
1976 adjust_fit(0,0); pickup rule.nib;
1977 lft x1=hround 1.5u-eps; x2=w-x1; top y1=top y2=h;
1978 draw z1--z2; % bar
1979 labels(1,2); endchar;
1980
1981 ecchar "Plus-or-minus sign"; % from sym
1982 beginarithchar(oct"261"); pickup rule.nib;
1983 numeric shiftup; shiftup=vround 1.5u;
1984 x1=x2=.5w; lft x3=lft x5=hround u-eps; x4=x6=w-x3;
1985 .5[y1,y2]=y3=y4=math_axis+shiftup; top y1=h+shiftup; y5=y6=y2;
1986 draw z1--z2; % stem
1987 draw z3--z4; % plus bar
1988 draw z5--z6; % minus bar
1989 labels(1,2,3,4,5,6); endchar;
1990
1991 ecchar"Degree sign"; % Yannis, Unicode Computer Modern
1992 beginchar(oct"260",4u#,cap_height#,0);
1993 adjust_fit(if monospace: 1.5u#,1.5u# else: u#,u# fi);
1994 pickup rule.nib; autorounded;
1995 if .5w <> good.x .5w: change_width; fi
1996 lft x6=0; x2=w-x6; top y8=h; y8-y2=x2-x8;
1997 circle_points; draw_circle; % circle
1998 labels(1,2,3,4,5,6,7,8); endchar;
1999
2000 ecchar"Tick mark"; % from accent (cmfonts, acute accent)
2001 beginchar(oct"264",9u#,min(asc_height#,2x_height#),0);
2002 italcorr h#*slant-if serifs: 1.5 fi u#;
2003 adjust_fit(0,0);
2004 if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
2005 y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
2006 numeric theta; theta=angle(z2-z1)+90;
2007 pos1(stem,theta); pos2(hair,theta);
2008 filldraw circ_stroke z1e--z2e; % diagonal
2009 else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
2010 rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
2011 top y1=h; bot y2=vround 2/3[h,x_height];
2012 filldraw stroke z1e--z2e; fi % diagonal
2013 penlabels(1,2); endchar;
2014
2015 iff not variant_g:
2016 ecchar"Micro sign"; % jk, based on cm `u'
2017 beginchar(oct"265",10u#,x_height#,desc_depth#);
2018 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
2019 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
2020 numeric light_vair; light_vair=vair if hefty: -vround 2vair_corr fi;
2021 if light_vair<fine.breadth: light_vair:=fine.breadth; fi
2022 pickup tiny.nib; pos1(stem,0); pos2(stem,0); pos7(stem,0);
2023 pos3(stem,0); pos4(stem',0);
2024 lft x1l=hround(2.5u-.5stem); x1=x2=x7; x3=w-x1; x3r=x4r;
2025 if serifs: top y1=h+min(oo,serif_drop); bot y4=-min(oo,serif_drop);
2026 else: top y1=h; bot y4=0; fi
2027 pos0(stem,0); pos0'(stem',0);
2028 x0=x3; x0'=x4; y0=y0'; bot y7=-d;
2029 penpos2'(stem-fine,-180); z2'=z2; y3=y1; y2=.5bar_height;
2030 penpos5(max(eps,light_vair-fine),-90); penpos6(thin_join-fine,0);
2031 y6=y0=2/3bar_height;
2032 filldraw stroke z1e--z7e; % left stem
2033 filldraw stroke z3e..z0e--z0'e..z4e; % right stem
2034 pickup fine.nib; bot y5r=-oo; x5l=.5w-.25u; lft x6l=tiny.lft x0l;
2035 (x,y5r)=whatever[z5l,z6l]; x5r:=max(x,.5[x5,x2'r]);
2036 filldraw stroke {{interim superness:=hein_super;
2037 pulled_arc.e(2',5)}} & z5e{right}...{up}z6e; % arc
2038 if serifs: sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper left serif
2039 sloped_serif.l(3,0,b,1/3,jut,serif_drop); % upper right serif
2040 sloped_serif.r(4,0',c,1/3,jut,min(oo,serif_drop)); % lower right serif
2041 pickup crisp.nib;
2042 dish_serif(7,1,d,1/3,jut,e,1/3,jut); fi % lower left serif
2043 penlabels(1,2,3,4,5,7); labels(6); endchar;
2044
2045 iff variant_g: % This triggers italics
2046 ecchar "Micro sign"; % from greekl (cm)
2047 beginchar(oct"265",9u#,x_height#,desc_depth#);
2048 italcorr 1/3x_height#*slant+.5hair#+.5u#;
2049 adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
2050 pos1(stem,-180); pos2(stem,-180); x1=x2=x3; lft x1r=hround(1.5u-.5stem);
2051 y1+.5stem=h+oo; y2-.5stem=-d-o;
2052 filldraw z1r---z2r..z2l---z1l..cycle; % left stem
2053 pos3(stem,-180); pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
2054 pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
2055 x5=x6=x7; x9=w; hook_out(7,8,9); % closing hook
2056 y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
2057 filldraw stroke super_arc.e(3,4)...{up}z5e; % left stem and arc
2058 filldraw circ_stroke z6e--z7e; % right stem
2059 math_fit(desc_depth#*slant+.5stem#-u#,ic#);
2060 penlabels(1,2,3,4,5,6,7,8,9); endchar;
2061
2062 ecchar "Paragraph mark"; % from mathsy
2063 beginchar(oct"266",11u#,asc_height#,desc_depth#);
2064 adjust_fit(0,0); pickup rule.nib; autorounded;
2065 top y1=h; bot y6=-d-eps; y4=y7=y9=y1;
2066 y8=y6; y3=y5=good.y .5[y1,y6];
2067 x7-x4=ceiling(rule_thickness+1.25u);
2068 lft x2=hround u; y2=.5[y1,y3]; x4=x5=x6; rt x9=hround(w-.5u);
2069 x7=x8=good.x(x9-1.5u); x1=x3=min(.5w,x4);
2070 filldraw z4..z1{left}...z2{down}...{right}z5--cycle; % filled bowl
2071 draw z9--z4--z6; % left stem and upper serif
2072 draw z7--z8; % right stem
2073 if serifs:
2074 x11=x9; x10-x8=x4-x9;
2075 bot y10=-d-eps; y10=y11;
2076 draw z10--z11; % lower serif
2077 fi
2078 labels(1,2,3,4,5,6,7,8,9,10,11); endchar;
2079
2080 ecchar "Centered dot"; % reengineered for catalan l.l
2081 beginchar(oct"267",(11u#-width_adj#-2max(2u#+.5cap_stem#,3u#)),
2082 x_height#,0);
2083 adjust_fit(0,0);
2084 pickup fine.nib;
2085 pos1(udot_diam,0); pos2(udot_diam,90);
2086 lft x1l=hround(.5w-.5udot_diam); y1+.5udot_diam=vround(bar_height+.5udot_diam);
2087 z1=z2; dot(1,2); % dot
2088 penlabels(1,2); endchar;
2089
2090 ecchar "Reference mark"; % From Haralambous/Plaice %(CMBR)
2091 beginchar(oct"270",1/3[sym_height#,asc_height#],
2092 1/3[sym_height#,asc_height#],0);
2093 italcorr .5sym_height#*slant-.5u#;
2094 adjust_fit(if monospace:
2095 -1/3[sym_height#,asc_height#] + mono_charwd#,
2096 -1/3[sym_height#,asc_height#] + mono_charwd#
2097 else: u#,u# fi);
2098 pickup rule.nib;
2099 Dot_size:=min(dot_size,max(1,.25h-rule_thickness));
2100 lft x1=0; top y1=h;
2101 x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=.5h; y2=y4;
2102 draw z1--z2; draw z3--z4; % diagonals
2103 top z1'=.5[top z1,top z3]-(0,.5Dot_size);
2104 rt z3'=.5[rt z3,rt z2]-(.5Dot_size,0);
2105 bot z2'=.5[bot z2,bot z4]+(0,.5Dot_size);
2106 lft z4'=.5[lft z4,lft z1]+(.5Dot_size,0);
2107 z1'=z1''; z2'=z2''; z3'=z3''; z4'=z4'';
2108 penpos1'(Dot_size,0);
2109 penpos1''(Dot_size,90); dot(1',1'');
2110 penpos2'(Dot_size,0);
2111 penpos2''(Dot_size,90); dot(2',2'');
2112 penpos3'(Dot_size,0);
2113 penpos3''(Dot_size,90); dot(3',3'');
2114 penpos4'(Dot_size,0);
2115 penpos4''(Dot_size,90); dot(4',4'');
2116 labels(1,2,3,4,1',2',3',4',1'',2'',3'',4'',1'r,1'l,1''r,1''l);
2117 endchar;
2118
2119 ecchar"Root sign"; % textsurd, from wnri (CMBR)
2120 beginchar(oct"273",8.5u#,body_height#,paren_depth#-rule_thickness#);
2121 italcorr body_height#*slant;
2122 adjust_fit(0,-letter_fit#);
2123 pickup rule.nib;
2124 w':=7u;
2125 x1=good.x (1/9w'+2.5u); x2=good.x (.65w'+2.5u);
2126 bot y1=-.5d; bot y2=asc_height;
2127 draw z1--z2; % diagonal
2128 pickup crisp.nib;
2129 % pos3(if hefty: else: .7 fi max(curve,rule_thickness),0);
2130 pos3(1.25 vair,0);
2131 x3l=1.5[x2,x1]; y3=.5[y1,y2];
2132 pos4(rule_thickness,0); x4=x1; bot y4=-.5d;
2133 pos5(vair,-45); x5l=good.x(x3l-u); z5l=whatever[z3r,z2];
2134 z6=z5r+whatever*(z2-z3r)=whatever[z3l,z4l];
2135 z7=whatever[z1,z2]=z3r+whatever*(z4l-z3l);
2136 filldraw z5r--z6--z4l--z4--z7--z3r--z5l--cycle; % left diagonal and serif
2137 x8=x2+2u; y8=y2;
2138 pickup rule.nib;
2139 draw z2--z8;
2140 penlabels(1,2,3,4,5,6,7,8);
2141 endchar;
2142
2143 ecchar "Euro currency sign"; % improved (CMBR)
2144 % sans serif variant only!
2145 beginchar(oct"277",14u#,cap_height#,0);
2146 italcorr cap_height#*slant-.5u#;
2147 adjust_fit(0,0);
2148 pickup fine.nib; pos1(1.2flare,69); pos2(slab,90);
2149 pos3(cap_curve,180); pos4(slab,270); pos5(flare,270); % 281
2150 rt x1r=hround(w-u); x2=x4=hround(x1-3u);
2151 lft x3r=hround (max(u,2u-.5cap_curve)+u); rt x5r=hround(w-1.4u);
2152 top y1r=vround .95h+o; top y2r=h+o; y3=.5h;
2153 bot y4r=-o; bot y5r=vround .08h-o; y5l:=good.y y5l; x5l:=good.x x5l;
2154 filldraw stroke rterm.e(2,1,right,.9,4) & super_arc.e(2,3)
2155 & super_arc.e(3,4) & term.e(4,5,right,.8,4); % arc and terminals
2156 % middle bars:
2157 pos7(slab,69); pos8(slab,69);
2158 pos9(slab,69); pos10(slab,69);
2159 % Unterkante oberer Balken:
2160 bot y7l=vround(y3+if hefty: .5vair else: min(vair, .06h) fi +eps);
2161 % Oberkante unterer Balken:
2162 top y9r=vround(y3-if hefty: .5vair else: min(vair, .06h) fi);
2163 y8=y7;
2164 y10=y9;
2165 x7=x9=hround u;
2166 rt x8r=hround(w - if serifs: 3 else: 2.5 fi u);
2167 rt x10r = rt x8r -
2168 ((slab + if hefty: vair else: 2min(vair, .06h) fi) * sind 21);
2169 filldraw stroke z7e--z8e; % upper bar
2170 filldraw stroke z9e--z10e;% lower bar
2171
2172 math_fit(-.3cap_height#*slant-.5u#,.5ic#);
2173
2174 penlabels(1,1',2,3,4,5,6,7,8,9,10); endchar;
2175
2176
2177 ecchar "Times operator"; % from mathsy
2178 beginarithchar(oct"326"); pickup rule.nib;
2179 x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
2180 x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
2181 draw z1--z2; draw z3--z4; % diagonals
2182 labels(1,2,3,4); endchar;
2183
2184 ecchar "Elementary division operator"; % from mathsy % (CMBR)
2185 beginarithchar(oct"366"); pickup rule.nib;
2186 numeric del; del=dot_size-currentbreadth;
2187 x3-.5del=good.x(.5w-.5del); center_on(x3);
2188 y3+.5del=good.y(math_axis+math_spread[.5sym_height,.6sym_height]+.5del);
2189 lft x1=hround u-eps; x2=w-x1; y1=y2=math_axis;
2190 draw z1--z2; % bar
2191 pos3(dot_size,0); pos4(dot_size,90); z3=z4;
2192 pos5(dot_size,0); pos6(dot_size,90); z5=z6; x5=x3; .5[y3,y5]=math_axis;
2193 dot(3,4); dot(5,6); % dots
2194 penlabels(1,2,3,4,5,6); endchar;
2195
2196
2197 endinput;