Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/brmsb.mf

raw
1 % MSB symbols, bright style [1996/07/02 v1.0 (WaS)]
2
3 cmchar "Lowercase variation of Greek kappa";
4 % will use same dimensions as standard Greek lowercase kappa
5 % see vol E, p 155.
6 beginchar(oct"173", 12u#, x_height#, 0);
7 italcorr 1/3x_height#*slant+.5hair#+.5u#;
8 adjust_fit(0,0); pickup rule.nib;
9 pos1(stem,0); pos2(stem,0);x1l=hround(2u-.5stem); x2r=w-x1l;
10 top y2+.3stem=h+oo; bot y1-.3stem=-oo;
11 filldraw z1l---z2l...z2r---z1r...cycle;
12 pickup crisp.nib;
13 pos3(hair,180); x3=lft x1l; y3=3/4h; pos4(stem,90);
14 top y4r+.15stem=h+oo; x4-x3=.05[x1,x2];
15 pos4'(hair,0); y4'=y3; x4'=1/4[x1,x2];
16 pos5(hair,90); z5=z1;
17 filldraw super_arc.r(3,4)&super_arc.r(4,4')...{z1-z2}z5&z5{z2-z1}
18 ...super_arc.l(4',4)&super_arc.l(4,3)---cycle; % left arm
19 pos8(hair,-90); pos6(hair,0);
20 z8=z2; pos7(stem, -90); bot y7r-.15stem=-oo; x6-x7=x4-x3;
21 x6=w-x3;
22 pos7'(hair,180); y7'=y6; x7'=w-x4';
23 y6=h-y3;
24 filldraw super_arc.r(6,7)&super_arc.r(7,7')...{z2-z1}z8&z8{z1-z2}
25 ...super_arc.l(7',7)&super_arc.l(7,6)---cycle; % right arm
26 %filldraw z8{z1-z2}..z7l...{up}z6r---z6l{-u,-2u}...z7r..{z2-z1}z8---cycle; %right arm
27 penlabels(range 1 thru 8,4'); endchar;
28
29 cmchar "H-bar symbol, slanted bar";
30 beginchar(oct"175",10u#,asc_height#,0);
31 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
32 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
33 pickup tiny.nib; pos1(stem,0); pos2(stem,0);
34 pos1'(stem',0); pos2'(stem',0); pos3(stem,0);
35 lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
36 top y1=h; bot y2=0; y1=y1'; y2=y2';
37 filldraw stroke z1'e--z2'e; % left stem
38 h_stroke(2,a,3,4); % arch and right stem
39 if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
40 numeric inner_jut; pickup tiny.nib;
41 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
42 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
43 dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
44 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
45
46 numeric macron_breadth; macron_breadth:=Vround .2[vair,stem];
47 pickup if serifs: crisp.nib else: fine.nib fi;
48 pos5(macron_breadth,90); pos6(macron_breadth,90);
49 y5=0.7h; y6=7/8h;
50 lft x5=w-2.5u-rt x6=hround 0.5u;
51 filldraw stroke z5e--z6e; % bar
52
53 penlabels(1,2,3,4,5,6); endchar;
54
55 cmchar "H-bar symbol, vertical bar";
56 beginchar(oct"176",10u#,asc_height#,0);
57 italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
58 adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
59 pickup tiny.nib; pos1(stem,0); pos2(stem,0);
60 pos1'(stem',0); pos2'(stem',0); pos3(stem,0);
61 lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
62 top y1=h; bot y2=0; y1=y1'; y2=y2';
63 filldraw stroke z1'e--z2'e; % left stem
64 h_stroke(2,a,3,4); % arch and right stem
65 if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
66 numeric inner_jut; pickup tiny.nib;
67 if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
68 else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
69 dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
70 dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
71
72 numeric macron_breadth; macron_breadth:=Vround .2[vair,stem];
73 pickup if serifs: crisp.nib else: fine.nib fi;
74 pos5(macron_breadth,90); pos6(macron_breadth,90);
75 top y5r=top y6r=0.81h; %h+o;
76 lft x5=w-2.5u-rt x6=hround 0.5u;
77 filldraw stroke z5e--z6e; % bar
78
79 penlabels(1,2,3,4,5,6); endchar;
80
81 cmchar "Reversed, reflected, lowercase Greek epsilon";
82 beginchar(oct"177",8u#,x_height#,0);
83 italcorr x_height#*slant+.5hair#-2u#;
84 adjust_fit(0,0); pickup fine.nib;
85 pos0(bar,90); pos1(bar,90); pos2(curve,180);
86 pos3(vair,270); pos4(hair,300); pos6(bar,90); pos7(bar,90);
87 x1=.5w+.5u; x0=x1+u; lft x2r=hround(1.5u-.5curve); x3=.5[x0,x1];
88 x4r=good.x(w-u); x5=w+.5u; x6=x0; z7=z2l;
89 top y0r=top y1r=h; y2=y5=y6=bar_height; bot y3r=-oo;
90 path p; p=z3r{right}...{up}z5;
91 numeric t; t=ypart(((x4r,y3r)--(x4r,y5))intersectiontimes p);
92 y4r=ypart point t of p;
93 filldraw circ_stroke z0e..pulled_arc.e(1,2) & pulled_arc.e(2,3)
94 ...z4e{direction t of p}; % arc
95 filldraw circ_stroke z6e--z7e; % bar
96 math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
97 picture v;
98 v:=currentpicture;
99 v:=v reflectedabout((0,h*aspect_ratio/2),(w,h*aspect_ratio/2));
100 v:=v reflectedabout((w/2,-d),(w/2,h));
101 currentpicture:=v shifted (2u,0);
102 penlabels(0,1,2,3,4,5,6,7); endchar;
103
104 slant:=mono_charic#:=0; % the remaining characters will not be slanted
105 currenttransform:=identity yscaled aspect_ratio scaled granularity;
106
107 cmchar "Upsidedown, uppercase Greek Omega";
108 beginchar(oct"146",13u#,cap_height#,0);
109 italcorr .75cap_height#*slant-.5u#;
110 adjust_fit(0,0);
111 pickup tiny.nib; pos1(vair,90); pos2(cap_curve,180);
112 pos3(vair,180); pos4(cap_curve,0); pos5(vair,0);
113 x1=.5w; top y1r=h+o; lft x2r=hround u; y2=y4=2/3h; x4=w-x2;
114 rt x3l=hround(1/3(w+.5u)+.5hair); bot y3=bot y5=0; x5=w-x3;
115 filldraw stroke z3e{up}...{up}z2e
116 & pulled_super_arc.e(2,1)(.5superpull)
117 & pulled_super_arc.e(1,4)(.5superpull)
118 & z4e{down}...{down}z5e; % bowl
119 numeric arm_thickness; path p; p=z3{up}...{up}z2;
120 arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[slab,cap_vstem] fi);
121 pickup crisp.nib; pos6(arm_thickness,-90); pos7(fudged.hair,-180);
122 bot y6r=0; x6=x3; lft x7r=hround .8u; y7=good.y(y6l+.5beak)+eps;
123 (x,y)=p intersectionpoint((0,y6l)--(w,y6l)); x6l:=x;
124 arm(6,7,a,.5beak_darkness,-1.2beak_jut); % left arm and beak
125 pos8(arm_thickness,-90); pos9(fudged.hair,0);
126 y8=y6; y9=y7; x8+x6=x9+x7=w; x8l:=w-x6l;
127 arm(8,9,b,.5beak_darkness,1.2beak_jut); % right arm and beak
128 %math_fit(0,.5ic#);
129 picture v; v:=currentpicture;
130 numeric t; t=h-d;
131 v:=v reflectedabout((0,0),(w,0));
132 currentpicture:=v shifted(0,aspect_ratio*cap_height);
133 penlabels(1,2,3,4,5,6,7,8,9); endchar;
134
135 cmchar "The letter Edh (Old English rune, like thorn)";
136 % adapted from cm partial differential sign, vol E, p 233.
137 beginchar(oct"147",10u#,asc_height#,0);
138 italcorr .7asc_height#*slant+.5curve#-1.5u#;
139 adjust_fit(0,0);
140 numeric top_thickness,bot_thickness,side_thickness,pull;
141 top_thickness=max(fine.breadth,vround(slab-2vair_corr));
142 bot_thickness=max(fine.breadth,vround(slab-vair_corr));
143 side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
144 pull=min(.25,1.5superpull);
145 pickup fine.nib; pos2(top_thickness,90);
146 pos3(side_thickness,0); pos4(bot_thickness,-90);
147 pos5(side_thickness,-180); pos6(vair,-270);
148 lft x5r=w-rt x3r=hround max(.75u,1.5u-.5side_thickness);
149 x4=x6+.1u=x2+u=.5w;
150 top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
151 y5=.5[y4,y6]; top y6=vround 5/8h+o;
152 path p; p=pulled_super_arc.l(3,4)(pull);
153 numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
154 pos7(thin_join,0); z7l=point t of p;
155 (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
156 x2:=x5; x2l:=x2r:=x2;
157 filldraw stroke pulled_super_arc.e(2,3)(pull)
158 & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
159 & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
160 & z6e{right}...{direction t of p}z7e; % arc and bowl
161 %pos1(hair,180); pos0(flare,180); % commenting out the arc and bulb
162 %lft x0r=min(lft x2-eps,hround 1.2u);
163 %y0=vround min(.85h-.5flare,.8h+.5flare)+o;
164 %{{less_tense; bulb(2,1,0)}}; % arc and bulb
165 %math_fit(-.3x_height#*slant+.5curve#-u#,ic#-u#);
166 pickup pencircle xscaled 1.4rule_thickness yscaled .5rule_thickness;
167 x10=x11=x5; x12=x13=w-x10; y10=y13;
168 y10-y11=y12-y13=cap_stem; .5[y11,y10]=.5[y6,y2];
169 draw z10--z11--z12--z13; % cross piece
170 penlabels(2,3,4,5,6,7,10,11,12,,13); endchar;
171