Debian Codegraph @

packages/seacas/applications/fastq/ciapal.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE CIAPAL (MXND, XN, YN, LXK, KXL, NXL, LXN, NNN, NNNOLD,
8 & NIT, EPS, RO, ALPHA)
9 C***********************************************************************
10
11 C SUBROUTINE CIAPAL = CENTROID INVERSE AREA PUSH AND LAPLACIAN SMOOTH
12
13 C***********************************************************************
14
15 C NOTE:
16 C IN THIS METHOD EACH CENTROID OF AN ELEMENT PUSHES OUT
17 C ON THE SURROUNDING NODES WITH A FORCE INVERSELY PROPORTIONAL
18 C TO THE AREA OF THE ELEMENT WHILE IT SIMULTANEOUSLY PULLS ON
19 C EACH NODE WITH A FORCE PROPORTIONAL TO THE LENGTH OF THE LINE
20 C CONNECTING THE CENTROID WITH EACH NODE.
21
22 C***********************************************************************
23
24 C VARIABLES USED:
25 C NIT = MAX NUMBER OF ITERATIONS TO DO
26 C EPS = NODE MOVEMENT TOLERANCE FOR CONVERGENCE
27 C RO = UNDER OR OVER-RELAXATION FACTOR.
28 C ALPHA = WEIGHT GIVEN TO AREA-PUSH VECTOR. USUALLY=0.5.
29 C WEIGHT GIVEN TO LAPLACIAN VECTOR = 1.-ALPHA.
30
31 C***********************************************************************
32
33 DIMENSION NODES (4)
34 DIMENSION KLIST (20), AREA (20), XCEN (20), YCEN (20)
35 DIMENSION LXK (4, MXND), KXL (2, 3*MXND)
36 DIMENSION NXL (2, 3*MXND), LXN (4, MXND)
37 DIMENSION XN (MXND), YN (MXND)
38
39 LOGICAL BIG, CCW, ERR
40 EPS2 = (EPS * RO) **2
41 BETA = 1.0 - ALPHA
42
43 C ITERATION LOOP
44
45 DO 140 IT = 1, NIT
46 BIG = .FALSE.
47
48 C NODE LOOP
49
50 DO 130 NODE = NNNOLD + 1, NNN
51
52 C SKIP CONTINUATION LINES AND BOUNDARY LINES
53
54 IF ((LXN (1, NODE).GT.0) .AND. (LXN (2, NODE).GT.0)) THEN
55
56 C GET ELEMENT LIST (IGNORE ERR IF IT IS BECAUSE TOO MANY WERE FOUND)
57
58 CALL GKXN (MXND, KXL, LXN, NODE, NUMK, KLIST, ERR)
59 IF ((ERR) .AND. (NUMK.LT.20))RETURN
60
61 C GET AREAS AND CENTROIDS
62
63 DO 110 IK = 1, NUMK
64 KK = KLIST (IK)
65 CCW = .TRUE.
66 CALL GNXKA (MXND, XN, YN, KK, NODES, AREA (IK), LXK,
67 & NXL, CCW)
68 XSUM = 0.
69 YSUM = 0.
70 DO 100 I = 1, 4
71 NN = NODES (I)
72 XSUM = XSUM + XN (NN)
73 YSUM = YSUM + YN (NN)
74 100 CONTINUE
75 XCEN (IK) = 0.25 * XSUM
76 YCEN (IK) = 0.25 * YSUM
77 110 CONTINUE
78
79 C COMPUTE AND SUM THE FORCE VECTORS
80
81 FX = 0.
82 FY = 0.
83 SUMW = 0.
84 SDX = 0.
85 SDY = 0.
86 DO 120 IK = 1, NUMK
87 DX = XCEN (IK) - XN (NODE)
88 DY = YCEN (IK) - YN (NODE)
89 AL2 = DX * DX + DY * DY
90 ARL = AREA (IK) * SQRT (AL2)
91 WEIGHT = 1.0E20
92 IF (ARL.GT.0.)WEIGHT = 1.0/ARL
93 SUMW = SUMW + WEIGHT
94 FX = FX - WEIGHT * DX
95 FY = FY - WEIGHT * DY
96 SDX = SDX + DX
97 SDY = SDY + DY
98 120 CONTINUE
99
100 C MOVE THE NODE
101
102 RSUMW = 1.0/SUMW
103 RNUMK = 1.0/DBLE(NUMK)
104 FX = ALPHA * FX * RSUMW + BETA * SDX * RNUMK
105 FY = ALPHA * FY * RSUMW + BETA * SDY * RNUMK
106 DELX = RO * FX
107 DELY = RO * FY
108 XN (NODE) = XN (NODE) + DELX
109 YN (NODE) = YN (NODE) + DELY
110 IF (DELX ** 2 + DELY ** 2 .GT. EPS2)BIG = .TRUE.
111 ENDIF
112 130 CONTINUE
113 IF (.NOT.BIG) RETURN
114 140 CONTINUE
115 RETURN
116 END