Debian Codegraph @

texmf-dist/fonts/source/public/bbold/bbpunc.mf

raw
1 % Blackboard bold punctuation, Alan Jeffrey, 13--18 Dec 1989.
2
3 % -------------------------------------------------------------------
4
5 bbcap
6 ("!")
7 (biggap#, tiny#, biggap#);
8
9 fatsymmetric;
10
11 "Exclamation mark `!'";
12
13 % The vertical.
14 draw
15 fatten
16 Top~Middle
17 -- (Bottom + space + fatness)~Middle;
18
19 % The dot.
20 draw
21 splodge
22 above Bottom~Middle
23
24 endchar;
25
26 % -------------------------------------------------------------------
27
28 bbchar
29 ("#")
30 (medgap#, arithmetic#, medgap#)
31 (ATop#, gBottom#);
32
33 "The hash sign `#'";
34
35 % The top line.
36 draw
37 (Horizon + space)~Left
38 -- (Horizon + space)~Right;
39
40 % The bottom line.
41 draw
42 (Horizon - space)~Left
43 -- (Horizon - space)~Right;
44
45 % The right vertical.
46 draw
47 rightof Top~(Middle + space)
48 -- rightof Bottom~(Middle + space);
49
50 % The left vertical.
51 outline
52 fatten
53 rightof Top~(Middle - space)
54 -- rightof Bottom~(Middle - space)
55
56 endchar;
57
58 % -------------------------------------------------------------------
59
60 bbchar
61 ("$")
62 (medgap#, smallcap#, medgap#)
63 (ATop# + jut#, aBottom# - jut#);
64
65 fatsymmetric;
66
67 "Dollar sign `$'";
68
69 % The path of the S.
70 draw
71 (Top - CCurl)~Right
72 .. ATop~Middle {left}
73 .. (ATop -+- BBar)~Left {down}
74 .. BBar~Middle {right}
75 .. (BBar -+- aBottom)~Right {down}
76 .. aBottom~Middle {left}
77 .. (Bottom + CCurl)~Left;
78
79 % The vertical.
80 outline
81 fatten
82 Bottom~Middle
83 -- Top~Middle
84
85 endchar;
86
87 % -------------------------------------------------------------------
88
89 bbchar
90 ("%")
91 (medgap#, smallcap#, medgap#)
92 (bracketTop#, aBottom# + aTop# - bracketTop#);
93
94 fatsymmetric;
95
96 "Per cent sign `%'";
97
98 % The dot at top left.
99 draw
100 splodge
101 below rightof Top~Left;
102
103 % The dot at bottom right.
104 draw
105 splodge
106 above leftof Bottom~Right;
107
108 % The diagonal.
109 draw
110 fatten
111 rightof Bottom~Left
112 -- leftof Top~Right
113
114 endchar;
115
116 % -------------------------------------------------------------------
117
118 bbchar
119 ("&")
120 (medgap#, arithmetic#, medgap#)
121 (ATop#, aBottom#);
122
123 "Ampersand `&'";
124
125 % z1 is the top point at which the curls cross. It is somewhere
126 % between the top point and the bottom point, and is at aTop.
127
128 z1 = whatever[leftof Top~Middle, Bottom~(Left -+- Middle)];
129 y1 = aTop;
130
131 % The curve.
132 var (path) ampersandpath;
133
134 ampersandpath
135 = (Bottom + cCurl)~Right
136 .. obelow Bottom~(Right - jut) {left}
137 ... z1
138 .. oabove leftof Top~Middle {right}
139 .. z1
140 .. aMiddle~Left {down}
141 .. obelow Bottom~(Left -+- Middle) {right}
142 .. aMiddle~(Right - space);
143
144 % The emphasis.
145 draw
146 fatcliptwice
147 (obelow rightof Bottom~Left -- rightof Top~Left)
148 (ampersandpath);
149
150 % The curve.
151 draw ampersandpath
152
153 endchar;
154
155 % -------------------------------------------------------------------
156
157 bbchar
158 ("'")
159 (medgap#, tiny#, medgap#)
160 (bTop#, bTop# - tiny# - comma_depth#);
161
162 fatsymmetric;
163
164 "Apostrophe `''";
165
166 % The dot and tail.
167 draw
168 splodger below Top~Middle
169 .. Bottom~Left
170
171 endchar;
172
173 % -------------------------------------------------------------------
174
175 bbchar
176 ("(")
177 (biggap#, tiny# + jut#, smallgap#)
178 (bracketTop#, bracketBottom#);
179
180 "Left bracket `('";
181
182 % The emphasis.
183 draw
184 fatcliptwice
185 (rightof Bottom~Left -- rightof Top~Left)
186 (Bottom~Right {left} .. Horizon~Left .. Top~Right {right});
187
188 % The curve.
189 draw
190 Bottom~Right {left}
191 .. Horizon~Left
192 .. Top~Right {right}
193
194 endchar;
195
196 % -------------------------------------------------------------------
197
198 bbchar
199 (")")
200 (smallgap#, tiny# + jut#, biggap#)
201 (bracketTop#, bracketBottom#);
202
203 "Right bracket `)'";
204
205 % The emphasis.
206 draw
207 fatcliptwice
208 (leftof Bottom~Right -- leftof Top~Right)
209 (Bottom~Left {right} .. Horizon~Right .. Top~Left {left});
210
211 % The curve.
212 draw
213 Bottom~Left {right}
214 .. Horizon~Right
215 .. Top~Left {left}
216
217 endchar;
218
219 % -------------------------------------------------------------------
220
221 bbchar
222 ("*")
223 (medgap#, (sqrt3)/2 * arithmetic#, medgap#)
224 (math_axis# + 1/2arithmetic#, math_axis# - 1/2arithmetic#)
225
226 fatsymmetric;
227
228 "Star `*'";
229
230 % The distance from the top of the character to the top of the diagonals.
231 var (numeric) adistance;
232 adistance = round ((Top - Horizon) / 2);
233
234 % The NW diagonal.
235 draw
236 (Bottom + adistance)~Right
237 -- (Top - adistance)~Left;
238
239 % The NE diagonal.
240 draw
241 (Bottom + adistance)~Left
242 -- (Top -adistance)~Right;
243
244 % The vertical, fattened.
245 outline
246 fatten
247 Bottom~Middle
248 -- Top~Middle
249
250 endchar;
251
252 % -------------------------------------------------------------------
253
254 bbchar
255 ("+")
256 (medgap#, arithmetic#, medgap#)
257 (math_axis# + 1/2arithmetic#, math_axis# - 1/2arithmetic#)
258
259 "Plus sign `+'";
260
261 % The horizontal line.
262 draw
263 Horizon~Left
264 -- Horizon~Right;
265
266 % The vertical, fattened.
267 outline
268 fatten
269 Bottom~Middle
270 -- Top~Middle
271
272 endchar;
273
274 % -------------------------------------------------------------------
275
276 bbchar
277 (",")
278 (medgap#, tiny#, medgap#)
279 (aBottom# + tiny#, aBottom# - comma_depth#);
280
281 fatsymmetric;
282
283 "Comma `,'";
284
285 % The dot and tail.
286 draw
287 splodger above aBottom~Middle
288 .. Bottom~Left
289
290 endchar;
291
292 % -------------------------------------------------------------------
293
294 bbchar
295 ("-")
296 (smallgap#, smalllower#, medgap#)
297 (aTop#, aBottom#);
298
299 "Hyphen `-'";
300
301 % The line.
302 draw
303 Horizon~Left
304 -- Horizon~Right
305
306 endchar;
307
308 % -------------------------------------------------------------------
309
310 bbchar
311 (".")
312 (medgap#, tiny#, medgap#)
313 (aBottom# + tiny#, aBottom#);
314
315 fatsymmetric;
316
317 "Full stop `.'";
318
319 % The dot.
320 draw
321 splodge
322 above Bottom~Middle
323
324 endchar;
325
326 % -------------------------------------------------------------------
327
328 bbchar
329 ("/")
330 (smallgap#, smallcap#, smallgap#)
331 (bracketTop#, bracketBottom#);
332
333 "Virgule (slash) `/'";
334
335 % The line.
336 draw
337 fatten
338 rightof Bottom~Left
339 -- leftof Top~Right
340
341 endchar;
342
343 % -------------------------------------------------------------------
344
345 bbchar
346 (":")
347 (medgap#, tiny#, medgap#)
348 (aTop#, aBottom#);
349
350 fatsymmetric;
351
352 "Colon `:'";
353
354 % The top dot.
355 draw
356 splodge
357 below Top~Middle;
358
359 % The bottom dot.
360 draw
361 splodge
362 above Bottom~Middle
363
364 endchar;
365
366 % -------------------------------------------------------------------
367
368 bbchar
369 (";")
370 (medgap#, tiny#, medgap#)
371 (aTop#, aBottom# - comma_depth#);
372
373 fatsymmetric;
374
375 "Semicolon `;'";
376
377 % The upper dot.
378 draw
379 splodge
380 below Top~Middle;
381
382 % The lower dot and tail.
383 draw
384 splodger above aBottom~Middle
385 .. Bottom~Left
386
387 endchar;
388
389 % -------------------------------------------------------------------
390
391 beginblacker 1.5;
392 bbchar
393 ("<")
394 (biggap#, arithmetic#, biggap#)
395 (math_axis# + 1/2lessthan#, math_axis# - 1/2lessthan#);
396
397 "Less than sign `<'";
398
399 % The top diagonal.
400 draw
401 Top~Right
402 --- Horizon~Left;
403
404 % The bottom diagonal, fattened, and clipped by the top.
405 % We need to carry on the diagonal past where it started,
406 % so we extend it up to the top of the character.
407 draw
408 fatcliponce
409 (leftof Bottom~Right
410 --- rightof Horizon~Left
411 .. farrightof Top~(2Left - Right))
412 (Top~Right -- Horizon~Left)
413
414 endchar;
415 endblacker;
416
417 % -------------------------------------------------------------------
418
419 bbchar
420 ("=")
421 (medgap#, tiny#, medgap#)
422 (math_axis# + 1/2tiny#, math_axis# - 1/2tiny#);
423
424 fatsymmetric;
425
426 "Centred dot";
427
428 % The dot.
429 draw
430 splodge
431 above Bottom~Middle
432
433 endchar;
434
435 % -------------------------------------------------------------------
436
437 beginblacker 1.5;
438
439 bbchar
440 (">")
441 (biggap#, arithmetic#, biggap#)
442 (math_axis# + 1/2lessthan#, math_axis# - 1/2lessthan#);
443
444 "Greater than sign `>'";
445
446 % The top diagonal.
447 draw
448 Top~Left
449 --- Horizon~Right;
450
451 % The bottom diagonal, fattened, and clipped by the top.
452 % We need to carry on the diagonal past where it started,
453 % so we extend it up to the top of the character.
454 draw
455 fatcliponce
456 (rightof Bottom~Left
457 --- leftof Horizon~Right
458 .. farleftof Top~(2Right - Left))
459 (Top~Left -- Horizon~Right)
460
461 endchar;
462 endblacker;
463
464 % -------------------------------------------------------------------
465
466 bbcap
467 ("?")
468 (medgap#, smallcap#, medgap#);
469
470 fatsymmetric;
471
472 "Question mark `?'";
473
474 % The height of the bottom of the curl.
475 var (numeric) curlBottom;
476
477 curlBottom = Bottom + fatness + space;
478
479 % The curl.
480 var (path) questionpath;
481
482 questionpath
483 = (Top - CCurl)~Left
484 .. oabove Top~Middle {right}
485 .. (1/3[Top, curlBottom])~Right {down}
486 .. rightof (2/3[Top, curlBottom])~Middle {left}
487 .. leftof curlBottom~Middle {down};
488
489 draw questionpath;
490
491 % The emphasis, clipped with the bottom bit of the question path.
492 draw
493 fatcliponce
494 (curlBottom~Middle -- oabove Top~Middle)
495 (subpath (2, infinity) of questionpath);
496
497 % The dot.
498 draw
499 splodge
500 above Bottom~Middle
501
502 endchar;
503
504 % -------------------------------------------------------------------
505
506 bbchar
507 ("@")
508 (medgap#, tiny# + 2fatness#, medgap#)
509 (ATop#, aBottom#);
510
511 "At sign `@'";
512
513 % The curl.
514 var (path) atpath;
515
516 atpath
517 = (Bottom + CCurl)~Right
518 .. obelow Bottom~Middle {left}
519 .. Horizon~Left {up}
520 .. oabove Top~Middle {right}
521 .. splodger leftof Horizon~Right;
522
523 % The emphasis.
524 draw
525 fatcliptwice
526 (obelow rightof Bottom~Left -- oabove rightof Top~Left)
527 (atpath);
528
529 % The curl.
530 draw atpath
531
532 endchar;
533
534 % -------------------------------------------------------------------
535
536 bbchar
537 ("[")
538 (biggap#, tiny# + jut#, smallgap#)
539 (bracketTop#, bracketBottom#);
540
541 "Left square bracket `['";
542
543 % The vertical.
544 draw
545 fatten
546 rightof Bottom~Left
547 -- rightof Top~Left;
548
549 % The top line.
550 draw
551 Top~Left
552 -- Top~Right;
553
554 % The bottom line.
555 draw
556 Bottom~Left
557 -- Bottom~Right
558
559 endchar;
560
561 % -------------------------------------------------------------------
562
563 bbchar
564 ("\")
565 (smallgap#, smallcap#, smallgap#)
566 (bracketTop#, bracketBottom#);
567
568 "Reverse slash `\'";
569
570 % The line.
571 draw
572 fatten
573 leftof Bottom~Right
574 -- rightof Top~Left
575
576 endchar;
577
578 % -------------------------------------------------------------------
579
580 bbchar
581 ("]")
582 (smallgap#, tiny# + jut#, biggap#)
583 (bracketTop#, bracketBottom#);
584
585 "Right square bracket `]'";
586
587 % The vertical.
588 draw
589 fatten
590 leftof Bottom~Right
591 -- leftof Top~Right;
592
593 % The top line.
594 draw
595 Top~Left
596 -- Top~Right;
597
598 % The bottom line.
599 draw
600 Bottom~Left
601 -- Bottom~Right
602
603 endchar;
604
605 % -------------------------------------------------------------------
606
607 beginblacker 1.25;
608 bbchar
609 ("^")
610 (biggap#, tiny# + jut#, smallgap#)
611 (bracketTop#, bracketBottom#);
612
613 "Left angle bracket";
614
615 % The emphasis, clipped by the bracket.
616 draw
617 fatcliptwice
618 (rightof Bottom~Left -- rightof Top~Left)
619 (Bottom~Right -- Horizon~Left -- Top~Right);
620
621 % The bracket.
622 draw
623 Bottom~Right
624 -- Horizon~Left
625 -- Top~Right
626
627 endchar;
628 endblacker;
629
630 % -------------------------------------------------------------------
631
632 beginblacker 1.25;
633 bbchar
634 ("_")
635 (smallgap#, tiny# + jut#, biggap#)
636 (bracketTop#, bracketBottom#);
637
638 "Right angle bracket";
639
640 % The emphasis, clipped by the bracket.
641 draw
642 fatcliptwice
643 (leftof Bottom~Right -- leftof Top~Right)
644 (Bottom~Left -- Horizon~Right -- Top~Left);
645
646 % The bracket.
647 draw
648 Bottom~Left
649 -- Horizon~Right
650 -- Top~Left
651
652 endchar;
653 endblacker;
654
655 % -------------------------------------------------------------------
656
657 bbchar
658 ("`")
659 (medgap#, tiny#, medgap#)
660 (bTop#, bTop# - tiny# - comma_depth#);
661
662 fatsymmetric;
663
664 "Reverse apostrophe ``'";
665
666 % The dot and tail.
667 draw
668 splodgel above Bottom~Middle
669 .. Top~Right
670
671 endchar;
672
673 % -------------------------------------------------------------------
674
675 bbchar
676 ("|")
677 (biggap#, tiny#, biggap#)
678 (bracketTop#, bracketBottom#);
679
680 "Vertical bar `|'";
681
682 % The line.
683 draw
684 fatten
685 Bottom~Middle
686 -- Top~Middle
687
688 endchar;
689
690 % -------------------------------------------------------------------
691