Debian Codegraph @

texmf-dist/fonts/source/public/wsuipa/iaccent.mf

raw
1 % Please see the file LICENCE-wsuipa.txt for licensing information.
2
3 % This is IACCENT.MF in text format, as of April 22, 1989.
4 % This file contains accents common to text roman and italic fonts.
5 % Character codes \0022--\0030, \0040, \0136--\0137, \0175--\0177 are generated.
6
7 % (Actually the accents in positions \0040, \0137, and \0175 are not generated
8 % unless |ligs>0|, since other symbols are substituted
9 % for those accents in non-ligature fonts.)
10
11
12 cmchar "Reversed Apostrophe";
13 beginchar(oct"163",5u#,asc_height#,0);
14 italcorr asc_height#*slant+.5dot_size#-2u#;
15 adjust_fit(0,0);
16 x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h;
17 def mymoc(suffix $,@)(expr dot_size,jut,depth) = % reversed comma
18 pickup fine.nib; pos$(dot_size,90);
19 pos@1(vair,90); pos@2(vair,180); pos@3(vair,-45);
20 z@1r=z$r; rt x@2r=hround(x$-.5dot_size-jut)-2eps; x@3=x$+.5u;
21 y@2=1/3[y@1,y@3]; bot y@3l=vround(y$-.5dot_size-depth);
22 y_:=ypart((z@1{left}...z@2{down}...z@3)
23 intersectiontimes (z$l{left}..{right}z$r)); if y_<0: y_:=1; fi
24 filldraw z$r{right}..subpath (0,y_) of (z$l{left}..{right}z$r)--cycle; % dot
25 filldraw stroke z@1e{left}...z@2e{down}...z@3e; % tail
26 penlabels(@1,@2,@3); enddef;
27
28 if monospace: mymoc(1,a,dot_size,.28u,vround 1.5comma_depth); % large comma
29 else: mymoc(1,a,dot_size,.25u,comma_depth); fi % comma with increased jut
30 penlabels(1); endchar;
31
32 cmchar "Corner accent";
33 beginchar(oct"153",7u#,min(asc_height#,2x_height#),0);
34 adjust_fit(0,0);
35 pickup light_rule.nib;
36 x1=1u; x2=x3=w-x1;
37 y1=h+eps=y2; y3=.87x_height;
38 draw z1--z2; draw z2--z3; % corner
39 penlabels(1,2,3); endchar;
40
41 cmchar "Scandinavian circle accent";
42 beginchar(oct"170",13u#+4/3(asc_height#-x_height#)*slant,asc_height#,0);
43 adjust_fit(cap_serif_fit#,cap_serif_fit#);
44 numeric circ_hair,circ_vair;
45 circ_hair=hround min(hair,u+.5); circ_vair=vround min(vair,(h-x_height)/6+.5);
46 penpos1(circ_vair,90); penpos3(circ_vair,-90);
47 penpos2(circ_hair,180); penpos4(circ_hair,0);
48 x2r=hround(.5w-1.5u-.5circ_hair);
49 x4r=w-x2r; x1=x3=.5w; y1r=h+apex_o; y2=y4=.5[y1,y3];
50 y3r=vround(1/3[x_height,h]+apex_o);
51 penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
52 & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
53 penlabels(1,2,3,4); endchar;
54
55 cmchar "Mid-Tilde (squiggle) accent";
56 beginchar(oct"173",12u#,x_height#+.5dot_size#,0);
57 italcorr h#*slant-u#;
58 adjust_fit(0,0);
59 if serifs: numeric theta; theta=angle(1/6(8u-vair),1/4(h-.62x_height));
60 pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
61 pos1(vair,theta+90); pos2(vair,theta+90);
62 pos3(vair,theta+90); pos4(vair,theta+90);
63 z2-z1=z4-z3=(mid_width-crisp)*dir theta;
64 lft x1r=w-rt x4l=hround 1.5u; top y4r=h;
65 bot y1l=vround(bot y1l+min(.6[.62x_height,h],y3l-.2vair)-top y1r);
66 pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
67 filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
68 --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
69 else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
70 pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
71 lft x1r=w-rt x5l=hround 1.5u; x2-x1=x3-x2=x4-x3=x5-x4;
72 bot y1=bot y4l=vround(.75[.62x_height,h]-vair);
73 top y2r=top y5=h; y3=.5[y2,y4];
74 filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
75 penlabels(1,2,3,4,5); endchar;
76
77 cmchar "Polish hook accent";
78 beginchar(oct"176",8u#,0,.875desc_depth#);
79 adjust_fit(0,0);
80 x1=.5w+.5u;
81 if serifs: pickup crisp.nib; pos1(stem,0); pos2(stem,0);
82 pos3(vair,90); pos4(stem,0); pos5(vair,-90);
83 x1=x2; z3l=z2l; x4=x2+1.5u; x5=x3-1.5u;
84 bot y1=-o; bot y2=-vround 2/7d-o; y4=.5[y3,y5]; bot y5=-d-o;
85 filldraw stroke z1e--z2e; % stem
86 filldraw stroke z3e{right}...z4e{down}...{left}z5e; % hook
87 else: pickup fine.nib; pos1(vair,0); top y1=-o-2;
88 pos2(.5[vair,stem],0); bot y2=-d-o; x2=x1-1.25u;
89 filldraw stroke z1e--z2e; fi % diagonal
90 currentpicture:= currentpicture reflectedabout((.5w,0),(.5w,d));
91 penlabels(1,2,3,4,5); endchar;
92
93 cmchar "Half-length Mark";
94 beginchar(oct"160",5.8u#,x_height#,0);
95 adjust_fit(0,0); pickup rule.nib;
96 lft x1=hround 1.1u; x2=w-x1; x3=.5w;
97 y2=good.y h+o=y1; bot y3=.57h;
98 filldraw z1---z2---z3---cycle; % triangle
99 labels(1,2,3); endchar;
100
101 cmchar "Length Mark";
102 beginchar(oct"161",5.8u#,x_height#,0);
103 adjust_fit(0,0); pickup rule.nib;
104 lft x1=hround 1.1u=lft x5; x2=w-x1=x6; x3=.5w=x4;
105 top y4=vround .43h; y5=y6=0;
106 y2=good.y h+o=y1; bot y3=.57h;
107 filldraw z1---z2---z3---cycle; % triangle
108 filldraw z4---z5---z6---cycle; % triangle
109 labels(1,2,3,4,5,6); endchar;
110
111 cmchar "Subscript Bridge";
112 beginchar(oct"147",7u#,0,1.1desc_depth#);
113 adjust_fit(0,0); pickup light_rule.nib;
114 lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
115 y2=good.y -.3d-o; bot y1=-d; y4=y2; y5=y1;
116 draw z2---z1; % stems and bar
117 draw z2---z4;
118 draw z5---z4; % stems and bar
119 labels(1,2,4,5); endchar;
120
121 cmchar "Under-ring";
122 beginchar(oct"171",13u#+4/3(asc_height#-x_height#)*slant,0,1.3desc_depth#);
123 adjust_fit(cap_serif_fit#,cap_serif_fit#);
124 numeric circ_hair,circ_vair;
125 circ_hair=hround min(hair,u+.5);
126 circ_vair=vround min(vair,(-d-x_height)/6+.5);
127 penpos1(vair,90); penpos3(vair,-90);
128 penpos2(hair,180); penpos4(hair,0);
129 x2r=hround(.5w-1.5u-.5hair);
130 x4r=w-x2r; x1=x3=.5w; y1r=-.2d-apex_o; y2=y4=.5[y1,y3];
131 y3r=vround(-d-apex_o);
132 penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
133 & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle; % bowl
134 penlabels(1,2,3,4); endchar;
135
136 cmchar "Subscript Umlaut (double dot) accent";
137 numeric dot_diam#,dot_diam;
138 dot_diam#=max(dot_size#,cap_curve#);
139 beginchar(oct"162",9u#,0,min(desc_depth#,10/7x_height#+.5dot_diam#));
140 dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
141 italcorr h#*slant+.5dot_diam#-2.25u#;
142 adjust_fit(0,0);
143 pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
144 x1=x2=2.75u; top y2r=-.3d-1;
145 if bot y2l<-desc_depth-o-slab:
146 y2l:=min(y2r-eps,-desc_depth-o-slab+.5tiny); fi
147 y1=.5[y2l,y2r]; dot(1,2); % left dot
148 pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
149 dot(3,4); % right dot
150 penlabels(1,2,3,4); endchar;
151
152 cmchar "Subscript Left Half-ring";
153 beginchar(oct"172",13u#+4/3(asc_height#-x_height#)*slant,0,1.2desc_depth#);
154 adjust_fit(cap_serif_fit#,cap_serif_fit#);
155 penpos1(cap_hair+stem_corr,90); penpos3(cap_hair+stem_corr,-90);
156 penpos2(cap_hair+stem_corr,180);
157 x2r=hround(.5w-1.5u-.5hair);
158 x1=x3=.58w; top y1r=-.15d-apex_o; y2=.5[y1,y3];
159 y3r=vround(-d-apex_o);
160 %penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3); % bowl
161 penstroke z1e{left}...{down}z2e{down}...{right}z3e;
162 penlabels(1,2,3); endchar;
163
164 cmchar "Under tilde (squiggle) accent";
165 beginchar(oct"174",12u#,0, 1.1desc_depth#);
166 italcorr d#*slant-u#;
167 adjust_fit(0,0);
168 if serifs: numeric theta;
169 theta=angle(1/6(8u-vair),1/3(h+desc_depth));
170 pickup crisp.nib; numeric mid_width; mid_width=.4[vair,stem];
171 pos1(vair,theta+90); pos2(vair,theta+90);
172 pos3(vair,theta+90); pos4(vair,theta+90);
173 z2-z1=z4-z3=(mid_width-crisp)*dir theta;
174 lft x1r=w-rt x4l=hround 1.5u; top y4r=-.3d+vair;
175 bot y1l=vround(bot y1l+min(.4[-d,-.15d],y3l-.35vair)-top y1r);
176 pair delta; ypart delta=3(y3l-y1l); delta=whatever*dir theta;
177 filldraw z1l..controls(z1l+delta)and(z3l-delta)..z3l..z4l
178 --z4r..controls(z4r-delta)and(z2r+delta)..z2r..z1r--cycle; % stroke
179 else: pickup fine.nib; pos1(vair,180); pos2(vair,90);
180 pos3(.5[vair,slab],90); pos4(vair,90); pos5(vair,180);
181 lft x1r=w-rt x5l=hround 1.5u; x2-x1=x3-x2=x4-x3=x5-x4;
182 bot y1=bot y4l=vround(-.76d-vair);
183 top y2r=top y5=-.2d; y3=.5[y2,y4];
184 filldraw stroke z1e{up}...z2e{right}..z3e..{right}z4e...{up}z5e; fi % stroke
185 penlabels(1,2,3,4,5); endchar;
186
187 cmchar "Subscript Hachek (check) accent";
188 beginchar(oct"175",9u#,0,desc_depth#);
189 h':=vround -d; % height of circumflex being inverted
190 if serifs: italcorr h#*slant+.5hair#-1.75u#;
191 adjust_fit(0,0);
192 pickup crisp.nib; pos2'(.4[vair,curve],90); top y2'r=h;
193 pos2(.4[vair,curve],90); x2=.5w;
194 x1=w-x3=good.x 2.25u; top y1=top y3=-.2d; y1-y2=-.5(y2'-d);
195 pos1(hair,angle(z2-z1)+90); pos3(hair,angle(z3-z2)+90);
196 filldraw stroke z1e--z2e--z3e; % diagonals
197 else: italcorr h#*slant-.5stem#+.5vair#-.75u#;
198 adjust_fit(0,0);
199 pickup fine.nib; pos1(vair,0); pos3(vair,0); x1=w-x3;
200 pos2(stem,0); bot y2=vround(1/12[-d,h']+o); x2=.5w;
201 top y1=top y3=-.1d+o; lft x1l=hround(rt x2r-3.25u-.5vair);
202 z0=whatever[z1r,z2r]=whatever[z2l,z3l];
203 y4l=y4r=y2; x4l=good.x .2[x2l,x2]; x4r=w-x4l;
204 filldraw z4l--z1l--z1r--z0--z3l--z3r--z4r--cycle; fi % diagonals
205 penlabels(0,1,2,3,4); endchar;
206
207
208 cmchar "subscript arch (inverted breve)";
209 beginchar(oct"177",9u#,0,desc_depth#);
210 italcorr h#*slant+.5vair#-1.5u#;
211 adjust_fit(0,0);
212 pickup crisp.nib; pos1(vair,-180); pos3(vair,0);
213 top y1=top y3=-d; lft x1r=w-rt x3r=hround(2u-.5vair);
214 numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
215 pos2(mid_thickness,90); x2=.5w;
216 top y2r=vround max(-.15d-o-tiny,-.68mid_thickness);
217 filldraw stroke z1e{up}...z2e{right}...{down}z3e; % stroke
218 penlabels(1,2,3); endchar;
219
220 cmchar "Vertical Stroke (superior)";
221 beginchar(oct"150",4u#,asc_height#,0); pickup rule.nib;
222 x1=x2=good.x .5w; top y1=h+eps; bot y2=x_height-eps;
223 draw z1--z2; % stem
224 labels(1,2); endchar;
225
226 cmchar "Vertical Stroke (inferior)";
227 beginchar(oct"151",4u#,.25x_height#,desc_depth#); pickup rule.nib;
228 x1=x2=good.x .5w; top y1=h+eps; bot y2=-d-eps;
229 draw z1--z2; % stem
230 labels(1,2); endchar;
231
232 cmchar "Syllabicity Mark";
233 beginchar(oct"152",4u#,0,1.4desc_depth#); pickup rule.nib;
234 x1=x2=good.x .5w; top y1=0-eps; bot y2=-d;
235 draw z1--z2; % stem
236 labels(1,2); endchar;
237
238 cmchar "left pointer";
239 beginchar(oct"166",8.2u#,asc_height#,0);
240 italcorr h#*slant-u#;
241 adjust_fit(0,0); pickup rule.nib;
242 lft x2=hround 1.5u-eps; x1=x3=w-x2;
243 y1=h; y3=.7h;
244 y2=.5[y1,y3];
245 draw z1--z2--z3; % diagonals
246 labels(1,2,3); endchar;
247
248 cmchar "right pointer";
249 beginchar(oct"167",8.2u#,asc_height#,0);
250 adjust_fit(0,0); pickup rule.nib;
251 rt x2=hround(w-1.5u)+eps; x1=x3=w-x2;
252 y1=h; y3=.7h;
253 y2=.5[y1,y3];
254 draw z1--z2--z3; % diagonals
255 labels(1,2,3); endchar;
256
257 cmchar "down pointer";
258 beginchar(oct"165",8.2u#,asc_height#,0);
259 adjust_fit(0,0); pickup rule.nib;
260 lft x1=hround 1.5u-eps; x3=w-x1;
261 x2=.5[x1,x3];
262 y1=asc_height=y3; y2=1.1x_height;
263 draw z1--z2--z3; % diagonals
264 labels(1,2,3); endchar;
265
266 cmchar "up pointer";
267 beginchar(oct"164",8.2u#,asc_height#,0);
268 adjust_fit(0,0); pickup rule.nib;
269 lft x1=hround 1.5u-eps; x3=w-x1;
270 x2=.5[x1,x3];
271 y1=1.1x_height=y3; y2=asc_height;
272 draw z1--z2--z3; % diagonals
273 labels(1,2,3); endchar;
274
275 cmchar "Bar down sign";
276 beginchar(oct"155",8u#,x_height#,0); pickup rule.nib;
277 x1=x2=.5w;
278 lft x3=hround 0+eps; x4=w-x3; top y1=top y3=top y4=h-stem_corr;
279 bot y2=0+u;
280 draw z1--z2; % stem
281 draw z3--z4; % crossbar
282 labels(1,2,3,4); endchar;
283
284 cmchar "Bar up sign";
285 beginchar(oct"154",8u#,x_height#,0); pickup rule.nib;
286 x1=x2=good.x .5w; top y1=h-stem_corr;
287 lft x3=hround 0+eps; x4=w-x3; bot y2=bot y3=bot y4=0+u;
288 draw z1--z2; % stem
289 draw z3--z4; % crossbar
290 labels(1,2,3,4); endchar;
291
292
293 cmchar "Bar right sign";
294 beginchar(oct"157",8u#,x_height#,0); pickup rule.nib;
295 lft x1=lft x2=hround 0+eps=lft x3; top y1=h-stem_corr;
296 x4=w-x1; bot y2= u; y3=.5[y1,y2]=y4;
297 draw z1--z2; % stem
298 draw z3--z4; % crossbar
299 labels(1,2,3,4); endchar;
300
301 cmchar "Bar Left sign";
302 beginchar(oct"156",8u#,x_height#,0); pickup rule.nib;
303 x1=x2=w-x4=x3; top y1=h-stem_corr;
304 lft x4=hround 0+eps; bot y2=u;
305 y3=.5[y1,y2]=y4;
306 draw z1--z2; % stem
307 draw z3--z4; % crossbar
308 labels(1,2,3,4); endchar;