Debian Codegraph @

data/da.sor

raw
1 ^0 nul
2 1$ en
3 1 et
4 2 to
5 3 tre
6 4 fire
7 5 fem
8 6 seks
9 7 syv
10 8 otte
11 9 ni
12 10 ti
13
14 11 elleve
15 12 tolv
16 13 tretten
17 14 fjorten
18 15 femten
19 16 seksten
20 17 sytten
21 18 atten
22 19 nitten
23
24 20 tyve
25 30 tredive
26 40 fyrre
27 50 halvtreds
28 60 tres
29 70 halvfjerds
30 80 firs
31 90 halvfems
32
33 (\d)(\d) $2|og$(\10)
34 (\d)(\d\d) $1 hundrede[ og $2]
35 (\d{1,3})(\d{3}) $1 tusind[ og $2]
36
37 a:1,0+
38 a:\d+,0+ er
39 a:1,(\d+) " og $1"
40 a:\d+,(\d+) "er og $1"
41
42 (\d{1,3})(\d{6}) $1| million$(a:\1,\2)
43 (\d{1,3})(\d{9}) $1| milliard$(a:\1,\2)
44 (\d{1,3})(\d{12}) $1| billion$(a:\1,\2)
45 (\d{1,3})(\d{15}) $1| billiard$(a:\1,\2)
46 (\d{1,3})(\d{18}) $1| trillion$(a:\1,\2)
47 (\d{1,3})(\d{21}) $1| trilliard$(a:\1,\2)
48 (\d{1,3})(\d{24}) $1| kvadrillion$(a:\1,\2)
49
50 # negative number
51
52 [-−](\d+) minus |$1
53
54 # decimals
55
56 ([-−]?\d+)[.,] $1| komma
57 "([-−]?\d+[.,]0*)(\d+)" $1 |$2
58 ([-−]?\d+[.,]\d*)(\d) $1| |$2
59
60 # currency
61
62 # unit/subunit singular/plural
63
64 us:([^,]*),([^,]*),([^,]*),([^,]*) \1
65 up:([^,]*),([^,]*),([^,]*),([^,]*) \2
66 ss:([^,]*),([^,]*),([^,]*),([^,]*) \3
67 sp:([^,]*),([^,]*),([^,]*),([^,]*) \4
68
69 CHF:(\D+) $(\1: schweizisk franc, schweizisk franc, centime, centimes)
70 CNY:(\D+) $(\1: renminbi yuan, renminbi yuan, fen, fen)
71 DKK:(\D+) $(\1: dansk krone, danske kroner, øre, øre)
72 EUR:(\D+) $(\1: euro, euro, cent, cent)
73 GBP:(\D+) $(\1: pund sterling, pund sterling, penny, pence)
74 ISK:(\D+) $(\1: islandsk krone, islandske kroner, eyrir, aurar)
75 JPY:(\D+) $(\1: yen, yen, sen, sen)
76 SEK:(\D+) $(\1: svensk krone, svenske kroner, öre, öre)
77 USD:(\D+) $(\1: US dollar, US dollar, cent, cent)
78
79 "([A-Z]{3}) ([-−]?1)([.,]00?)?" $2$(\1:us)
80 "([A-Z]{3}) ([-−]?\d+)([.,]00?)?" $2$(\1:up)
81
82 "(CNY [-−]?\d+)[.,]10?" $1 $2 jiao
83 "(CNY [-−]?\d+)[.,](\d)0?" $1 $2 jiao
84 "(CNY [-−]?\d+[.,]\d)1" $1 $2 fen
85 "(CNY [-−]?\d+[.,]\d)(\d)" $1 $2 fen
86
87 "(([A-Z]{3}) [-−]?\d+)[.,](01)" $1 |$(1)$(\2:ss)
88 "(([A-Z]{3}) [-−]?\d+)[.,](\d)" $1 |$(\30)$(\2:sp)
89 "(([A-Z]{3}) [-−]?\d+)[.,](\d\d)" $1 |$3$(\2:sp)
90
91 == ordinal ==
92
93 ([-−]?\d+) $(ordinal |$1)
94
95 nul nulte # 0
96 en først # 1
97 "(.*) en" \1 først # 1
98 (.*)to \1anden # 2
99 (.*)tre \1tredje # 3
100 (.*)fire \1fjerde # 4
101 (.*(fem|ellev|tolv|ard|on))(e|er)? \1te # 5, 11, 12, 10^6, 10^9 etc.
102 (.*)seks \1sjette # 6
103 (.*)tres \1tressende # 60
104 (.*(syv|ott|ni|ti|tyv|trediv|fyrr|s))e? \1ende # 7, 8, 9, 10, 20, 30, 40, 50, 70, 80, 90
105 (.*en) \1de # 13-19
106 (.*tusind) \1e # 1000 etc.
107 (.*) \1 # 100, etc.
108
109 == ordinal-number ==
110
111 (\d+) \1.
112
113 == help ==
114
115 "" |$(1)|, |$(2)|, |$(3)|\n$(help ordinal)$(help ordinal-number)
116 (ordinal(-number)?) \1: |$(\1 1)|, |$(\1 2)|, |$(\1 3)|\n