Debian Codegraph @

m4/intmax_t.m4

raw
1 # intmax_t.m4
2 # serial 9
3 dnl Copyright (C) 1997-2004, 2006-2007, 2009-2024 Free Software Foundation,
4 dnl Inc.
5 dnl This file is free software; the Free Software Foundation
6 dnl gives unlimited permission to copy and/or distribute it,
7 dnl with or without modifications, as long as this notice is preserved.
8 dnl This file is offered as-is, without any warranty.
9
10 dnl From Paul Eggert.
11
12 AC_PREREQ([2.53])
13
14 # Define intmax_t to 'long' or 'long long'
15 # if it is not already defined in <stdint.h> or <inttypes.h>.
16
17 AC_DEFUN([gl_AC_TYPE_INTMAX_T],
18 [
19 dnl For simplicity, we assume that a header file defines 'intmax_t' if and
20 dnl only if it defines 'uintmax_t'.
21 AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
22 AC_REQUIRE([gl_AC_HEADER_STDINT_H])
23 if test $gl_cv_header_inttypes_h = no && test $gl_cv_header_stdint_h = no; then
24 AC_DEFINE_UNQUOTED([intmax_t], [long long],
25 [Define to long or long long if <inttypes.h> and <stdint.h> don't define.])
26 else
27 AC_DEFINE([HAVE_INTMAX_T], [1],
28 [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
29 fi
30 ])
31
32 dnl An alternative would be to explicitly test for 'intmax_t'.
33
34 AC_DEFUN([gt_AC_TYPE_INTMAX_T],
35 [
36 AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
37 AC_REQUIRE([gl_AC_HEADER_STDINT_H])
38 AC_CACHE_CHECK([for intmax_t], [gt_cv_c_intmax_t],
39 [AC_COMPILE_IFELSE(
40 [AC_LANG_PROGRAM(
41 [[
42 #include <stddef.h>
43 #include <stdlib.h>
44 #if HAVE_STDINT_H_WITH_UINTMAX
45 #include <stdint.h>
46 #endif
47 #if HAVE_INTTYPES_H_WITH_UINTMAX
48 #include <inttypes.h>
49 #endif
50 ]],
51 [[intmax_t x = -1; return !x;]])],
52 [gt_cv_c_intmax_t=yes],
53 [gt_cv_c_intmax_t=no])])
54 if test $gt_cv_c_intmax_t = yes; then
55 AC_DEFINE([HAVE_INTMAX_T], [1],
56 [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
57 else
58 AC_DEFINE_UNQUOTED([intmax_t], [long long],
59 [Define to long or long long if <stdint.h> and <inttypes.h> don't define.])
60 fi
61 ])