Debian Codegraph @

examples/bio_nsg/bio_template/K_P.mod

raw
1 : Comment: The persistent component of the K current
2 : Reference: Voltage-gated K+ channels in layer 5 neocortical pyramidal neurones from young rats:subtypes and gradients,Korngreen and Sakmann, J. Physiology, 2000
3
4
5 NEURON {
6 SUFFIX K_P
7 USEION k READ ek WRITE ik
8 RANGE gbar, g, ik
9 }
10
11 UNITS {
12 (S) = (siemens)
13 (mV) = (millivolt)
14 (mA) = (milliamp)
15 }
16
17 PARAMETER {
18 gbar = 0.00001 (S/cm2)
19 vshift = 0 (mV)
20 tauF = 1
21 }
22
23 ASSIGNED {
24 v (mV)
25 ek (mV)
26 ik (mA/cm2)
27 g (S/cm2)
28 celsius (degC)
29 mInf
30 mTau
31 hInf
32 hTau
33 }
34
35 STATE {
36 m
37 h
38 }
39
40 BREAKPOINT {
41 SOLVE states METHOD cnexp
42 g = gbar*m*m*h
43 ik = g*(v-ek)
44 }
45
46 DERIVATIVE states {
47 rates()
48 m' = (mInf-m)/mTau
49 h' = (hInf-h)/hTau
50 }
51
52 INITIAL{
53 rates()
54 m = mInf
55 h = hInf
56 }
57
58 PROCEDURE rates() {
59 LOCAL qt
60 qt = 2.3^((celsius-21)/10)
61 UNITSOFF
62 mInf = 1 / (1 + exp(-(v - (-14.3 + vshift)) / 14.6))
63 if (v < -50 + vshift){
64 mTau = tauF * (1.25+175.03*exp(-(v - vshift) * -0.026))/qt
65 } else {
66 mTau = tauF * (1.25+13*exp(-(v - vshift) * 0.026))/qt
67 }
68 hInf = 1/(1 + exp(-(v - (-54 + vshift))/-11))
69 hTau = (360+(1010+24*(v - (-55 + vshift)))*exp(-((v - (-75 + vshift))/48)^2))/qt
70 UNITSON
71 }