Debian Codegraph @

data/hr.sor

raw
1 #
2 # Regular number to text transducer for Serbian (Cyrillic) written in Soros
3 # Copyright (c) Goran Rakic <[email protected]> 2009.
4 # Modified and translated for Croatian by Mihovil Stanic <[email protected]> 2014.
5 #
6 # Released under Creative Commons 3.0 Attribution - Share Alike license
7 # and relicensed under GNU Lesser General Public License as published by
8 # the Free Software Foundation, either version 3 of the License, or
9 # (at your option) any later version.
10 #
11 # Visit http://numbertext.org for more info on Soros language and syntax
12 #
13
14 (\d{1,3})\.([\d.,]+) $(\1\2)
15
16 ^0 nula
17 1 jedan
18 2 dva
19 3 tri
20 4 četiri
21 5 pet
22 6 šest
23 7 sedam
24 8 osam
25 9 devet
26 10 deset
27
28 11 jedanaest
29 14 četrnaest
30 16 šesnaest
31 1(\d) $1naest
32
33 4(\d) četrdeset[ $1]
34 5(\d) pedeset[ $1]
35 6(\d) šezdeset[ $1]
36 9(\d) devedeset[ $1]
37 (\d)(\d) $1deset[ $2]
38
39 1(\d\d) sto[ $1]
40 2(\d\d) dvjesto[ $1]
41 3(\d\d) tristo[ $1]
42 (\d)(\d\d) $1sto[ $2]
43
44 1(\d\d\d) tisuću[ $1]
45 2(\d\d\d) dvije tisuće[ $1]
46 ([34])(\d\d\d) $1 tisuće[ $2]
47 (\d{0,1})1(\d)(\d\d\d) $(\11\2) tisuća[ $3]
48 (\d{1,2})1(\d\d\d) $(\10) jedna tisuća[ $2]
49 (\d{1,2})2(\d\d\d) $(\10) dvije tisuće[ $2]
50 (\d{1,2})([34])(\d\d\d) $(\10) $2 tisuće[ $3]
51 (\d{1,3})(\d\d\d) $1 tisuća[ $2]
52
53 1(\d{6}) milion[ $1]
54 (\d{0,4})1(\d)(\d{6}) $(\11\2) miliona[ $3]
55 (\d{1,5})1(\d{6}) $(\10) jedan milion[ $2]
56 (\d{1,3})(\d{6}) $1 miliona[ $2]
57
58 1(\d{9}) milijarda[ $1]
59 2(\d{9}) dvije milijarde[ $1]
60 ([34])(\d{9}) $1 milijarde[ $2]
61 (\d{1,2})0(\d{9}) $(\10) milijardi[ $2]
62 (\d{0,1})1(\d)(\d{9}) $(\11\2) milijardi[ $3]
63 (\d{1,2})1(\d{9}) $(\10) jedna milijarda[ $2]
64 (\d{1,2})2(\d{9}) $(\10) dvije milijarde[ $2]
65 (\d{1,2})([34])(\d{9}) $(\10) $2 milijarde[ $3]
66 (\d{1,3})(\d{9}) $1 milijarde[ $2]
67
68 1(\d{12}) bilijun[ $1]
69 (\d{0,4})1(\d)(\d{12}) $(\11\2) bilijuna[ $3]
70 (\d{1,5})1(\d{12}) $(\10) jedan bilijun[ $2]
71 (\d{1,6})(\d{12}) $1 bilijuna[ $2]
72
73 1(\d{18}) trilijun[ $1]
74 (\d{0,4})1(\d)(\d{18}) $(\11\2) trilijuna[ $3]
75 (\d{1,5})1(\d{18}) $(\10) jedan trilijun[ $2]
76 (\d{1,6})(\d{18}) $1 trilijuna[ $2]
77
78 1(\d{24}) kvadrilijun[ $1]
79 (\d{0,4})1(\d)(\d{24}) $(\11\2) kvadrilijuna[ $3]
80 (\d{1,5})1(\d{24}) $(\10) jedan kvadrilijun[ $2]
81 (\d{1,6})(\d{24}) $1 kvadrilijuna[ $2]
82
83 1(\d{30}) kvintilijun[ $1]
84 (\d{0,4})1(\d)(\d{30}) $(\11\2) kvintilijuna[ $3]
85 (\d{1,5})1(\d{30}) $(\10) jedan kvintilijun[ $2]
86 (\d{1,6})(\d{30}) $1 kvintilijuna[ $2]
87
88 1(\d{36}) sekstilijun[ $1]
89 (\d{0,4})1(\d)(\d{36}) $(\11\2) sekstilijuna[ $3]
90 (\d{1,5})1(\d{36}) $(\10) jedan sekstilijun[ $2]
91 (\d{1,6})(\d{36}) $1 sekstilijuna[ $2]
92
93 # negative number
94
95 [-−] minus
96 [-−](\d+) minus |$1
97
98 # Decimal code by https://twitter.com/_uranium_
99 "([-−]?\d+)[.,]" $1| zarez
100 "([-−]?\d+[.,])([^0]\d)" $1 $2
101 "([-−]?\d+[.,]\d*[1-9]?)0+$" $1
102 "([-−]?\d+[.,])(\d)(\d)(\d)" $1| |$2 |$3 |$4
103 "([-−]?\d+[.,]\d*)(\d)" $1 |$2
104
105 # currency
106
107 # unit/subunit
108
109 us:([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*) \1
110 up:([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*) \2
111 ug:([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*) \3
112 ss:([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*) \4
113 sp:([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*) \5
114 sg:([^,]*),([^,]*),([^,]*),([^,]*),([^,]*),([^,]*) \6
115
116 HRK:(\D+) $(\1: kuna, kune, kuna, lipa, lipe, lipa) #ff
117 DKK:(\D+) $(\1: kruna, krune, kruna, ora, ore, ora) #ff
118 SEK:(\D+) $(\1: kruna, krune, kruna, ora, ore, ora) #ff
119 CZK:(\D+) $(\1: kruna, krune, kruna, haler, halera, halera) #fm
120 HUF:(\D+) $(\1: forinta, forinte, forinti, filer, filera, filera) #fm
121 GBP:(\D+) $(\1: funta, funte, funti, peni, penija, penija) #fm
122 BAM:(\D+) $(\1: konvertibilna marka, konvertibilne marke, konvertibilnih marki, fening, feninga, feninga) #fm
123 BGN:(\D+) $(\1: lev, leva, leva, stotinka, stotinke, stotinki) #mf
124 RSD:(\D+) $(\1: dinar, dinara, dinara, para, pare, para) #mf
125 RON:(\D+) $(\1: leu, leu, leu, ban, bana, bana) #mm
126 CHF:(\D+) $(\1: franak, franka, franaka, centim, centima, centima) #mm
127 EUR:(\D+) $(\1: euro, eura, eura, cent, centa, centa) #mm
128 USD:(\D+) $(\1: dolar, dolara, dolara, cent, centa, centa) #mm
129 PLN:(\D+) $(\1: zlot, zlota, zlota, groš, groša, groša) #mm
130
131 # Covers cases where currency sign is after numbers or different position
132 "(.*) kn" $(HRK \1)
133 "(.*) €" $(EUR \1)
134 "(.*)€" $(EUR \1)
135 "€(.*)" $(EUR \1)
136 "€ (.*)" $(EUR \1)
137 "(.*) Ft" $(HUF \1)
138 "(.*) din." $(RSD \1)
139 "\$(.*)" $(USD \1)
140 "\$ (.*)" $(USD \1)
141 "(.*) \$" $(USD \1)
142 "KM(.*)" $(BAM \1)
143 "£(.*)" $(GBP \1)
144 "(.*) HRK" $(HRK \1)
145 "(.*) DKK" $(DKK \1)
146 "(.*) SEK" $(SEK \1)
147 "(.*) CZK" $(CZK \1)
148 "(.*) HUF" $(HUF \1)
149 "(.*) GBP" $(GBP \1)
150 "(.*) BAM" $(BAM \1)
151 "(.*) BGN" $(BGN \1)
152 "(.*) RSD" $(RSD \1)
153 "(.*) RON" $(RON \1)
154 "(.*) CHF" $(CHF \1)
155 "(.*) EUR" $(EUR \1)
156 "(.*) USD" $(USD \1)
157 "(.*) PLN" $(PLN \1)
158
159 "(HRK|DKK|SEK|CZK|HUF|GBP|BAM) ([-−]?1)([.,]00?)?" jedna$(\1:us) #female, for 1
160 "(HRK|DKK|SEK|CZK|HUF|GBP|BAM) ([-−]?2)([.,]00?)?" dvije$(\1:up) #female, for 2
161 "(HRK|DKK|SEK|CZK|HUF|GBP|BAM) ([02-9])1([.,]00?)?" $(\20) jedna$(\1:us) #female, for numbers from 21-91 ending with 1
162 "(HRK|DKK|SEK|CZK|HUF|GBP|BAM) ([02-9])2([.,]00?)?" $(\20) dvije$(\1:up) #female, for numbers from 22-92 ending with 2
163 "(HRK|DKK|SEK|CZK|HUF|GBP|BAM) ([-−]?\d*)([02-9])1([.,]00?)?" $(\200) $(\30) jedna$(\1:us) #female, for numbers >100 ending with 1 but not 11
164 "(HRK|DKK|SEK|CZK|HUF|GBP|BAM) ([-−]?\d*)([02-9])2([.,]00?)?" $(\200) $(\30) dvije$(\1:up) #female, for numbers >100 ending with 2 but not 12
165 "([A-Z]{3}) ([-−]?1)([.,]00?)?" $2|$(\1:us)
166 "([A-Z]{3}) ([-−]?\d*[02-9]1)([.,]00?)?" $2|$(\1:us)
167 "([A-Z]{3}) ([-−]?[234])([.,]00?)?" $2|$(\1:up)
168 "([A-Z]{3}) ([-−]?\d*[02-9][234])([.,]00?)?" $2|$(\1:up)
169 "([A-Z]{3}) ([-−]?\d+)([.,]00?)?" $2|$(\1:ug)
170
171 "((HRK|DKK|SEK|BGN|RSD) [-−]?\d+)[.,]([02-9])1" $1 $(\30) jedna $(\2:ss) #decimal, female, ending with 1 but not 11
172 "((HRK|DKK|SEK|BGN|RSD) [-−]?\d+)[.,]([02-9])2" $1 $(\30) dvije $(\2:sp) #decimal, female, ending with 2 but not 12
173 "(([A-Z]{3}) [-−]?\d+)[.,](01)" $1 |$(1)$(\2:ss)
174 "(([A-Z]{3}) [-−]?\d+)[.,]([02-9]1)" $1 |$3$(\2:ss)
175 "(([A-Z]{3}) [-−]?\d+)[.,]([02-9][234])" $1 |$3$(\2:sp)
176 "(([A-Z]{3}) [-−]?\d+)[.,](\d)" $1 |$(\30)$(\2:sg)
177 "(([A-Z]{3}) [-−]?\d+)[.,](\d\d)" $1 |$3$(\2:sg)
178
179 == ordinal-number ==
180
181 (\d+) \1.
182
183 == help ==
184
185 "" |$(1)|, |$(2)|, |$(3)|\n$(help ordinal-number)
186 (.*) \1: |$(\1 1)|, |$(\1 2)|, |$(\1 3)|\n