Debian Codegraph @

data/sh.sor

raw
1 #
2 # Regular number to text transducer for Serbian (Cyrillic) written in Soros
3 # Copyright (c) Goran Rakic <[email protected]> 2009.
4 #
5 # Released under Creative Commons 3.0 Attribution - Share Alike license
6 # and relicensed under GNU Lesser General Public License as published by
7 # the Free Software Foundation, either version 3 of the License, or
8 # (at your option) any later version.
9 #
10 # Visit http://numbertext.org for more info on Soros language and syntax
11 #
12
13 (\d{1,3})\.([\d.,]+) $(\1\2)
14
15 ^0 nula
16 1 jedan
17 2 dva
18 3 tri
19 4 četiri
20 5 pet
21 6 šest
22 7 sedam
23 8 osam
24 9 devet
25 10 deset
26
27 11 jedanaest
28 14 četrnaest
29 16 šesnaest
30 1(\d) $1naest
31
32 4(\d) četrdeset[ $1]
33 5(\d) pedeset[ $1]
34 6(\d) šezdeset[ $1]
35 9(\d) devedeset[ $1]
36 (\d)(\d) $1deset[ $2]
37
38 1(\d\d) sto[ $1]
39 2(\d\d) dvesta[ $1]
40 3(\d\d) trista[ $1]
41 (\d)(\d\d) $1sto[ $2]
42
43 1(\d\d\d) hiljadu[ $1]
44 2(\d\d\d) dve hiljade[ $1]
45 ([34])(\d\d\d) $1 hiljade[ $2]
46 (\d{0,1})1(\d)(\d\d\d) $(\11\2) hiljada[ $3]
47 (\d{1,2})1(\d\d\d) $(\10) jedna hiljada[ $2]
48 (\d{1,2})2(\d\d\d) $(\10) dve hiljade[ $2]
49 (\d{1,2})([34])(\d\d\d) $(\10) $2 hiljade[ $3]
50 (\d{1,3})(\d\d\d) $1 hiljada[ $2]
51
52 1(\d{6}) milion[ $1]
53 (\d{0,4})1(\d)(\d{6}) $(\11\2) miliona[ $3]
54 (\d{1,5})1(\d{6}) $(\10) jedan milion[ $2]
55 (\d{1,3})(\d{6}) $1 miliona[ $2]
56
57 1(\d{9}) milijarda[ $1]
58 2(\d{9}) dve milijarde[ $1]
59 ([34])(\d{9}) $1 milijarde[ $2]
60 (\d{1,2})0(\d{9}) $(\10) milijardi[ $2]
61 (\d{0,1})1(\d)(\d{9}) $(\11\2) milijardi[ $3]
62 (\d{1,2})1(\d{9}) $(\10) jedna milijarda[ $2]
63 (\d{1,2})2(\d{9}) $(\10) dve milijarde[ $2]
64 (\d{1,2})([34])(\d{9}) $(\10) $2 milijarde[ $3]
65 (\d{1,3})(\d{9}) $1 milijarde[ $2]
66
67 1(\d{12}) bilion[ $1]
68 (\d{0,4})1(\d)(\d{12}) $(\11\2) biliona[ $3]
69 (\d{1,5})1(\d{12}) $(\10) jedan bilion[ $2]
70 (\d{1,6})(\d{12}) $1 biliona[ $2]
71
72 1(\d{18}) trilion[ $1]
73 (\d{0,4})1(\d)(\d{18}) $(\11\2) triliona[ $3]
74 (\d{1,5})1(\d{18}) $(\10) jedan trilion[ $2]
75 (\d{1,6})(\d{18}) $1 triliona[ $2]
76
77 1(\d{24}) kvadrilion[ $1]
78 (\d{0,4})1(\d)(\d{24}) $(\11\2) kvadriliona[ $3]
79 (\d{1,5})1(\d{24}) $(\10) jedan kvadrilion[ $2]
80 (\d{1,6})(\d{24}) $1 kvadriliona[ $2]
81
82 1(\d{30}) kvintilion[ $1]
83 (\d{0,4})1(\d)(\d{30}) $(\11\2) kvintiliona[ $3]
84 (\d{1,5})1(\d{30}) $(\10) jedan kvintilion[ $2]
85 (\d{1,6})(\d{30}) $1 kvintiliona[ $2]
86
87 1(\d{36}) sekstilion[ $1]
88 (\d{0,4})1(\d)(\d{36}) $(\11\2) sekstiliona[ $3]
89 (\d{1,5})1(\d{36}) $(\10) jedan sekstilion[ $2]
90 (\d{1,6})(\d{36}) $1 sekstiliona[ $2]
91
92 [-−](\d+) minus $1
93
94 # Decimal code by https://twitter.com/_uranium_
95 "([-−]?\d+)," $1| koma
96 "([-−]?\d+,)([^0]\d)" $1 $2
97 "([-−]?\d+,\d*[1-9]?)0+$" $1
98 "([-−]?\d+,)(\d)(\d)(\d)" $1| |$2 |$3 |$4
99 "([-−]?\d+,\d*)(\d)" $1 |$2
100
101 == ordinal-number ==
102
103 (\d+) \1.
104
105 == help ==
106
107 "" |$(1)|, |$(2)|, |$(3)|\n$(help ordinal-number)
108 (.*) \1: |$(\1 1)|, |$(\1 2)|, |$(\1 3)|\n