Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/bromms.mf

raw
1 % This file contains special characters of ``math italic'' fonts
2 % that actually are not supposed to be slanted.
3 % Changed for the CM Bright fonts [1995/09/23 v0.997 WaS]
4
5 % Codes \0050--\0057, \0072--\0077, and \0133--\0137 are generated.
6
7 % The italic corrections are zero in all of these characters.
8
9 cmchar "Leftward top half arrow";
10 compute_spread(.45sym_height#,.55sym_height#);
11 beginchar(oct"050",18sym_u#,v_center(spread#+rule_thickness#));
12 adjust_fit(0,0); pickup crisp.nib;
13 pos1(rule_thickness,90); pos2(rule_thickness,90);
14 pos3(rule_thickness,0); pos4(rule_thickness,0);
15 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-sym_u); lft x0=hround sym_u;
16 y3-y0=y0-y4=.36asc_height+eps; x3=x4=x0+4sym_u+eps;
17 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
18 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
19 numeric t; path p; p=z4r..{2(x0-x4),y0-y4}z6r;
20 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
21 filldraw z0--(x0,y2l)---z1l..z1r---z2r
22 ..subpath (t,0) of\\(z3r..{2(x0-x3),y0-y3}z5r)
23 --z3l..{2(x0-x3),y0-y3}cycle; % arrowhead and stem
24 penlabels(0,1,2,3,4,5,6); endchar;
25
26 cmchar "Leftward bottom half arrow";
27 compute_spread(.45sym_height#,.55sym_height#);
28 beginchar(oct"051",18sym_u#,v_center(spread#+rule_thickness#));
29 adjust_fit(0,0); pickup crisp.nib;
30 pos1(rule_thickness,90); pos2(rule_thickness,90);
31 pos3(rule_thickness,0); pos4(rule_thickness,0);
32 y0=y1=y2=math_axis; x1+.5rule_thickness=hround(w-sym_u); lft x0=hround sym_u;
33 y3-y0=y0-y4=.36asc_height+eps; x3=x4=x0+4sym_u+eps;
34 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
35 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
36 numeric t; path p; p=z4r..{2(x0-x4),y0-y4}z6r;
37 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
38 filldraw z0{2(x4-x0),y4-y0}..z4l
39 --subpath (0,t) of\\(z4r..{2(x0-x4),y0-y4}z6r)
40 ..z2l---z1l..z1r---(x0,y2r)--cycle; % arrowhead and stem
41 penlabels(0,1,2,3,4,5,6); endchar;
42
43 cmchar "Rightward top half arrow";
44 compute_spread(.45sym_height#,.55sym_height#);
45 beginchar(oct"052",18sym_u#,v_center(spread#+rule_thickness#));
46 adjust_fit(0,0); pickup crisp.nib;
47 pos1(rule_thickness,90); pos2(rule_thickness,90);
48 pos3(rule_thickness,0); pos4(rule_thickness,0);
49 y0=y1=y2=math_axis; x1-.5rule_thickness=hround sym_u; rt x0=hround(w-sym_u);
50 y3-y0=y0-y4=.36asc_height+eps; x3=x4=x0-4sym_u-eps;
51 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
52 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
53 numeric t; path p; p=z4l..{2(x0-x4),y0-y4}z6r;
54 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
55 filldraw z0--(x0,y2l)---z1l..z1r---z2r
56 ..subpath (t,0) of\\(z3l..{2(x0-x3),y0-y3}z5r)
57 --z3r..{2(x0-x3),y0-y3}cycle; % arrowhead and stem
58 penlabels(0,1,2,3,4,5,6); endchar;
59
60 cmchar "Rightward bottom half arrow";
61 compute_spread(.45sym_height#,.55sym_height#);
62 beginchar(oct"053",18sym_u#,v_center(spread#+rule_thickness#));
63 adjust_fit(0,0); pickup crisp.nib;
64 pos1(rule_thickness,90); pos2(rule_thickness,90);
65 pos3(rule_thickness,0); pos4(rule_thickness,0);
66 y0=y1=y2=math_axis; x1-.5rule_thickness=hround sym_u; rt x0=hround(w-sym_u);
67 y3-y0=y0-y4=.36asc_height+eps; x3=x4=x0-4sym_u-eps;
68 pos5(rule_thickness,angle(z4-z0)); z5l=z0;
69 pos6(rule_thickness,angle(z3-z0)); z6l=z0;
70 numeric t; path p; p=z4l..{2(x0-x4),y0-y4}z6r;
71 t=xpart(p intersectiontimes((0,y2l)--(w,y2l))); x2=xpart point t of p;
72 filldraw z0{2(x4-x0),y4-y0}..z4r
73 --subpath (0,t) of\\(z4l..{2(x0-x4),y0-y4}z6r)
74 ..z2l---z1l..z1r---(x0,y2r)--cycle; % arrowhead and stem
75 penlabels(0,1,2,3,4,5,6); endchar;
76
77 cmchar "Left hook";
78 compute_spread(.45sym_height#,.55sym_height#);
79 beginchar(oct"054",5sym_u#,v_center(2spread#+rule_thickness#));
80 adjust_fit(0,0); pickup rule.nib; autorounded;
81 lft x2=hround sym_u-eps; x1=x3=w-x2;
82 y1-y3=spread; y2=.5[y1,y3]; y3=math_axis;
83 draw z1{left}...z2{down}...z3{right}; % hook
84 labels(1,2,3); endchar;
85
86 cmchar "Right hook";
87 compute_spread(.45sym_height#,.55sym_height#);
88 beginchar(oct"055",5sym_u#,v_center(2spread#+rule_thickness#));
89 adjust_fit(0,0); pickup rule.nib; autorounded;
90 rt x2=hround(w-sym_u)+eps; x1=x3=w-x2;
91 y1-y3=spread; y2=.5[y1,y3]; y3=math_axis;
92 draw z1{right}...z2{down}...z3{left}; % hook
93 labels(1,2,3); endchar;
94
95 cmchar "Triangle pointing right";
96 beginchar(oct"056",9sym_u#,v_center(sym_height#));
97 adjust_fit(0,0); pickup rule.nib;
98 numeric a,b; a=sqrt(3.14159\\ /sqrt3); % triangle area $=$ circle area
99 b=.5w-(rt hround sym_u); .5[x1',x2']=.5w; x2'-x1'=a*b*sqrt3;
100 x1=x3=good.x x1'; x2=good.x x2';
101 y2=.5[y1,y3]=math_axis; y1=good.y(y2+a*b);
102 draw z1--z2--z3--cycle; % triangle
103 labels(1,2,3); endchar;
104
105 cmchar "Triangle pointing left";
106 beginchar(oct"057",9sym_u#,v_center(sym_height#));
107 adjust_fit(0,0); pickup rule.nib;
108 numeric a,b; a=sqrt(3.14159\\ /sqrt3); % triangle area $=$ circle area
109 b=.5w-(rt hround sym_u); .5[x1',x2']=.5w; x1'-x2'=a*b*sqrt3;
110 x1=x3=good.x x1'; x2=good.x x2';
111 y2=.5[y1,y3]=math_axis; y1=good.y(y2+a*b);
112 draw z1--z2--z3--cycle; % triangle
113 labels(1,2,3); endchar;
114
115 cmchar "Period";
116 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
117 define_whole_blacker_pixels(dot_diam);
118 beginchar(oct"072",5u#,dot_diam#,0); % non-ASCII position
119 adjust_fit(0,0); pickup fine.nib;
120 pos1(dot_diam,0); pos2(dot_diam,90);
121 lft x1l=hround(.5w-.5dot_diam); bot y2l=0; z1=z2; dot(1,2); % dot
122 penlabels(1,2); endchar;
123
124 cmchar "Comma";
125 numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
126 define_whole_blacker_pixels(dot_diam);
127 beginchar(oct"073",5u#,dot_diam#,comma_depth#); % non-ASCII position
128 adjust_fit(0,0);
129 x1-.5dot_diam=hround(.5w-.5dot_diam); y1-.5dot_diam=0;
130 comma(1,a,dot_diam,.2u,comma_depth); % dot and tail
131 penlabels(1); endchar;
132
133 cmchar "Less than sign";
134 compute_spread(5/4sym_height#,3/2sym_height#);
135 beginchar("<",14sym_u#,v_center(spread#+rule_thickness#));
136 italcorr h#*slant-sym_u#;
137 adjust_fit(0,0); pickup rule.nib;
138 lft x2=hround 1.5u-eps; x1=x3=w-x2;
139 y1-y3=spread; y2=.5[y1,y3]=math_axis;
140 draw z1--z2--z3; % diagonals
141 labels(1,2,3); endchar;
142
143 cmchar "Virgule (slash)";
144 beginchar(oct"075",9sym_u#,body_height#,paren_depth#); % non-ASCII position
145 italcorr body_height#*slant-.5sym_u#;
146 adjust_fit(0,0); pickup rule.nib;
147 rt x1=hround(w-sym_u)+eps; top y1=h+eps;
148 lft x2=hround sym_u-eps; bot y2=-d-eps;
149 draw z1--z2; % diagonal
150 penlabels(1,2); endchar;
151
152 cmchar "Greater than sign";
153 compute_spread(5/4sym_height#,3/2sym_height#);
154 beginchar(">",14sym_u#,v_center(spread#+rule_thickness#));
155 italcorr math_axis#*slant-sym_u#;
156 adjust_fit(0,0); pickup rule.nib;
157 rt x2=hround(w-1.5sym_u)+eps; x1=x3=w-x2;
158 y1-y3=spread; y2=.5[y1,y3]=math_axis;
159 draw z1--z2--z3; % diagonals
160 labels(1,2,3); endchar;
161
162 cmchar "Five-pointed star";
163 beginchar(oct"077",9sym_u#,v_center(sym_height#));
164 adjust_fit(0,0); pickup tiny.nib;
165 numeric theta; theta=360/5; % degrees between points
166 pos0(curve,0); pos1(rule_thickness,90); x0=x1=good.x .5w;
167 top y1r=vround(math_axis+.5x_height+.5rule_thickness);
168 ypart(.5[z1,z0+(z1-z2) rotated 2theta])=math_axis;
169 pos2(curve,theta); pos3(rule_thickness,90+theta);
170 z2=z0; z3-z0=(z1-z0) rotated theta;
171 z4=whatever[z0l,z1r]=whatever[z2r,z3r];
172 filldraw for n=0 upto 4:
173 z0+(z1r-z0)rotated(n*theta)--z0+(z4-z0)rotated(n*theta)--endfor
174 cycle; % star
175 penlabels(0,1,2,3,4); endchar;
176
177 cmchar "Musical flat sign";
178 beginchar(oct"133",7u#,body_height#,0);
179 adjust_fit(0,0); pickup crisp.nib;
180 numeric light_hair; light_hair=if hefty: vair else: hair fi;
181 pos1(light_hair,0); pos2(light_hair,180); pos3(light_hair,0); x1=x2=x3;
182 pos4(.25[light_hair,curve],60); pos5(curve,0);
183 lft x1l=hround u; x4=.5w; rt x5r=hround(w-u);
184 top y1=h; bot y3=-o; top y4=x_height+o;
185 y2=y4-.2x_height; y5=3/4x_height;
186 filldraw stroke z1e--z3e; % stem
187 filldraw stroke z2e{up}...z4e{right}...z5e{down}
188 ...{2(x3-x5e),y3-y5e}z3e; % bowl
189 penlabels(1,2,3,4,5); endchar;
190
191 cmchar "Musical natural sign";
192 beginchar(oct"134",7u#,asc_height#,desc_depth#);
193 adjust_fit(0,0); pickup crisp.nib;
194 numeric light_hair; light_hair=if hefty: vair else: hair fi;
195 pos1(light_hair,0); pos2(curve,90); pos3(curve,90);
196 pos4(curve,90); pos5(curve,90); pos6(light_hair,0);
197 rt x1r=hround 15/8u; x2=x4=x1l; x3=x5=x6r=w-x2;
198 y1=h+o; top y2r=0; .5[y2,y3]=0; y4-y2=y5-y3=x_height; bot y6=-d-o;
199 x2'=x1r; z2'=whatever[z2r,z3r]; x5'=x6l; z5'=whatever[z4l,z5l];
200 (x1r,y)=z1l+whatever*(z5-z4); y6l:=y6l-(y-y1r); y1r:=y;
201 filldraw z1l--z2l--z3l--z3r--z2'--z1r--cycle; % left stem and lower bar
202 filldraw z6r--z5r--z4r--z4l--z5'--z6l--cycle; % right stem and upper bar
203 penlabels(1,2,3,4,5,6); endchar;
204
205 cmchar "Musical sharp sign";
206 beginchar(oct"135",7u#,asc_height#,desc_depth#);
207 adjust_fit(0,0); pickup crisp.nib;
208 numeric light_hair; light_hair=if hefty: vair else: hair fi;
209 pos1(curve,90); pos2(curve,90); pos3(curve,90); pos4(curve,90);
210 lft x1=lft x3=hround u; x2=x4=w-x1;
211 top y3r=0; .5[y3,y4]=0; y1-y3=y2-y4=x_height;
212 filldraw stroke z1e--z2e; filldraw stroke z3e--z4e; % bars
213 numeric theta,hstem; theta=angle(z2-z1);
214 (hstem-crisp)*cosd theta=light_hair-crisp;
215 pos5(hstem,theta); pos6(hstem,theta); pos7(hstem,theta); pos8(hstem,theta);
216 lft x5l=lft x6l=hround(2u-.5light_hair); x7=x8=w-x6;
217 top y7l=h+o; bot y6r=-d-o; z7-z5=z8-z6=(whatever,0) rotated theta;
218 filldraw stroke z5e--z6e; filldraw stroke z7e--z8e; % stems
219 penlabels(1,2,3,4,5,6,7,8); endchar;
220
221 cmchar "Slur below (smile)";
222 beginchar(oct"136",18sym_u#,v_center(.5sym_height#));
223 adjust_fit(0,0); pickup fine.nib;
224 numeric light_stem; light_stem=Vround .5[vair,stem];
225 x1-.5hair=hround sym_u; y1+.5hair=vround(h+.5hair); x3=w-x1; y3=y1;
226 pos2(light_stem,90); x2=.5w; y2l=good.y -d;
227 numeric theta; theta=angle((z2-z1)yscaled 3);
228 pos1(hair,90+theta); pos3(hair,90-theta);
229 filldraw z1l{dir theta}...z2l...{dir-theta}z3l
230 ..z3r{-dir-theta}...z2r...{-dir theta}z1r..cycle; % arc
231 penlabels(1,2,3); endchar;
232
233 cmchar "Slur above (frown)";
234 beginchar(oct"137",18sym_u#,v_center(.5sym_height#));
235 adjust_fit(0,0); pickup fine.nib;
236 numeric light_stem; light_stem=Vround .5[vair,stem];
237 x1-.5hair=hround sym_u; y1-.5hair=vround(-d-.5hair); x3=w-x1; y3=y1;
238 pos2(light_stem,90); x2=.5w; y2=good.y h;
239 numeric theta; theta=angle((z2-z1)yscaled 3);
240 pos1(hair,90+theta); pos3(hair,90-theta);
241 filldraw z1l{dir theta}...z2l...{dir-theta}z3l
242 ..z3r{-dir-theta}...z2r...{-dir theta}z1r..cycle; % arc
243 penlabels(1,2,3); endchar;