Debian Codegraph @

examples/bio_nsg/bio_template/Ca_LVA.mod

raw
1 : Comment: LVA ca channel. Note: mtau is an approximation from the plots
2 : Reference: Avery and Johnston 1996, tau from Randall 1997
3 : Comment: shifted by -10 mv to correct for junction potential
4 : Comment: corrected rates using q10 = 2.3, target temperature 34, orginal 21
5
6 NEURON {
7 SUFFIX Ca_LVA
8 USEION ca READ eca WRITE ica
9 RANGE gbar, g, ica
10 }
11
12 UNITS {
13 (S) = (siemens)
14 (mV) = (millivolt)
15 (mA) = (milliamp)
16 }
17
18 PARAMETER {
19 gbar = 0.00001 (S/cm2)
20 }
21
22 ASSIGNED {
23 v (mV)
24 eca (mV)
25 ica (mA/cm2)
26 g (S/cm2)
27 celsius (degC)
28 mInf
29 mTau
30 hInf
31 hTau
32 }
33
34 STATE {
35 m
36 h
37 }
38
39 BREAKPOINT {
40 SOLVE states METHOD cnexp
41 g = gbar*m*m*h
42 ica = g*(v-eca)
43 }
44
45 DERIVATIVE states {
46 rates()
47 m' = (mInf-m)/mTau
48 h' = (hInf-h)/hTau
49 }
50
51 INITIAL{
52 rates()
53 m = mInf
54 h = hInf
55 }
56
57 PROCEDURE rates(){
58 LOCAL qt
59 qt = 2.3^((celsius-21)/10)
60
61 UNITSOFF
62 v = v + 10
63 mInf = 1.0000/(1+ exp((v - -30.000)/-6))
64 mTau = (5.0000 + 20.0000/(1+exp((v - -25.000)/5)))/qt
65 hInf = 1.0000/(1+ exp((v - -80.000)/6.4))
66 hTau = (20.0000 + 50.0000/(1+exp((v - -40.000)/7)))/qt
67 v = v - 10
68 UNITSON
69 }