Debian Codegraph @

texmf-dist/fonts/source/public/bbold/bbgreekl.mf

raw
1 % Blackboard bold lower case Greek, Alan Jeffrey, 15--18 Dec 1989.
2 %
3 % These characters occupy spaces oct "013" to oct "040", and oct "177".
4 % This is because ! occupies oct "041" and I have to stick omega
5 % somewhere.
6
7 % -------------------------------------------------------------------
8
9 bbchar
10 (oct "013")
11 (smallgap#, medlower#, smallgap# + jut#)
12 (aTop#, aBottom#);
13
14 "Lowercase Greek alpha";
15
16 % The curve.
17 var (path) alphapath;
18
19 alphapath
20 = Top~(Right + jut) {down}
21 .. obelow Bottom~Middle {left}
22 .. Horizon~Left {up}
23 .. oabove Top~Middle {right}
24 .. Bottom~(Right + jut){right};
25
26 % The emphasis.
27 draw
28 fatcliptwice
29 (rightof obelow Bottom~Left -- rightof oabove Top~Left)
30 (alphapath);
31
32 % The curve.
33 draw alphapath
34
35 endchar;
36
37 % -------------------------------------------------------------------
38
39 bbchar
40 (oct "014")
41 (medgap#, smalllower# + fatness#, smallgap#)
42 (bTop#, gBottom#);
43
44 "Lowercase Greek beta";
45
46 % The top curve.
47 var (path) betapath;
48
49 betapath
50 = aBottom~Left
51 --- aTop~Left
52 .. oabove rightof Top~Middle {right}
53 .. (Top -+- aTop)~Right {down}
54 .. rightof aTop~Middle {left};
55
56 % The emphasis
57 draw
58 fatcliponce
59 (rightof Bottom~Left -- rightof oabove Top~Left)
60 (betapath);
61
62 % The top curve.
63 draw betapath;
64
65 % The bottom curve.
66 draw
67 rightof aTop~Middle {right}
68 .. aMiddle~Right {down}
69 .. obelow rightof aBottom~Middle {left}
70 .. farrightof (aBottom + cCurl)~Left
71
72 endchar;
73
74 % -------------------------------------------------------------------
75
76 bbchar
77 (oct "015")
78 (smallgap#, medlower#, smallgap#)
79 (aTop#, gBottom#);
80
81 "Lowercase Greek gamma";
82
83 % The curve.
84 var (path) gammapath;
85
86 gammapath
87 = Top~Left {right}
88 .. aBottom~Right {down}
89 .. obelow Bottom~Middle {left}
90 .. aBottom~Left {up}
91 .. Top~Right {right};
92
93 % The emphasis.
94 draw
95 fatcliptwice
96 (obelow rightof Bottom~Left -- rightof Top~Left)
97 (subpath (1,infinity) of gammapath);
98
99 % The curve.
100 draw gammapath
101
102 endchar;
103
104 % -------------------------------------------------------------------
105
106 bbchar
107 (oct "016")
108 (smallgap#, medlower#, smallgap#)
109 (bTop#, aBottom#);
110
111 "Lowercase Greek delta";
112
113 % The path.
114 var (path) deltapath;
115
116 deltapath
117 = aTop~Middle {left}
118 .. aMiddle~Left {down}
119 .. obelow Bottom~Middle {right}
120 .. aMiddle~Right {up}
121 .. aTop~Middle
122 .. (aTop -+- Top)~Left {up}
123 .. oabove Top~Middle {right}
124 .. (Top - cCurl)~Right;
125
126 % The emphasis, clipped by the first bit of the curve (ie the bowl).
127 draw
128 fatcliptwice
129 (obelow rightof Bottom~Left -- rightof Top~Left)
130 (subpath (0,4) of deltapath);
131
132 % The curve.
133 draw deltapath
134
135 endchar;
136
137 % -------------------------------------------------------------------
138
139 bbchar
140 (oct "017")
141 (smallgap#, medlower#, smallgap#)
142 (aTop#, aBottom#);
143
144 "Lowercase Greek epsilon";
145
146 % The curve.
147 var (path) epsilonpath;
148
149 epsilonpath
150 = (Top - cCurl)~Right
151 .. oabove Top~Middle {left}
152 .. aMiddle~Left {down}
153 .. obelow Bottom~Middle {right}
154 .. (Bottom + cCurl)~Right;
155
156 % The emphasis.
157 draw
158 fatcliptwice
159 (obelow rightof Bottom~Left -- oabove rightof Top~Left)
160 (epsilonpath);
161
162 % The curve.
163 draw epsilonpath;
164
165 % The bar.
166 draw
167 farrightof eBar~Left
168 -- farrightof eBar~(Left + jut)
169
170 endchar;
171
172 % -------------------------------------------------------------------
173
174 bbchar
175 (oct "020")
176 (medgap#, smalllower#, smallgap#)
177 (bTop#, gBottom#);
178
179 "Lowercase Greek zeta";
180
181 % The curl.
182 var (path) zetapath;
183
184 zetapath
185 = Top~Right
186 .. aMiddle~Left {down}
187 .. aBottom~Middle
188 .. (aBottom -+- Bottom)~Right {down}
189 .. Bottom~(Right - jut) {left};
190
191 % The emphasis.
192 draw
193 fatcliptwice
194 (rightof Bottom~Left -- rightof Top~Left)
195 (zetapath);
196
197 % The curl.
198 draw zetapath
199
200 endchar;
201
202 % -------------------------------------------------------------------
203
204 bbchar
205 (oct "021")
206 (medgap#, smalllower# + fatness#, medgap#)
207 (aTop#, gBottom#);
208
209 "Lowercase Greek eta";
210
211 % The emphasis.
212 draw
213 fatten
214 rightof aBottom~Left
215 -- rightof Top~Left;
216
217 % The curl.
218 draw
219 farrightof (Top - cCurl)~Left
220 .. oabove rightof Top~Middle {right}
221 .. (Top - hCurl)~Right
222 --- Bottom~Right
223
224 endchar;
225
226 % -------------------------------------------------------------------
227
228 bbchar
229 (oct "022")
230 (smallgap#, medlower#, smallgap#)
231 (bTop#, aBottom#);
232
233 "Lowercase Greek theta";
234
235 % The curve.
236 var (path) thetapath;
237
238 thetapath
239 = Horizon~Right {up}
240 .. oabove Top~Middle {left}
241 .. Horizon~Left {down}
242 .. obelow Bottom~Middle {right}
243 .. cycle;
244
245 % The emphasis.
246 draw
247 fatcliptwice
248 (rightof obelow Bottom~Left -- oabove rightof Top~Left)
249 (thetapath);
250
251 % The curve.
252 draw thetapath;
253
254 % The bar.
255 draw
256 farrightof Horizon~Left
257 -- Horizon~Right
258
259 endchar;
260
261 % -------------------------------------------------------------------
262
263 bbchar
264 (oct "023")
265 (medgap#, tiny#, medgap#)
266 (aTop#, aBottom#);
267
268 "Lowercase Greek iota";
269
270 % The vertical, clipped by a curve.
271 draw
272 fatcliponce
273 (Top~Middle -- Bottom~Middle)
274 (leftof (Bottom + hCurl)~Middle {down}
275 .. rightof Bottom~Middle {right})
276
277 endchar;
278
279 % -------------------------------------------------------------------
280
281 bbchar
282 (oct "024")
283 (medgap#, smalllower# + fatness#, smallgap#)
284 (aTop#, aBottom#);
285
286 "Lowercase Greek kappa";
287
288 % The vertical.
289 draw
290 fatten
291 rightof Bottom~Left
292 -- rightof Top~Left;
293
294 % The top stroke.
295 draw
296 farrightof eBar~Left
297 -- Top~Right;
298
299 % The bottom stroke.
300 draw
301 farrightof eBar~Left {right}
302 .. Bottom~Right {right}
303
304 endchar;
305
306 % -------------------------------------------------------------------
307
308 bbchar
309 (oct "025")
310 (smallgap#, medlower#, smallgap#)
311 (bTop#, aBottom#);
312
313 "Lowercase Greek lambda";
314
315 % The SW diagonal.
316 draw
317 Horizon~Middle
318 -- Bottom~Left;
319
320 % The SE diagonal, fattened.
321 outline
322 fatten
323 rightof Top~Left
324 -- leftof Bottom~Right
325
326 endchar;
327
328 % -------------------------------------------------------------------
329
330 bbchar
331 (oct "026")
332 (medgap#, smalllower# + fatness#, medgap#)
333 (aTop#, gBottom#);
334
335 "Lowercase Greek mu";
336
337 % The left vertical, fattened.
338 draw
339 fatten
340 rightof Bottom~Left
341 -- rightof Top~Left;
342
343 % The curl.
344 draw
345 farrightof (aBottom + cCurl)~Left
346 .. obelow rightof aBottom~Middle {right}
347 .. (aBottom + hCurl)~Right
348 --- Top~Right;
349
350 % The right vertical.
351 draw
352 Top~Right
353 -- aBottom~Right
354
355 endchar;
356
357 % -------------------------------------------------------------------
358
359 bbchar
360 (oct "027")
361 (medgap#, medlower#, smallgap#)
362 (aTop#, aBottom#);
363
364 "Lowercase Greek nu";
365
366 % The left vertical, clipped by the stroke.
367 draw
368 fatcliponce
369 (rightof Top~Left -- rightof Bottom~Left)
370 (Bottom~Left .. Top~Right {up});
371
372 % The stroke.
373 draw
374 Bottom~Left
375 .. Top~Right {up}
376
377 endchar;
378
379 % -------------------------------------------------------------------
380
381 bbchar
382 (oct "030")
383 (medgap#, smalllower#, smallgap#)
384 (bTop#, gBottom#);
385
386 "Lowercase Greek xi";
387
388 % The curls.
389 var (path) xitop, xibottom;
390
391 xibottom
392 = farrightof aTop~(Left + jut) {left}
393 .. aMiddle~Left {down}
394 .. aBottom~Middle
395 .. (aBottom -+- Bottom)~Right {down}
396 .. Bottom~(Right - jut) {left};
397
398 xitop
399 = Top~Right {left}
400 .. (Top -+- aTop)~Left {down}
401 .. farrightof aTop~(Left + jut) {right};
402
403 % The top emphasis.
404 draw
405 fatcliptwice
406 (rightof Bottom~Left -- rightof Top~Left)
407 (xitop);
408
409 % The top curl.
410 draw xitop;
411
412 % The bottom emphasis.
413 draw
414 fatcliptwice
415 (rightof Bottom~Left -- rightof Top~Left)
416 (xibottom);
417
418 % The bottom curl.
419 draw xibottom
420
421 endchar;
422
423 % -------------------------------------------------------------------
424
425 bbchar
426 (oct "031")
427 (smallgap#, smalllower# + fatness#, smallgap#)
428 (aTop#, aBottom#);
429
430 "Lowercase Greek pi";
431
432 % The top bar.
433 draw
434 Top~Left
435 --- Top~Right;
436
437 % The left vertical, fattened.
438 draw
439 fatten
440 rightof Bottom~(Left + jut)
441 -- rightof Top~(Left + jut);
442
443 % The right vertical.
444 draw
445 Bottom~(Right - jut)
446 -- Top~(Right - jut)
447
448 endchar;
449
450 % -------------------------------------------------------------------
451
452 bbchar
453 (oct "032")
454 (medgap#, medlower#, smallgap#)
455 (aTop#, gBottom#);
456
457 "Lowercase Greek rho";
458
459 % The bowl.
460 var (path) rhopath;
461
462 rhopath
463 = aMiddle~Left {up}
464 .. oabove aTop~Middle {right}
465 .. aMiddle~Right {down}
466 .. obelow aBottom~Middle {left}
467 .. cycle;
468
469 % The bowl.
470 draw rhopath;
471
472 % The emphasis, clipped by the beginning of the curve.
473 outline
474 fatcliponce
475 (rightof Bottom~Left -- rightof bracketTop~Left)
476 (subpath (0,2) of rhopath);
477
478 endchar;
479
480 % -------------------------------------------------------------------
481
482 bbchar
483 (oct "033")
484 (smallgap#, medlower#, smallgap# + jut#)
485 (aTop#, aBottom#);
486
487 "Lowercase Greek sigma";
488
489 % The bowl.
490 var (path) sigmapath;
491
492 sigmapath
493 = Horizon~Right {up}
494 .. Top~Middle {left}
495 .. Horizon~Left {down}
496 .. obelow Bottom~Middle {right}
497 .. cycle;
498
499 % The emphasis.
500 draw
501 fatcliptwice
502 (rightof obelow Bottom~Left -- rightof Top~Left)
503 (sigmapath);
504
505 % The bowl.
506 draw sigmapath;
507
508 % The bar, jutting out to the right.
509 draw
510 Top~Middle
511 -- Top~(Right + jut)
512
513 endchar;
514
515 % -------------------------------------------------------------------
516
517 bbchar
518 (oct "034")
519 (smallgap#, medlower#, smallgap#)
520 (aTop#, aBottom#);
521
522 fatsymmetric;
523
524 "Lowercase Greek tau";
525
526 % The top line.
527 draw
528 Top~Left
529 -- Top~Right;
530
531 % The vertical, clipped by a curve.
532 draw
533 fatcliponce
534 (Top~Middle -- Bottom~Middle)
535 (leftof (Bottom + hCurl)~Middle {down}
536 .. rightof Bottom~Middle {right})
537
538 endchar;
539
540 % -------------------------------------------------------------------
541
542 bbchar
543 (oct "035")
544 (medgap#, medlower#, medgap#)
545 (aTop#, aBottom#);
546
547 "Lowercase Greek upsilon";
548
549 % The curve.
550 var (path) upsilonpath;
551
552 upsilonpath
553 = Top~Left
554 --- (Bottom + hCurl)~Left
555 .. obelow Bottom~Middle {right}
556 .. (Bottom + hCurl)~Right
557 --- Top~Right;
558
559 % The emphasis.
560 draw
561 fatcliponce
562 (rightof Top~Left -- rightof obelow Bottom~Left)
563 (upsilonpath);
564
565 % The curve.
566 draw upsilonpath
567
568 endchar;
569
570 % -------------------------------------------------------------------
571
572 bbchar
573 (oct "036")
574 (smallgap#, medlower#, smallgap#)
575 (bTop#, gBottom#);
576
577 fatsymmetric;
578
579 "Lowercase Greek phi";
580
581 % The bowl.
582 draw
583 Middle~Right {up}
584 .. aTop~Middle {left}
585 .. aMiddle~Left {down}
586 .. aBottom~Middle {right}
587 .. cycle;
588
589 % The vertical, fattened.
590 outline
591 fatten
592 Top~Middle
593 -- Bottom~Middle
594
595 endchar;
596
597 % -------------------------------------------------------------------
598
599 bbchar
600 (oct "037")
601 (smallgap#, medlower#, smallgap#)
602 (aTop#, gBottom#);
603
604 "Lowercase Greek chi";
605
606 % The SE diagonal.
607 draw
608 Top~Left
609 -- Bottom~Right;
610
611 % The SW diagonal, fattened.
612 outline
613 fatten
614 leftof Top~Right
615 -- rightof Bottom~Left
616
617 endchar;
618
619 % -------------------------------------------------------------------
620
621 bbchar
622 (oct "040")
623 (medgap#, medlower#, medgap#)
624 (bTop#, gBottom#);
625
626 fatsymmetric;
627
628 "Lowercase Greek psi";
629
630 % The curve.
631 draw
632 aTop~Left
633 --- (aBottom + hCurl)~Left
634 .. aBottom~Middle {right}
635 .. (aBottom + hCurl)~Right
636 --- aTop~Right;
637
638 % The vertical, fattened.
639 outline
640 fatten
641 Top~Middle
642 -- Bottom~Middle
643
644 endchar;
645
646 % -------------------------------------------------------------------
647
648 bbchar
649 (oct "177")
650 (smallgap#, biglower#, smallgap#)
651 (aTop#, aBottom#);
652
653 symmetric;
654
655 "Lowercase Greek omega";
656
657 % The left curve.
658 var (path) omegapath;
659
660 omegapath
661 = farrightof Top~Left
662 .. Horizon~Left {down}
663 .. obelow Bottom~(Left -+- Middle) {right}
664 .. eBar~Middle {up};
665
666 % The emphasis.
667 draw
668 fatcliptwice
669 (rightof Top~Left -- obelow rightof Bottom~Left)
670 (omegapath);
671
672 % The left curve.
673 draw omegapath;
674
675 % The right curve.
676 draw
677 eBar~Middle {down}
678 .. obelow Bottom~(Right -+- Middle) {right}
679 .. Horizon~Right {up}
680 .. farleftof Top~Right
681
682 endchar;
683
684 % -------------------------------------------------------------------