Debian Codegraph @

data/de.sor

raw
1 ^0$ null
2 1$ eins
3 1 ein
4 2 zwei
5 3 drei
6 4 vier
7 5 fünf
8 6 sechs
9 7 sieben
10 8 acht
11 9 neun
12 10 zehn
13 11 elf
14 12 zwölf
15 16 sechzehn
16 17 siebzehn
17 1(\d) $1zehn
18 2(\d) [$1und]zwanzig
19 3(\d) [$1und]dreissig # [:de-CH:] [:de-LI:]
20 3(\d) [$1und]dreißig
21 6(\d) [$1und]sechzig
22 7(\d) [$1und]siebzig
23 (\d)(\d) [$2und]$1zig
24 (\d)(\d\d) $1hundert$2
25 (\d{1,3})(\d{3}) $1tausend$2
26 1(\d{6}) eine Million[ $1]
27 (\d{1,3})(\d{6}) $1 Millionen[ $2]
28 1(\d{9}) eine Milliarde[ $1]
29 (\d{1,3})(\d{9}) $1 Milliarden[ $2]
30 1(\d{12}) eine Billion[ $1]
31 (\d{1,3})(\d{12}) $1 Billionen[ $2]
32 1(\d{15}) eine Billiarde[ $1]
33 (\d{1,3})(\d{15}) $1 Billiarden[ $2]
34 1(\d{18}) eine Trillion[ $1]
35 (\d{1,3})(\d{18}) $1 Trillionen[ $2]
36 1(\d{21}) eine Trilliarde[ $1]
37 (\d{1,3})(\d{21}) $1 Trilliarden[ $2]
38
39 # negative number
40
41 [-−](\d+) minus |$1
42
43 # decimals
44
45 "([-−]?\d+)[.,]" $1| Komma
46 "([-−]?\d+[.,]\d*)(\d)" $1| |$2
47
48 # currency
49
50 # unit/subunit singular/plural
51
52 us:([^,]*),([^,]*),([^,]*),([^,]*) \1
53 up:([^,]*),([^,]*),([^,]*),([^,]*) \2
54 ss:([^,]*),([^,]*),([^,]*),([^,]*) \3
55 sp:([^,]*),([^,]*),([^,]*),([^,]*) \4
56
57 CHF:(\D+) $(\1: Schweizer Franken, Schweizer Franken, Rappen, Rappen)
58 CNY:(\D+) $(\1: Yuan, Yuan, Fen, Fen)
59 EUR:(\D+) $(\1: Euro, Euro, Cent, Cent)
60 GBP:(\D+) $(\1: Pfund Sterling, Pfund Sterling, Penny, Pence)
61 USD:(\D+) $(\1: US-Dollar, US-Dollar, Cent, Cents)
62
63 "JPY ([-−]?\d+([.,]\d+)?)" $1 Yen
64
65 "([A-Z]{3}) ([-−]?1)([.,]00?)?" $2$(\1:us)
66 "([A-Z]{3}) ([-−]?\d+)([.,]00?)?" $2$(\1:up)
67
68 "(CNY [-−]?\d+)[.,]10?" $1 $2 Jiao
69 "(CNY [-−]?\d+)[.,](\d)0?" $1 $2 Jiao
70 "(CNY [-−]?\d+[.,]\d)1" $1 $2 Fen
71 "(CNY [-−]?\d+[.,]\d)(\d)" $1 $2 Fen
72
73 "(([A-Z]{3}) [-−]?\d+)[.,](01)" $1 und $(1)$(\2:ss)
74 "(([A-Z]{3}) [-−]?\d+)[.,](\d)" $1 und $(\30)$(\2:sp)
75 "(([A-Z]{3}) [-−]?\d+)[.,](\d\d)" $1 und $3$(\2:sp)
76
77 == ordinal ==
78
79 ([-−]?[024569]) $1te
80 ([-−]?\d*0[24569]) $1te
81 ([-−]?\d*1\d) $1te
82 ([-−]?\d+) $(ordinal $1)
83
84 (.*)eins \1erste
85 (.*)drei \1dritte
86 (.*)sieben \1siebte
87 (.*)acht \1achte
88 "(.*)eine Milli(on|ard)e?" \1einmilli\2ste
89 "(.*)eine Billi(on|ard)e?" \1einbilli\2ste
90 "(.*)eine Trilli(on|ard)e?" \1eintrilli\2ste
91 "(.*) Milli(on|ard)en" \1milli\2ste
92 "(.*) Billi(on|ard)en" \1billi\2ste
93 "(.*) Trilli(on|ard)en" \1trilli\2ste
94 (.*) \1ste
95
96 == ordinal-number ==
97
98 (\d+) \1.
99
100 == year ==
101
102 (10)([0-9][0-9]) tausend$2
103 (1[1-9])([0-9][0-9]) $1hundert$2
104 (.*) $1
105
106 == help ==
107
108 "" |$(1)|, |$(2)|, |$(3)|\n$(help ordinal)$(help ordinal-number)
109 (ordinal(-number)?) \1: |$(\1 1)|, |$(\1 2)|, |$(\1 3)|\n