Debian Codegraph @

m4/mkdir.m4

raw
1 # mkdir.m4
2 # serial 20
3 dnl Copyright (C) 2001, 2003-2004, 2006, 2008-2024 Free Software Foundation, Inc.
4 dnl This file is free software; the Free Software Foundation
5 dnl gives unlimited permission to copy and/or distribute it,
6 dnl with or without modifications, as long as this notice is preserved.
7 dnl This file is offered as-is, without any warranty.
8
9 # On some systems, mkdir ("foo/", 0700) fails because of the trailing slash.
10 # On others, mkdir ("foo/./", 0700) mistakenly succeeds.
11 # On such systems, arrange to use a wrapper function.
12 AC_DEFUN([gl_FUNC_MKDIR],
13 [dnl
14 AC_REQUIRE([gl_SYS_STAT_H_DEFAULTS])
15 AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
16 AC_CHECK_HEADERS_ONCE([unistd.h])
17 AC_CACHE_CHECK([whether mkdir handles trailing slash],
18 [gl_cv_func_mkdir_trailing_slash_works],
19 [rm -rf conftest.dir
20 AC_RUN_IFELSE(
21 [AC_LANG_PROGRAM([[
22 #include <sys/types.h>
23 #include <sys/stat.h>
24 ]GL_MDA_DEFINES],
25 [[return mkdir ("conftest.dir/", 0700);]])],
26 [gl_cv_func_mkdir_trailing_slash_works=yes],
27 [gl_cv_func_mkdir_trailing_slash_works=no],
28 [case "$host_os" in
29 # Guess yes on Linux systems.
30 linux-* | linux) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
31 # Guess yes on systems that emulate the Linux system calls.
32 midipix*) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
33 # Guess yes on glibc systems.
34 *-gnu* | gnu*) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
35 # Guess yes on MSVC, no on mingw.
36 windows*-msvc*) gl_cv_func_mkdir_trailing_slash_works="guessing yes" ;;
37 mingw* | windows*) AC_EGREP_CPP([Known], [
38 #ifdef _MSC_VER
39 Known
40 #endif
41 ],
42 [gl_cv_func_mkdir_trailing_slash_works="guessing yes"],
43 [gl_cv_func_mkdir_trailing_slash_works="guessing no"])
44 ;;
45 # If we don't know, obey --enable-cross-guesses.
46 *) gl_cv_func_mkdir_trailing_slash_works="$gl_cross_guess_normal" ;;
47 esac
48 ])
49 rm -rf conftest.dir
50 ])
51 case "$gl_cv_func_mkdir_trailing_slash_works" in
52 *yes) ;;
53 *)
54 REPLACE_MKDIR=1
55 ;;
56 esac
57
58 AC_CACHE_CHECK([whether mkdir handles trailing dot],
59 [gl_cv_func_mkdir_trailing_dot_works],
60 [rm -rf conftest.dir
61 AC_RUN_IFELSE(
62 [AC_LANG_PROGRAM([[
63 #include <sys/types.h>
64 #include <sys/stat.h>
65 ]GL_MDA_DEFINES],
66 [[return !mkdir ("conftest.dir/./", 0700);]])],
67 [gl_cv_func_mkdir_trailing_dot_works=yes],
68 [gl_cv_func_mkdir_trailing_dot_works=no],
69 [case "$host_os" in
70 # Guess yes on glibc systems.
71 *-gnu* | gnu*) gl_cv_func_mkdir_trailing_dot_works="guessing yes" ;;
72 # Guess yes on musl systems.
73 *-musl*) gl_cv_func_mkdir_trailing_dot_works="guessing yes" ;;
74 # Guess yes on systems that emulate the Linux system calls.
75 midipix*) gl_cv_func_mkdir_trailing_dot_works="guessing yes" ;;
76 # Guess no on native Windows.
77 mingw* | windows*) gl_cv_func_mkdir_trailing_dot_works="guessing no" ;;
78 # If we don't know, obey --enable-cross-guesses.
79 *) gl_cv_func_mkdir_trailing_dot_works="$gl_cross_guess_normal" ;;
80 esac
81 ])
82 rm -rf conftest.dir
83 ]
84 )
85 case "$gl_cv_func_mkdir_trailing_dot_works" in
86 *yes) ;;
87 *)
88 REPLACE_MKDIR=1
89 AC_DEFINE([FUNC_MKDIR_DOT_BUG], [1], [Define to 1 if mkdir mistakenly
90 creates a directory given with a trailing dot component.])
91 ;;
92 esac
93 ])