Debian Codegraph @

examples/bio_nsg/bio_template/components/mechanisms/modfiles/stp5isyn.mod

raw
1 COMMENT
2 Current-based version of the conductance-based model stp5syn (refer to the stp5syn.mod)
3 In this model the synatic current is defined as i = g*e, whereas in the conductance based model i = g*(v - e).
4 Since the current is proportional to conductance, this model may be used to report the values of conductance by recording the current.
5
6 ENDCOMMENT
7
8
9 NEURON {
10 POINT_PROCESS stp5isyn
11 RANGE e, i, tau_1, tau_r0, a_FDR, tau_FDR, a_D, tau_D, a_i, tau_i, a_f, tau_f, pbtilde, Pmax
12 NONSPECIFIC_CURRENT i
13 }
14
15 UNITS {
16 (nA) = (nanoamp)
17 (mV) = (millivolt)
18 (umho) = (micromho)
19 }
20
21 PARAMETER {
22 : e = synaptic reversal potential
23 e = 0 (mV)
24
25 : tau_1 = baseline level of release probability
26 tau_1 = 10 (ms)
27
28 : tau_r0 = baseline level of tau_r0
29 tau_r0 = 1000 (ms)
30
31 : tau_FDR = time constant for tau_r relaxation
32 tau_FDR = 1000 (ms)
33
34 : a_FDR = amount of tau_r reduction after each spike
35 a_FDR = 0.5
36
37 : tau_D = relaxation time of D
38 tau_D = 100 (ms)
39
40 : a_D = amount of desentization
41 a_D = 0.5
42
43 : tau_i = relaxation time for p0
44 tau_i = 100 (ms)
45
46 : a_i = amount of decrease of baseline probability after each spike
47 a_i = 0.5
48
49 : tau_f = facilitation time constant (relaxation time constant for p)
50 tau_f = 10 (ms)
51
52 : a_f = amount of facilitation (increase of p after each spike)
53 a_f = 0.5
54
55 : pbtilde = baseline level of pb
56 pbtilde = 0.5
57
58 }
59
60 ASSIGNED {
61 v (mV)
62 i (nA)
63 Pmax
64 }
65
66 STATE {
67 n
68 p
69 tau_r
70 D
71 pb
72 g
73 }
74
75 INITIAL {
76 n=1
77 pb=pbtilde
78 p=pb
79 tau_r=tau_r0
80 D=1
81 g=0
82
83 }
84
85 BREAKPOINT {
86 SOLVE state METHOD cnexp
87 : i = g*(v - e)
88 i = g*e
89 Pmax = n*p*D
90
91 }
92
93 DERIVATIVE state {
94 g' = -g/tau_1
95 n' = (1-n)/tau_r
96 p' = (pb-p)/tau_f
97 tau_r' = (tau_r0-tau_r)/tau_FDR
98 D' = (1-D)/tau_D
99 pb' = (pbtilde-pb)/tau_i
100
101 }
102
103 NET_RECEIVE(weight (umho)) {
104 g = g + weight*Pmax
105 n = n - n*p
106 p = p + a_f*(1-p)
107 tau_r = tau_r - a_FDR*tau_r
108 D = D - a_D*p*n*D
109 pb = pb - a_i*pb
110
111 }
112
113