Debian Codegraph @

data/es.sor

raw
1 ^0 cero
2 1$ uno
3 1 un
4 2 dos
5 3 tres
6 4 cuatro
7 5 cinco
8 6 seis
9 7 siete
10 8 ocho
11 9 nueve
12 10 diez
13 11 once
14 12 doce
15 13 trece
16 14 catorce
17 15 quince
18 16 dieciséis
19 1(\d) dieci$1
20 20 veinte
21 21$ veintiuno
22 21 veintiún
23 22 veintidós
24 23 veintitrés
25 26 veintiséis
26 2(\d) veinti$1
27 30 treinta
28 40 cuarenta
29 50 cincuenta
30 60 sesenta
31 70 setenta
32 80 ochenta
33 90 noventa
34 (\d)(\d) $(\10) y $2
35 1(\d\d) cien[to $1]
36 500 quinientos
37 700 setecientos
38 900 novecientos
39 ([579])(\d\d) $(\100) $2
40 (\d)(\d\d) $1cientos[ $2]
41 1(\d{3}) mil[ $1]
42 (\d{1,3})(\d{3}) $1 mil[ $2]
43 1(\d{6}) un millón[ $1]
44 (\d{1,6})(\d{6}) $1 millones[ $2]
45 1(\d{12}) un billón[ $1]
46 (\d{1,6})(\d{12}) $1 billones[ $2]
47 1(\d{18}) un trillón[ $1]
48 (\d{1,6})(\d{18}) $1 trillones[ $2]
49 1(\d{24}) un cuatrillón[ $1]
50 (\d{1,6})(\d{24}) $1 cuatrillones[ $2]
51 1(\d{30}) un quintillón[ $1]
52 (\d{1,6})(\d{30}) $1 quintillones[ $2]
53
54 # negative number
55
56 [-−](\d+) menos |$1
57
58 # decimals
59
60 ([-−]?\d+)[.] $1| punto
61 ([-−]?\d+)[,] $1| coma
62 ([-−]?\d+[.,])([^0]\d) $1| |$2
63 ([-−]?\d+[.,])(\d)(\d)(\d) |$1 |$2| |$3| |$4
64 ([-−]?\d+[.,]\d*)(\d) $1| |$2
65
66 # currency
67
68 # unit/subunit singular/plural
69
70 us:([^,]*),([^,]*),([^,]*),([^,]*) \1
71 up:([^,]*),([^,]*),([^,]*),([^,]*) \2
72 ss:([^,]*),([^,]*),([^,]*),([^,]*) \3
73 sp:([^,]*),([^,]*),([^,]*),([^,]*) \4
74
75 ARS:(\D+) $(\1: peso argentino, pesos argentinos, centavo, centavos)
76 BOB:(\D+) $(\1: boliviano, bolivianos, centavo, centavos)
77 BZD:(\D+) $(\1: dólar beliceño, dólares beliceños, centavo, centavos)
78 CEC:(\D+) $(\1: peso convertible, pesos convertibles, centavo, centavos)
79 CHF:(\D+) $(\1: franco suizo, francos suizos, céntimo, céntimos)
80 CLP:(\D+) $(\1: peso chileno, pesos chilenos, centavo, centavos)
81 CNY:(\D+) $(\1: yuan renminbi, yuan renminbi, fen, fen)
82 COP:(\D+) $(\1: peso colombiano, pesos colombianos, centavo, centavos)
83 CRC:(\D+) $(\1: colón costarricense, colones costarricenses, céntimo, céntimos)
84 DOP:(\D+) $(\1: peso dominicano, pesos dominicanos, centavo, centavos)
85 ESP:(\D+) $(\1: peseta, pesetas, céntimo, céntimos)
86 EUR:(\D+) $(\1: euro, euros, céntimo, céntimos)
87 GBP:(\D+) $(\1: libra esterlina, libras esterlinas, penique, peniques)
88 GTQ:(\D+) $(\1: quetzal, quetzales, centavo, centavos)
89 HNL:(\D+) $(\1: lempira, lempiras, centavo, centavos)
90 JPY:(\D+) $(\1: yen, yenes, sen, sen)
91 MXN:(\D+) $(\1: peso mexicano, pesos mexicanos, centavo, centavos)
92 NIO:(\D+) $(\1: córdoba, córdobas, centavo, centavos)
93 PAB:(\D+) $(\1: balboa, balboas, céntimo, céntimos)
94 PEN:(\D+) $(\1: sol, soles, centavo, centavos)
95 PYG:(\D+) $(\1: guaraní, guaraníes, céntimo, céntimos)
96 SVC:(\D+) $(\1: colón salvadoreño, colones salvadoreños, céntimo, céntimos)
97 USD:(\D+) $(\1: dólar estadounidense, dólares estadounidenses, centavo, centavos)
98 UYU:(\D+) $(\1: peso uruguayo, pesos uruguayos, centésimo, centésimos)
99 VE[DS]:(\D+) $(\1: bolívar venezolano, bolívares venezolanos, centavo, centavos)
100 VEF:(\D+) $(\1: bolívar fuerte, bolívares fuertes, céntimo, céntimos)
101
102 # masculine to feminine conversion of "un" after millions,
103 # if "as?$" matches currency name
104
105 f:(.*ill)(.*),(.*) \1$(f:\2,\3) # don't modify un in millions
106 f:(.*)[uú]n([^a].*,|,)(.*as?) $(f:\1una\2\3) # un libra -> una libra
107 f:(.*ient)o(s.*),(.*as?) $(f:\1a\2,\3) # doscientos libra/libras -> doscientas
108 f:(.*),(.*) \1\2
109
110 "([A-Z]{3}) ([-−]?1)([.,]00?)?"$(f:|$2,$(\1:us))
111 "([A-Z]{3}) ([-−]?\d+0{6,})([.,]00?)?" $2 de$(\1:up)
112 "([A-Z]{3}) ([-−]?\d+)([.,]00?)?"$(f:|$2,$(\1:up))
113
114 "(CNY [-−]?\d+)[.,]10?" $1 $2 jiao
115 "(CNY [-−]?\d+)[.,](\d)0?" $1 $2 jiao
116 "(CNY [-−]?\d+[.,]\d)1" $1 $2 fen
117 "(CNY [-−]?\d+[.,]\d)(\d)" $1 $2 fen
118
119 "(([A-Z]{3}) [-−]?\d+)[.,](01)" $1 con |$(1)$(\2:ss)
120 "(([A-Z]{3}) [-−]?\d+)[.,](\d)" $1 con |$(\30)$(\2:sp)
121 "(([A-Z]{3}) [-−]?\d+)[.,](\d\d)" $1 con |$3$(\2:sp)
122
123 # ordinal
124
125 feminine:(.*ill)(.*) \1$(feminine:\2) # don't modify un in millions
126 feminine:(.*ient)o(s.*) $(feminine:\1a\2) # doscientos -> doscientas
127 feminine:(.*)[uú]no?([^a].*|$) $(feminine:\1una\2) # un -> una
128 feminine:(.*) \1
129
130 == feminine ==
131
132 (.*) $(feminine:|$1|)
133
134 == masculine ==
135
136 1 un
137 (.*) $1
138
139 == ordinal-masculine ==
140
141 (.*) $(ordinal \1)
142
143 == ordinal ==
144
145 1 primero
146 2 segundo
147 3 tercero
148 4 cuarto
149 5 quinto
150 6 sexto
151 7 séptimo
152 8 octavo
153 9 noveno
154 10 décimo
155 1([1-79]) decimo$(ordinal \1)
156 18 decimoctavo
157 20 vigésimo
158 2(\d) vigesimo$(ordinal \1)
159 30 trigésimo
160 40 cuadragésimo
161 50 quincuagésimo
162 60 sexagésimo
163 70 septuagésimo
164 80 octogésimo
165 90 nonagésimo
166 (\d)(\d) $(ordinal \10) $(ordinal \2)
167 100 centésimo
168 200 ducentésimo
169 300 tricentésimo
170 400 cuadringentésimo
171 500 quingentésimo
172 600 sexcentésimo
173 700 septingentésimo
174 800 octingentésimo
175 900 noningentésimo
176 (\d)(\d\d) $(ordinal \100) $(ordinal \2)
177 1(\d{3}) milésimo[ $(ordinal \1)]
178 (\d{1,3})(\d{3}) $1 milésimo[ $(ordinal \2)]
179 1(\d{6}) millonésimo[ $(ordinal \1)]
180 (\d{1,3})(\d{6}) $1 millonésimo[ $(ordinal \2)]
181 1(\d{9}) milmillonésimo[ $(ordinal \1)]
182 (\d{1,3})(\d{9}) $1 milmillonésimo[ $(ordinal \2)]
183
184 == ordinal-feminine ==
185
186 ([-−]?\d+) $(ordinal-feminine $(ordinal-masculine \1))
187 (.*)o\b(.*) $(ordinal-feminine \1a\2)
188 (.*) \1
189
190 == ordinal-masculine-adjective ==
191
192 ([-−]?\d+) $(ordinal-masculine-adjective $(ordinal-masculine \1))
193 (.*)decimoprimero \1undécimo
194 (.*)decimosegundo \1duodécimo
195 (.*(primer|tercer))o \1
196 (.*) \1
197
198 # ordinal abbreviation
199
200 == (ordinal)-number(-feminine|-masculine|-masculine-adjective)? ==
201
202 ([-−]?\d+) \3$(ordinal-number $(\1\2 \3))
203 .*er .ᵉʳ
204 .*a .ª
205 .*o .º
206
207 == help ==
208
209 "" $(1)|, $(2), $(3)\n$(\0 feminine)$(\0 masculine)$(\0 ordinal-number-masculine)$(\0 ordinal-number-masculine-adjective)$(\0 ordinal-number-feminine)$(\0 ordinal-feminine)$(\0 ordinal-masculine)$(\0 ordinal-masculine-adjective)
210 (feminine|masculine|ordinal(-number)?(-feminine|-masculine)?(-adjective)?) \1: $(\1 1), $(\1 2), $(\1 3)\n