Debian Codegraph @

examples/bio_nsg/bio_template/stp5syn.mod

raw
1 COMMENT
2 A model (# 5 using terminology of Jung Hoon Lee) of a short-term synaptic plasticity.
3 The magnitude of the peak conductance is found by solving Eqs (3,4,5,8,10) in Hennig, 2013. "Theoretical models of synaptic short term plasticity. Frontiers in computational neuroscience, 7, p.45."
4 This file could be used to simulate simpler models by setting to zero the parameters in the unused equations(e.g, a_D,a_i,a_f).
5
6 State variables:
7
8 n = fraction of available vesicles
9 D = fraction of non-desensitized receptors
10 tau_r = time constant for vesicle replenishment
11 pb = baseline vesicle release probability
12 p = vesicle release probability
13
14 After each spike the magnitude of the peak conductance changes by the factor w*Pmax, where w is the static synaptic weight and Pmax is the activity-dependent factor that could be interpreted as a probability of a transmitter release by the presynaptic terminal.
15
16 The post_synaptic dynamics of individual synaptic events is modeled by a single exponential synapse with the time constant tau_1.
17
18 Implemented by Sergey L. Gratiy,
19
20 ENDCOMMENT
21
22 : Declaring parameters as RANGE allows them to change as a function of a position alogn the cell
23 NEURON {
24 POINT_PROCESS stp5syn
25 RANGE e, i, tau_1, tau_r0, a_FDR, tau_FDR, a_D, tau_D, a_i, tau_i, a_f, tau_f, pbtilde, Pmax
26 NONSPECIFIC_CURRENT i
27 }
28
29 UNITS {
30 (nA) = (nanoamp)
31 (mV) = (millivolt)
32 (umho) = (micromho)
33 }
34
35 : Declaration of the default values of parameters
36 PARAMETER {
37 : e = synaptic reversal potential
38 e = 0 (mV)
39
40 : tau_1 = baseline level of release probability
41 tau_1 = 10 (ms)
42
43 : tau_r0 = baseline level of tau_r0
44 tau_r0 = 1000 (ms)
45
46 : tau_FDR = time constant for tau_r relaxation
47 tau_FDR = 1000 (ms)
48
49 : a_FDR = amount of tau_r reduction after each spike
50 a_FDR = 0.5
51
52 : tau_D = relaxation time of D
53 tau_D = 100 (ms)
54
55 : a_D = amount of desentization
56 a_D = 0.5
57
58 : tau_i = relaxation time for p0
59 tau_i = 100 (ms)
60
61 : a_i = amount of decrease of baseline probability after each spike
62 a_i = 0.5
63
64 : tau_f = facilitation time constant (relaxation time constant for p)
65 tau_f = 10 (ms)
66
67 : a_f = amount of facilitation (increase of p after each spike)
68 a_f = 0.5
69
70 : pbtilde = baseline level of p0
71 pbtilde = 0.5
72
73 }
74 : Declaration of dependent and external variables that collectively are called ASSIGNED
75 ASSIGNED {
76 v (mV)
77 i (nA)
78 Pmax
79 }
80
81 : Declaration of the state variables
82 STATE {
83 n
84 p
85 tau_r
86 D
87 pb
88 g
89 }
90
91 : Initial conditions for the state variables
92 INITIAL {
93 n=1
94 p=1
95 tau_r=tau_r0
96 D=1
97 pb=pbtilde
98 g=0
99
100 }
101
102 : Integration method + assignment statements
103 BREAKPOINT {
104 SOLVE state METHOD cnexp
105 i = g*(v - e)
106 Pmax = n*p*D
107 }
108
109 : Definition of teh dynamics between the presynaptic activations
110 DERIVATIVE state {
111 n' = (1-n)/tau_r
112 p' = (pb-p)/tau_f
113 tau_r' = (tau_r0-tau_r)/tau_FDR
114 D' = (1-D)/tau_D
115 pb' = (pbtilde-pb)/tau_i
116 g' = -g/tau_1
117
118 }
119
120 : This block defines what happens to the state variables at the moment presynaptic activation
121 NET_RECEIVE(weight (umho)) {
122 g = g + weight*Pmax
123 n = n - n*p
124 p = p + a_f*(1-p)
125 tau_r = tau_r - a_FDR*tau_r
126 D = D - a_D*p*n*D
127 pb = pb - a_i*pb
128
129 }
130
131