Debian Codegraph @

m4/locale-ja.m4

raw
1 # locale-ja.m4
2 # serial 19
3 dnl Copyright (C) 2003, 2005-2024 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 dnl From Bruno Haible.
10
11 dnl Determine the name of a japanese locale with EUC-JP encoding.
12 AC_DEFUN_ONCE([gt_LOCALE_JA],
13 [
14 AC_REQUIRE([AC_CANONICAL_HOST])
15 AC_REQUIRE([AM_LANGINFO_CODESET])
16 AC_CACHE_CHECK([for a traditional japanese locale], [gt_cv_locale_ja], [
17 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
18 #include <locale.h>
19 #include <time.h>
20 #if HAVE_LANGINFO_CODESET
21 # include <langinfo.h>
22 #endif
23 #include <stdlib.h>
24 #include <string.h>
25 struct tm t;
26 char buf[16];
27 int main ()
28 {
29 /* On BeOS and Haiku, locales are not implemented in libc. Rather, libintl
30 imitates locale dependent behaviour by looking at the environment
31 variables, and all locales use the UTF-8 encoding. */
32 #if defined __BEOS__ || defined __HAIKU__
33 return 1;
34 #else
35 /* Check whether the given locale name is recognized by the system. */
36 # if defined _WIN32 && !defined __CYGWIN__
37 /* On native Windows, setlocale(category, "") looks at the system settings,
38 not at the environment variables. Also, when an encoding suffix such
39 as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
40 category of the locale to "C". */
41 if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
42 || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
43 return 1;
44 # else
45 if (setlocale (LC_ALL, "") == NULL) return 1;
46 # endif
47 /* Check whether nl_langinfo(CODESET) is nonempty and not "ASCII" or "646".
48 On Mac OS X 10.3.5 (Darwin 7.5) in the fr_FR locale, nl_langinfo(CODESET)
49 is empty, and the behaviour of Tcl 8.4 in this locale is not useful.
50 On OpenBSD 4.0, when an unsupported locale is specified, setlocale()
51 succeeds but then nl_langinfo(CODESET) is "646". In this situation,
52 some unit tests fail.
53 On MirBSD 10, when an unsupported locale is specified, setlocale()
54 succeeds but then nl_langinfo(CODESET) is "UTF-8". */
55 # if HAVE_LANGINFO_CODESET
56 {
57 const char *cs = nl_langinfo (CODESET);
58 if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
59 || strcmp (cs, "UTF-8") == 0)
60 return 1;
61 }
62 # endif
63 # ifdef __CYGWIN__
64 /* On Cygwin, avoid locale names without encoding suffix, because the
65 locale_charset() function relies on the encoding suffix. Note that
66 LC_ALL is set on the command line. */
67 if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
68 # endif
69 /* Check whether MB_CUR_MAX is > 1. This excludes the dysfunctional locales
70 on Cygwin 1.5.x. */
71 if (MB_CUR_MAX == 1)
72 return 1;
73 /* Check whether in a month name, no byte in the range 0x80..0x9F occurs.
74 This excludes the UTF-8 encoding (except on MirBSD). */
75 {
76 const char *p;
77 t.tm_year = 1975 - 1900; t.tm_mon = 2 - 1; t.tm_mday = 4;
78 if (strftime (buf, sizeof (buf), "%B", &t) < 2) return 1;
79 for (p = buf; *p != '\0'; p++)
80 if ((unsigned char) *p >= 0x80 && (unsigned char) *p < 0xa0)
81 return 1;
82 }
83 return 0;
84 #endif
85 }
86 ]])])
87 if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
88 case "$host_os" in
89 # Handle native Windows specially, because there setlocale() interprets
90 # "ar" or "ara" as "Arabic" or "Arabic_Saudi Arabia.1256",
91 # "en" or "eng" as "English" or "English_United States.1252",
92 # "fr" or "fra" as "French" or "French_France.1252",
93 # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
94 # "ja" or "jpn" as "Japanese" or "Japanese_Japan.932",
95 # and similar.
96 mingw* | windows*)
97 # Note that on native Windows, the Japanese locale is
98 # Japanese_Japan.932, and CP932 is very different from EUC-JP, so we
99 # cannot use it here.
100 gt_cv_locale_ja=none
101 ;;
102 *)
103 # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
104 # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
105 # configure script would override the LC_ALL setting. Likewise for
106 # LC_CTYPE, which is also set at the beginning of the configure script.
107 # Test for the AIX locale name.
108 if (LC_ALL=ja_JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
109 gt_cv_locale_ja=ja_JP
110 else
111 # Test for the locale name with explicit encoding suffix.
112 if (LC_ALL=ja_JP.EUC-JP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
113 gt_cv_locale_ja=ja_JP.EUC-JP
114 else
115 # Test for the HP-UX, OSF/1, NetBSD locale name.
116 if (LC_ALL=ja_JP.eucJP LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
117 gt_cv_locale_ja=ja_JP.eucJP
118 else
119 # Test for the IRIX, FreeBSD locale name.
120 if (LC_ALL=ja_JP.EUC LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
121 gt_cv_locale_ja=ja_JP.EUC
122 else
123 # Test for the Solaris 10 locale name.
124 if (LC_ALL=ja LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
125 gt_cv_locale_ja=ja
126 else
127 # Special test for NetBSD 1.6.
128 if test -f /usr/share/locale/ja_JP.eucJP/LC_CTYPE; then
129 gt_cv_locale_ja=ja_JP.eucJP
130 else
131 # None found.
132 gt_cv_locale_ja=none
133 fi
134 fi
135 fi
136 fi
137 fi
138 fi
139 ;;
140 esac
141 fi
142 rm -fr conftest*
143 ])
144 LOCALE_JA=$gt_cv_locale_ja
145 case $LOCALE_JA in #(
146 '' | *[[[:space:]\"\$\'*@<:@]]*)
147 dnl This locale name might cause trouble with sh or make.
148 AC_MSG_WARN([invalid locale "$LOCALE_JA"; assuming "none"])
149 LOCALE_JA=none;;
150 esac
151 AC_SUBST([LOCALE_JA])
152 ])