Debian Codegraph @

packages/seacas/applications/fastq/getwt.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE GETWT (MP, ML, MXLPS, NIX, ILIST, XLIST, ILINE, LCON,
8 & LTYPE, COOR, LINKP, FRACT, ADDLNK, ERR)
9 C***********************************************************************
10
11 C SUBROUTINE GETWT = GETS A WEIGHT BASED ON A PERCENTAGE DISTANCE ALONG
12 C THE GIVEN SIDE LINE LIST.
13
14 C***********************************************************************
15
16 C SUBROUTINE CALLED BY:
17 C ADDWT = ADDS THE WEIGHTING FACTORS TO ANY NODES WITH
18 C FLAGS CONTAINING WEIGHTS
19
20 C***********************************************************************
21
22 C VARIABLES USED:
23 C FRACT = THE FRACTION OF TOTAL DISTANCE ALONG THE X AXIS
24 C (TAKES BACK THE WEIGHT OR Y VALUE AT THAT % DISTANCE)
25
26 C***********************************************************************
27
28 DIMENSION ILIST (MXLPS), XLIST (MXLPS)
29 DIMENSION ILINE (ML), LCON (3, ML), LTYPE (ML)
30 DIMENSION COOR (2, MP), LINKP (2, MP)
31
32 LOGICAL ADDLNK, ERR
33
34 ADDLNK = .FALSE.
35 ERR = .FALSE.
36 PI = ATAN2(0.0, -1.0)
37 TWOPI = 2.*PI
38
39 C GET THE X VALUE
40
41 X = FRACT* (XLIST (NIX)-XLIST (1))+XLIST (1)
42
43 C FIND THE LINE THIS BELONGS TO
44
45 DO 100 I = 1, NIX-1
46 IF ((X.LE.XLIST (I+1)).AND. (X.GE.XLIST (I))) THEN
47 IL = ILIST (I)
48 GOTO 110
49 ENDIF
50 100 CONTINUE
51 CALL MESSAGE('PROBLEMS IN GETWT - NO X SPAN FOUND')
52 ERR = .TRUE.
53 RETURN
54
55 110 CONTINUE
56
57 C NOW GET THE Y VALUE FOR THE X AND THE LINE (AND TYPE OF LINE) GIVEN
58
59 KT = LTYPE (IL)
60 CALL LTSORT (MP, LINKP, LCON (1, IL), IP1, ADDLNK)
61 CALL LTSORT (MP, LINKP, LCON (2, IL), IP2, ADDLNK)
62 CALL LTSORT (MP, LINKP, IABS (LCON (3, IL)), IP3, ADDLNK)
63 IF (LCON (3, IL).LT.0)IP3 = -IP3
64
65 C CHECK FOR EXACT LINE END PLACEMENT
66
67 EPS = ABS (XLIST (NIX)-XLIST (1))*.00001
68 IF (ABS (X-COOR (1, IP1)).LT.EPS) THEN
69 FRACT = COOR (2, IP1)
70 RETURN
71 ELSEIF (ABS (X-COOR (1, IP2)).LT.EPS) THEN
72 FRACT = COOR (2, IP2)
73 RETURN
74 ENDIF
75
76 C GET INTERMEDIATE Y VALUE BASED ON THE LINE TYPE
77
78 C FIRST - STRAIGHT LINES
79
80 IF (KT.EQ.1) THEN
81 IF (COOR (1, IP1).GT.COOR (1, IP2)) THEN
82 IHOLD = IP1
83 IP1 = IP2
84 IP2 = IHOLD
85 ENDIF
86 XFRACT = (X-COOR (1, IP1))/ (COOR (1, IP2)-COOR (1, IP1))
87 FRACT = (XFRACT* (COOR (2, IP2)-COOR (2, IP1)))+COOR (2, IP1)
88
89 C NEXT - CORNER LINES
90
91 ELSEIF (KT.EQ.2) THEN
92 IF (COOR (1, IP1).GT.COOR (1, IP2)) THEN
93 IHOLD = IP1
94 IP1 = IP2
95 IP2 = IHOLD
96 ENDIF
97 IF (COOR (1, IP3).GT.X) THEN
98 IP2 = IP3
99 XFRACT = (X-COOR (1, IP1))/ (COOR (1, IP2)-COOR (1, IP1))
100 FRACT = (XFRACT * (COOR (2, IP2) - COOR (2, IP1)))
101 & + COOR (2, IP1)
102 ELSEIF (COOR (1, IP3).LT.X) THEN
103 IP1 = IP3
104 XFRACT = (X-COOR (1, IP1))/ (COOR (1, IP2)-COOR (1, IP1))
105 FRACT = (XFRACT* (COOR (2, IP2) - COOR (2, IP1)))
106 & + COOR (2, IP1)
107 ELSE
108 FRACT = COOR (2, IP3)
109 ENDIF
110
111 C NEXT - ARCS
112
113 ELSEIF ((KT.EQ.3).OR. (KT.EQ.4).OR. (KT.EQ.6)) THEN
114
115 C ARCWITH CENTER GIVEN
116 C ARCGOES FROM 1ST POINT TO 2ND IN *COUNTER-CLOCKWISE* DIRECTION.
117
118 IF (KT.EQ.3) THEN
119 XCEN = COOR (1, IABS (IP3))
120 YCEN = COOR (2, IABS (IP3))
121
122 C CIRCLE WITH THIRD POINT ON ARC.
123
124 ELSEIF (KT.EQ.4) THEN
125 THETA1 = ATAN2 (COOR (2, IP3)-COOR (2, IP1), COOR (1, IP3)-
126 & COOR (1, IP1))+PI/2.0
127 THETA2 = ATAN2 (COOR (2, IP3)-COOR (2, IP2), COOR (1, IP3)-
128 & COOR (1, IP2))+PI/2.0
129 DET = -COS (THETA1)*SIN (THETA2)+COS (THETA2)*SIN (THETA1)
130 X1 = 0.5 * (COOR (1, IP1)+COOR (1, IP3))
131 Y1 = 0.5 * (COOR (2, IP1)+COOR (2, IP3))
132 X2 = 0.5 * (COOR (1, IP2)+COOR (1, IP3))
133 Y2 = 0.5 * (COOR (2, IP2)+COOR (2, IP3))
134 R = (-SIN (THETA2) * (X2-X1)+COS (THETA2) * (Y2-Y1))/DET
135 XCEN = X1 + R * COS (THETA1)
136 YCEN = Y1 + R * SIN (THETA1)
137
138 C CIRCLE WITH RADIUS GIVEN
139
140 ELSEIF (KT.EQ.6) THEN
141 DX = 0.5 * (COOR (1, IP2)-COOR (1, IP1))
142 DY = 0.5 * (COOR (2, IP2)-COOR (2, IP1))
143 CHORD = SQRT (DX*DX+DY*DY)
144 R = ABS (COOR (1, IABS (IP3)))
145 IF (R.LE.CHORD) THEN
146 XCEN = 0.5 * (COOR (1, IP1)+COOR (1, IP2))
147 YCEN = 0.5 * (COOR (2, IP1)+COOR (2, IP2))
148 ELSE
149 ARM = SQRT (R * R-CHORD * CHORD)
150 IF (IP3.LT.0) THEN
151 XCEN = COOR (1, IP1)+DX+ARM * DY/CHORD
152 YCEN = COOR (2, IP1)+DY-ARM * DX/CHORD
153 ELSE
154 XCEN = COOR (1, IP1)+DX-ARM * DY/CHORD
155 YCEN = COOR (2, IP1)+DY+ARM * DX/CHORD
156 ENDIF
157 ENDIF
158 ENDIF
159 R1 = SQRT ((COOR (1, IP1)-XCEN) **2 + (COOR (2, IP1)-YCEN) **2)
160 R2 = SQRT ((COOR (1, IP2)-XCEN) **2 + (COOR (2, IP2)-YCEN) **2)
161 IF ((R1.EQ.0.).OR. (R2.EQ.0.)) THEN
162 ERR = .TRUE.
163 WRITE (*, 10000)ILINE (IL)
164 RETURN
165 ENDIF
166 THETA1 = ATAN2 (COOR (2, IP1)-YCEN, COOR (1, IP1)-XCEN)
167 THETA2 = ATAN2 (COOR (2, IP2)-YCEN, COOR (1, IP2)-XCEN)
168
169 C ARCWITH THE CENTER GIVEN
170
171 IF (KT.EQ.3) THEN
172 IF ((IP3.GE.0).AND. (THETA2.LE.THETA1))THETA2 = THETA2+TWOPI
173 IF ((IP3.LT.0).AND. (THETA1.LE.THETA2))THETA1 = THETA1+TWOPI
174 TANG = THETA2-THETA1
175
176 C CIRCULAR ARC WITH 3RD POINT ON ARC - CLOCKWISE OR COUNTER-CLOCKWISE
177
178 ELSEIF (KT.EQ.4) THEN
179 THETA3 = ATAN2 (COOR (2, IP3)-YCEN, COOR (1, IP3)-XCEN)
180 IF (THETA2.LE.THETA1)THETA2 = THETA2+TWOPI
181 IF (THETA3.LE.THETA1)THETA3 = THETA3+TWOPI
182 TANG = THETA2-THETA1
183 IF (THETA3.GT.THETA2)TANG = - (TWOPI-TANG)
184
185 C CIRCULAR ARC WITH RADIUS GIVEN - CLOCKWISE OR COUNTER-CLOCKWISE
186
187 ELSEIF (KT.EQ.6) THEN
188 IF ((IP3.GE.0).AND. (THETA2.LE.THETA1))THETA2 = THETA2+TWOPI
189 IF ((IP3.LT.0).AND. (THETA1.LE.THETA2))THETA1 = THETA1+TWOPI
190 TANG = THETA2-THETA1
191 ENDIF
192
193 C NOW ITERATE UNTIL THE X VALUE IS WITHIN SOME EPSILON
194
195 AA = (LOG (R2/R1))/ (THETA2-THETA1)
196 BB = R2/EXP (AA * THETA2)
197 ANG = THETA1
198 EPS = ABS (COOR (1, IP1)-COOR (1, IP2)) * .000001
199 DO 140 I = 1, 10
200 DEL = TANG * .1
201 DO 120 J = 1, 10
202 ANG = ANG+DEL
203 RADIUS = BB * EXP (AA * ANG)
204 XTEST = XCEN+COS (ANG) * RADIUS
205 IF (EPS.GE.ABS (XTEST-X)) THEN
206 FRACT = YCEN+SIN (ANG) * RADIUS
207 GOTO 150
208 ELSEIF ((COOR (1, IP1) .LT. COOR (1, IP2))
209 & .AND. (XTEST .GT. X)) THEN
210 ANG = ANG-DEL
211 TANG = DEL
212 GOTO 130
213 ELSEIF ((COOR (1, IP1) .GT. COOR (1, IP2))
214 & .AND. (XTEST .LT. X)) THEN
215 ANG = ANG-DEL
216 TANG = DEL
217 GOTO 130
218 ENDIF
219 120 CONTINUE
220 130 CONTINUE
221 140 CONTINUE
222 ERR = .TRUE.
223 WRITE (*, 10010)ILINE (IL)
224 RETURN
225 150 CONTINUE
226
227 C FINALLY PARABOLAS
228
229 ELSEIF (KT.EQ.5) THEN
230
231 C CHECK LEGITIMACY OF DATA
232
233 IF (COOR (1, IP1).GT.COOR (1, IP2)) THEN
234 IJK = IP1
235 IP1 = IP2
236 IP2 = IJK
237 ENDIF
238 XMID = (COOR (1, IP1)+COOR (1, IP2)) * 0.5
239 YMID = (COOR (2, IP1)+COOR (2, IP2)) * 0.5
240 DOT = (COOR (1, IP2)-COOR (1, IP1)) * (COOR (1, IP3)-XMID)
241 & + (COOR (2, IP2)-COOR (2, IP1)) * (COOR (2, IP3)-YMID)
242 PERP = SQRT ((COOR (1, IP2)-COOR (1, IP1)) **2+ (COOR (2, IP2)-
243 & COOR (2, IP1)) **2) * SQRT ((COOR (1, IP3)-XMID) **2
244 & + (COOR (2, IP3) - YMID) **2)
245 IF (DOT.GE.0.05 * PERP) THEN
246 WRITE (*, 10020)ILINE (IL)
247 ERR = .TRUE.
248 RETURN
249 ENDIF
250
251 C GET TRANSFORMATION TO PARABOLA COORDINATE SYSTEM (Y = 4AX **2)
252
253 HALFW = SQRT ((COOR (1, IP2)-COOR (1, IP1)) **2 +
254 & (COOR (2, IP2) - COOR (2, IP1)) **2) *0.5
255 HEIGHT = SQRT ((XMID-COOR (1, IP3)) **2 +
256 & (YMID - COOR (2, IP3)) **2)
257 IF ((HEIGHT.EQ.0).OR. (HALFW.EQ.0.)) THEN
258 WRITE (*, 10030)ILINE (IL)
259 ERR = .TRUE.
260 RETURN
261 ENDIF
262 A = HEIGHT/ (HALFW **2)
263 XTOP = COOR (1, IP3)
264 YTOP = COOR (2, IP3)
265 THETA = ATAN2 (YMID-YTOP, XMID-XTOP)
266 SINT = SIN (THETA)
267 COST = COS (THETA)
268 IF (SINT.EQ.0.0) THEN
269 WRITE (*, 10040)ILINE (IL)
270 ERR = .TRUE.
271 RETURN
272 ENDIF
273 COTT = COST/SINT
274
275 C FIND THE EQUATION OF THE LINE FOR X = CONSTANT IN NEW COORDINATES
276
277 X0 = X-XTOP
278 B = - (SINT * X0)- (COTT * COST * X0)
279
280 C IF THE LINE HAS A ZERO SLOPE, THEN FIND THE SIMPLE SOLUTION
281
282 IF (COTT.EQ.0.0) THEN
283 YNEW = B
284 ELSE
285 DIVIS = 1.- (4. * COTT * A * B)
286 IF (DIVIS.LT.0.0) THEN
287 WRITE (*, 10050)ILINE (IL)
288 ERR = .TRUE.
289 RETURN
290 ENDIF
291 XDIVIS = SQRT (DIVIS)
292 Y1 = (1.+XDIVIS)/ (2. * COTT * A)
293 Y2 = (1.-XDIVIS)/ (2. * COTT * A)
294 IF ((ABS (Y1).LE.HALFW).AND. (ABS (Y2).GT.HALFW)) THEN
295 YNEW = Y1
296 ELSEIF ((ABS (Y2).LE.HALFW).AND. (ABS (Y1).GT.HALFW)) THEN
297 YNEW = Y2
298 ELSE
299 WRITE (*, 10060)ILINE (IL)
300 ENDIF
301 ENDIF
302
303 C TRANSLATE THIS XNEW TO A Y VALUE
304
305 XNEW = A * YNEW * YNEW
306 FRACT = (XNEW * SINT)+ (YNEW * COST)+YTOP
307 ENDIF
308
309 RETURN
310
311 10000 FORMAT (' POINTS GIVEN FOR LINE', I5, ' DO NOT DEFINE AN ARC')
312 10010 FORMAT (' NO X ON ARC LINE', I5, ' FOUND IN GETWT')
313 10020 FORMAT (' POINTS FOR LINE', I5, ' DOES NOT DEFINE A PARABOLA')
314 10030 FORMAT (' ZERO LINE LENGTH FOR PARABOLA LINE', I5, ' IN GETWT')
315 10040 FORMAT (' PARABOLA ALIGNMENT PROBLEMS FOR LINE', I5, ' IN GETWT')
316 10050 FORMAT (' PARABOLA INTERSECTION PROBLEMS FOR LINE', I5,
317 & ' IN GETWT')
318 10060 FORMAT (' PARABOLA SOLUTION PROBLEMS FOR LINE', I5, ' IN GETWT')
319
320 END