Debian Codegraph @

examples/bio_nsg/bio_template/components/mechanisms/modfiles/stp2syn.mod

raw
1 COMMENT
2 A model (# 2 using terminology of Jung Hoon Lee) of a short-term synaptic plasticity.
3 The magnitude of the peak conductance is found by solving Eqs (3,5) in Hennig, 2013. "Theoretical models of synaptic short term plasticity. Frontiers in computational neuroscience, 7, p.45."
4
5 State variables:
6
7 n = fraction of available vesicles
8 tau_r = time constant for vesicle replenishment
9
10 After each spike the magnitude of the peak conductance changes by the factor w*Pmax, where
11 w is the static synaptic weight and Pmax is the dynamically changing factor that could be interpreted as a probability of a transmitter release by the presynaptic terminal.
12
13 The post_synaptic dynamics of individual synaptic events is modeled by a single exponential synapse with the time constant tau_1
14
15 Implemented by Sergey L. Gratiy
16
17 ENDCOMMENT
18
19
20
21
22 NEURON {
23 POINT_PROCESS stp2syn
24 RANGE e, i, p0, tau_1, tau_r0, a_FDR, tau_FDR, Pmax
25 NONSPECIFIC_CURRENT i
26 }
27
28 UNITS {
29 (nA) = (nanoamp)
30 (mV) = (millivolt)
31 (umho) = (micromho)
32 (uS) = (microsiemens)
33
34 }
35
36 PARAMETER {
37 : e = synaptic reversal potential
38 e = 0 (mV)
39
40 : p0 = baseline level of release probability
41 p0 = 0.3
42
43 : tau_1 = baseline level of release probability
44 tau_1 = 5 (ms)
45
46 : tau_r0 = baseline level of tau_r0
47 tau_r0 = 1000 (ms)
48
49 : tau_FDR = time constant for tau_r relaxation
50 tau_FDR = 1000 (ms)
51
52 : a_FDR = magnitude of tau_r reduction after each spike
53 a_FDR = 0.5
54
55
56 }
57
58 ASSIGNED {
59 v (mV)
60 i (nA)
61 Pmax
62 }
63
64 STATE {
65 n
66 tau_r
67 g
68 }
69
70 INITIAL {
71 n=1
72 tau_r=tau_r0
73 g=0
74 }
75
76 BREAKPOINT {
77 SOLVE state METHOD cnexp
78 i = g*(v - e)
79 Pmax = n*p0
80 }
81
82 DERIVATIVE state {
83 g' = -g/tau_1
84 n' = (1-n)/tau_r
85 tau_r' = (tau_r0-tau_r)/tau_FDR
86 }
87
88 NET_RECEIVE(weight (umho)) {
89 g = g + weight*Pmax
90 n = n - n*p0
91 tau_r = tau_r - a_FDR*tau_r
92
93 }
94
95