Debian Codegraph @

m4/sys_wait_h.m4

raw
1 # sys_wait_h.m4
2 # serial 9
3 dnl Copyright (C) 2008-2024 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 AC_DEFUN_ONCE([gl_SYS_WAIT_H],
10 [
11 AC_REQUIRE([gl_SYS_WAIT_H_DEFAULTS])
12
13 dnl <sys/wait.h> is always overridden, because of GNULIB_POSIXCHECK.
14 gl_CHECK_NEXT_HEADERS([sys/wait.h])
15
16 dnl Ensure the type pid_t gets defined.
17 AC_REQUIRE([AC_TYPE_PID_T])
18
19 dnl Check for declarations of anything we want to poison if the
20 dnl corresponding gnulib module is not in use.
21 gl_WARN_ON_USE_PREPARE([[#include <sys/wait.h>]],
22 [waitpid])
23 ])
24
25 # gl_SYS_WAIT_MODULE_INDICATOR([modulename])
26 # sets the shell variable that indicates the presence of the given module
27 # to a C preprocessor expression that will evaluate to 1.
28 # This macro invocation must not occur in macros that are AC_REQUIREd.
29 AC_DEFUN([gl_SYS_WAIT_MODULE_INDICATOR],
30 [
31 dnl Ensure to expand the default settings once only.
32 gl_SYS_WAIT_H_REQUIRE_DEFAULTS
33 gl_MODULE_INDICATOR_SET_VARIABLE([$1])
34 dnl Define it also as a C macro, for the benefit of the unit tests.
35 gl_MODULE_INDICATOR_FOR_TESTS([$1])
36 ])
37
38 # Initializes the default values for AC_SUBSTed shell variables.
39 # This macro must not be AC_REQUIREd. It must only be invoked, and only
40 # outside of macros or in macros that are not AC_REQUIREd.
41 AC_DEFUN([gl_SYS_WAIT_H_REQUIRE_DEFAULTS],
42 [
43 m4_defun(GL_MODULE_INDICATOR_PREFIX[_SYS_WAIT_H_MODULE_INDICATOR_DEFAULTS], [
44 gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_WAITPID])
45 ])
46 m4_require(GL_MODULE_INDICATOR_PREFIX[_SYS_WAIT_H_MODULE_INDICATOR_DEFAULTS])
47 AC_REQUIRE([gl_SYS_WAIT_H_DEFAULTS])
48 ])
49
50 AC_DEFUN([gl_SYS_WAIT_H_DEFAULTS],
51 [
52 dnl Assume proper GNU behavior unless another module says otherwise.
53 ])