Debian Codegraph @

texmf-dist/fonts/source/public/cmbright/bitalms.mf

raw
1 % This file contains miscellaneous symbols of math italic fonts.
2 % The character codes are \0100, \0140, and \0173--\0177.
3 % Changed for the CM Bright fonts [1995/10/18 v0.998 WaS];
4 % changes are marked by (CMBR).
5
6 cmchar "Partial differential sign";
7 beginchar(oct"100",10u#,asc_height#,0);
8 italcorr .7asc_height#*slant+.5curve#-1.5u#;
9 adjust_fit(0,0);
10 numeric top_thickness,bot_thickness,side_thickness,pull;
11 top_thickness=max(fine.breadth,vround(slab-2vair_corr));
12 bot_thickness=max(fine.breadth,vround(slab-vair_corr));
13 side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
14 pull=min(.25,1.5superpull);
15 pickup fine.nib; pos2(top_thickness,90);
16 pos3(side_thickness,0); pos4(bot_thickness,-90);
17 pos5(side_thickness,-180); pos6(vair,-270);
18 lft x5r=w-rt x3r=hround max(.75u,1.5u-.5side_thickness);
19 x4=x6+.1u=x2+u=.5w;
20 top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
21 y5=.5[y4,y6]; top y6=vround 5/8h+o;
22 path p; {{interim superness:=more_super; p=pulled_super_arc.l(3,4)(pull)}};
23 numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
24 pos7(thin_join,0); z7l=point t of p;
25 (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
26 filldraw stroke pulled_super_arc.e(2,3)(pull)
27 & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
28 & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
29 & z6e{right}...{direction t of p}z7e; % arc and bowl
30 pos1(hair,180); pos0(flare,180);
31 lft x0r=min(lft x2-eps,hround 1.2u);
32 y0=vround min(.85h-.5flare,.8h+.5flare)+o;
33 {{less_tense; bulb(2,1,0)}}; % arc and bulb
34 math_fit(-.3x_height#*slant+.5curve#-u#,ic#-u#);
35 penlabels(0,1,2,3,4,5,6,7); endchar;
36
37 cmchar "Lowercase italic script l";
38 beginchar(oct"140",4.5u#+max(1.5u#,stem#),asc_height#,0);
39 italcorr .8asc_height#*slant-u#;
40 adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
41 pos1(hair,-45); pos2(hair,0); pos3(vair,90);
42 pos4(stem,180); pos5(vair,270); pos6(hair,315);
43 lft x1l=hround(lft x1l-x1); rt x2r=hround(w-1.5u); x3=.5w;
44 lft x4r=hround .5u; x5=x3+.75u; x6=x1+w+1;
45 y1=y6=.125h; y2=.8h; top y3r=h+oo; y4=.5[y3,y5]; bot y5=-oo;
46 filldraw stroke z1e{10u,asc_height}...z2e{up}...pulled_arc.e(3,4)
47 & pulled_arc.e(4,5)...z6e{10u,asc_height}; % bowl and hook
48 math_fit(0,ic#); penlabels(1,2,3,4,5,6); endchar;
49
50 cmchar "Dotless letter i"; % (CMBR)
51 beginchar(oct"173",5u#,x_height#,0);
52 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
53 adjust_fit(serif_fit#+stem_shift# if monospace:+.25u#fi,serif_fit#-stem_shift#);
54 pickup tiny.nib; pos1(stem',0); pos2(stem',0);
55 if odd(w-stem'): change_width; fi
56 lft x1l=hround(.5w-.5stem'); x1=x2;
57 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=0;
58 filldraw stroke z1e--z2e; % stem
59 if serifs: sloped_serif.l(1,2,a,1/3,.95jut,serif_drop); % upper serif
60 dish_serif(2,1,b,1/3,jut,c,1/3,.9jut); fi % lower serif
61 penlabels(1,2); endchar;
62
63 cmchar "Dotless letter j"; % (CMBR)
64 beginchar(oct"174",5.5u#,x_height#,desc_depth#);
65 italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
66 adjust_fit(serif_fit#+2stem_shift# if monospace:+.5u# fi,
67 serif_fit#-2stem_shift# if monospace:-.5u# fi);
68 pickup tiny.nib; pos1(stem',0); pos2(stem',0);
69 rt x1r=hround(.5w+.25u+.5stem'); x1=x2;
70 top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=-1/3d;
71 filldraw stroke z1e--z2e; % stem
72 if serifs: sloped_serif.l(1,2,a,1/3,1.1jut,serif_drop); % upper serif
73 pickup tiny.nib; pos5(vair,-90); pos6(hair,-180); pos7(flare,-180);
74 x5=.5[x2,x6r]; bot y5r=-d-oo; y6-.5flare=-.88d;
75 if monospace: lft x6r=0 else: z6r=z7r; rt x7l=floor .75u fi;
76 (x,y5r)=whatever[z5l,z2l]; x5r:=max(x,.5[x6r,x5]);
77 filldraw stroke z2e{down}...z5e{left}; bulb(5,6,7); % arc and bulb
78 else: pickup fine.nib; pos2'(stem',0); z2'=z2;
79 pos6(.2[vair,stem'],-90); pos7(vair,-90);
80 lft x7r=hround -.75u; bot y7r=vround 5/6(-d-oo);
81 x3r=x1r; top y4r=min(2x_height,h+1);
82 (x,y7l)=whatever[z7r,(x1,min(h,asc_height))]; x7l:=x;
83 z5r=z2'r; (x2'l,y5l)=whatever[z7l,z5r]; x5l=x2'l; y5=y5r;
84 x6r=.5[x7r,x5r]; x6l:=.5[x7l,x5l]; bot y6r=-d-oo;
85 filldraw stroke z2'e..{down}z5e & super_arc.e(5,6)
86 & term.e(6,7,left,1,4); fi % arc and terminal
87 penlabels(1,2,5,6,7); endchar;
88
89 cmchar "Weierstrass p";
90 beginchar(oct"175",11u#,x_height#,desc_depth#);
91 italcorr .7x_height#*slant+.5stem#-u# if math_fitting:-.5u# fi;
92 adjust_fit(0,0); pickup fine.nib;
93 numeric theta; theta=90-angle(8u,h); slope:=-h/8u; % angle at middle
94 pos2(vair,-90); pos1(vstem,theta); pos7(vair,-90);
95 x2+.5u=x1=x7-.5u=3u; top y2l=h+o; bot y7r=-d-o; y1=.4[-d,h];
96 lft x3l=hround .5u; rt x6r=hround max(rt x7+.5,.5w-.25u);
97 x3r-x3l=x6r-x6l=(hround .5[vair,vstem])-fine;
98 ellipse_set(2l,3l,4l,1l); ellipse_set(2r,3r,4r,1r); y3=y3r;
99 ellipse_set(7l,6l,5l,1l); ellipse_set(7r,6r,5r,1r); y6=y6r;
100 filldraw stroke super_arc.e(2,3) & z3e{down}
101 ..z4e---z5e..z6e{down} & super_arc.e(6,7); % flourish
102 pos8(hair,180); pos9(vair,90); pos10(stem,0);
103 pos11(vair,-90); pos12(hair,-180); pos13(.3[hair,flare],-180);
104 rt x10r=hround(w-1.5u+.5stem); lft x12r=hround(.5w-.5u);
105 rt x8l=hround 2.25u; x9=x11=max(x12l+eps,.5w+1.5u);
106 y8=0; top y9r=vround(.9h+o); y10=.5[y9,y11]; bot y11r=-oo;
107 filldraw stroke z7e{left}...z8e{up}...pulled_arc.e(9,10)
108 & pulled_arc.e(10,11); % stem and bowl
109 y13-.5(.6[hair,flare])=.15h; bulb(11,12,13); % bulb
110 math_fit(0,ic#); penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
111
112 cmchar "Arrow (vector) accent";
113 beginchar(oct"176",9u#,asc_height#+.5rule_thickness#,0);
114 italcorr .7[x_height#,asc_height#]*slant;
115 adjust_fit(0,0); pickup rule.nib;
116 lft x1=hround .5u; x2=w-x1; y1=y2=good.x .7[x_height,asc_height];
117 draw z1--z2; % bar
118 rt x3=rt x4=hround(x2-u);
119 y3=y2+.3(asc_height-x_height); y4=y2-.3(asc_height-x_height);
120 draw z3{x2-x3,2(y2-y3)}...{2(x2-x3),y2-y3}z2; % upper point
121 draw z4{x2-x4,2(y2-y4)}...{2(x2-x4),y2-y4}z2; % lower point
122 labels(1,2,3,4); endchar;
123
124 cmchar "Tie accent";
125 beginchar(oct"177",5u#,asc_height#,0);
126 italcorr 4/9[x_height#,asc_height#]*slant+4.5u#+2letter_fit#+.5hair#;
127 adjust_fit(if monospace:2u#,2u# else:serif_fit#,serif_fit# fi);
128 pickup fine.nib; pos1(hair,180); pos2(vround 1/5[vair,stem],90); pos3(hair,0);
129 lft x1r=hround(.5w-.5hair); x2=.5[x1,x3];
130 rt x3r=hround(w+4u+2letter_fit+.5hair);
131 y1=y3=4/9[x_height,asc_height]; top y2r=vround 8/9[x_height,asc_height];
132 filldraw stroke super_arc.e(1,2) & super_arc.e(2,3); % arc
133 penlabels(1,2,3); endchar;