Debian Codegraph @

texmf-dist/fonts/source/public/wsuipa/igreekl.mf

raw
1 % Please see the file LICENCE-wsuipa.txt for licensing information.
2
3 % This is IGREEKL.MF in text format, as of Apr. 22, 1989.
4 % This lowercase Greek alphabet was prepared by D. E. Knuth in December, 1979,
5 % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
6 % (It has been designed for math formulas, not Greek texts.)
7 % The programs were revised for the new \MF\ conventions in 1985.
8
9 % Character codes \0013--\0047 are generated.
10
11 cmchar "Lowercase Greek epsilon";
12 beginchar(oct"030",8.25u#,x_height#,0);
13 italcorr x_height#*slant-.5u#;
14 adjust_fit(0,0);
15 numeric top_thickness,mid_thickness,bot_thickness;
16 top_thickness=max(fine.breadth,vround(slab-2vair_corr));
17 mid_thickness=max(fine.breadth,vround 2/3vair);
18 bot_thickness=max(fine.breadth,vround(slab-vair_corr));
19 pickup fine.nib; pos2(top_thickness,90); top y2l=h+o;
20 pos3(max(.6fine.breadth,.35[curve,cap_curve]-stem_corr),180);
21 lft x3l=hround(1.25u);
22 pos9(bot_thickness,angle(-2u,-h));
23 rt x9l=hround w-.75u; top y9l=vround .25h-o;
24 y9r:=good.y y9r-eps; x9r:=good.x x9r;
25 pos4(vair,-90); pos5(vair,-90);
26 pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x9];
27 pos7(max(.6fine.breadth,.35[curve,cap_curve]-stem_corr),180);
28 lft x7l=hround(.75u);
29 lft x5=min(hround 4u,lft x6)-eps;
30 pos8(bot_thickness,-90); bot y8r=-o;
31 y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
32 top y5l=vround(.54h+.5vair); y5r=y6l;
33 x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
34 filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
35 & z3e{down}...z4e---z5e; % upper bowl
36 filldraw z5r--z6l--z6r--z5l---cycle; % middle tip
37 filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
38 & pulled_super_arc.e(7,8)(.5superpull); % lower bowl
39 numeric bulb_diam[];
40 bulb_diam1=flare-.75(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
41 pos0(bulb_diam1,0); pos1(hair,0);
42 lft x0r=hround w-1.25u; y0=min(.9h-.5bulb_diam1,.75h+.5bulb_diam1);
43 bulb(2,1,0); % upper bulb
44 filldraw stroke term.e(8,9,right,1,4); % lower terminal
45 penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
46
47 cmchar "Lowercase Greek reversed epsilon";
48 beginchar(oct"31",8.5u#,x_height#,0);
49 italcorr x_height#*slant-.5u#;
50 adjust_fit(0,0);
51 numeric top_thickness,mid_thickness,bot_thickness;
52 top_thickness=max(fine.breadth,vround(slab-2vair_corr));
53 mid_thickness=max(fine.breadth,vround 2/3vair);
54 bot_thickness=max(fine.breadth,vround(slab-vair_corr));
55 pickup fine.nib; pos2(top_thickness,90); top y2l=h+o;
56 pos3(max(.6fine.breadth,.35[curve,cap_curve]-stem_corr),0);
57 rt x3r=hround(w-1.25u);
58 pos4(vair,-90); pos5(vair,-90);
59 pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
60 pos7(max(.6fine.breadth,.35[curve,cap_curve]-stem_corr),0);
61 rt x7r=hround(w-.75u);
62 lft x5=min(hround 4u,lft x6)-eps;
63 pos8(bot_thickness,-90); bot y8r=-o;
64 y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
65 top y5l=vround(.54h+.5vair); y5r=y6l;
66 x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
67 filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
68 & z3e{down}...z4e---z5e; % upper bowl
69 filldraw z5r--z6l--z6r--z5l---cycle; % middle tip
70 filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
71 & pulled_super_arc.e(7,8)(.5superpull); % lower bowl
72 numeric bulb_diam[];
73 bulb_diam1=flare-.75(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
74 pos0(bulb_diam1,180); pos1(hair,180);
75 lft x0r=hround 1.25u; y0=min(.9h-.5bulb_diam1,.75h+.5bulb_diam1);
76 bulb(2,1,0); % upper bulb
77 pos9(bot_thickness,angle(-2u,-h));
78 lft x9r=hround .75u; top y9l=vround .25h-o;
79 y9r:=good.y y9r-eps; x9l:=good.x x9l;
80 filldraw stroke term.e(8,9,left,1,4); % lower terminal
81 penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
82
83 cmchar "Right-hook lowercase Greek reversed epsilon";
84 beginchar(oct"32",11.5u#,x_height#,0);
85 italcorr x_height#*slant-.5u#;
86 adjust_fit(0,0);
87 numeric top_thickness,mid_thickness,bot_thickness;
88 top_thickness=max(fine.breadth,vround(slab-2vair_corr));
89 mid_thickness=max(fine.breadth,vround 2/3vair);
90 bot_thickness=max(fine.breadth,vround(slab-vair_corr));
91 pickup fine.nib; pos2(top_thickness,90); top y2r=h+o;
92 pos3(.3[curve,cap_curve]-stem_corr,0);
93 rt x3r=hround(.78w-1.25u);
94 pos4(vair,-90); pos5(vair,-90);
95 pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
96 pos7(.3[curve,cap_curve]-stem_corr,0);
97 rt x7r=hround(.78w-.75u);
98 lft x5=min(hround 4u,lft x6)-eps;
99 pos8(bot_thickness,-90); bot y8r=-o;
100 y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
101 top y5l=vround(.54h+.5vair); y5r=y6l;
102 x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
103 filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
104 & z3e{down}...z4e---z5e; % upper bowl
105 filldraw z5r--z6l--z6r--z5l---cycle; % middle tip
106 filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
107 & pulled_super_arc.e(7,8)(.5superpull); % lower bowl
108 numeric bulb_diam[];
109 bulb_diam1=flare-.5(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
110 pos0(bulb_diam1,180); pos1(hair,180);
111 lft x0r=hround 1.25u; y0=min(.9h-.5bulb_diam1,.75h+.5bulb_diam1);
112 bulb(2,1,0); % upper bulb
113 pos9(bot_thickness,angle(-2u,-h));
114 lft x9r=hround .75u; top y9l=vround .25h-o;
115 y9r:=good.y y9r-eps; x9l:=good.x x9l;
116 filldraw stroke term.e(8,9,left,1,4); % lower terminal
117 % right hook
118 pos10(hair,0); pos11(hair,0); pos12(hair,0);
119 pos13(hair,90); pos14(hair,180);
120 z10=z3; top y11=h; rt x11r=hround(x3r+2u)=rt x12r;
121 y12=.65[y11,y13]=y14; x13=.5[x11,x14];
122 bot y13l=.5h; x14l=w;
123 filldraw stroke z10e--z11e;
124 filldraw stroke z11e--z12e...z13e...z14e;
125 penlabels(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
126
127 cmchar "Lowercase Greek closed reversed epsilon";
128 beginchar(oct"33",8.5u#,x_height#,0);
129 italcorr x_height#*slant-.5u#;
130 adjust_fit(0,0);
131 numeric top_thickness,mid_thickness,bot_thickness;
132 top_thickness=max(fine.breadth,vround(slab-2vair_corr));
133 mid_thickness=max(fine.breadth,vround 2/3vair);
134 bot_thickness=max(fine.breadth,vround(slab-vair_corr));
135 pickup fine.nib; pos2(top_thickness,90); top y2r=h+o;
136 pos3(max(.6fine.breadth,.35[curve,cap_curve]-stem_corr),0);
137 rt x3r=hround(w-1.25u);
138 pos4(vair,-90); pos5(vair,-90);
139 pos5'(slab,180); y5'=y5; x5'=0;
140 pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
141 pos7(max(.6fine.breadth,.35[curve,cap_curve]-stem_corr),0);
142 rt x7r=hround(w-.75u);
143 lft x5=min(hround 4u,lft x6)-eps;
144 pos8(bot_thickness,-90); bot y8r=-o;
145 y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
146 top y5l=vround(.54h+.5vair); y5r=y6l;
147 x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
148 filldraw stroke z8e{left}...{up}z5'e...z2e
149 &pulled_super_arc.e(2,3)(.5superpull)
150 & z3e{down}...z4e---z5e; % upper bowl
151 filldraw z5r--z6l--z6r--z5l---cycle; % middle tip
152 filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
153 & pulled_super_arc.e(7,8)(.5superpull); % lower bowl
154 penlabels(2,3,4,5,6,7,8,,5'); endchar;
155
156 cmchar "Lowercase Greek theta";
157 beginchar(oct"123",8.25u#,asc_height#,0);
158 italcorr .7asc_height#*slant+.5curve#-u#;
159 adjust_fit(0,0); pickup fine.nib;
160 pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
161 x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
162 top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
163 filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
164 & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
165 pos2'(bar,90); pos4'(bar,90); z2'=z2l; z4'=z4l;
166 filldraw stroke z2'e--z4'e; % bar
167 math_fit(-.3asc_height#*slant-u#+.5curve#,ic#-.5u#);
168 penlabels(1,2,3,4); endchar;
169
170 cmchar "Lowercase Greek iota";
171 beginchar(oct"051",5u#,x_height#,0);
172 italcorr 1/3x_height#*slant+.5hair#+.5u#;
173 adjust_fit(if monospace: u#,u# else: 0,0 fi); pickup fine.nib;
174 pos1(stem,0); lft x1l=hround(1.5u-.5stem); y1+.5stem=h+oo;
175 x2=x1-.25u; x4=w; hook_out(2,3,4)(skewed); % closing hook
176 filldraw circ_stroke z1e{down}...{-u,-x_height}z2e; % stem
177 math_fit(0,ic#); penlabels(1,2,3,4); endchar;
178
179 cmchar "Lowercase Greek lambda";
180 beginchar(oct"62",10.5u#,asc_height#,0);
181 adjust_fit(0,0); pickup fine.nib;
182 pos1(vair,90); lft x1=hround .1u; top y1r=h;
183 x2=x1+2u; y2=.7[x_height,h]; x3=w-2u; bot y4=-oo; y3=max(.07h,y4+eps);
184 z4-(.25u,0)=whatever[z2,z3]; numeric theta; theta=angle(z2-z3)-90;
185 pos2(stem,theta); pos3(stem,theta); pos4(stem,0);
186 filldraw circ_stroke z1e{right}...z2e---z3e
187 ...{2(x4e-x3e),y4e-y3e}z4e; % long diagonal
188 y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
189 x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
190 filldraw circ_stroke z6e--z5e; % short diagonal
191 penlabels(1,2,3,4,5,6); endchar;
192
193 cmchar "Lowercase crossed Greek lambda";
194 beginchar(oct"063",10.5u#,asc_height#,0);
195 adjust_fit(0,0); pickup fine.nib;
196 pos1(vair,90); lft x1=hround .1u; top y1r=h;
197 x2=x1+2u; y2=.7[x_height,h]; x3=w-2u; bot y4=-oo; y3=max(.07h,y4+eps);
198 z4-(.25u,0)=whatever[z2,z3]; numeric theta; theta=angle(z2-z3)-90;
199 pos2(stem,theta); pos3(stem,theta); pos4(stem,0);
200 filldraw circ_stroke z1e{right}...z2e---z3e
201 ...{2(x4e-x3e),y4e-y3e}z4e; % long diagonal
202 y5=.5[bar_height,x_height]; z5=whatever[z2,z3];
203 x6=1.5u; y6-.5stem=-oo; pos5(hair,theta-90); pos6(stem,angle(z5-z6)-90);
204 filldraw circ_stroke z6e--z5e; % short diagonal
205 pickup fine.nib;
206 pos7(bar,125); pos8(bar,125);
207 x7=x1; y7 = .57h; top y8=.9h;
208 x8=.5[x5,x4];
209 filldraw stroke z7e--z8e; % crossbar
210 penlabels(1,2,3,4,5,6,7,8); endchar;
211
212 cmchar "Script v (Lowercase Greek upsilon)";
213 beginchar(oct"131",9u#,x_height#,0);
214 italcorr x_height#*slant;
215 adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
216 x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
217 hook_in(0,1,2)(skewed); % opening hook
218 pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
219 x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
220 filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
221 ..tension atleast 1.05..{up}z5e; % left stem and arc
222 v_bulb(5,6); % closing bulb
223 math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
224 penlabels(0,1,2,3,4,5,6); endchar;
225
226 cmchar "Lowercase Greek chi";
227 beginchar(oct"133",9.5u#,x_height#,desc_depth#);
228 italcorr x_height#*slant+.5hair#-1.5u#;
229 adjust_fit(0,0); pickup fine.nib;
230 pos1(hair,180); pos2(vair,80); pos5(vair,80); pos6(hair,180);
231 x1-.5hair=hround-.5hair; x6=w-x1; x2=w-x5=u;
232 y1=y2l-h/8; top y2r=h+oo; bot y5l=-d-oo; y6=y5r+h/8;
233 z0=.5[z2,z5]; z2'=z2l+(.5u,0); z5'=z5r-(.5u,0);
234 numeric theta; theta=angle(z5'-z2')+90;
235 pos3(stem,theta); pos4(stem,theta);
236 y3r=y2r-h/8; y4l=y5l+h/8; z3l=whatever[z2',z0]; z4r=whatever[z0,z5'];
237 filldraw stroke z1e{up}...z2e{right}...z3e{z4r-z3l}
238 ..z4e{z4r-z3l}...{right}z5e...{up}z6e; % major diagonal and hooks
239 x8=w-x7=2u; y7+.5hair=h; y8-.5hair=-d;
240 numeric theta; theta=angle(z7-z8)-90;
241 pos7(hair,theta); pos8(hair,theta);
242 filldraw z7l---z8l..z8r---z7r..cycle; % minor diagonal
243 math_fit((desc_depth#-x_height#)*slant+ic#,ic#);
244 penlabels(0,1,2,2',3,4,5',5,6,7,8); endchar;
245
246 cmchar "Lowercase Greek omega";
247 beginchar(oct"076",11u#,x_height#,0);
248 italcorr x_height#*slant;
249 adjust_fit(0,0); pickup fine.nib;
250 pos2(hair,-180); lft x2r=hround.5u; y2=y4=y6=y8=bar_height;
251 y1+.5hair=h; x1=x2+.75u; pos1(hair,angle(2(x1-x2),y1-y2)+90);
252 pos3(vstem,-90); pos4(hair,0); pos5(vair,90);
253 pos6(hair,180); pos7(vstem,270); pos8(hair,360);
254 bot y3r=bot y7r=-oo; top y5r=vround(.2[y4,h]+.5vair);
255 x3=.4[x2,x4]; x7+.25u=.6[x6,x8]; rt x8r=hround(w-.5u);
256 x5+.5stem=hround(.5w+.5stem)+eps;
257 x5=.5[x4,x6]; rt x4r-lft x6r=min(stem,2hair)+2eps;
258 if x4l<x6l: x4l:=x6l:=x5; fi
259 filldraw circ_stroke z1e{2(x2-x1),y2-y1}...z2e{down}...z3e{right}
260 ...{up}z4e...{left}z5e; % left arc
261 filldraw stroke z5e{left}...z6e{down}...z7e{right}...{up}z8e; % right arc
262 v_bulb(8,9); % closing bulb
263 math_fit(-bar_height#*slant,2/3ic#); penlabels(1,2,3,4,5,6,7,8,9); endchar;
264
265 cmchar "Closed lowercase Greek omega";
266 beginchar(oct"077",11u#,x_height#,0);
267 italcorr x_height#*slant;
268 adjust_fit(0,0); pickup fine.nib;
269 pos2(hair,-180); lft x2r=hround.5u; y2=y4=y6=y8=bar_height;
270 y1-.5hair=h; x1=.5w; pos1(hair,angle(2(x1-x2),y1-y2)+90);
271 pos3(vstem,-90); pos4(hair,0); pos5(vair,90);
272 pos6(hair,180); pos7(vstem,270); pos8(hair,360);
273 bot y3r=bot y7r=-oo; top y5r=vround(.2[y4,h]+.5vair);
274 x3=.4[x2,x4]; x7+.25u=.6[x6,x8]; rt x8r=hround(w-.5u);
275 x5+.5stem=hround(.5w+.5stem)+eps;
276 x5=.5[x4,x6]; rt x4r-lft x6r=min(stem,2hair)+2eps;
277 if x4l<x6l: x4l:=x6l:=x5; fi
278 filldraw circ_stroke z1e{left}...z2e{down}...z3e{right}
279 ...{up}z4e...{left}z5e; % left arc
280 filldraw stroke z5e{left}...z6e{down}...z7e{right}...{up}z8e...{left}z1e;
281 % right arc
282 penlabels(1,2,3,4,5,6,7,8); endchar;
283
284 cmchar "The letter baby gamma";
285 beginchar(oct"041",if serifs: 9.5u# else:9u# fi,x_height#,0);
286 italcorr x_height#*slant-.05u#;
287 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
288 numeric stem[],outer_jut,xjut,alpha[];
289 stem1=fudged.stem-4stem_corr; stem2=min(1.5fudged.hair,stem1);
290 outer_jut=.75jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
291 x1l=l+letter_fit+.1u+outer_jut; x2r=r-letter_fit-.3u-outer_jut-xjut;
292 x3l=l+letter_fit+2.5outer_jut+xjut; x4r=r-letter_fit-2outer_jut;
293 y1=y2=h; y3=y4=.3h; z11=z3;
294 x10=.5[x3,x4]; y10r=0;
295 alpha1=diag_ratio(1,stem1,h,x4r-x1l);
296 alpha2=diag_ratio(1,stem2,h,x2r-x3l);
297 penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
298 penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
299 penpos10(alpha2*stem2,-90); penpos11(alpha2*stem2,180);
300 if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
301 x12=x34=x0; y13=y24=y0;
302 z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
303 z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
304 forsuffixes $=13,24,34: z$'=.2[z$,z0]; endfor
305 fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
306 --diag_end(34',4l,.5,1,4r,24')--z24'
307 --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
308 else: fill diag_end(4r,1r,.5,1,1l,4l)
309 --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
310 fill diag_end(2l,3l,.5,1,3r,2r)
311 --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi % right diagonal
312 filldraw stroke pulled_arc.e(4,10) & pulled_arc.e(10,11);% lower bowl
313 if serifs: numeric inner_jut[]; pickup tiny.nib;
314 prime_points_inside(1,4); prime_points_inside(2,3);
315 prime_points_inside(3,2); prime_points_inside(4,1);
316 if rt x1'r+jut+.5u+1<=lft x2'l-jut-xjut: inner_jut1=jut;
317 else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
318 if rt x3'r+jut+.5u+1<=lft x4'l-jut-xjut: inner_jut2=jut;
319 else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
320 dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1); % upper left serif
321 dish_serif(2',3,e,2/3,inner_jut1+xjut,
322 f,1/2,outer_jut+xjut)(dark); fi % upper right serif
323 penlabels(0,1,2,3,4,10,12,13,24,34); endchar;
324
325 cmchar "The letter IPA Gamma";
326 beginchar(oct"040",if serifs: 9.5u# else:9u# fi,x_height#,desc_depth#);
327 italcorr x_height#*slant-.05u#;
328 adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
329 numeric stem[],outer_jut,xjut,alpha[];
330 stem1=fudged.stem-4stem_corr; stem2=min(fudged.hair,stem1);
331 outer_jut=.75jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
332 x1l=l+letter_fit+.1u+outer_jut; x2r=r-letter_fit-.3u-outer_jut-xjut;
333 x3l=l+letter_fit+2.2outer_jut+xjut; x4r=r-letter_fit-2.2outer_jut;
334 y1=y2=h; y3=y4=-.25d; z11=z3;
335 x10=.5[x3,x4]; y10r=-d;
336 alpha1=diag_ratio(1,stem1,h,x4r-x1l);
337 alpha2=diag_ratio(1,stem2,h,x2r-x3l);
338 penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
339 penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
340 penpos10(alpha2*stem2,-90); penpos11(alpha2*stem2,180);
341 if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
342 x12=x34=x0; y13=y24=y0;
343 z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
344 z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
345 forsuffixes $=13,24,34: z$'=.2[z$,z0]; endfor
346 fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
347 --diag_end(34',4l,.5,1,4r,24')--z24'
348 --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
349 else: fill diag_end(4r,1r,.5,1,1l,4l)
350 --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
351 fill diag_end(2l,3l,.5,1,3r,2r)
352 --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi % right diagonal
353 filldraw stroke pulled_arc.e(4,10) & pulled_arc.e(10,11);% lower bowl
354 if serifs: numeric inner_jut[]; pickup tiny.nib;
355 prime_points_inside(1,4); prime_points_inside(2,3);
356 prime_points_inside(3,2); prime_points_inside(4,1);
357 if rt x1'r+jut+.5u+1<=lft x2'l-jut-xjut: inner_jut1=jut;
358 else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
359 if rt x3'r+jut+.5u+1<=lft x4'l-jut-xjut: inner_jut2=jut;
360 else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
361 dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1); % upper left serif
362 dish_serif(2',3,e,2/3,inner_jut1+xjut,
363 f,1/2,outer_jut+xjut)(dark); fi % upper right serif
364 penlabels(0,1,2,3,4,10,12,13,24,34); endchar;
365
366 cmchar "Lowercase Greek gamma";
367 beginchar(oct"037",10u#,x_height#,desc_depth#);
368 italcorr x_height#*slant-.5u#;
369 adjust_fit(0,0); pickup fine.nib;
370 pos1(hair,180); pos2(vstem+dw,90);
371 pos4(hair,0); pos5(vair,-90); pos6(hair,-180); pos7(hair,-180);
372 bot y1=.5772156649h; top y2r=h+oo; y4=y6=-.5d;
373 bot y5r=-d-o; top y7=h;
374 lft x1r=hround(.5u-.5hair); x2=3u; rt x4r=hround(w-2.5u); x5=.5[x4,x6];
375 rt x4r-lft x6r= hround 3/4[hair,stem] + eps; rt x7l=hround(w-.5u);
376 if x4l<x6l: x4l:=x6l:=x5; fi
377 pos3(vair,angle(z4-z2)+90); x3=superness[x2,x4]; y3=superness[y4,y2];
378 filldraw stroke z1e{up}...z2e{right}...z3e{z4-z2}
379 ...z4e{down}...{left}z5e; % arc
380 filldraw stroke z5e{left}...z6e{up}..{2(x7-x6),y7-y6}z7e; % stem
381 penlabels(1,2,3,4,5,6,7); endchar;
382
383 cmchar "Lowercase Greek alpha";
384 beginchar(oct"002",11u#,x_height#,0);
385 italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.5u#);
386 adjust_fit(0,0); pickup fine.nib;
387 pos0(2hair,0); pos1(2vair,-90); pos2(curve,-180); pos3(vair,-270);
388 z4=(w-3.25u,9/16h); z5=(w-2.75u,.5[vair,y4]);
389 numeric theta; theta=angle(z4-z5)-90;
390 pos4(stem,theta); pos5(stem,theta);
391 pos6(vair,90); pos7(hair,180);
392 rt x0r=hround(w-u); x1=x3=.5w-u; lft x2r=hround(1.5u-.5curve);
393 x6=w-u; x7+.5hair=hround(w+.5hair-epsilon);
394 y0=vround .9[bar_height,h]; bot y1r=bot y6l=-oo;
395 y2=.5[y1,y3]; top y3r=h+oo; y7=1/4bar_height;
396 filldraw stroke z0e{down}...pulled_arc.e(1,2) & pulled_arc.e(2,3)
397 ...z4e---z5e...z6e{right}...{up}z7e; % diagonal, bowl, and hook
398 penlabels(0,1,2,3,4,5,6,7); endchar;
399
400 cmchar "Lowercase Greek beta";
401 beginchar(oct"011",9.5u#,asc_height#,desc_depth#);
402 italcorr .5[x_height#,asc_height#]*slant-u#;
403 adjust_fit(0,0); pickup fine.nib;
404 pos0(1.5hair,180); pos1(1.5hair,180); pos2(vair,90);
405 pos3(stem,0); pos4(vair,-90); pos5(hair,-180);
406 pos6(vair,-270); pos7(curve,-360); pos8(vair,-450); pos9(1.25hair,-540);
407 x0=x1=x9; lft x0l=hround(1.5u-.5hair); x2=x4=x6=x8=.5w+.25u;
408 rt x3r=hround(w-1.5u); rt x7r=hround(w-1.5u+.5curve); rt x5l=hround(x4-u);
409 bot y0=-d; y1=top y6r=x_height; top y2r=h+oo; y3=.5[y2,y4];
410 y5=.5[y4,y6]; top y6r-bot y4r=vstem+eps; bot y8=-oo; y7=y9=.5[y6,y8];
411 if y6l<y4l: y6l:=y4l:=y5; fi
412 filldraw stroke z0e---z1e...pulled_arc.e(2,3)
413 & pulled_arc.e(3,4)...{up}z5e; % stem and upper bowl
414 filldraw stroke z5e{up}...pulled_arc.e(6,7)
415 & pulled_arc.e(7,8)...{up}z9e; % lower bowl
416 penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
417
418 cmchar "Lowercase Greek phi";
419 beginchar(oct"103",11u#,asc_height#,desc_depth#);
420 italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
421 adjust_fit(0,0); pickup fine.nib;
422 numeric light_curve; light_curve=hround(.5[stem,curve]-2stem_corr);
423 pos1(vair,90); pos2(light_curve,180); pos3(vair,270); pos4(light_curve,360);
424 x1=x3=.5w; lft x2r=hround(1.5u-.5light_curve); x4=w-x2;
425 top y1=x_height+oo; y2=y4=.5[y1,y3]; bot y3=-oo;
426 filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
427 & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
428 pos5(hair,0); pos6(hair,0); x5=x6=.5w; top y5=.9h; bot y6=-d-oo;
429 filldraw stroke z5e--z6e; % stem
430 penlabels(1,2,3,4,5,6); endchar;
431
432 cmchar "Lowercase Greek sigma";
433 beginchar(oct"117",10.25u#,x_height#,0);
434 italcorr x_height#*slant+.5stem#-u#;
435 adjust_fit(0,0); pickup fine.nib;
436 pos1(vstem,90); pos2(stem,0); pos3(vair,-90);
437 pos4(stem,-180); pos5(vstem,-270); pos6(vstem,-270);
438 x1=x3=x5=.5[x2,x4]; rt x2r=hround(w-2.5u);
439 lft x4r=hround(1.5u-.5curve);x6=w-1.5u;
440 top y1r=h; y2=y4=.5[y1,y3]; bot y3r=-oo; y5=y6=y1;
441 filldraw circ_stroke z6e..pulled_arc.e(5,4) & pulled_arc.e(4,3)
442 & pulled_arc.e(3,2) & pulled_arc.e(2,1); % ear and bowl
443 penlabels(1,2,3,4,5,6); endchar;