Debian Codegraph @

texmf-dist/fonts/source/public/bbold/bbupper.mf

raw
1 % Blackboard bold capitals, Alan Jeffrey, 11--14 Dec 1989.
2
3 % -------------------------------------------------------------------
4
5 bbcap
6 ("A")
7 (smallgap#, medcap#, smallgap#);
8
9 "The letter A";
10
11 % The bar, clipped by the wedge.
12 draw
13 cliptwice
14 (ABar~Left -- ABar~Right)
15 (Bottom~Left -- Top~Middle -- Bottom~Right);
16
17 % The left line, fattened, and clipped by the right line.
18 outline
19 fatcliponce
20 (rightof Bottom~Left -- rightof Top~Middle)
21 (Top~Middle -- Bottom~Right);
22
23 % The right line.
24 draw
25 Top~Middle
26 -- Bottom~Right
27
28 endchar;
29
30 % -------------------------------------------------------------------
31
32 bbcap
33 ("B")
34 (biggap#, smallcap#, medgap#);
35
36 "The letter B";
37
38 % The top arc.
39 draw
40 Top~Left
41 -- Top~Middle {right}
42 .. (Top -+- BBar)~Right
43 .. {left} BBar~Middle
44 -- BBar~Left;
45
46 % The bottom arc.
47 draw
48 BBar~Left
49 -- BBar~Middle {right}
50 .. (BBar -+- Bottom)~Right
51 .. {left} Bottom~Middle
52 -- Bottom~Left;
53
54 % The left line, fattened.
55 outline
56 fatten
57 rightof Top~Left
58 -- rightof Bottom~Left
59
60 endchar;
61
62 % -------------------------------------------------------------------
63
64 bbcap
65 ("C")
66 (medgap#, medcap#, medgap#);
67
68 "The letter C";
69
70 % The curve of the C.
71 var (path) Cpath;
72
73 Cpath
74 = (Top - CCurl)~Right
75 .. oabove Top~Middle {left}
76 .. Horizon~Left {down}
77 .. obelow Bottom~Middle {right}
78 .. (Bottom + CCurl)~Right;
79
80 % The fat line emphasising the left side, clipped by the curve.
81 draw
82 fatcliptwice
83 (obelow rightof Bottom~Left -- oabove rightof Top~Left)
84 (Cpath);
85
86 % The curve.
87 draw Cpath
88
89 endchar;
90
91 % -------------------------------------------------------------------
92
93 bbcap
94 ("D")
95 (biggap#, medcap#, medgap#);
96
97 "The letter D";
98
99 % The curve of the D.
100 draw
101 Top~Left
102 -- Top~Middle {right}
103 .. Horizon~Right {down}
104 .. {left} Bottom~Middle
105 -- Bottom~Left;
106
107 % The left line, fattened.
108 draw
109 fatten
110 rightof Top~Left
111 --- rightof Bottom~Left
112
113 endchar;
114
115 % -------------------------------------------------------------------
116
117 bbcap
118 ("E")
119 (biggap#, smallcap#, smallgap#);
120
121 "The letter E";
122
123 % The top line.
124 draw
125 Top~Left
126 -- Top~Right;
127
128 % The bar.
129 draw
130 BBar~Left
131 -- farrightof BBar~(Left + bigjut);
132
133 % The bottom line.
134 draw
135 Bottom~Left
136 -- Bottom~Right;
137
138 % The left line, fattened.
139 outline
140 fatten
141 rightof Top~Left
142 -- rightof Bottom~Left
143
144 endchar;
145
146 % -------------------------------------------------------------------
147
148 bbcap
149 ("F")
150 (biggap#, smallcap#, smallgap#);
151
152 "The letter F";
153
154 % The top line.
155 draw
156 Top~Left
157 -- Top~Right;
158
159 % The bar.
160 draw
161 BBar~Left
162 -- farrightof BBar~(Left + bigjut);
163
164 % The left line, fattened.
165 outline
166 fatten
167 rightof Top~Left
168 -- rightof Bottom~Left
169 endchar;
170
171 % -------------------------------------------------------------------
172
173 bbcap
174 ("G")
175 (medgap#, medcap#, medgap#);
176
177 "The letter G";
178
179 % The curve of the G (which is the same as of a C).
180 var (path) Gpath;
181
182 Gpath
183 = (Top - CCurl)~Right
184 .. oabove Top~Middle {left}
185 .. Horizon~Left {down}
186 .. obelow Bottom~Middle {right}
187 .. (Bottom + CCurl)~Right;
188
189 % The emphasis for the left of the curve.
190 draw
191 fatcliptwice
192 (rightof obelow Bottom~Left -- oabove rightof Top~Left)
193 (Gpath);
194
195 % The curve.
196 draw Gpath;
197
198 % The bar.
199 draw
200 (Bottom + CCurl)~Right
201 -- GBar~Right
202 -- GBar~(Right - bigjut)
203
204 endchar;
205
206 % -------------------------------------------------------------------
207
208 bbcap
209 ("H")
210 (biggap#, medcap#, biggap#);
211
212 "The letter H";
213
214 % The right line.
215 draw
216 Top~Right
217 -- Bottom~Right;
218
219 % The bar.
220 draw
221 BBar~Left
222 -- BBar~Right;
223
224 % The left line, fattened.
225 outline
226 fatten
227 rightof Top~Left
228 -- rightof Bottom~Left
229
230 endchar;
231
232 % -------------------------------------------------------------------
233
234 bbcap
235 ("I")
236 (biggap#, tiny#, biggap#);
237
238 "The letter I";
239
240 % The vertical, fattened.
241 draw
242 fatten
243 Top~Middle
244 -- Bottom~Middle
245
246 endchar;
247
248 % -------------------------------------------------------------------
249
250 bbcap
251 ("J")
252 (medgap#, smallcap#, biggap#);
253
254 "The letter J";
255
256 % The curve.
257 var (path) Jpath;
258
259 Jpath
260 = Top~Right
261 -- (Bottom -+- Top)~Right {down}
262 .. obelow Bottom~Middle {left}
263 .. (Bottom + CCurl)~Left;
264
265 % The emphasis on the J, clipped by the curve.
266 draw
267 fatcliponce
268 (leftof Top~Right -- obelow leftof Bottom~Right)
269 (Jpath);
270
271 % The curve.
272 draw Jpath
273
274 endchar;
275
276 % -------------------------------------------------------------------
277
278 bbcap
279 ("K")
280 (biggap#, smallcap#, medgap#);
281
282 "The letter K";
283
284 % The point at which the top diagonal hits the left side of the character.
285 % It is somewhere along the line from the top right to BBar~Middle.
286
287 z1 = whatever[Top~Right, BBar~Middle];
288 x1 = Left;
289
290 % The top diagonal.
291 draw
292 z1 -- Top~Right;
293
294 % The bottom diagonal.
295 draw
296 BBar~Middle
297 -- Bottom~Right;
298
299 % The left edge, fattened.
300 outline
301 fatten
302 rightof Top~Left
303 -- rightof Bottom~Left
304
305 endchar;
306
307 % -------------------------------------------------------------------
308
309 bbcap
310 ("L")
311 (biggap#, smallcap#, smallgap#);
312
313 "The letter L";
314
315 % The bottom line.
316 draw
317 Bottom~Left
318 -- Bottom~Right;
319
320 % The left line, fattened.
321 draw
322 fatten
323 rightof Top~Left
324 -- rightof Bottom~Left
325
326 endchar;
327
328 % -------------------------------------------------------------------
329
330 bbcap
331 ("M")
332 (biggap#, medcap#, biggap#);
333
334 symmetric;
335
336 "The letter M";
337
338 % The left line, fattened and clipped by the left diagonal.
339
340 draw
341 fatcliponce
342 (rightof Bottom~Left -- rightof Top~Left)
343 (Top~Left -- BBar~Middle);
344
345 % The rest of the letter.
346 draw
347 Top~Left
348 -- BBar~Middle
349 -- Top~Right
350 -- Bottom~Right
351
352 endchar;
353
354 % -------------------------------------------------------------------
355
356 bbcap
357 ("N")
358 (biggap#, medcap#, biggap#);
359
360 "The letter N";
361
362 % The left line, fattened and clipped by the diagonal.
363
364 draw
365 fatcliponce
366 (rightof Bottom~Left -- rightof Top~Left)
367 (Top~Left -- Bottom~Right);
368
369 % The rest of the letter.
370 draw
371 Top~Left
372 -- Bottom~Right
373 -- Top~Right
374
375 endchar;
376
377 % -------------------------------------------------------------------
378
379 bbcap
380 ("O")
381 (medgap#, medcap#, medgap#);
382
383 "The letter O";
384
385 % The path of the O.
386 var (path) Opath;
387
388 Opath
389 = oabove Top~Middle
390 .. Horizon~Left
391 .. obelow Bottom~Middle
392 .. Horizon~Right
393 .. cycle;
394
395 % The emphasis at the left of the O, clipped by the O curve.
396 draw
397 fatcliptwice
398 (obelow rightof Bottom~Left -- oabove rightof Top~Left)
399 (Opath);
400
401 % The curve.
402 draw Opath
403
404 endchar;
405
406 % -------------------------------------------------------------------
407
408 bbcap
409 ("P")
410 (biggap#, smallcap#, medgap#);
411
412 "The letter P";
413
414 % The arc.
415 draw
416 Top~Left
417 -- Top~Middle {right}
418 .. (Top -+- BBar)~Right
419 .. {left} BBar~Middle
420 -- BBar~Left;
421
422 % The left line, fattened.
423 outline
424 fatten
425 rightof Top~Left
426 -- rightof Bottom~Left
427
428 endchar;
429
430 % -------------------------------------------------------------------
431
432 bbchar
433 ("Q")
434 (medgap#, medcap#, medgap#)
435 (ATop#, QTailBottom#);
436
437 "The letter Q";
438
439 % The path of the Q.
440 var (path) Qpath;
441
442 Qpath
443 = oabove Top~Middle
444 .. (Top -+- aBottom)~Left
445 .. obelow aBottom~Middle
446 .. (Top -+- aBottom)~Right
447 .. cycle;
448
449 % The emphasis at the left of the Q, clipped by the Q curve.
450 draw
451 fatcliptwice
452 (obelow rightof Bottom~Left -- oabove rightof Top~Left)
453 (Qpath);
454
455 % The curve.
456 draw Qpath;
457
458 % The tail.
459 draw
460 QTailTop~Middle
461 -- QTailBottom~Right
462
463 endchar;
464
465
466 % -------------------------------------------------------------------
467
468 bbcap
469 ("R")
470 (biggap#, smallcap#, medgap#);
471
472 "The letter R";
473
474 % The arc.
475 draw
476 Top~Left
477 -- Top~Middle {right}
478 .. (Top -+- BBar)~Right
479 .. {left} BBar~Middle
480 -- BBar~Left;
481
482 % The left line, fattened.
483 outline
484 fatten
485 rightof Top~Left
486 -- rightof Bottom~Left;
487
488 % The diagonal.
489 draw
490 BBar~Middle
491 -- Bottom~Right
492
493 endchar;
494
495 % -------------------------------------------------------------------
496
497 bbcap
498 ("S")
499 (medgap#, smallcap#, medgap#);
500
501 "The letter S";
502
503 % The path of the S.
504 var (path) Spath;
505
506 Spath
507 = (Top - CCurl)~Right
508 .. oabove Top~Middle {left}
509 .. (Top -+- BBar)~Left {down}
510 .. BBar~Middle {right}
511 .. (BBar -+- Bottom)~Right {down}
512 .. obelow Bottom~Middle {left}
513 .. (Bottom + CCurl)~Left;
514
515 % The emphasis at the top left of the S.
516 draw
517 fatcliptwice
518 (oabove rightof Top~Left -- rightof BBar~Left)
519 (subpath (0, 4) of Spath);
520
521 % The path of the S.
522 draw Spath
523
524 endchar;
525
526 % -------------------------------------------------------------------
527
528 bbcap
529 ("T")
530 (smallgap#, medcap#, smallgap#);
531
532 fatsymmetric;
533
534 "The letter T";
535
536 % The top line.
537 draw
538 Top~Left
539 -- Top~Right;
540
541 % The vertical, fattened.
542 draw
543 fatten
544 Top~Middle
545 -- Bottom~Middle
546
547 endchar;
548
549 % -------------------------------------------------------------------
550
551 bbcap
552 ("U")
553 (biggap#, medcap#, biggap#);
554
555 "The letter U";
556
557 % The path of the U.
558 var (path) Upath;
559
560 Upath
561 = Top~Left
562 -- Horizon~Left {down}
563 .. obelow Bottom~Middle {right}
564 .. {up} Horizon~Right
565 -- Top~Right;
566
567 % The emphasis of the U.
568 draw
569 fatcliponce
570 (rightof Top~Left -- obelow rightof Bottom~Left)
571 (Upath);
572
573 % The path of the U.
574 draw Upath
575
576 endchar;
577
578 % -------------------------------------------------------------------
579
580 bbcap
581 ("V")
582 (smallgap#, medcap#, smallgap#);
583
584 symmetric;
585
586 "The letter V";
587
588 % The left diagonal, clipped by the right.
589 draw
590 fatcliponce
591 (rightof Top~Left -- rightof Bottom~Middle)
592 (Bottom~Middle -- Top~Right);
593
594 % The right diagonal.
595 draw
596 Bottom~Middle
597 -- Top~Right
598
599 endchar;
600
601 % -------------------------------------------------------------------
602
603 bbcap
604 ("W")
605 (smallgap#, bigcap#, smallgap#);
606
607 symmetric;
608
609 "The letter W";
610
611 % The left diagonal, clipped by the rest.
612 draw
613 fatcliponce
614 (rightof Top~Left -- rightof Bottom~(Left -+- Middle))
615 (Bottom~(Left -+- Middle) -- BBar~Middle);
616
617 % The rest of the letter.
618 draw
619 Bottom~(Left -+- Middle)
620 -- BBar~Middle
621 -- Bottom~(Middle -+- Right)
622 -- Top~Right
623
624 endchar;
625
626 % -------------------------------------------------------------------
627
628 bbcap
629 ("X")
630 (medgap#, medcap#, medgap#);
631
632 "The letter X";
633
634 % The SE diagonal.
635 draw
636 Top~Left
637 -- Bottom~Right;
638
639 % The SW diagonal, fattened.
640 outline
641 fatten
642 leftof Top~Right
643 -- rightof Bottom~Left
644
645 endchar;
646
647 % -------------------------------------------------------------------
648
649 bbcap
650 ("Y")
651 (smallgap#, medcap#, smallgap#);
652
653 fatsymmetric;
654
655 "The letter Y";
656
657 % The fat stroke running top left to bottom.
658 draw
659 fatten
660 rightof Top~Left
661 -- BBar~Middle
662 -- Bottom~Middle;
663
664 % The right diagonal.
665 draw
666 rightof BBar~Middle
667 -- Top~Right
668
669 endchar;
670
671 % -------------------------------------------------------------------
672
673 bbcap
674 ("Z")
675 (medgap#, medcap#, medgap#);
676
677 "The letter Z";
678
679 % The top line.
680 draw
681 Top~Left
682 -- Top~Right;
683
684 % The diagonal, fattened.
685 draw
686 fatten
687 leftof Top~Right
688 -- rightof Bottom~Left;
689
690 % The bottom line.
691 draw
692 Bottom~Left
693 -- Bottom~Right
694
695 endchar;
696
697 % -------------------------------------------------------------------
698