Debian Codegraph @

texmf-dist/fonts/source/public/bbold/bbgreeku.mf

raw
1 % Blackboard bold uppercase greek, Alan Jeffrey, 13--18 Dec 1989.
2 %
3 % These characters occupy the same space they do in cmr, ie oct "000"
4 % to oct "012".
5
6 % -------------------------------------------------------------------
7
8 bbcap
9 (oct "000")
10 (biggap#, smallcap#, smallgap#);
11
12 "Uppercase Greek Gamma";
13
14 % The vertical, fattened.
15 draw
16 fatten
17 rightof Bottom~Left
18 -- rightof Top~Left;
19
20 % The horizontal.
21 draw
22 Top~Left
23 -- Top~Right
24
25 endchar;
26
27 % -------------------------------------------------------------------
28
29 bbcap
30 (oct "001")
31 (smallgap#, medcap#, smallgap#);
32
33 symmetric;
34
35 "Uppercase Greek Delta";
36
37 % Left diagonal, clipped by the right diagonal.
38 draw
39 fatcliponce
40 (rightof Bottom~Left -- rightof Top~Middle)
41 (Top~Middle -- Bottom~Right);
42
43 % Right diagonal.
44 draw
45 Top~Middle
46 -- Bottom~Right;
47
48 % Base.
49 draw
50 Bottom~Left
51 -- Bottom~Right
52
53 endchar;
54
55 % -------------------------------------------------------------------
56
57 bbcap
58 (oct "002")
59 (medgap#, medcap#, medgap#);
60
61 "Uppercase Greek Theta";
62
63 % The circle.
64 var (path) Thetapath;
65
66 Thetapath
67 = oabove Top~Middle {left}
68 .. Horizon~Left {down}
69 .. obelow Bottom~Middle {right}
70 .. Horizon~Right {up}
71 .. cycle;
72
73 % The emphasis at the left.
74 draw
75 fatcliptwice
76 (rightof obelow Bottom~Left -- oabove rightof Top~Left)
77 (Thetapath);
78
79 % The circle.
80 draw Thetapath;
81
82 % The dash in the middle.
83 draw
84 farrightof Horizon~(Left + space)
85 -- Horizon~(Right - space)
86
87 endchar;
88
89 % -------------------------------------------------------------------
90
91 bbcap
92 (oct "003")
93 (smallgap#, medcap#, smallgap#);
94
95 symmetric;
96
97 "Uppercase Greek Lambda";
98
99 % Left diagonal, clipped by the right diagonal.
100 draw
101 fatcliponce
102 (rightof Bottom~Left -- rightof Top~Middle)
103 (Top~Middle -- Bottom~Right);
104
105 % Right diagonal.
106 draw
107 Top~Middle
108 -- Bottom~Right
109
110 endchar;
111
112 % -------------------------------------------------------------------
113
114 bbcap
115 (oct "004")
116 (medgap#, medcap#, medgap#);
117
118 symmetric;
119
120 "Uppercase Greek Xi";
121
122 % Top line.
123 draw
124 Top~Left
125 -- Top~Right;
126
127 % Middle line.
128 draw
129 Horizon~(Left + bigspace)
130 -- Horizon~(Right - bigspace);
131
132 % Bottom line.
133 draw
134 Bottom~Left
135 -- Bottom~Right
136
137 endchar;
138
139 % -------------------------------------------------------------------
140
141 bbcap
142 (oct "005")
143 (biggap#, smallcap#, biggap#);
144
145 "Uppercase Greek Pi";
146
147 % The right line.
148 draw
149 Top~Right
150 -- Bottom~Right;
151
152 % The bar.
153 draw
154 Top~Left
155 -- Top~Right;
156
157 % The left line, fattened.
158 draw
159 fatten
160 rightof Top~Left
161 -- rightof Bottom~Left
162
163 endchar;
164
165 % -------------------------------------------------------------------
166
167 bbcap
168 (oct "006")
169 (medgap#, medcap#, medgap#);
170
171 "Uppercase Greek Sigma";
172
173 % The top line.
174 draw
175 Top~Left
176 -- Top~Right;
177
178 % The bottom line.
179 draw
180 Bottom~Left
181 -- Bottom~Right;
182
183 % The diagonals.
184 draw
185 fatten
186 rightof Bottom~Left
187 -- Horizon~Middle
188 -- rightof Top~Left
189
190 endchar;
191
192 % -------------------------------------------------------------------
193
194 bbcap
195 (oct "007")
196 (smallgap#, medcap#, smallgap#);
197
198 fatsymmetric;
199
200 "Uppercase Greek Upsilon";
201
202 % The stem.
203 draw
204 fatten
205 Bottom~Middle
206 -- BBar~Middle;
207
208 % The left arc.
209 draw
210 leftof BBar~Middle
211 --- leftof (Top - CCurl)~Middle
212 .. oabove ((leftof Top~Left) -+- (Top~Middle)) {left}
213 .. (Top - CCurl)~Left {down};
214
215 % The right arc.
216 draw
217 rightof BBar~Middle {up}
218 --- rightof (Top - CCurl)~Middle
219 .. oabove ((rightof Top~Right) -+- (Top~Middle)) {right}
220 .. (Top - CCurl)~Right {down}
221
222 endchar;
223
224 % -------------------------------------------------------------------
225
226 bbcap
227 (oct "010")
228 (medgap#, medcap#, medgap#);
229
230 fatsymmetric;
231
232 "Uppercase Greek Phi";
233
234 % The circle.
235 draw
236 (Top - CCurl)~Middle {left}
237 .. Horizon~Left {down}
238 .. (Bottom + CCurl)~Middle {right}
239 .. Horizon~Right {up}
240 .. cycle;
241
242 % The vertical.
243 outline
244 fatten
245 Bottom~Middle
246 -- Top~Middle
247
248 endchar;
249
250 % -------------------------------------------------------------------
251
252 bbcap
253 (oct "011")
254 (smallgap#, medcap#, smallgap#);
255
256 fatsymmetric;
257
258 "Uppercase Greek Psi";
259
260 % The stroke.
261 draw
262 (Top - CCurl)~Left {right}
263 .. leftof Horizon~(Left -+- Middle) {down}
264 .. (Bottom + CCurl)~Middle {right}
265 .. rightof Horizon~(Right -+- Middle) {up}
266 .. (Top - CCurl)~Right {right};
267
268 % The vertical.
269 outline
270 fatten
271 Bottom~Middle
272 -- Top~Middle
273
274 endchar;
275
276 % -------------------------------------------------------------------
277
278 bbcap
279 (oct "012")
280 (medgap#, medcap#, medgap#);
281
282 "Uppercase Greek Omega";
283
284 % The curve.
285 var (path) Omegapath;
286
287 Omegapath
288 = farrightof Bottom~Left
289 .. Horizon~Left {up}
290 .. oabove Top~Middle {right}
291 .. Horizon~Right {down}
292 .. farleftof Bottom~Right ;
293
294 % The emphasis.
295 draw
296 fatcliptwice
297 (rightof Bottom~Left -- oabove rightof Top~Left)
298 (Omegapath);
299
300 % The curve.
301 draw Omegapath;
302
303 % The left foot.
304 draw
305 Bottom~Left
306 -- farrightof Bottom~Left;
307
308 % The right foot.
309 draw
310 Bottom~Right
311 -- farleftof Bottom~Right
312
313 endchar;
314
315 % -------------------------------------------------------------------