Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/ebrlig.mf

raw
1 % ebrlig.mf
2 % [= exrlig.mf, changed by Walter Schmidt, see (CMBR)]
3 %
4 % (c) Copyright 1995, 1996, 1997 J"org Knappen
5 % (c) Copyright 1990, 1992 Norbert Schwarz
6 %
7 % This file is part of the EC Bright fonts version 1.0
8 %
9 % Content:
10 %
11 % roman style ligature characters
12 % dotless i,j; ligatures fi, ff, fl, ffi, ffl
13
14 version_check(1,0); % |version_check| was introduced in dc1.3
15
16 ecchar "Dotless letter i";
17 beginchar(oct"031",5u#,x_height#,0);
18 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
19 adjust_fit(serif_fit#+stem_shift# if monospace:+.25u#fi,serif_fit#-stem_shift#);
20 pickup tiny.nib; pos1(stem',0); pos2(stem',0);
21 if odd(w-stem'): change_width; fi
22 lft x1l=hround(.5w-.5stem'); x1=x2;
23 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=0;
24 filldraw stroke z1e--z2e; % stem
25 if serifs or monospace:
26 sloped_serif.l(1,2,a,1/3,.95jut,serif_drop); % upper serif
27 fi
28 if serifs: dish_serif(2,1,b,1/3,jut,c,1/3,.9jut); fi % lower serif
29 penlabels(1,2); endchar;
30
31 ecchar "Dotless letter j";
32 beginchar(oct"032",5.5u#,x_height#,desc_depth#);
33 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
34 adjust_fit(serif_fit#+2stem_shift# if monospace:+.5u# fi,
35 serif_fit#-2stem_shift# if monospace:-.5u# fi);
36 pickup tiny.nib; pos1(stem',0); pos2(stem',0);
37 rt x1r=hround(.5w+.25u+.5stem'); x1=x2;
38 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=-1/3d;
39 filldraw stroke z1e--z2e; % stem
40 if serifs: sloped_serif.l(1,2,a,1/3,1.1jut,serif_drop); % upper serif
41 pickup tiny.nib; pos5(vair,-90); pos6(hair,-180); pos7(flare,-180);
42 x5=.5[x2,x6r]; bot y5r=-d-oo; y6-.5flare=-.88d;
43 if monospace: lft x6r=0 else: z6r=z7r; rt x7l=floor .75u fi;
44 (x,y5r)=whatever[z5l,z2l]; x5r:=max(x,.5[x6r,x5]);
45 filldraw stroke z2e{down}...z5e{left}; bulb(5,6,7); % arc and bulb
46 else: pickup fine.nib; pos2'(stem',0); z2'=z2;
47 pos6(.2[vair,stem'],-90); pos7(vair,-90);
48 lft x7r=hround -.75u; bot y7r=vround 5/6(-d-oo);
49 x3r=x1r; top y4r=min(2x_height,h+1);
50 (x,y7l)=whatever[z7r,(x1,min(h,asc_height))]; x7l:=x;
51 z5r=z2'r; (x2'l,y5l)=whatever[z7l,z5r]; x5l=x2'l; y5=y5r;
52 x6r=.5[x7r,x5r]; x6l:=.5[x7l,x5l]; bot y6r=-d-oo;
53 filldraw stroke z2'e..{down}z5e & super_arc.e(5,6)
54 & term.e(6,7,left,1,4); fi % arc and terminal
55 penlabels(1,2,5,6,7); endchar;
56
57
58 numeric itc#; % modified italic correction on `f' and `ff'
59 itc#=if serifs: max(0,flare#-.25u#) else: 1.25u# fi;
60
61
62 ecchar "The ligature fi"; %(CMBR)
63 beginchar(oct"034",10u#+2letter_fit#,asc_height#,0);
64 italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:idot_diam# fi-2u#;
65 normal_adjust_fit(0,serif_fit#);
66 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
67 pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
68 pos12(stem',0); x11=x12; bot y12=0;
69 pickup fine.nib; numeric bulb_diam, inner_jut;
70 if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
71 pos2(bulb_diam,0); x2r=x12r;
72 y2+.5bulb_diam=.8[x_height,h+oo]; top y11=x_height+min(oo,serif_drop);
73 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
74 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
75 else: bulb_diam=stem';
76 pos2(6/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u;
77 pickup tiny.nib; pos13(bulb_diam,0); pos14(bulb_diam,90);
78 x13=x11-.5; top y14r=min(2x_height,h+1); top y11=x_height;
79 if bot y14l-x_height<tiny: y14l:=min(y14r-eps,y11+2tiny); fi
80 x13=x14; y13=.5[y14l,y14r]; dot(13,14); % dot
81 fi; % this is the ligature we're drawing
82 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
83 pickup tiny.nib; filldraw stroke z11e--z12e; % right stem
84 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
85 pos3(bar,90); pos4(bar,90);
86 if serifs: x4=x11; % bar will overlap upper right serif
87 sloped_serif.l(11,12,d,1/3,jut,min(oo,serif_drop)); % upper right serif
88 dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut); % lower right serif
89 else: rt x4= hround 5.3u; fi
90 pickup crisp.nib; filldraw stroke z3e--z4e; % bar
91 penlabels(1,2,3,4,11,12,13,14); endchar;
92
93
94 ecchar "The ligature ff";
95 beginchar(oct"033",10.5u#+2letter_fit#,asc_height#,0);
96 italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
97 normal_adjust_fit(0,0);
98 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
99 pos11(stem',0); rt x11r=hround(w-3u+.5stem');
100 pickup fine.nib; numeric bulb_diam, inner_jut;
101 if serifs: bulb_diam=hround .8[stem,flare];
102 pos2(bulb_diam,0); pos12(bulb_diam,0);
103 rt x2r=hround(rt x11r-stem_corr); lft x12l=hround(w-.75u+.5);
104 y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
105 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
106 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
107 else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 6.25u;
108 pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(w+.75u); fi
109 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
110 f_stroke(11,12,d,e,f,inner_jut,1.25jut); % right stem, arc, terminal, serif
111 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
112 pos3(bar,90); pos4(bar,90);
113 rt x4=hround(w-1/3u);
114 if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
115 pos4'(bar,90); x4'=x11; y4'=y4;
116 filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
117 else: filldraw stroke z3e--z4e; fi % bar
118 penlabels(1,2,3,4,11,12); endchar;
119
120
121 ecchar "The ligature fl";
122 beginchar(oct"035",10u#+2letter_fit#,asc_height#,0);
123 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
124 normal_adjust_fit(0,serif_fit#);
125 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
126 pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
127 pos12(stem',0); x11=x12; bot y12=0; top y11=h;
128 filldraw stroke z11e--z12e; % right stem
129 pickup fine.nib; numeric bulb_diam, inner_jut;
130 if serifs: bulb_diam=hround .8[stem,flare];
131 pos2(bulb_diam,0); x2r=x11r-stem_corr;
132 y2+.5bulb_diam=.9[x_height,h+oo];
133 sloped_serif.l(11,12,d,1/3,eps,max(serif_drop,oo)); % erase excess at top
134 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
135 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
136 else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u; fi
137 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
138 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
139 pos3(bar,90); pos4(bar,90);
140 if serifs: x4=x11;
141 dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut); % lower right serif
142 else: rt x4= hround 5.3u; fi
143 pickup crisp.nib; filldraw stroke z3e--z4e; % bar
144 penlabels(1,2,3,4,11,12); endchar;
145
146 ecchar "The ligature ffi";% (CMBR)
147 beginchar(oct"036",15u#+4letter_fit#,asc_height#,0);
148 italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:idot_diam# fi-2u#;
149 normal_adjust_fit(0,serif_fit#);
150 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
151 pos11(stem',0); lft x11l=hround(.5w-.5stem');
152 pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
153 pos22(stem',0); x21=x22; bot y22=0;
154 pickup fine.nib; numeric bulb_diam, inner_jut;
155 if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
156 pos2(bulb_diam,0); x2r=x11r-stem_corr;
157 pos12(bulb_diam,0); x12r=x21r;
158 top y21=x_height+min(oo,serif_drop);
159 y2+.5bulb_diam=.8[x_height,h+oo]; y12=y2;
160 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
161 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
162 else: bulb_diam=stem';
163 pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
164 pos12(6/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u);
165 pickup tiny.nib; pos23(bulb_diam,0); pos24(bulb_diam,90);
166 x23=x21-.5; top y24r=min(2x_height,h+1); top y21=x_height;
167 if bot y24l-x_height<tiny: y24l:=min(y24r-eps,y21+2tiny); fi
168 x23=x24; y23=.5[y24l,y24r]; dot(23,24); fi % dot
169 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
170 f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
171 pickup tiny.nib; filldraw stroke z21e--z22e; % right stem
172 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
173 pos3(bar,90); pos4(bar,90);
174 if serifs: x4=x21; % bar will overlap upper right serif
175 sloped_serif.l(21,22,g,1/3,jut,min(oo,serif_drop)); % upper right serif
176 dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut); % lower right serif
177 else: rt x4=hround(.5w+2.8u); fi
178 pickup crisp.nib;
179 if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
180 pos4'(bar,90); x4'=x11; y4'=y4;
181 filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
182 else: filldraw stroke z3e--z4e; fi % bar
183 penlabels(1,2,3,4,11,12,21,22,23,24); endchar;
184
185 ecchar "The ligature ffl";
186 beginchar(oct"037",15u#+4letter_fit#,asc_height#,0);
187 italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
188 normal_adjust_fit(0,serif_fit#);
189 pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
190 pos11(stem',0); lft x11l=hround(.5w-.5stem');
191 pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
192 pos22(stem',0); x21=x22; bot y22=0; top y21=h;
193 filldraw stroke z21e--z22e; % right stem
194 pickup fine.nib; numeric bulb_diam, inner_jut;
195 if serifs: bulb_diam=hround .8[stem,flare];
196 pos2(bulb_diam,0); x2r=x11r-stem_corr;
197 pos12(bulb_diam,0); x12r=x21r-stem_corr;
198 y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
199 sloped_serif.l(21,22,g,1/3,eps,max(serif_drop,oo)); % erase excess at top
200 if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
201 else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
202 else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
203 pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u); fi
204 f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
205 f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
206 pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
207 pos3(bar,90); pos4(bar,90);
208 if serifs: dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut); % lower right serif
209 pickup crisp.nib; x4=x21;
210 else: rt x4=hround(.5w+2.8u); fi
211 if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
212 pos4'(bar,90); x4'=x11; y4'=y4;
213 filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e; % bars
214 else: filldraw stroke z3e--z4e; fi % bar
215 penlabels(1,2,3,4,11,12,21,22); endchar;
216
217 endinput;