Debian Codegraph @

packages/seacas/applications/fastq/zhole.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE ZHOLE (MP, ML, MS, MR, NS, MAXNL, MAXNP, MAXPRM, NPRM,
8 & MAXNBC, MAXSBC, KNBC, KSBC, KNUM, IPOINT, COOR, IPBOUN, ILINE,
9 & LTYPE, NINT, FACTOR, LCON, ILBOUN, ISBOUN, ISIDE, NLPS, IFLINE,
10 & ILLIST, ISLIST, INDXH, NPPF, IFPB, LISTPB, NLPF, IFLB,
11 & LISTLB, NSPF, IFSB, LISTSB, LINKP, LINKL, LINKS, LINKPB,
12 & LINKLB, LINKSB, X, Y, NID, LISTL, MARKED, NL, LSTNBC, MXND,
13 & XN, YN, NUID, LXK, KXL, NXL, LXN, NXH, NPERIM, NNN, NNNOLD,
14 & KKK, LLL, IAVAIL, NAVAIL, JHOLE, INSIDE, EPS, NOROOM, ERR,
15 & AMESUR, XNOLD, YNOLD, NXKOLD, MMPOLD, LINKEG, LISTEG, BMESUR,
16 & MLINK, NPROLD, NPNOLD, NPEOLD, NNXK, REMESH, REXMIN, REXMAX,
17 & REYMIN, REYMAX, IDIVIS, SIZMIN, EMAX, EMIN)
18 C***********************************************************************
19
20 C SUBROUTINE ZHOLE = REMESHES AROUND HOLE IN REGION
21
22 C***********************************************************************
23
24 DIMENSION IPOINT(MP), COOR(2, MP), IPBOUN(MP)
25 DIMENSION ILINE(ML), NINT(ML), LTYPE(ML), FACTOR(ML), LCON(3, ML)
26 DIMENSION ILBOUN(ML), ISBOUN(ML)
27 DIMENSION ISIDE(MS), NLPS(MS), IFLINE(MS), ILLIST(MS*3)
28 DIMENSION ISLIST(4*MR), LINKP(2, MP), LINKL(2, ML)
29 DIMENSION LINKS(2, MS), LISTL(MAXNL)
30 DIMENSION X(MAXNP), Y(MAXNP), NID(MAXNP, MAXPRM), NPERIM(MAXPRM)
31 DIMENSION LINKPB(2, MP), NPPF(MP), IFPB(MP), LISTPB(2, MP)
32 DIMENSION LINKLB(2, ML), NLPF(ML), IFLB(ML), LISTLB(2, ML)
33 DIMENSION LINKSB(2, ML), NSPF(ML), IFSB(ML), LISTSB(2, ML)
34 DIMENSION LSTNBC(MAXNBC)
35 DIMENSION XN(MXND), YN(MXND), NUID(MXND), LXK(4, MXND)
36 DIMENSION KXL(2, 3*MXND), NXL(2, 3*MXND), LXN(4, MXND)
37 DIMENSION NXH(MXND)
38 DIMENSION KLIST1(20), LINES(20), NODES(4)
39
40 DIMENSION AMESUR(NPEOLD), XNOLD(NPNOLD), YNOLD(NPNOLD)
41 DIMENSION NXKOLD(NNXK, NPEOLD), MMPOLD(3, NPROLD)
42 DIMENSION LINKEG(2, MLINK), LISTEG(4 * NPEOLD), BMESUR(NPNOLD)
43
44 LOGICAL ADDLNK, CCW, DELETE, ERR, EVEN, LREAL, NOROOM, COUNT
45 LOGICAL LPNTIN, REMESH, LCIRCL, LDEL
46
47 C CHECK FOR INPUT ERRORS
48
49 ERR = .FALSE.
50 IF (NNN - NNNOLD .LE. 0) THEN
51 CALL MESSAGE('NO NODES DEFINED IN REGION')
52 ERR = .TRUE.
53
54 C GOOD INPUT
55
56 ELSE
57 LNUM = ABS(ISLIST(INDXH))
58 ADDLNK = .FALSE.
59 CALL LTSORT (ML, LINKL, LNUM, LIN, ADDLNK)
60 LCIRCL = NS .EQ. 1 .AND. LTYPE(LIN) .EQ. 3
61
62 C CIRCULAR HOLE
63
64 IF (LCIRCL) THEN
65 CALL LTSORT (MP, LINKP, LCON(1, LIN), I1, ADDLNK)
66 CALL LTSORT (MP, LINKP, LCON(2, LIN), I2, ADDLNK)
67 IF (I1 .NE. I2) THEN
68 CALL MESSAGE('CIRCULAR HOLE DOES NOT CLOSE')
69 ERR = .TRUE.
70 GO TO 380
71 END IF
72 CALL LTSORT (MP, LINKP, LCON(3, LIN), I2, ADDLNK)
73 XCEN = COOR(1, I2)
74 YCEN = COOR(2, I2)
75 RADIUS = (COOR(1, I1) - XCEN)**2 + (COOR(2, I1) - YCEN)**2
76 IF (RADIUS .LE. 0.0) THEN
77 CALL MESSAGE('RADIUS HAS ZERO LENGTH')
78 ERR = .TRUE.
79 GO TO 380
80 END IF
81 XMIN = XCEN - SQRT(RADIUS)
82 XMAX = XCEN + SQRT(RADIUS)
83 YMIN = YCEN - SQRT(RADIUS)
84 YMAX = YCEN + SQRT(RADIUS)
85 NPERV = NINT(LIN)
86
87 C NON-CIRCULAR HOLE
88 ELSE
89 NLP1 = NL + 1
90 CCW = .TRUE.
91 COUNT = .FALSE.
92 EVEN = .FALSE.
93 LREAL = .FALSE.
94
95 CALL PERIM (MP, ML, MS, NS, MAXNL, MAXNP, MAXNBC, MAXSBC,
96 & KNBC, KSBC, KNUM, IPOINT, COOR, IPBOUN, ILINE, LTYPE,
97 & NINT, FACTOR, LCON, ILBOUN, ISBOUN, ISIDE, NLPS, IFLINE,
98 & ILLIST, ISLIST(INDXH), NPPF, IFPB, LISTPB, NLPF, IFLB,
99 & LISTLB, NSPF, IFSB, LISTSB, LINKP, LINKL, LINKS, LINKPB,
100 & LINKLB, LINKSB, X, Y, NID(1, NPRM), NPERIM(NPRM),
101 & LISTL(NLP1), NL1, LSTNBC, MARKED, EVEN, LREAL, ERR, CCW,
102 & COUNT, NOROOM, AMESUR, XNOLD, YNOLD, NXKOLD, MMPOLD,
103 & LINKEG, LISTEG, BMESUR, MLINK, NPROLD, NPNOLD, NPEOLD,
104 & NNXK, REMESH, REXMIN, REXMAX, REYMIN, REYMAX, IDIVIS,
105 & SIZMIN, EMAX, EMIN)
106 IF (ERR .OR. NOROOM) GO TO 380
107 NPERV = NPERIM(NPRM)
108 NPNT = NPERV
109 XMIN = X(1)
110 XMAX = XMIN
111 YMIN = Y(1)
112 YMAX = YMIN
113 DO 100 I = 1, NPNT
114 XCEN = XCEN + X(I)
115 YCEN = YCEN + Y(I)
116 XMIN = MIN(XMIN, X(I))
117 XMAX = MAX(XMAX, X(I))
118 YMIN = MIN(YMIN, Y(I))
119 YMAX = MAX(YMAX, Y(I))
120 100 CONTINUE
121 XCEN = XCEN/DBLE(NPNT)
122 YCEN = YCEN/DBLE(NPNT)
123 RADIUS = SQRT((XCEN - X(1))**2 + (YCEN - Y(1))**2)
124 DO 110 I = 2, NPNT
125 R = SQRT((XCEN - X(I))**2 + (YCEN - Y(I))**2)
126 RADIUS = MIN(RADIUS, R)
127 110 CONTINUE
128 END IF
129
130 C INITIALIZE NODES PER (ON) HOLE
131
132 DO 120 I = 1, NNN
133 NXH(I) = 0
134 120 CONTINUE
135
136 C DELETE EVERYTHING ATTACHED TO NODES WITHIN HOLE
137
138 NEAR = 0
139 SMALL = 0.0
140 DO 130 I = NNNOLD + 1, NNN
141 IF (XN(I) .GT. XMIN .AND. XN(I) .LT. XMAX .AND.
142 & YN(I) .GT. YMIN .AND. YN(I) .LT. YMAX) THEN
143 DIST = (XN(I) - XCEN)**2 + (YN(I) - YCEN)**2
144 IF (LCIRCL) THEN
145 LDEL = DIST .LT. RADIUS
146 ELSE
147 LDEL = LPNTIN (MAXNP, X, Y, NPNT, XN(I), YN(I))
148 END IF
149 IF (DIST .LT. SMALL .OR. NEAR .EQ. 0) THEN
150 NEAR = I
151 SMALL = DIST
152 END IF
153 IF (LDEL) THEN
154 IF (NUID(I) .EQ. 0) THEN
155 CALL DELHOL (I, MXND, LXK, KXL, NXL, LXN, NXH,
156 & NUID, NNN, IAVAIL, NAVAIL, NOROOM, ERR)
157 IF (NOROOM .OR. ERR) GO TO 380
158
159 C CANNOT DELETE BOUNDARY NODES
160
161 ELSE
162 CALL MESSAGE('HOLE CROSSES FIXED BOUNDARY')
163 ERR = .TRUE.
164 GO TO 380
165 END IF
166 END IF
167 END IF
168 130 CONTINUE
169
170 C PROCESS SMALL CIRCLES (I.E. SMALLER THAN AN ELEMENT)
171
172 IF (SMALL .GT. RADIUS) THEN
173 CCW = .TRUE.
174 CALL GKXN (MXND, KXL, LXN, NEAR, KS1, KLIST1, ERR)
175 DO 150 I = 1, KS1
176 CALL GNXKA (MXND, XN, YN, KLIST1(I), NODES, AREA, LXK,
177 & NXL, CCW)
178 SUM = 0.0
179 DO 140 J = 1, 4
180 J1 = J + 1
181 IF (J1 .GT. 4) J1 = 1
182 SUM = SUM + ABS((XN(NODES(J1)) - XN(NODES(J)))*(YCEN
183 & - YN(NODES(J))) - (XCEN - XN(NODES(J)))
184 & *(YN(NODES(J1)) - YN(NODES(J))))
185 140 CONTINUE
186 SUM = SUM/2.0
187 IF (ABS((AREA - SUM)/AREA) .LT. 1.0E-4) GO TO 160
188 150 CONTINUE
189 CALL MESSAGE('FAILED TO FIND ELEMENT SURROUNDING '//
190 & 'SMALL HOLE')
191 ERR = .TRUE.
192 GO TO 380
193 160 CONTINUE
194
195 DO 170 I = 1, 4
196 IF (NUID(NODES(I)) .EQ. 0) THEN
197 CALL DELHOL (NODES(I), MXND, LXK, KXL, NXL, LXN, NXH,
198 & NUID, NNN, IAVAIL, NAVAIL, NOROOM, ERR)
199 IF (NOROOM .OR. ERR) GO TO 380
200 END IF
201 170 CONTINUE
202 END IF
203
204 C SQUARE UP BOUNDARY (DELETE INTERIOR NODES WITH ONLY TWO LINES)
205
206 180 CONTINUE
207 DELETE = .FALSE.
208 DO 190 I = NNNOLD + 1, NNN
209 IF (NXH(I) .EQ. 1 .AND. NUID(I) .EQ. 0) THEN
210 CALL GETLXN (MXND, LXN, I, LINES, NUML, ERR)
211 IF (NUML .EQ. 2 .AND. NUID(I) .EQ. 0) THEN
212 CALL DELHOL (I, MXND, LXK, KXL, NXL, LXN, NXH,
213 & NUID, NNN, IAVAIL, NAVAIL, NOROOM, ERR)
214 IF (NOROOM .OR. ERR) GO TO 380
215 DELETE = .TRUE.
216 END IF
217 END IF
218 190 CONTINUE
219 IF (DELETE) GO TO 180
220
221 C GENERATE DELETED ELEMENT BOUNDARY NODE LIST
222
223 NH = 0
224 DO 200 I = NNNOLD + 1, NNN
225 IF (NXH(I) .GT. 0) THEN
226 NH = NH + 1
227 NXH(NH) = I
228 END IF
229 200 CONTINUE
230
231 C ENSURE THAT THERE ARE A MINIMUM OF MIN(12, NPERV) INTERVALS
232 C AROUND HOLE
233
234 IF (NH .LT. MAX(12, NPERV)) THEN
235 DO 210 I = NH + 1, MXND
236 NXH(I) = 0
237 210 CONTINUE
238
239 DO 220 I = 1, NH
240 IF (NUID(NXH(I)) .EQ. 0) THEN
241 CALL DELHOL (NXH(I), MXND - NH, LXK, KXL, NXL, LXN,
242 & NXH(NH + 1), NUID, NNN, IAVAIL, NAVAIL, NOROOM,
243 & ERR)
244 IF (NOROOM .OR. ERR) GO TO 380
245 DELETE = .TRUE.
246 ELSE
247 I1 = NXH(I) + NH
248 NXH(I1) = 1
249 END IF
250 220 CONTINUE
251
252 IF (DELETE) THEN
253 I1 = 0
254 DO 230 I = NH + 1, MXND
255 I1 = I1 + 1
256 NXH(I1) = NXH(I)
257 230 CONTINUE
258 GO TO 180
259 ELSE
260 CALL MESSAGE
261 & ('INTERVAL MISMATCH BETWEEN HOLE AND BOUNDARY.')
262 CALL MESSAGE('ALL ELEMENTS DELETED.')
263 ERR = .TRUE.
264 GO TO 380
265 END IF
266 END IF
267
268 C ORDER THE INTERIOR NODE LIST
269
270 DO 260 I = 1, NH - 1
271 CALL GETLXN (MXND, LXN, NXH(I), LINES, NUML, ERR)
272 DO 250 J = 1, NUML
273 J1 = NXL(2, LINES(J)) + NXL(1, LINES(J)) - NXH(I)
274 DO 240 K = I + 1, NH
275 IF (NXH(K) .EQ. J1) THEN
276 NXH(K) = NXH(I + 1)
277 NXH(I + 1) = J1
278 GO TO 260
279 END IF
280 240 CONTINUE
281 250 CONTINUE
282 260 CONTINUE
283
284 C MAKE SURE LOOP CLOSES
285
286 CALL GETLXN (MXND, LXN, NXH(NH), LINES, NUML, ERR)
287 DO 270 J = 1, NUML
288 J1 = NXL(2, LINES(J)) + NXL(1, LINES(J)) - NXH(NH)
289 IF (NXH(1) .EQ. J1) THEN
290 GO TO 280
291 END IF
292 270 CONTINUE
293 CALL MESSAGE('HOLE PERIMETER DOES NOT CLOSE')
294 ERR = .TRUE.
295 GO TO 380
296 280 CONTINUE
297
298 C MAKE SURE HOLE PERIMETER IS DEFINED COUNTER-CLOCKWISE
299
300 PI = ACOS(-1.0)
301 TWOPI = PI + PI
302 SPIRO = 0.0
303 AGOLD = ATAN2(YN(NXH(1)) - YN(NXH(NH)),
304 & XN(NXH(1)) - XN(NXH(NH)))
305 DO 290 I = 1, NH
306 IF (I .EQ. NH) THEN
307 NEXT = 1
308 ELSE
309 NEXT = I + 1
310 END IF
311 AGNEW = ATAN2(YN(NXH(NEXT)) - YN(NXH(I)),
312 & XN(NXH(NEXT)) - XN(NXH(I)))
313 DIFF = AGNEW - AGOLD
314 IF (DIFF .GT. PI) THEN
315 DIFF = DIFF - TWOPI
316 ELSE IF (DIFF .LT .-PI) THEN
317 DIFF = DIFF + TWOPI
318 END IF
319 IF (ABS(ABS(DIFF) - PI) .LT .1.0E-3) THEN
320 CALL MESSAGE('PERIMETER CONTAINS SWITCHBACKS')
321 ERR = .TRUE.
322 GO TO 380
323 ENDIF
324 SPIRO = SPIRO + DIFF
325 AGOLD = AGNEW
326 290 CONTINUE
327
328 IF (SPIRO .LT .0.0) THEN
329 DO 300 I = 1, NH/2
330 ITEMP = NXH(I)
331 NXH(I) = NXH(NH - I + 1)
332 NXH(NH - I + 1) = ITEMP
333 300 CONTINUE
334 ELSE IF ((ABS(SPIRO) .LT .PI) .OR.
335 & (ABS(SPIRO) .GT. (3.*PI))) THEN
336 CALL MESSAGE
337 & ('UNABLE TO DETERMINE CW OR CCW SENSE OF HOLE')
338 ERR = .TRUE.
339 GO TO 380
340 ENDIF
341
342 C FIND THE BEST STARTING POINT ON THE CIRCULAR HOLE
343
344 IF (NNN + NH .GT. MXND) THEN
345 NOROOM = .TRUE.
346 GO TO 380
347 END IF
348
349 C GENERATE THE PERIMETER OF THE HOLE
350
351 EVEN = .TRUE.
352 CCW = .TRUE.
353 LREAL = .TRUE.
354 COUNT = .TRUE.
355 IF (NPERV .NE. NH) THEN
356 IF (LCIRCL) THEN
357 NINT(LIN) = NH
358 ELSE
359 TDIST = 0.0
360 DO 310 I = 1, NL1
361 LNUM = LISTL(NL + I)
362 CALL LTSORT (ML, LINKL, LNUM, LIN, ADDLNK)
363 I1 = LCON (1, LIN)
364 I2 = LCON (2, LIN)
365 I3 = LCON (3, LIN)
366 CALL LTSORT (MP, LINKP, I1, J1, ADDLNK)
367 CALL LTSORT (MP, LINKP, I2, J2, ADDLNK)
368 IF (I3 .NE. 0) THEN
369 CALL LTSORT (MP, LINKP, IABS (I3), J3, ADDLNK)
370 IF (I3 .LT. 0) J3 = -J3
371 ELSE
372 J3 = 0
373 END IF
374 CALL LINLEN (MP, COOR, LINKP, JHOLE, ILINE(LIN),
375 & LTYPE(LIN), I3, J1, J2, J3, DIST, ERR)
376 IF (ERR) GO TO 380
377 TDIST = TDIST + DIST
378 310 CONTINUE
379 NSUM = 0
380 DO 320 I = 1, NL1 - 1
381 LNUM = LISTL(NL + I)
382 CALL LTSORT (ML, LINKL, LNUM, LIN, ADDLNK)
383 I1 = LCON (1, LIN)
384 I2 = LCON (2, LIN)
385 I3 = LCON (3, LIN)
386 CALL LTSORT (MP, LINKP, I1, J1, ADDLNK)
387 CALL LTSORT (MP, LINKP, I2, J2, ADDLNK)
388 IF (I3 .NE. 0) THEN
389 CALL LTSORT (MP, LINKP, IABS (I3), J3, ADDLNK)
390 IF (I3 .LT. 0) J3 = -J3
391 ELSE
392 J3 = 0
393 END IF
394 CALL LINLEN (MP, COOR, LINKP, JHOLE, ILINE(LIN),
395 & LTYPE(LIN), I3, J1, J2, J3, DIST, ERR)
396 IF (ERR) GO TO 380
397 NINT(LIN) = INT(NH * DIST/TDIST + 0.5)
398 NSUM = NSUM + NINT(LIN)
399 320 CONTINUE
400 LNUM = LISTL(NL + NL1)
401 CALL LTSORT (ML, LINKL, LNUM, LIN, ADDLNK)
402 NINT(LIN) = NH - NSUM
403 END IF
404 CALL MESSAGE('INTERVALS MODIFIED FOR HOLE')
405 END IF
406 NLP1 = NL + 1
407 CALL PERIM (MP, ML, MS, NS, MAXNL, MAXNP, MAXNBC, MAXSBC, KNBC,
408 & KSBC, KNUM, IPOINT, COOR, IPBOUN, ILINE, LTYPE, NINT,
409 & FACTOR, LCON, ILBOUN, ISBOUN, ISIDE, NLPS, IFLINE, ILLIST,
410 & ISLIST(INDXH), NPPF, IFPB, LISTPB, NLPF, IFLB, LISTLB, NSPF,
411 & IFSB, LISTSB, LINKP, LINKL, LINKS, LINKPB, LINKLB, LINKSB,
412 & X, Y, NID(1, NPRM), NPERIM(NPRM), LISTL(NLP1), NL1, LSTNBC,
413 & MARKED, EVEN, LREAL, ERR, CCW, COUNT, NOROOM, AMESUR, XNOLD,
414 & YNOLD, NXKOLD, MMPOLD, LINKEG, LISTEG, BMESUR, MLINK,
415 & NPROLD, NPNOLD, NPEOLD, NNXK, REMESH, REXMIN, REXMAX,
416 & REYMIN, REYMAX, IDIVIS, SIZMIN, EMAX, EMIN)
417 IF (NOROOM .OR. ERR) GO TO 380
418 IF (NL1 .GE. 0 .AND. NL + NL1 .LE. MAXNL) THEN
419 NL = NL + NL1
420 ELSE
421 CALL MESSAGE('UNABLE TO ADD HOLE LINES TO REGION LINE LIST')
422 ERR = .TRUE.
423 GO TO 380
424 END IF
425
426 C TACK THE HOLE LINE LIST ONTO THE BOUNDARY LINE LIST
427
428 IF (NPERIM(NPRM) .NE. NH) THEN
429 CALL MESSAGE('INTERVAL MISMATCH ON HOLE PERIMETER')
430 ERR = .TRUE.
431 GO TO 380
432 END IF
433
434 ISTART = 0
435 DIST = 0.0
436 DO 340 I = 1, NH
437 SUM = 0.0
438 I1 = I - 1
439 DO 330 J = 1, NH
440 I1 = I1 + 1
441 IF (I1 .GT. NH) I1 = 1
442 I2 = NXH(I1)
443 SUM = SUM + (XN(I2) - X(J))**2 + (YN(I2) - Y(J))**2
444 330 CONTINUE
445
446 IF (SUM .LT. DIST .OR. ISTART .EQ. 0) THEN
447 DIST = SUM
448 ISTART = I
449 END IF
450 340 CONTINUE
451
452 NNNX = NNN
453 DO 350 J = 1, NH
454 NNN = NNN + 1
455 XN(NNN) = X(J)
456 YN(NNN) = Y(J)
457 NUID(NNN) = NID(J, NPRM)
458 350 CONTINUE
459
460 C FIRST ROW OF ELEMENTS
461
462 CALL INNERH (MXND, NXH, NUID, LXK, KXL, NXL, LXN, KKK, LLL,
463 & NNN, NNNX, NH, ISTART, IAVAIL, NAVAIL, NOROOM, ERR)
464 IF (NOROOM .OR. ERR) GO TO 380
465
466 C INSERT INNER NECKLACE OF ELEMENTS
467
468 ISTART = 1
469 DO 370 J = 1, INSIDE
470 NNNX = NNN
471 DO 360 I = 1, NH
472 NNN = NNN + 1
473 NXH(I) = NNNX - NH + I
474 XN(NNN) = XN(NXH(I))
475 YN(NNN) = YN(NXH(I))
476 NUID(NNN) = NUID(NXH(I))
477 NUID(NXH(I)) = 0
478 LXN(2, NXH(I)) = ABS(LXN(2, NXH(I)))
479 360 CONTINUE
480 CALL INNERH (MXND, NXH, NUID, LXK, KXL, NXL, LXN, KKK, LLL,
481 & NNN, NNNX, NH, ISTART, IAVAIL, NAVAIL, NOROOM, ERR)
482 IF (NOROOM .OR. ERR) GO TO 380
483 370 CONTINUE
484 END IF
485
486 380 CONTINUE
487 RETURN
488 END