Debian Codegraph @

examples/bio_nsg/bio_template/NaV.mod

raw
1 TITLE Mouse sodium current
2 : Kinetics of Carter et al. (2012)
3 : Based on 37 degC recordings from mouse hippocampal CA1 pyramids
4
5 NEURON {
6 SUFFIX NaV
7 USEION na READ ena WRITE ina
8 RANGE g, gbar
9 }
10
11 UNITS {
12 (mV) = (millivolt)
13 (S) = (siemens)
14 }
15
16 PARAMETER {
17 gbar = .015 (S/cm2)
18
19 : kinetic parameters
20 Con = 0.01 (/ms) : closed -> inactivated transitions
21 Coff = 40 (/ms) : inactivated -> closed transitions
22 Oon = 8 (/ms) : open -> Ineg transition
23 Ooff = 0.05 (/ms) : Ineg -> open transition
24 alpha = 400 (/ms)
25 beta = 12 (/ms)
26 gamma = 250 (/ms) : opening
27 delta = 60 (/ms) : closing
28
29 alfac = 2.51
30 btfac = 5.32
31
32 : Vdep
33 x1 = 24 (mV) : Vdep of activation (alpha)
34 x2 = -24 (mV) : Vdep of deactivation (beta)
35 }
36
37 ASSIGNED {
38
39 : rates
40 f01 (/ms)
41 f02 (/ms)
42 f03 (/ms)
43 f04 (/ms)
44 f0O (/ms)
45 f11 (/ms)
46 f12 (/ms)
47 f13 (/ms)
48 f14 (/ms)
49 f1n (/ms)
50 fi1 (/ms)
51 fi2 (/ms)
52 fi3 (/ms)
53 fi4 (/ms)
54 fi5 (/ms)
55 fin (/ms)
56
57 b01 (/ms)
58 b02 (/ms)
59 b03 (/ms)
60 b04 (/ms)
61 b0O (/ms)
62 b11 (/ms)
63 b12 (/ms)
64 b13 (/ms)
65 b14 (/ms)
66 b1n (/ms)
67 bi1 (/ms)
68 bi2 (/ms)
69 bi3 (/ms)
70 bi4 (/ms)
71 bi5 (/ms)
72 bin (/ms)
73
74 v (mV)
75 ena (mV)
76 ina (milliamp/cm2)
77 g (S/cm2)
78 celsius (degC)
79 }
80
81 STATE {
82 C1 FROM 0 TO 1
83 C2 FROM 0 TO 1
84 C3 FROM 0 TO 1
85 C4 FROM 0 TO 1
86 C5 FROM 0 TO 1
87 I1 FROM 0 TO 1
88 I2 FROM 0 TO 1
89 I3 FROM 0 TO 1
90 I4 FROM 0 TO 1
91 I5 FROM 0 TO 1
92 O FROM 0 TO 1
93 I6 FROM 0 TO 1
94 }
95
96 BREAKPOINT {
97 SOLVE activation METHOD sparse
98 g = gbar * O
99 ina = g * (v - ena)
100 }
101
102 INITIAL {
103 rates(v)
104 SOLVE seqinitial
105 }
106
107 KINETIC activation
108 {
109 rates(v)
110 ~ C1 <-> C2 (f01,b01)
111 ~ C2 <-> C3 (f02,b02)
112 ~ C3 <-> C4 (f03,b03)
113 ~ C4 <-> C5 (f04,b04)
114 ~ C5 <-> O (f0O,b0O)
115 ~ O <-> I6 (fin,bin)
116 ~ I1 <-> I2 (f11,b11)
117 ~ I2 <-> I3 (f12,b12)
118 ~ I3 <-> I4 (f13,b13)
119 ~ I4 <-> I5 (f14,b14)
120 ~ I5 <-> I6 (f1n,b1n)
121 ~ C1 <-> I1 (fi1,bi1)
122 ~ C2 <-> I2 (fi2,bi2)
123 ~ C3 <-> I3 (fi3,bi3)
124 ~ C4 <-> I4 (fi4,bi4)
125 ~ C5 <-> I5 (fi5,bi5)
126
127 CONSERVE C1 + C2 + C3 + C4 + C5 + O + I1 + I2 + I3 + I4 + I5 + I6 = 1
128 }
129
130 LINEAR seqinitial { : sets initial equilibrium
131 ~ I1*bi1 + C2*b01 - C1*( fi1+f01) = 0
132 ~ C1*f01 + I2*bi2 + C3*b02 - C2*(b01+fi2+f02) = 0
133 ~ C2*f02 + I3*bi3 + C4*b03 - C3*(b02+fi3+f03) = 0
134 ~ C3*f03 + I4*bi4 + C5*b04 - C4*(b03+fi4+f04) = 0
135 ~ C4*f04 + I5*bi5 + O*b0O - C5*(b04+fi5+f0O) = 0
136 ~ C5*f0O + I6*bin - O*(b0O+fin) = 0
137
138 ~ C1*fi1 + I2*b11 - I1*( bi1+f11) = 0
139 ~ I1*f11 + C2*fi2 + I3*b12 - I2*(b11+bi2+f12) = 0
140 ~ I2*f12 + C3*fi3 + I4*bi3 - I3*(b12+bi3+f13) = 0
141 ~ I3*f13 + C4*fi4 + I5*b14 - I4*(b13+bi4+f14) = 0
142 ~ I4*f14 + C5*fi5 + I6*b1n - I5*(b14+bi5+f1n) = 0
143
144 ~ C1 + C2 + C3 + C4 + C5 + O + I1 + I2 + I3 + I4 + I5 + I6 = 1
145 }
146
147 PROCEDURE rates(v(mV) )
148 {
149 LOCAL qt
150 qt = 2.3^((celsius-37)/10)
151
152 f01 = qt * 4 * alpha * exp(v/x1)
153 f02 = qt * 3 * alpha * exp(v/x1)
154 f03 = qt * 2 * alpha * exp(v/x1)
155 f04 = qt * 1 * alpha * exp(v/x1)
156 f0O = qt * gamma
157 f11 = qt * 4 * alpha * alfac * exp(v/x1)
158 f12 = qt * 3 * alpha * alfac * exp(v/x1)
159 f13 = qt * 2 * alpha * alfac * exp(v/x1)
160 f14 = qt * 1 * alpha * alfac * exp(v/x1)
161 f1n = qt * gamma
162 fi1 = qt * Con
163 fi2 = qt * Con * alfac
164 fi3 = qt * Con * alfac^2
165 fi4 = qt * Con * alfac^3
166 fi5 = qt * Con * alfac^4
167 fin = qt * Oon
168
169 b01 = qt * 1 * beta * exp(v/x2)
170 b02 = qt * 2 * beta * exp(v/x2)
171 b03 = qt * 3 * beta * exp(v/x2)
172 b04 = qt * 4 * beta * exp(v/x2)
173 b0O = qt * delta
174 b11 = qt * 1 * beta * exp(v/x2) / btfac
175 b12 = qt * 2 * beta * exp(v/x2) / btfac
176 b13 = qt * 3 * beta * exp(v/x2) / btfac
177 b14 = qt * 4 * beta * exp(v/x2) / btfac
178 b1n = qt * delta
179 bi1 = qt * Coff
180 bi2 = qt * Coff / (btfac)
181 bi3 = qt * Coff / (btfac^2)
182 bi4 = qt * Coff / (btfac^3)
183 bi5 = qt * Coff / (btfac^4)
184 bin = qt * Ooff
185 }
186