Debian Codegraph @

texmf-dist/fonts/source/public/bbold/bblower.mf

raw
1 % Blackboard bold lower case, Alan Jeffrey, 12--18 Dec 1989.
2
3 % -------------------------------------------------------------------
4
5 bbchar
6 ("a")
7 (smallgap#, medlower#, medgap#)
8 (aTop#, aBottom#);
9
10 "The letter a";
11
12 % The curve.
13 var (path) apath;
14
15 apath
16 = (Top - cCurl)~Right
17 .. oabove Top~Middle {left}
18 .. Horizon~Left {down}
19 .. obelow Bottom~Middle {right}
20 .. (Bottom + cCurl)~Right;
21
22 % The emphasis to the left, clipped by the curve.
23 draw
24 fatcliptwice
25 (oabove rightof Top~Left -- obelow rightof Bottom~Left)
26 (apath);
27
28 % The curve.
29 draw apath;
30
31 % The line at the right.
32 draw
33 Top~Right
34 -- Bottom~Right;
35
36 endchar;
37
38 % -------------------------------------------------------------------
39
40 bbchar
41 ("b")
42 (medgap#, medlower# + fatness#, smallgap#)
43 (bTop#, aBottom#);
44
45 "The letter b";
46
47 % The curve.
48 draw
49 farrightof (aTop - cCurl)~Left
50 .. oabove rightof aTop~Middle {right}
51 .. aMiddle~Right {down}
52 .. obelow rightof Bottom~Middle {left}
53 .. farrightof (Bottom + cCurl)~Left;
54
55 % The vertical, fattened.
56 draw
57 fatten
58 rightof Bottom~Left
59 -- rightof Top~Left;
60
61 endchar;
62
63 % -------------------------------------------------------------------
64
65 bbchar
66 ("c")
67 (smallgap#, medlower#, smallgap#)
68 (aTop#, aBottom#);
69
70 "The letter c";
71
72 % The curve.
73 var (path) cpath;
74
75 cpath
76 = (Top - cCurl)~Right
77 .. oabove Top~Middle {left}
78 .. Horizon~Left {down}
79 .. obelow Bottom~Middle {right}
80 .. (Bottom + cCurl)~Right;
81
82 % The emphasis to the left, clipped by the curve.
83 draw
84 fatcliptwice
85 (oabove rightof Top~Left -- obelow rightof Bottom~Left)
86 (cpath);
87
88 % The curve.
89 draw cpath
90
91 endchar;
92
93 % -------------------------------------------------------------------
94
95 bbchar
96 ("d")
97 (smallgap#, medlower#, medgap#)
98 (bTop#, aBottom#);
99
100 "The letter d";
101
102 % The curve.
103 var (path) dpath;
104
105 dpath
106 = (aTop - cCurl)~Right
107 .. oabove aTop~Middle {left}
108 .. aMiddle~Left {down}
109 .. obelow Bottom~Middle {right}
110 .. (Bottom + cCurl)~Right;
111
112 % The emphasis to the left, clipped by the curve.
113 draw
114 fatcliptwice
115 (oabove rightof aTop~Left -- obelow rightof Bottom~Left)
116 (dpath);
117
118 % The curve.
119 draw dpath;
120
121 % The line at the right.
122 draw
123 Bottom~Right
124 -- Top~Right
125
126 endchar;
127
128 % -------------------------------------------------------------------
129
130 bbchar
131 ("e")
132 (smallgap#, medlower#, smallgap#)
133 (aTop#, aBottom#);
134
135 "The letter e";
136
137 % The curve.
138 var (path) epath;
139
140 epath
141 = eBar~Right
142 .. oabove Top~Middle {left}
143 .. Horizon~Left {down}
144 .. obelow Bottom~Middle {right}
145 .. (Bottom + cCurl)~Right;
146
147 % The bar.
148 draw
149 farrightof eBar~Left
150 -- eBar~Right;
151
152 % The emphasis to the left, clipped by the curve.
153 outline
154 fatcliptwice
155 (oabove rightof Top~Left -- obelow rightof Bottom~Left)
156 (epath);
157
158 % The curve.
159 draw epath;
160
161 endchar;
162
163 % -------------------------------------------------------------------
164
165 bbchar
166 ("f")
167 (medgap#, smalllower#, 0pt#)
168 (bTop#, aBottom#);
169
170 "The letter f";
171
172 % The curve.
173 var (path) fpath;
174
175 fpath
176 = (Top - hCurl)~Left {up}
177 .. oabove Top~Middle {right}
178 .. (Top - cCurl)~Right;
179
180 % The bar.
181 draw
182 aTop~Left
183 -- farrightof aTop~(Left + jut);
184
185 % The emphasis at the left of the curve.
186 outline
187 fatcliponce
188 (rightof Bottom~Left -- oabove rightof Top~Left)
189 (fpath);
190
191 % The curve.
192 draw fpath
193
194 endchar;
195
196 % -------------------------------------------------------------------
197
198 bbchar
199 ("g")
200 (smallgap#, medlower#, medgap#)
201 (aTop#, gBottom#);
202
203 "The letter g";
204
205 % The bowl path.
206 var (path) gpath;
207
208 gpath
209 = (Top - cCurl)~Right
210 .. oabove Top~Middle {left}
211 .. aMiddle~Left {down}
212 .. obelow aBottom~Middle {right}
213 .. (aBottom + cCurl)~Right;
214
215 % Emphasis of the bowl.
216 draw
217 fatcliptwice
218 (obelow rightof aBottom~Left -- oabove rightof Top~Left)
219 (gpath);
220
221 % The bowl.
222 draw gpath;
223
224 % The tail.
225 draw
226 Top~Right
227 --- aBottom~Right
228 .. obelow Bottom~Middle {left}
229 .. (Bottom + gCurl)~Left
230
231 endchar;
232
233 % -------------------------------------------------------------------
234
235 bbchar
236 ("h")
237 (medgap#, smalllower# + fatness#, medgap#)
238 (bTop#, aBottom#);
239
240 "The letter h";
241
242 % The curve.
243 draw
244 farrightof (aTop - cCurl)~Left
245 .. oabove rightof aTop~Middle {right}
246 .. (aTop - hCurl)~Right
247 --- Bottom~Right;
248
249 % The vertical, fattened.
250 draw
251 fatten
252 rightof Bottom~Left
253 -- rightof Top~Left
254
255 endchar;
256
257 % -------------------------------------------------------------------
258
259 bbchar
260 ("i")
261 (medgap#, tiny#, medgap#)
262 (iTop#, aBottom#);
263
264 fatsymmetric;
265
266 "The letter i";
267
268 % The vertical, fattened.
269 draw
270 fatten
271 Bottom~Middle
272 -- aTop~Middle;
273
274 % The dot.
275 draw
276 splodge
277 below Top~Middle
278
279 endchar;
280
281 % -------------------------------------------------------------------
282
283 bbchar
284 ("j")
285 (0pt#, smalllower#, medgap#)
286 (iTop#, gBottom#);
287
288 "The letter j";
289
290 % The curve.
291 var (path) jpath;
292
293 jpath
294 = aTop~Right
295 --- aBottom~Right
296 .. obelow Bottom~Middle {left}
297 .. (Bottom + gCurl)~Left;
298
299 % The emphasis.
300 draw
301 fatcliponce
302 (leftof aTop~Right -- obelow leftof Bottom~Right)
303 (jpath);
304
305 % The curve.
306 draw jpath;
307
308 % The dot.
309 draw
310 splodge
311 below leftof Top~Right
312
313 endchar;
314
315 % -------------------------------------------------------------------
316
317 bbchar
318 ("k")
319 (medgap#, smalllower# + fatness#, smallgap#)
320 (bTop#, aBottom#);
321
322 "The letter k";
323
324 % The point at which the top diagonal hits the left side of the character.
325 % It is somewhere along the line from aTop~Right to eBar~Middle.
326
327 z1 = whatever[aTop~Right, eBar~Middle];
328 x1 = Left;
329
330 % The top diagonal.
331 draw
332 z1 -- aTop~Right;
333
334 % The bottom diagonal.
335 draw
336 eBar~Middle
337 -- Bottom~Right;
338
339 % The left edge, fattened.
340 outline
341 fatten
342 rightof Top~Left
343 -- rightof Bottom~Left
344
345 endchar;
346
347 % -------------------------------------------------------------------
348
349 bbchar
350 ("l")
351 (medgap#, tiny#, medgap#)
352 (bTop#, aBottom#);
353
354 "The letter l";
355
356 % The fattened vertical, clipped at the left by a curve.
357
358 draw
359 fatcliponce
360 (Top~Middle -- Bottom~Middle)
361 (leftof Horizon~Middle
362 --- leftof (Bottom + hCurl)~Middle
363 .. rightof Bottom~Middle {right})
364
365 endchar;
366
367 % -------------------------------------------------------------------
368
369 bbchar
370 ("m")
371 (medgap#, biglower#, medgap#)
372 (aTop#, aBottom#);
373
374 symmetric;
375
376 "The letter m";
377
378 % The vertical, fattened.
379 draw
380 fatten
381 rightof Bottom~Left
382 -- rightof Top~Left;
383
384 % The first bump.
385 draw
386 farrightof (Top - cCurl)~Left
387 .. oabove (farrightof Top~Left -+- rightof Top~Middle) {right}
388 .. rightof (Top - hCurl)~Middle
389 --- rightof Bottom~Middle;
390
391 % The second bump.
392 draw
393 rightof (Top - hCurl)~Middle {up}
394 .. oabove (rightof Top~Middle -+- Top~Right) {right}
395 .. (Top - hCurl)~Right
396 --- Bottom~Right
397
398 endchar;
399
400 % -------------------------------------------------------------------
401
402 bbchar
403 ("n")
404 (medgap#, smalllower# + fatness#, medgap#)
405 (aTop#, aBottom#);
406
407 "The letter n";
408
409 % The vertical, fattened.
410 draw
411 fatten
412 rightof Bottom~Left
413 -- rightof Top~Left;
414
415 % The bump.
416 draw
417 farrightof (Top - cCurl)~Left
418 .. oabove rightof Top~Middle {right}
419 .. (Top - hCurl)~Right
420 --- Bottom~Right;
421
422 endchar;
423
424 % -------------------------------------------------------------------
425
426 bbchar
427 ("o")
428 (smallgap#, medlower#, smallgap#)
429 (aTop#, aBottom#);
430
431 "The letter o";
432
433 % The circle;
434 var (path) opath;
435
436 opath
437 = oabove Top~Middle {right}
438 .. Horizon~Right {down}
439 .. obelow Bottom~Middle {left}
440 .. Horizon~Left {up}
441 .. cycle;
442
443 % The emphasis.
444 draw
445 fatcliptwice
446 (obelow rightof Bottom~Left -- oabove rightof Top~Left)
447 (opath);
448
449 % The o.
450 draw opath
451
452 endchar;
453
454 % -------------------------------------------------------------------
455
456 bbchar
457 ("p")
458 (medgap#, medlower# + fatness#, smallgap#)
459 (aTop#, gBottom#);
460
461 "The letter p";
462
463 % The curve.
464 draw
465 farrightof (Top - cCurl)~Left
466 .. oabove rightof Top~Middle {right}
467 .. aMiddle~Right {down}
468 .. obelow rightof aBottom~Middle {left}
469 .. farrightof (aBottom + cCurl)~Left;
470
471 % The vertical, fattened.
472 draw
473 fatten
474 rightof Bottom~Left
475 -- rightof Top~Left;
476
477 endchar;
478
479 % -------------------------------------------------------------------
480
481 bbchar
482 ("q")
483 (smallgap#, medlower#, medgap#)
484 (aTop#, gBottom#);
485
486 "The letter q";
487
488 % The curve.
489 var (path) qpath;
490
491 qpath
492 = (Top - cCurl)~Right
493 .. oabove Top~Middle {left}
494 .. aMiddle~Left {down}
495 .. obelow aBottom~Middle {right}
496 .. (aBottom + cCurl)~Right;
497
498 % The emphasis to the left, clipped by the curve.
499 draw
500 fatcliptwice
501 (oabove rightof Top~Left -- obelow rightof Bottom~Left)
502 (qpath);
503
504 % The curve.
505 draw qpath;
506
507 % The line at the right.
508 draw
509 Bottom~Right
510 -- Top~Right
511
512 endchar;
513
514 % -------------------------------------------------------------------
515
516 bbchar
517 ("r")
518 (medgap#, smalllower# + fatness#, smallgap#)
519 (aTop#, aBottom#);
520
521 "The letter r";
522
523 % The vertical, fattened.
524 draw
525 fatten
526 rightof Bottom~Left
527 -- rightof Top~Left;
528
529 % The bump.
530 draw
531 farrightof (Top - cCurl)~Left
532 .. oabove rightof Top~Middle {right}
533 .. (Top - cCurl)~Right
534
535 endchar;
536
537 % -------------------------------------------------------------------
538
539 bbchar
540 ("s")
541 (smallgap#, smalllower#, smallgap#)
542 (aTop#, aBottom#);
543
544 "The letter s";
545
546 % The path of the S.
547 var (path) spath;
548
549 spath
550 = (Top - cCurl)~Right
551 .. oabove Top~Middle {left}
552 .. (Top -+- eBar)~Left {down}
553 .. eBar~Middle {right}
554 .. (eBar -+- Bottom)~Right {down}
555 .. obelow Bottom~Middle {left}
556 .. (Bottom + cCurl)~Left;
557
558 % The emphasis at the top left of the S.
559 draw
560 fatcliptwice
561 (oabove rightof Top~Left -- obelow rightof Bottom~Left)
562 (subpath (0, 4) of spath);
563
564 % The path of the S.
565 draw spath
566
567 endchar;
568
569 % -------------------------------------------------------------------
570
571 bbchar
572 ("t")
573 (medgap#, smalllower#, smallgap#)
574 (bTop#, aBottom#);
575
576 "The letter t";
577
578 % The curve.
579 var (path) tpath;
580
581 tpath
582 = (Bottom + hCurl)~Left {down}
583 .. obelow Bottom~Middle {right}
584 .. (Bottom + cCurl)~Right;
585
586 % The bar.
587 draw
588 aTop~Left
589 -- aTop~Right;
590
591 % The emphasis.
592 outline
593 fatcliponce
594 (rightof Top~Left -- obelow rightof Bottom~Left)
595 (tpath);
596
597 % The curve.
598 draw tpath
599
600 endchar;
601
602 % -------------------------------------------------------------------
603
604 bbchar
605 ("u")
606 (medgap#, medlower#, medgap#)
607 (aTop#, aBottom#);
608
609 "The letter u";
610
611 % The curve of the u.
612 var (path) upath;
613
614 upath
615 = Top~Left
616 --- Horizon~Left
617 .. obelow Bottom~Middle {right}
618 .. {up} Horizon~Right;
619
620 % The emphasis.
621 draw
622 fatcliponce
623 (rightof Top~Left -- obelow rightof Bottom~Left)
624 (upath);
625
626 % The curve.
627 draw upath;
628
629 % The right line.
630 draw
631 Bottom~Right
632 -- Top~Right
633
634 endchar;
635
636 % -------------------------------------------------------------------
637
638 bbchar
639 ("v")
640 (smallgap#, medlower#, smallgap#)
641 (aTop#, aBottom#);
642
643 symmetric;
644
645 "The letter v";
646
647 % The left diagonal, clipped by the right.
648 draw
649 fatcliponce
650 (rightof Top~Left -- rightof Bottom~Middle)
651 (Bottom~Middle -- Top~Right);
652
653 % The right diagonal.
654 draw
655 Bottom~Middle
656 -- Top~Right
657
658 endchar;
659
660 % -------------------------------------------------------------------
661
662 bbchar
663 ("w")
664 (smallgap#, biglower#, smallgap#)
665 (aTop#, aBottom#);
666
667 symmetric;
668
669 "The letter w";
670
671 % The left diagonal, clipped by the rest.
672 draw
673 fatcliponce
674 (rightof Top~Left -- rightof Bottom~(Left -+- Middle))
675 (Bottom~(Left -+- Middle) -- eBar~Middle);
676
677 % The rest of the letter.
678 draw
679 Bottom~(Left -+- Middle)
680 -- eBar~Middle
681 -- Bottom~(Middle -+- Right)
682 -- Top~Right
683
684 endchar;
685
686 % -------------------------------------------------------------------
687
688 bbchar
689 ("x")
690 (smallgap#, medlower#, smallgap#)
691 (aTop#, aBottom#);
692
693 "The letter x";
694
695 % The SE diagonal.
696 draw
697 Top~Left
698 -- Bottom~Right;
699
700 % The SW diagonal, fattened.
701 outline
702 fatten
703 leftof Top~Right
704 -- rightof Bottom~Left
705
706 endchar;
707
708 % -------------------------------------------------------------------
709
710 bbchar
711 ("y")
712 (smallgap#, medlower#, smallgap#)
713 (aTop#, gBottom#);
714
715 symmetric;
716
717 "The letter y";
718
719 % The left diagonal, fattened, and clipped by the right.
720 draw
721 fatcliponce
722 (rightof Top~Left -- rightof aBottom~Middle)
723 (Top~Right -- aBottom~Middle);
724
725 % The right diagonal and tail.
726 draw
727 Top~Right
728 --- aBottom~Middle
729 .. obelow Bottom~Left
730
731 endchar;
732
733 % -------------------------------------------------------------------
734
735 bbchar
736 ("z")
737 (smallgap#, medlower#, smallgap#)
738 (aTop#, aBottom#);
739
740 "The letter z";
741
742 % The top line.
743 draw
744 Top~Left
745 -- Top~Right;
746
747 % The diagonal, fattened.
748 draw
749 fatten
750 leftof Top~Right
751 -- rightof Bottom~Left;
752
753 % The bottom line.
754 draw
755 Bottom~Left
756 -- Bottom~Right
757
758 endchar;
759
760 % -------------------------------------------------------------------