Debian Codegraph @

packages/seacas/applications/fastq/pickm5.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE PICKM5 (N, X, Y, ANGLE, IST2, IST3, IST4, IST5, INDST,
8 & M1, N1, N2, N3, N4)
9 C***********************************************************************
10
11 C SUBROUTINE PICKM5 = DETERMINES A REASONABLE SHAPE FOR A LOGICAL
12 C PENTAGON WITH PERIMETER GIVEN IN X AND Y
13
14 C***********************************************************************
15
16 C VARIABLES IN: N....... NUMBER OF POINTS
17 C X, Y.... ARRAY OF COORDINATES
18 C ANGLE... ARRAY OF ANGLES
19 C OUT: Ni...... POINTERS TO THE CHOSEN CORNERS
20
21 C WRITTEN BY: HORACIO RECALDE DATE: JAN, 1988
22
23 C**********************************************************************
24
25 PARAMETER (NSA = 10, NSA2 = 12)
26 PARAMETER (BIGNUM = 99999.0, MAXTRY = 10)
27
28 DIMENSION X(N), Y(N), ANGLE(N), IST1(NSA2), IST2(N), IST3(N)
29 DIMENSION IST4(N), IST5(N), INDEX(NSA + 1), INDST(N)
30 DIMENSION SMANG(NSA + 1)
31 LOGICAL CHECK
32
33 C--- SET THE MAXIMUM SIDE AND TOLERANCE
34
35 PI = ATAN2(0.0, -1.0)
36 MMAX = N/2 - 1
37 TOL = 150./180.*PI
38
39 C---GET THE 10 SMALLEST ANGLES
40
41 CALL CSMANG (N, X, Y, ANGLE, NSA, SMANG, INDEX)
42 IF (ANGLE (INDEX (1)) .GT. TOL) THEN
43 M1 = -1
44 RETURN
45 END IF
46
47 C---CHECK CONDITIONS ON THE 5 SMALLEST ANGLES
48
49 CALL CHCOND (N, NSA, SMANG, INDEX, M1, N1, N2, N3, N4, CHECK)
50 IF (CHECK) RETURN
51
52 SUMANG = BIGNUM
53
54 C---PUSH ANGLE INDEX ON FIRST STACK
55
56 CALL SKINIT (IST1, NSA2, NSA, IERROR)
57 DO 100 I = NSA, 1, -1
58 CALL SKPUSH (IST1, NSA2, INDEX (I), IERROR)
59 100 CONTINUE
60
61 C---POP TOP OF FIRST STACK
62
63 110 CONTINUE
64 CALL SKPOP (IST1, NSA2, M1, IERROR)
65 IF (IERROR .EQ. 2) GO TO 200
66 IF (ANGLE (M1) .GT. SUMANG) GO TO 200
67 SUM1 = ANGLE (M1)
68
69 C---SELECT SECOND TRIAL
70
71 MM1 = M1 + 2
72 IF (MM1 .GT. N) MM1 = MM1 - N
73 NN1 = MIN (M1 + MMAX, M1 + N - 8)
74 IF (NN1 .GT. N) NN1 = NN1 - N
75 CALL SORTST (N, ANGLE, MM1, NN1, IRANGE, INDST)
76
77 C---PUSH ANGLE INDEX ON SECOND STACK IN DESCENDING ORDER
78
79 CALL SKINIT (IST2, N, N - 2, IERROR)
80 DO 120 I = MIN (MAXTRY, IRANGE), 1, -1
81 CALL SKPUSH (IST2, N, INDST (I), IERROR)
82 120 CONTINUE
83
84 C---POP TOP OF SECOND STACK
85
86 130 CONTINUE
87 CALL SKPOP (IST2, N, M2, IERROR)
88 IF (IERROR .EQ. 2) GO TO 110
89 IF (SUM1 + ANGLE (M2) .GE. SUMANG) GO TO 110
90 SUM2 = SUM1 + ANGLE (M2)
91 N1 = M2 - M1
92 IF (N1 .LT. 0) N1 = N + N1
93
94 C---SELECT THIRD TRIAL NODE AND SORT IN ASCENDING ORDER
95
96 MM2 = M2 + 2
97 IF (MM2 .GT. N) MM2 = MM2 - N
98 NN2 = MIN (M1 + N1 + MMAX, M1 + N - 6)
99 IF (NN2 .GT. N) NN2 = NN2 - N
100 CALL SORTST (N, ANGLE, MM2, NN2, IRANGE, INDST)
101
102 C---PUSH ANGLE INDEX ON THIRD STACK IN DESCENDING ORDER
103
104 CALL SKINIT (IST3, N, N - 2, IERROR)
105 DO 140 I = MIN (MAXTRY, IRANGE), 1, -1
106 CALL SKPUSH (IST3, N, INDST (I), IERROR)
107 140 CONTINUE
108
109 C---POP TOP OF THIRD STACK
110
111 150 CONTINUE
112 CALL SKPOP (IST3, N, M3, IERROR)
113 IF (IERROR .EQ. 2) GO TO 130
114 IF (SUM2 + ANGLE (M3) .GE. SUMANG) GO TO 130
115 SUM3 = SUM2 + ANGLE (M3)
116 N2 = M3 - M2
117 IF (N2 .LT. 0) N2 = N + N2
118 IF (N1 + N2 .GT. N/2 -1) GO TO 150
119
120 C---SELECT FOURTH TRIAL AND SORT IN ASCENDING ORDER
121
122 MM3 = M3 + 2
123 IF (MM3 .GT. N) MM3 = MM3 - N
124 NN3 = MIN (M1 + N1 + N2 + MMAX, M1 + N - 4)
125 IF (NN3 .GT. N) NN3 = NN3 - N
126 CALL SORTST (N, ANGLE, MM3, NN3, IRANGE, INDST)
127
128 C---PUSH ANGLE INDEX ON FOURTH STACK IN DESCENDING ORDER
129
130 CALL SKINIT (IST4, N, N - 2, IERROR)
131 DO 160 I = MIN (MAXTRY, IRANGE), 1, -1
132 CALL SKPUSH (IST4, N, INDST (I), IERROR)
133 160 CONTINUE
134
135 C---POP TOP OF FOURTH STACK
136
137 170 CONTINUE
138 CALL SKPOP (IST4, N, M4, IERROR)
139 IF (IERROR .EQ. 2) GO TO 150
140 IF (SUM3 + ANGLE (M4) .GE. SUMANG) GO TO 150
141 SUM4 = SUM3 + ANGLE (M4)
142 N3 = M4 - M3
143 IF (N3 .LT. 0) N3 = N + N3
144 IF (N2 + N3 .GT. N/2 -1) GO TO 170
145
146 C---SELECT FIFTH TRIAL AND SORT IN ASCENDING ORDER
147
148 MM4 = M4 + 2
149 IF (MM4 .GT. N) MM4 = MM4 - N
150 NN4 = MIN (M1 + N1 + N2 + N3 + MMAX, M1 + N - 2)
151 IF (NN4 .GT. N) NN4 = NN4 - N
152 CALL SORTST (N, ANGLE, MM4, NN4, IRANGE, INDST)
153
154 C---PUSH ANGLE INDEX ON FIFTH STACK IN DESCENDING ORDER
155
156 CALL SKINIT (IST5, N, N - 2, IERROR)
157 DO 180 I = MIN (MAXTRY, IRANGE), 1, -1
158 CALL SKPUSH (IST5, N, INDST (I), IERROR)
159 180 CONTINUE
160
161 C---POP TOP OF FIFTH STACK
162
163 190 CONTINUE
164 CALL SKPOP (IST5, N, M5, IERROR)
165 IF (IERROR .EQ. 2) GO TO 170
166 IF (SUM4 + ANGLE (M5) .GT. SUMANG) GO TO 170
167
168 N4 = M5 - M4
169 IF (N4 .LT. 0) N4 = N + N4
170 N5 = M1 - M5
171 IF (N5 .LT. 0) N5 = N + N5
172
173 C--- CHECK COMPATIBILITY EQUATIONS
174
175 IF ( (N1 + N2 + N3 .LT. N4 + N5 + 2) .OR.
176 & (N2 + N3 + N4 .LT. N5 + N1 + 2) .OR.
177 & (N3 + N4 + N5 .LT. N1 + N2 + 2) .OR.
178 & (N4 + N5 + N1 .LT. N2 + N3 + 2) .OR.
179 & (N5 + N1 + N2 .LT. N3 + N4 + 2)) THEN
180 ELSE
181 SUMANG = SUM4 + ANGLE (M5)
182 M1HOLD = M1
183 N1HOLD = N1
184 N2HOLD = N2
185 N3HOLD = N3
186 N4HOLD = N4
187 END IF
188 GO TO 190
189
190 200 CONTINUE
191 IF (SUMANG .EQ. BIGNUM) THEN
192 M1 = 0
193 ELSE
194 M1 = M1HOLD
195 N1 = N1HOLD
196 N2 = N2HOLD
197 N3 = N3HOLD
198 N4 = N4HOLD
199 END IF
200
201 RETURN
202 END