Debian Codegraph @

packages/seacas/applications/fastq/wrgens.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 SUBROUTINE WRGENS (MS, MR, NPNODE, NPELEM, MXNFLG, MXSFLG, NPREGN,
8 & NPNBC, NPSBC, IUNIT, NNN, KKK, NNXK, NODES, NELEMS, NNFLG,
9 & NNPTR, NNLEN, NSFLG, NSPTR, NSLEN, NVPTR, NVLEN, NSIDEN,
10 & MAPDXG, XN, YN, NXK, MAT, MAPGXD, MATMAP, WTNODE, WTSIDE,
11 & NBCNOD, NNLIST, NBCSID, NSLIST, NVLIST, NUMMAT, LINKM, TITLE,
12 & ERR, EIGHT, NINE, VERSN)
13 C************************************************************************
14
15 C SUBROUTINE WRGENS = WRITES GENESIS DATABASE MESH OUTPUT
16
17 C***********************************************************************
18
19 PARAMETER (IGUESS = 1000)
20
21 C IGUESS IS THE NUMBER OF ELEMENT BLOCKS, FOR USE WITH THE ENAME
22 C VARIABLE. IF THIS VARIABLE IS NOT AS LARGE AS NUMMAT, IT WILL NOT
23 C RESULT IN A FATAL ERROR, BUT SIMPLY A WARNING, AND NO ELEMENT
24 C NAMES WILL BE WRITTEN.
25
26 DIMENSION XN (NPNODE), YN (NPNODE), NXK (NNXK, NPELEM)
27 DIMENSION MAT (NPELEM)
28 DIMENSION NODES (NPNBC), NELEMS (NPSBC), NSIDEN (NPSBC)
29 DIMENSION NNFLG (MXNFLG), NNLEN (MXNFLG)
30 DIMENSION NNPTR (MXNFLG), WTNODE (NPNBC)
31 DIMENSION NSFLG (MXSFLG), NSLEN (MXSFLG)
32 DIMENSION NSPTR (MXSFLG), WTSIDE (NPSBC)
33 DIMENSION NVLEN (MXSFLG), NVPTR (MXSFLG), LINKM (2, (MS+MR))
34 DIMENSION MAPDXG (NPNODE), MAPGXD (NPNODE), MATMAP (3, NPREGN)
35
36 CHARACTER*72 TITLE, HOLD*80
37 CHARACTER*8 DATE, TIME, VERSN1, VERSN2, XNAME, YNAME
38 CHARACTER*8 ENAME (IGUESS)
39 CHARACTER*10 VERSN
40
41 LOGICAL ERR, EIGHT, NINE
42
43 integer lcon(9)
44 integer lbar(3)
45
46 data lcon /1,3,5,7,2,4,6,8,9/
47 data lbar /1,3,2/
48
49 CALL EXDATE (DATE)
50 CALL EXTIME (TIME)
51 VERSN1 = ' '
52 VERSN2 = ' '
53 VERSN1 = VERSN (1:5)
54 VERSN2 = VERSN (6:10)
55 ERR = .TRUE.
56 HOLD = TITLE
57 XNAME = 'X'
58 YNAME = 'Y'
59
60 C CHECK TO MAKE SURE THAT THERE IS ENOUGH ROOM FOR ELEMENT NAMES
61
62 IF (NUMMAT.GT.IGUESS) THEN
63 CALL MESSAGE('WARNING: THE NUMBER OF ELEMENT BLOCKS EXCEEDS')
64 CALL MESSAGE(' THE CAPACITY TO NAME EACH BLOCK.')
65 CALL MESSAGE(' NO ELEMENT NAMES WILL BE WRITTEN.')
66 ENDIF
67
68 C WRITE OUT HEADER INFORMATION
69
70 WRITE (IUNIT, ERR = 110)HOLD
71 IJK = 2
72 IVERS = 1
73 C ... Fix up side set nodes for 8 and 9 node elements.
74 C ... At this point, they are treated as two linear segments,
75 C ... They should be ends followed by middle
76
77 C 1-----3-----2 Now: 1 3 3 2 Correct: 1 2 3
78
79 if (eight .or. nine) then
80 nvlst = nvlist / 4 * 3
81 if (nslist .gt. 1) then
82 nslst = nslist / 2
83 else
84 nslst = nslist
85 end if
86 else
87 nvlst = nvlist
88 nslst = nslist
89 end if
90
91 WRITE (IUNIT, ERR = 110)NNN, IJK, KKK, NUMMAT, NBCNOD, NNLIST,
92 & NBCSID, NSLST, NVLST, IVERS
93
94 C WRITE OUT NODE BLOCK
95
96 WRITE (IUNIT, ERR = 110) (XN (I), I = 1, NNN),
97 & (YN (I), I = 1, NNN)
98 WRITE (IUNIT, ERR = 110) (MAPDXG (I), I = 1, KKK)
99
100 C WRITE OUT ELEMENT BLOCKS
101
102 DO 100 I = 1, NUMMAT
103 IF (NXK (3, MATMAP (2, I)) .EQ. 0) THEN
104 INODE = 2
105 NATTR = 1
106 ATTR = 1.
107 IF (I.LE.IGUESS)ENAME (I) = 'BEAM'
108 ELSEIF (NXK (4, MATMAP (2, I)) .EQ. 0) THEN
109 INODE = 3
110 NATTR = 1
111 ATTR = 1.
112 IF (I.LE.IGUESS)ENAME (I) = 'BEAM'
113 CALL MESSAGE('NOTE: The connectivity numbering for 3-node')
114 CALL MESSAGE(' beams/trusses has been fixed to')
115 CALL MESSAGE(' conform to EXODUS convention (1-3-2)')
116 ELSEIF (EIGHT) THEN
117 INODE = 8
118 NATTR = 0
119 IF (I.LE.IGUESS)ENAME (I) = 'QUAD'
120 ELSEIF (NINE) THEN
121 INODE = 9
122 NATTR = 0
123 IF (I.LE.IGUESS)ENAME (I) = 'QUAD'
124 ELSE
125 INODE = 4
126 NATTR = 0
127 IF (I.LE.IGUESS)ENAME (I) = 'QUAD'
128 ENDIF
129
130 C NLOOP IS NEEDED TO WRITE SOMETHING OUT THE CURRENT COUNTER IS ZERO.
131 C THIS IS DONE TO SOLVE A CRAY OPERATING SYSTEM [CTSS] PROBLEM
132 C WHERE NULL RECORD WRITES ARE NOT DONE APPROPRIATELY
133
134 WRITE (IUNIT, ERR = 110) MATMAP (1, I),
135 & MATMAP (3, I) - MATMAP (2, I)+1, INODE, NATTR
136 C... 8 or 9 node quads
137 IF (INODE .EQ. 8 .or. inode .eq. 9) THEN
138 write (iunit, err = 110) ((nxk(lcon(ii), k), ii=1, nnxk),
139 $ k = matmap(2,i), matmap(3,i))
140 C... 3 node beam/truss
141 ELSEIF (INODE .EQ. 3) THEN
142 write (iunit, err = 110) ((nxk(lbar(ii), k), ii=1, inode),
143 $ k = matmap(2,i), matmap(3,i))
144 C... 4 node quad or 2 node beam/truss
145 ELSE
146 WRITE (IUNIT, ERR = 110) ((NXK (J, K), J = 1, INODE),
147 & K = MATMAP (2, I), MATMAP (3, I))
148 ENDIF
149 NLOOP = MAX0 (1, NATTR*KKK)
150 WRITE (IUNIT, ERR = 110) (ATTR, J = 1, NLOOP)
151 100 CONTINUE
152
153 C WRITE OUT NODAL BOUNDARY FLAGS
154
155 NLOOP = MAX0 (1, NBCNOD)
156 WRITE (IUNIT, ERR = 110) (NNFLG (I), I = 1, NLOOP)
157 WRITE (IUNIT, ERR = 110) (NNLEN (I), I = 1, NLOOP)
158 WRITE (IUNIT, ERR = 110) (NNPTR (I), I = 1, NLOOP)
159 NLOOP = MAX0 (1, NNLIST)
160 WRITE (IUNIT, ERR = 110) (NODES (I), I = 1, NLOOP)
161 WRITE (IUNIT, ERR = 110) (WTNODE (I), I = 1, NLOOP)
162
163 C WRITE OUT SIDE BOUNDARY FLAGS
164
165 C ... Fix up side set nodes and elements for 8 and 9 node elements.
166 C ... At this point, they are treated as two linear segments,
167 C ... They should be ends followed by middle
168
169 C 1-----3-----2 Now: 1 3 3 2 Correct: 1 2 3
170
171 if (eight .or. nine) then
172 ipn = 1
173 ipe = 1
174 do 130 ibc = 1, nbcsid
175
176 ibee = nsptr(ibc)
177 iene = nsptr(ibc) + nslen(ibc) - 1
178 nsptr(ibc) = ipe
179 nslen(ibc) = max(1, nslen(ibc)/2)
180 do 115 iel = ibee, iene, 2
181 nelems(ipe) = nelems(iel)
182 ipe = ipe + 1
183 115 continue
184
185 ibeg = nvptr(ibc)
186 iend = nvptr(ibc) + nvlen(ibc) - 1
187 nvptr(ibc) = ipn
188 nvlen(ibc) = nvlen(ibc) / 4 * 3
189
190 do 120 inod = ibeg, iend, 4
191 nsiden(ipn) = nsiden(inod)
192 nsiden(ipn+2) = nsiden(inod+1)
193 nsiden(ipn+1) = nsiden(inod+3)
194 wtside(ipn) = wtside(inod)
195 wtside(ipn+2) = wtside(inod+1)
196 wtside(ipn+1) = wtside(inod+3)
197 ipn = ipn + 3
198 120 continue
199 130 continue
200 nvlist = ipn - 1
201 nslist = ipe - 1
202 end if
203
204 NLOOP = MAX0 (1, NBCSID)
205 WRITE (IUNIT, ERR = 110) (NSFLG (I), I = 1, NLOOP)
206 WRITE (IUNIT, ERR = 110) (NSLEN (I), I = 1, NLOOP)
207 WRITE (IUNIT, ERR = 110) (NVLEN (I), I = 1, NLOOP)
208 WRITE (IUNIT, ERR = 110) (NSPTR (I), I = 1, NLOOP)
209 WRITE (IUNIT, ERR = 110) (NVPTR (I), I = 1, NLOOP)
210 NLOOP = MAX0 (1, NSLIST)
211 WRITE (IUNIT, ERR = 110) (NELEMS (I), I = 1, NLOOP)
212 NLOOP = MAX0 (1, NVLIST)
213 WRITE (IUNIT, ERR = 110) (NSIDEN (I), I = 1, NLOOP)
214 WRITE (IUNIT, ERR = 110) (WTSIDE (I), I = 1, NLOOP)
215
216 C WRITE OUT THE QA INFORMATION
217
218 IHOLD = 1
219 WRITE (IUNIT, ERR = 110)IHOLD
220 WRITE (IUNIT, ERR = 110)VERSN1, VERSN2, DATE, TIME
221
222 C WRITE THE HEADER INFORMATION
223
224 IHOLD = 0
225 WRITE (IUNIT, ERR = 110)IHOLD
226
227 C WRITE THE COORDINATE NAMES AND ELEMENT NAMES
228
229 WRITE (IUNIT)XNAME, YNAME
230 IF (NUMMAT.LE.IGUESS)WRITE (IUNIT) (ENAME (I), I = 1, NUMMAT)
231
232 C SUCCESSFUL WRITE COMPLETED
233
234 CALL MESSAGE(' ')
235 CALL MESSAGE(' ')
236 CALL MESSAGE('GENESIS OUTPUT FILE SUCCESSFULLY WRITTEN')
237 CALL MESSAGE(' ')
238 ERR = .FALSE.
239 RETURN
240
241 C ERR DURING WRITE PROBLEMS
242
243 110 CONTINUE
244 CALL MESSAGE('ERR DURING WRITE TO OUTPUT FILE')
245 CALL MESSAGE(' - NO FILE SAVED -')
246 RETURN
247
248 END