Debian Codegraph @

m4/netdb_h.m4

raw
1 # netdb_h.m4
2 # serial 15
3 dnl Copyright (C) 2008-2024 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 AC_DEFUN_ONCE([gl_NETDB_H],
10 [
11 AC_REQUIRE([gl_NETDB_H_DEFAULTS])
12 gl_CHECK_NEXT_HEADERS([netdb.h])
13 if test $ac_cv_header_netdb_h = yes; then
14 HAVE_NETDB_H=1
15 else
16 HAVE_NETDB_H=0
17 fi
18 AC_SUBST([HAVE_NETDB_H])
19
20 dnl Check for declarations of anything we want to poison if the
21 dnl corresponding gnulib module is not in use.
22 gl_WARN_ON_USE_PREPARE([[#include <netdb.h>]],
23 [getaddrinfo freeaddrinfo gai_strerror getnameinfo])
24 ])
25
26 # gl_NETDB_MODULE_INDICATOR([modulename])
27 # sets the shell variable that indicates the presence of the given module
28 # to a C preprocessor expression that will evaluate to 1.
29 # This macro invocation must not occur in macros that are AC_REQUIREd.
30 AC_DEFUN([gl_NETDB_MODULE_INDICATOR],
31 [
32 dnl Ensure to expand the default settings once only.
33 gl_NETDB_H_REQUIRE_DEFAULTS
34 gl_MODULE_INDICATOR_SET_VARIABLE([$1])
35 dnl Define it also as a C macro, for the benefit of the unit tests.
36 gl_MODULE_INDICATOR_FOR_TESTS([$1])
37 ])
38
39 # Initializes the default values for AC_SUBSTed shell variables.
40 # This macro must not be AC_REQUIREd. It must only be invoked, and only
41 # outside of macros or in macros that are not AC_REQUIREd.
42 AC_DEFUN([gl_NETDB_H_REQUIRE_DEFAULTS],
43 [
44 m4_defun(GL_MODULE_INDICATOR_PREFIX[_NETDB_H_MODULE_INDICATOR_DEFAULTS], [
45 gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_GETADDRINFO])
46 ])
47 m4_require(GL_MODULE_INDICATOR_PREFIX[_NETDB_H_MODULE_INDICATOR_DEFAULTS])
48 AC_REQUIRE([gl_NETDB_H_DEFAULTS])
49 ])
50
51 AC_DEFUN([gl_NETDB_H_DEFAULTS],
52 [
53 dnl Assume proper GNU behavior unless another module says otherwise.
54 HAVE_STRUCT_ADDRINFO=1; AC_SUBST([HAVE_STRUCT_ADDRINFO])
55 HAVE_DECL_FREEADDRINFO=1; AC_SUBST([HAVE_DECL_FREEADDRINFO])
56 HAVE_DECL_GAI_STRERROR=1; AC_SUBST([HAVE_DECL_GAI_STRERROR])
57 HAVE_DECL_GETADDRINFO=1; AC_SUBST([HAVE_DECL_GETADDRINFO])
58 HAVE_DECL_GETNAMEINFO=1; AC_SUBST([HAVE_DECL_GETNAMEINFO])
59 REPLACE_GAI_STRERROR=0; AC_SUBST([REPLACE_GAI_STRERROR])
60 REPLACE_GETADDRINFO=0; AC_SUBST([REPLACE_GETADDRINFO])
61 ])