Debian Codegraph @

m4/mbstate_t.m4

raw
1 # mbstate_t.m4
2 # serial 14
3 dnl Copyright (C) 2000-2002, 2008-2024 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 # From Paul Eggert.
10
11 # BeOS 5 has <wchar.h> but does not define mbstate_t,
12 # so you can't declare an object of that type.
13 # Check for this incompatibility with Standard C.
14
15 # AC_TYPE_MBSTATE_T
16 # -----------------
17 AC_DEFUN([AC_TYPE_MBSTATE_T],
18 [
19 AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS]) dnl for HP-UX 11.11
20
21 AC_CACHE_CHECK([for mbstate_t], [ac_cv_type_mbstate_t],
22 [AC_COMPILE_IFELSE(
23 [AC_LANG_PROGRAM(
24 [AC_INCLUDES_DEFAULT[
25 #include <wchar.h>]],
26 [[mbstate_t x; return sizeof x;]])],
27 [ac_cv_type_mbstate_t=yes],
28 [ac_cv_type_mbstate_t=no])])
29 if test $ac_cv_type_mbstate_t = yes; then
30 AC_DEFINE([HAVE_MBSTATE_T], [1],
31 [Define to 1 if <wchar.h> declares mbstate_t.])
32 else
33 AC_DEFINE([mbstate_t], [int],
34 [Define to a type if <wchar.h> does not define.])
35 fi
36 ])