Debian Codegraph @

m4/mbsinit.m4

raw
1 # mbsinit.m4
2 # serial 10
3 dnl Copyright (C) 2008, 2010-2024 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 AC_DEFUN([gl_FUNC_MBSINIT],
10 [
11 AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
12 AC_REQUIRE([AC_CANONICAL_HOST])
13
14 AC_REQUIRE([AC_TYPE_MBSTATE_T])
15 gl_MBSTATE_T_BROKEN
16
17 AC_CHECK_FUNCS_ONCE([mbsinit])
18 if test $ac_cv_func_mbsinit = no; then
19 HAVE_MBSINIT=0
20 AC_CHECK_DECLS([mbsinit],,, [[
21 #include <wchar.h>
22 ]])
23 if test $ac_cv_have_decl_mbsinit = yes; then
24 dnl On Minix 3.1.8, the system's <wchar.h> declares mbsinit() although
25 dnl it does not have the function. Avoid a collision with gnulib's
26 dnl replacement.
27 REPLACE_MBSINIT=1
28 fi
29 else
30 if test $REPLACE_MBSTATE_T = 1; then
31 REPLACE_MBSINIT=1
32 else
33 dnl On mingw, mbsinit() always returns 1, which is inappropriate for
34 dnl states produced by mbrtowc() for an incomplete multibyte character
35 dnl in multibyte locales.
36 case "$host_os" in
37 mingw* | windows*) REPLACE_MBSINIT=1 ;;
38 esac
39 fi
40 fi
41 ])
42
43 # Prerequisites of lib/mbsinit.c.
44 AC_DEFUN([gl_PREREQ_MBSINIT], [
45 :
46 ])