| 1 |
TEMPLATE = aux |
| 2 |
|
| 3 |
load(qt_build_paths) |
| 4 |
|
| 5 |
qtPrepareTool(LRELEASE, lrelease) |
| 6 |
qtPrepareTool(LCONVERT, lconvert) |
| 7 |
qtPrepareTool(LUPDATE, lupdate) |
| 8 |
LUPDATE += -locations relative -no-ui-lines |
| 9 |
|
| 10 |
TS_TARGETS = |
| 11 |
|
| 12 |
# meta target name, target name, project files, ts files |
| 13 |
defineTest(addTsTarget) { |
| 14 |
dir = $$section(PWD, /, 0, -3) |
| 15 |
for(p, 3): \ |
| 16 |
exists($$dir/$$p): \ |
| 17 |
pros += -pro-out $$shell_quote($$shadowed($$dir/$$dirname(p))) $$p |
| 18 |
isEmpty(pros): return() |
| 19 |
cv = $${2}.commands |
| 20 |
$$cv = cd $$dir && $$LUPDATE $$pros -ts $$4 |
| 21 |
export($$cv) |
| 22 |
dv = $${1}.depends |
| 23 |
$$dv += $$2 |
| 24 |
export($$dv) |
| 25 |
TS_TARGETS += $$1 $$2 |
| 26 |
export(TS_TARGETS) |
| 27 |
} |
| 28 |
|
| 29 |
TS_MODULES = |
| 30 |
|
| 31 |
# target basename, project files |
| 32 |
defineTest(addTsTargets) { |
| 33 |
files = $$files($$PWD/$${1}_??.ts) $$files($$PWD/$${1}_??_??.ts) |
| 34 |
for(file, files) { |
| 35 |
lang = $$replace(file, .*_((.._)?..)\\.ts$, \\1) |
| 36 |
addTsTarget(ts-$$lang, ts-$$1-$$lang, $$2, $$file) |
| 37 |
} |
| 38 |
addTsTarget(ts-untranslated, ts-$$1-untranslated, $$2, $$PWD/$${1}_untranslated.ts) |
| 39 |
addTsTarget(ts-all, ts-$$1-all, $$2, $$PWD/$${1}_untranslated.ts $$files) |
| 40 |
TS_MODULES += $$1 |
| 41 |
export(TS_MODULES) |
| 42 |
} |
| 43 |
|
| 44 |
addTsTargets(qtbase, qtbase/src/src.pro \ |
| 45 |
qtactiveqt/src/src.pro \ # just 4 strings from QAxSelect |
| 46 |
qtimageformats/src/src.pro \ # just 10 error messages from tga reader. uses bad context. |
| 47 |
) |
| 48 |
addTsTargets(qtdeclarative, qtdeclarative/src/src.pro) |
| 49 |
addTsTargets(qtquickcontrols, qtquickcontrols/src/src.pro) |
| 50 |
addTsTargets(qtquickcontrols2, qtquickcontrols2/src/src.pro) |
| 51 |
addTsTargets(qtmultimedia, qtmultimedia/src/src.pro) |
| 52 |
addTsTargets(qtscript, qtscript/src/src.pro) |
| 53 |
#addTsTargets(qtsvg, qtsvg/src/src.pro) # empty |
| 54 |
addTsTargets(qtxmlpatterns, qtxmlpatterns/src/src.pro) |
| 55 |
#addTsTargets(qtwebkit, qtwebkit/WebKit.pro) # messages from test browser only |
| 56 |
|
| 57 |
#addTsTargets(qt3d, qt3d/src/src.pro) # empty except one dubious error message |
| 58 |
addTsTargets(qtconnectivity, qtconnectivity/src/src.pro) |
| 59 |
#addTsTargets(qtdocgallery, qtdocgallery/src/src.pro) # dead module |
| 60 |
#addTsTargets(qtfeedback, qtfeedback/src/src.pro) # empty |
| 61 |
#addTsTargets(qtjsondb, qtjsondb/src/src.pro) # dead module, just 3 error messages |
| 62 |
addTsTargets(qtlocation, qtlocation/src/src.pro) |
| 63 |
#addTsTargets(qtpim, qtpim/src/src.pro) # not part of 5.0 |
| 64 |
#addTsTargets(qtsensors, qtsensors/src/src.pro) # empty |
| 65 |
#addTsTargets(qtsystems, qtsystems/src/src.pro) # not part of 5.0 |
| 66 |
addTsTargets(qtwebsockets, qtwebsockets/src/src.pro) |
| 67 |
addTsTargets(qtserialport, qtserialport/src/src.pro) |
| 68 |
addTsTargets(qtwebengine, qtwebengine/src/src.pro) |
| 69 |
|
| 70 |
addTsTargets(designer, qttools/src/designer/designer.pro) |
| 71 |
addTsTargets(linguist, qttools/src/linguist/linguist/linguist.pro) |
| 72 |
addTsTargets(assistant, qttools/src/assistant/assistant/assistant.pro) # add qcollectiongenerator here as well? |
| 73 |
addTsTargets(qt_help, qttools/src/assistant/help/help.pro) |
| 74 |
#addTsTargets(qmlscene, qtdeclarative/tools/qmlscene/qmlscene.pro) # almost empty due to missing tr() |
| 75 |
|
| 76 |
check-ts.commands = (cd $$PWD && perl check-ts.pl) |
| 77 |
check-ts.depends = ts-all |
| 78 |
|
| 79 |
isEqual(QMAKE_DIR_SEP, /) { |
| 80 |
commit-ts.commands = \ |
| 81 |
cd $$PWD/..; \ |
| 82 |
git add -N \"translations/*_??.ts\" && \ |
| 83 |
for f in `git diff-files --name-only translations/*_??.ts`; do \ |
| 84 |
$$LCONVERT -locations none -i \$\$f -o \$\$f; \ |
| 85 |
done; \ |
| 86 |
git add \"translations/*_??.ts\" && git commit |
| 87 |
} else { |
| 88 |
wd = $$replace(PWD, /, \\)\\.. |
| 89 |
commit-ts.commands = \ |
| 90 |
cd $$wd && \ |
| 91 |
git add -N \"translations/*_??.ts\" && \ |
| 92 |
for /f usebackq %%f in (`git diff-files --name-only translations/*_??.ts`) do \ |
| 93 |
$$LCONVERT -locations none -i %%f -o %%f $$escape_expand(\\n\\t) \ |
| 94 |
cd $$wd && git add \"translations/*_??.ts\" && git commit |
| 95 |
} |
| 96 |
|
| 97 |
ts.commands = \ |
| 98 |
@echo \"The \'ts\' target has been removed in favor of more fine-grained targets.\" && \ |
| 99 |
echo \"Use \'ts-<target>-<lang>\' or \'ts-<lang>\' instead. To add a language,\" && \ |
| 100 |
echo \"use \'untranslated\' for <lang>, rename the files and re-run \'qmake\'.\" |
| 101 |
|
| 102 |
QMAKE_EXTRA_TARGETS += $$unique(TS_TARGETS) ts commit-ts check-ts |
| 103 |
|
| 104 |
updateqm.input = TRANSLATIONS |
| 105 |
updateqm.output = $$MODULE_BASE_OUTDIR/translations/${QMAKE_FILE_BASE}.qm |
| 106 |
updateqm.commands = $$LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT} |
| 107 |
silent:updateqm.commands = @echo lrelease ${QMAKE_FILE_IN} && $$updateqm.commands |
| 108 |
updateqm.depends = $$LRELEASE_EXE |
| 109 |
updateqm.name = LRELEASE ${QMAKE_FILE_IN} |
| 110 |
updateqm.CONFIG += no_link no_clean target_predeps |
| 111 |
QMAKE_EXTRA_COMPILERS += updateqm |
| 112 |
|
| 113 |
# generate empty _en.ts files |
| 114 |
empty_ts = "<TS></TS>" |
| 115 |
for (module_name, TS_MODULES) { |
| 116 |
write_file($$OUT_PWD/$${module_name}_en.ts, empty_ts)|error("Aborting.") |
| 117 |
} |
| 118 |
write_file($$OUT_PWD/qt_en.ts, empty_ts)|error("Aborting.") |
| 119 |
|
| 120 |
TRANSLATIONS = $$files(*.ts) |
| 121 |
!isEqual(OUT_PWD, $$PWD): TRANSLATIONS += $$files($$OUT_PWD/*.ts) |
| 122 |
|
| 123 |
translations.path = $$[QT_INSTALL_TRANSLATIONS] |
| 124 |
translations.files = $$TRANSLATIONS |
| 125 |
translations.files ~= s,\\.ts$,.qm,g |
| 126 |
translations.files ~= s,^$$re_escape($$OUT_PWD),,g |
| 127 |
translations.files ~= s,^,$$MODULE_BASE_OUTDIR/translations/,g |
| 128 |
translations.CONFIG += no_check_exist |
| 129 |
INSTALLS += translations |
| 130 |
|
| 131 |
QMAKE_DISTCLEAN += $$translations.files |