Debian Codegraph @

packages/seacas/applications/fastq/arelax.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE ARELAX (MXND, XN, YN, LXK, KXL, NXL, LLL, ARFACT)
8 C***********************************************************************
9
10 C SUBROUTINE ARELAX = CALCULATES UNDER - RELAXATION FACTOR FOR AREA PULL
11 C AND LAPLACIAN SMOOTHER
12
13 C***********************************************************************
14
15 C NOTE:
16 C THE AREA PULL AND LAPLACIAN SMOOTHER WILL OVER - CORRECT
17 C AND BECOME UNSTABLE WHEN TYPICAL MESH ELEMENTS ARE MUCH
18 C LONGER THAN THEY ARE WIDE, SAY BY A FACTOR OF SIX OR MORE.
19 C THIS ROUTINE COMPUTES AN APPROPRIATE UNDER - RELAXATION
20 C FACTOR TO BE USED TO HELP CORRECT THIS PROBLEM. ON REGIONS
21 C WHICH HAVE GENERALLY NEAR SQUARE ELEMENTS WITH A SMALL
22 C PERCENTAGE OF VERY LONG THIN ELEMENTS THIS FACTOR WILL
23 C PROBABLY NOT ADEQUATELY HANDLE THE DIFFICULTY. IN SUCH
24 C SITUATIONS AN ALTERNATE SMOOTHER (SUCH AS THE CENTROID - AREA -
25 C PULL) SHOULD BE USED.
26 C THE FACTOR RETURNED BY THIS ROUTINE MAY BE LARGER THAN ONE,
27 C WHICH MEANS THAT OVER - RELAXATION IS APPROPRIATE.
28
29 C***********************************************************************
30
31 DIMENSION NODES (4), LXK (4, MXND), KXL (2, 3 * MXND)
32 DIMENSION NXL (2, 3 * MXND)
33 DIMENSION XN (MXND), YN (MXND)
34
35 LOGICAL CCW
36
37 ARFACT = 1.0
38 RATSUM = 0.
39 NUM = 0
40
41 DO 100 MYL = 1, LLL
42
43 C SKIP BOUNDARY LINES
44
45 IF (KXL(1, myL) .gt. 0 .and. KXL (2, myL) .GT. 0) THEN
46 CCW = .TRUE.
47 CALL GNXKA (MXND, XN, YN, KXL (1, MYL), NODES, AREA1, LXK,
48 & NXL, CCW)
49 CALL GNXKA (MXND, XN, YN, KXL (2, MYL), NODES, AREA2, LXK,
50 & NXL, CCW)
51 N1 = NXL (1, MYL)
52 N2 = NXL (2, MYL)
53 DXDY = (XN (N2) - XN (N1)) **2 + (YN (N2) - YN (N1)) **2
54 IF (AREA1 + AREA2 .GT. 0) THEN
55 RATIO = 2.0 * DXDY / (AREA1 + AREA2)
56 IF (RATIO .GE. 0.99) THEN
57 NUM = NUM + 1
58 RATSUM = RATSUM + RATIO
59 ENDIF
60 ENDIF
61 ENDIF
62 100 CONTINUE
63
64 IF (NUM .LE. 0) RETURN
65 ASPECT = RATSUM / DBLE(NUM)
66 ARFACT = AMIN1 (2.0 / ASPECT, 1.5)
67
68 RETURN
69
70 END